Writing function in excel

Is this article up to date?

In this tutorial we will learn about Excel VBA function

1) What is Visual Basic in Excel?

2) How to use VBA in Excel?

3) How to create User defined function?

4) How to write Macro?

How to write VBA code

Excel provides the user with a large collection of ready-made functions, more than enough to satisfy the average user. Many more can be added by installing the various add-ins that are available. Most calculations can be achieved with what is provided, but it isn’t long before you find yourself wishing that there was a function that did a particular job, and you can’t find anything suitable in the list. You need a UDF. A UDF (User Defined Function) is simply a function that you create yourself with VBA. UDFs are often called «Custom Functions». A UDF can remain in a code module attached to a workbook, in which case it will always be available when that workbook is open. Alternatively you can create your own add-in containing one or more functions that you can install into Excel just like a commercial add-in. UDFs can be accessed by code modules too. Often UDFs are created by developers to work solely within the code of a VBA procedure and the user is never aware of their existence. Like any function, the UDF can be as simple or as complex as you want. Let’s start with an easy one…

A Function to Calculate the Area of a Rectangle

Yes, I know you could do this in your head! The concept is very simple so you can concentrate on the technique. Suppose you need a function to calculate the area of a rectangle. You look through Excel’s collection of functions, but there isn’t one suitable. This is the calculation to be done:

AREA = LENGTH x WIDTH

Open a new workbook and then open the Visual Basic Editor (Tools > Macro > Visual Basic Editor or ALT+F11).

You will need a module in which to write your function so choose Insert > Module. Into the empty module type: Function Area and press ENTER.The Visual Basic Editor completes the line for you and adds an End Function line as if you were creating a subroutine.So far it looks like this…

Function Area()

End Function

Place your cursor between the brackets after «Area». If you ever wondered what the brackets are for, you are about to find out! We are going to specify the «arguments» that our function will take (an argument is a piece of information needed to do the calculation). Type Length as double, Width as double and click in the empty line underneath. Note that as you type, a scroll box pops-up listing all the things appropriate to what you are typing.

This feature is called Auto List Members. If it doesn’t appear either it is switched off (turn it on at Tools > Options > Editor) or you might have made a typing error earlier. It is a very useful check on your syntax. Find the item you need and double-click it to insert it into your code. You can ignore it and just type if you want. Your code now looks like this…

Function Area(Length As Double, Width As Double)

End Function

Declaring the data type of the arguments is not obligatory but makes sense. You could have typed Length, Width and left it as that, but warning Excel what data type to expect helps your code run more quickly and picks up errors in input. The double data type refers to number (which can be very large) and allows fractions. Now for the calculation itself. In the empty line first press the TAB key to indent your code (making it easier to read) and type Area = Length * Width. Here’s the completed code…

Function Area(Length As Double, Width As Double)
    Area = Length * Width
End Function

You will notice another of the Visual Basic Editor’s help features pop up as you were typing, Auto Quick Info…

It isn’t relevant here. Its purpose is to help you write functions in VBA, by telling you what arguments are required. You can test your function right away. Switch to the Excel window and enter figures for Length and Width in separate cells. In a third cell enter your function as if it were one of the built-in ones. In this example cell A1 contains the length (17) and cell B1 the width (6.5). In C1 I typed =area(A1,B1) and the new function calculated the area (110.5)…

Sometimes, a function’s arguments can be optional. In this example we could make the Width argument optional. Supposing the rectangle happens to be a square with Length and Width equal. To save the user having to enter two arguments we could let them enter just the Length and have the function use that value twice (i.e. multiply Length x Length). So the function knows when it can do this we must include an IF Statement to help it decide. Change the code so that it looks like this…

Function Area(Length As Double, Optional Width As Variant)
    If IsMissing(Width) Then
        Area = Length * Length
    Else
        Area = Length * Width
    End If
End Function

Note that the data type for Width has been changed to Variant to allow for null values. The function now allows the user to enter just one argument e.g. =area(A1).The IF Statement in the function checks to see if the Width argument has been supplied and calculates accordingly…

A Function to Calculate Fuel Consumption

I like to keep a check on my car’s fuel consumption so when I buy fuel I make a note of the mileage and how much fuel it takes to fill the tank. Here in the UK fuel is sold in litres. The car’s milometer (OK, so it’s an odometer) records distance in miles. And because I’m too old and stupid to change, I only understand MPG (miles per gallon). Now if you think that’s all a bit sad, how about this. When I get home I open up Excel and enter the data into a worksheet that calculates the MPG for me and charts the car’s performance. The calculation is the number of miles the car has travelled since the last fill-up divided by the number of gallons of fuel used…

MPG = (MILES THIS FILL — MILES LAST FILL) / GALLONS OF FUEL

but because the fuel comes in litres and there are 4.546 litres in a gallon..

MPG = (MILES THIS FILL — MILES LAST FILL) / LITRES OF FUEL x 4.546

Here’s how I wrote the function…

Function MPG(StartMiles As Integer, FinishMiles As Integer, Litres As Single)
    MPG = (FinishMiles - StartMiles) / Litres * 4.546
End Function

and here’s how it looks on the worksheet…

Not all functions perform mathematical calculations. Here’s one that provides information…

A Function That Gives the Name of the Day

I am often asked if there is a date function that gives the day of the week as text (e.g. Monday). The answer is no*, but it’s quite easy to create one. (*Addendum: Did I say no? Check the note below to see the function I forgot!). Excel has the WEEKDAY function, which returns the day of the week as a number from 1 to 7. You get to choose which day is 1 if you don’t like the default (Sunday). In the example below the function returns «5» which I happen to know means «Thursday».

But I don’t want to see a number, I want to see «Thursday». I could modify the calculation by adding a VLOOKUP function that referred to a table somewhere containing a list of numbers and a corresponding list of day names. Or I could have the whole thing self-contained with multiple nested IF statements. Too complicated! The answer is a custom function…

Function DayName(InputDate As Date)
    Dim DayNumber As Integer
    DayNumber = Weekday(InputDate, vbSunday)
    Select Case DayNumber
        Case 1
            DayName = "Sunday"
        Case 2
            DayName = "Monday"
        Case 3
            DayName = "Tuesday"
        Case 4
            DayName = "Wednesday"
        Case 5
            DayName = "Thursday"
        Case 6
            DayName = "Friday"
        Case 7
            DayName = "Saturday"
    End Select
End Function

I’ve called my function «DayName» and it takes a single argument, which I call «InputDate» which (of course) has to be a date. Here’s how it works…

• The first line of the function declares a variable that I have called «DayNumber» which will be an Integer (i.e. a whole number).
• The next line of the function assigns a value to that variable using Excel’s WEEKDAY function. The value will be a number between 1 and 7. Although the default is 1=Sunday, I’ve included it anyway for clarity.
• Finally a Case Statement examines the value of the variable and returns the appropriate piece of text.

Here’s how it looks on the worksheet…

Accessing Your Custom Functions

If a workbook has a VBA code module attached to it that contains custom functions, those functions can be easily addressed within the same workbook as demonstrated in the examples above. You use the function name as if it were one of Excel’s built-in functions.

You can also find the functions listed in the Function Wizard (sometimes called the Paste Function tool). Use the wizard to insert a function in the normal way (Insert > Function).

Scroll down the list of function categories to find User Defined and select it to see a list of available UDFs…

You can see that the user defined functions lack any description other than the unhelpful «No help available» message, but you can add a short description…

Make sure you are in the workbook that contains the functions. Go to Tools > Macro > Macros. You won’t see your functions listed here but Excel knows about them! In the Macro Name box at the top of the dialog, type the name of the function, then click the dialog’s Options button. If the button is greyed out either you’ve spelled the function name wrong, or you are in the wrong workbook, or it doesn’t exist! This opens another dialog into which you can enter a short description of the function. Click OK to save the description and (here’s the confusing bit) click Cancel to close the Macro dialog box. Remember to Save the workbook containing the function. Next time you go to the Function Wizard your UDF will have a description…

Like macros, user defined functions can be used in any other workbook as long as the workbook containing them is open. However it is not good practice to do this. Entering the function in a different workbook is not simple. You have to add its host workbook’s name to the function name. This isn’t difficult if you rely on the Function Wizard, but clumsy to write out manually. The Function Wizard shows the full names of any UDFs in other workbooks…

If you open the workbook in which you used the function at a time when the workbook containing the function is closed, you will see an error message in the cell in which you used the function. Excel has forgotten about it! Open the function’s host workbook, recalculate, and all is fine again. Fortunately there is a better way.

If you want to write User Defined Functions for use in more than one workbook the best method is to create an Excel Add-In. Find out how to do this in the tutorial Build an Excel Add-In.

Addendum

I really ought to know better! Never, ever, say never! Having told you that there isn’t a function that provides the day’s name, I have now remembered the one that can. Look at this example…

The TEXT function returns the value of a cell as text in a specific number format. So in the example I could have chosen =TEXT(A1,»ddd») to return «Thu», =TEXT(A1,»mmmm») to return «September» etc. The Excel’s help has some more examples of ways to use this function.

If you liked our blogs, share it with your friends on Facebook. And also you can follow us on Twitter and Facebook.
We would love to hear from you, do let us know how we can improve, complement or innovate our work and make it better for you. Write us at info@exceltip.com

Microsoft Excel’s table structure is a great way to keep organized. But the program is much more than just a series of rows and columns into which you can enter data.

Excel really becomes powerful once you start using functions, which are mathematical formulas that help you quickly and easily make calculations that would be difficult to do by hand.

Functions can do many things to speed up your calculations. For example, you could use functions to take the sum of a row or column of data; find the average of a series of numbers; output the current date; find the number of orders placed by a particular customer within a given period of time; look up the e-mail address of a customer based on his or her name; and much more. It’s all automatic — no manual entry required.

Let’s take a closer look at functions to see how they work.

The structure of a function

Think of a function like a recipe: you put together a series of ingredients, and the recipe spits out something totally new and different (and, in most cases, more useful, or delicious, than the thing that you put in). Like recipes, functions have three key pieces that you should keep track of:

• First, there’s the function name. This is just like the recipe name that you would see at the top of one of the pages of your cookbook. It is a unique identifier that tells Excel what we are trying to cook up.
• Next, there are arguments. Arguments are just like the ingredients of a recipe. They’re pieces that you put in that will eventually combine to make something bigger.
• Finally, there’s the output. The output of a function is just like the output of a recipe — it’s the final product that is ready to be presented to the user (or, in the case of a recipe, eaten).

Writing a function in Excel

When we enter functions into Excel, we use a special character to tell the program that what we are entering is a function and not a normal block of text: the equals sign (=). Whenever Excel sees the = sign at the beginning of the input to a cell, it recognizes that we are about to feed it a function.

The basic structure of a function is as follows:

=FUNCTION_NAME(argument_1, argument_2, argument_3...)
Output: Output

After the = sign, we write the name of the function to tell Excel which recipe we want to use. Then, we use the open parentheses sign (() to tell the program that we’re about to give it a list of arguments.

We then list the arguments to the function, one by one, separated by commas, to tell Excel what ingredients we are using. Note that just like recipes, each function has its own specific number of arguments that it needs to receive. Some just take one argument; others take two or even more.

To finish writing a function, wrap up the list of arguments with the close parentheses sign ()) to tell Excel that you’re done writing the list of ingredients. Then press the Enter key to complete your entry. You’ll see that rather than displaying the text that you entered, Excel shows the output of your completed function.

A practical example

Let’s look at a practical example using the SUM function. This is one of Excel’s most-used recipes — it takes any number of arguments (all of which should be numerical), and spits out the sum of those arguments. The formula for SUM is as follows:

=SUM(number_1, number_2...)

To recap: the name of the function is SUM. The arguments are number_1, number_2, and as many additional numbers as you want to put in (this particular function takes an unlimited number of arguments, just like a recipe that gets better and better as you throw in more ingredients). When you’re done writing the function and press Enter, Excel will show you the output.

Try entering the following into a cell on a blank spreadsheet:

=SUM(3, 7)
Output: 10

Excel outputs 10, because the SUM of 3 and 7 is 10.

Here’s another example with even more arguments:

=SUM(1, 2, 3, 4, 5)
Output: 15

Here, Excel outputs 15, the SUM of 1, 2, 3, 4, and 5.

Infinite arguments and optional arguments

Throughout these pages, we’ll use a couple different types of notation to denote special cases within functions:

First, some functions, like SUM above, have a theoretically infinite number of arguments. For example, you can take the SUM of an infinite number of numerals. In cases like this, we use three dots (…) to denote an infinite number of additional arguments, like so:

=FUNCTION_NAME(argument_1, argument_2, argument_3...)

If a function has a finite number of arguments, you won’t see that … at the end, like this:

=FUNCTION_NAME(argument_1, argument_2)

Finally, some arguments to functions are optional, just like some ingredients of a recipe might be optional. If one or more arguments of a function are optional, we’ll follow them up with an (optional) designator like so:

=FUNCTION_NAME(argument_1, argument_2 (optional))

In most of our function tutorials, we’ll explain why something is optional and how you can use it.

That’s it! Now that you know what a function is, check out our tutorials on some of Excel’s logical functions to get rolling with Excel’s most powerful tool.

Comments

Excel allows you to create custom functions using VBA, called «User Defined Functions» (UDFs) that can be used the same way you would use SUM() or other built-in Excel functions. They can be especially useful for advanced mathematics or special text manipulation or date calculations prior to 1900. Many Excel add-ins provide large collections of specialized functions.

This article will help you get started creating user defined functions with a few useful examples.

NOTE: The new LAMBDA Function, available within «Production: Current Channel builds of Excel» is going to revolutionize how custom functions can be used in Excel without VBA.

Watch the Video

How to Create a Custom User Defined Function

1. Open a new Excel workbook.
2. Get into VBA (Press Alt+F11)
3. Insert a new module (Insert > Module)
4. Copy and Paste the Excel user defined function examples
5. Get out of VBA (Press Alt+Q)
6. Use the functions — They will appear in the Paste Function dialog box (Shift+F3) under the «User Defined» category

If you want to use a UDF in more than one workbook, you can save your functions to your personal.xlsb workbook or save them in your own custom add-in. To create an add-in, save your excel file that contains your VBA functions as an add-in file (.xla for Excel 2003 or .xlam for Excel 2007+). Then load the add-in (Tools > Add-Ins… for Excel 2003 or Developer > Excel Add-Ins for Excel 2010+).

Warning! Be careful about using custom functions in spreadsheets that you need to share with others. If they don’t have your add-in, the functions will not work when they use the spreadsheet.

Benefits of User Defined Excel Functions

• Create a complex or custom math function.
• Simplify formulas that would otherwise be extremely long «mega formulas».
• Diagnostics such as checking cell formats.
• Custom text manipulation.
• Advanced array formulas and matrix functions.
• Date calculations prior to 1900 using the built-in VBA date functions.

Limitations of UDF’s

• Cannot «record» an Excel UDF like you can an Excel macro.
• More limited than regular VBA macros. UDF’s cannot alter the structure or format of a worksheet or cell.
• If you call another function or macro from a UDF, the other macro is under the same limitations as the UDF.
• Cannot place a value in a cell other than the cell (or range) containing the formula. In other words, UDF’s are meant to be used as «formulas», not necessarily «macros».
• Excel user defined functions in VBA are usually much slower than functions compiled in C++ or FORTRAN.
• Often difficult to track errors.
• If you create an add-in containing your UDF’s, you may forget that you have used a custom function, making the file less sharable.
• Adding user defined functions to your workbook will trigger the «macro» flag (a security issue: Tools > Macros > Security…).

User Defined Function Examples

To see the following examples in action, download the file below. This file contains the VBA custom functions, so after opening it you will need to enable macros.

Download the Example File (CustomFunctions.xlsm)

Example #1: Get the Address of a Hyperlink

The following example can be useful when extracting hyperlinks from tables of links that have been copied into Excel, when doing post-processing on Excel web queries, or getting the email address from a list of «mailto:» hyperlinks.

This function is also an example of how to use an optional Excel UDF argument. The syntax for this custom Excel function is:

=LinkAddress(cell,[default_value])

To see an example of how to work with optional arguments, look up the IsMissing command in Excel’s VBA help files (F1).

Function LinkAddress(cell As range, _ 
                     Optional default_value As Variant) 
  'Lists the Hyperlink Address for a Given Cell 
  'If cell does not contain a hyperlink, return default_value 
  If (cell.range("A1").Hyperlinks.Count <> 1) Then 
      LinkAddress = default_value 
  Else 
      LinkAddress = cell.range("A1").Hyperlinks(1).Address 
  End If 
End Function

Example #2: Extract the Nth Element From a String

This example shows how to take advantage of some functions available in VBA to do some slick text manipulation. What if you had a bunch of telephone numbers in the following format: 1-800-999-9999 and you wanted to pull out just the 3-digit prefix?

This UDF takes as arguments the text string, the number of the element you want to grab (n), and the delimiter as a string (eg. «-«). The syntax for this example user defined function in Excel is:

=GetElement(text,n,delimiter)

Example: If B3 contains «1-800-333-4444″, and cell C3 contains the formula, =GetElement(B3,3,»-«), C3 will then equal «333». To turn the «333» into a number, you would use =VALUE(GetElement(B3,3,»-«)).

Function GetElement(text As Variant, n As Integer, _ 
                    delimiter As String) As String 
    GetElement = Split(text, delimiter)(n - 1)
End Function

Example #3: Return the name of a month

The following function is based on the built-in visual basic MonthName() function and returns the full name of the month given the month number. If the second argument is TRUE, it will return the abbreviation.

=VBA_MonthName(month,boolean_abbreviate)

Example: =VBA_MonthName(3) will return «March» and =VBA_MonthName(3,TRUE) will return «Mar.»

Function VBA_MonthName(themonth As Long, _
   		Optional abbreviate As Boolean) As Variant 
    VBA_MonthName = MonthName(themonth, abbreviate)
End Function

Example #4: Calculate Age for Years Prior to 1900

The Excel function DATEDIF(start_date,end_date,»y») is a very simple way to calculate the age of a person if the dates are after 1/1/1900. The VBA date functions like Year(), Month(), Day(), DateSerial(), DateValue() are able to handle all the Gregorian dates, so custom functions based on the VBA functions can allow you to work with dates prior to 1900. The function below is designed to work like DATEDIF(start_date,end_date,»y») as long as end_date >= start_date.

=AgeInYears(start_date,end_date)

Example: =AgeInYears(«10-Oct-1850″,»5-Jan-1910») returns the value 59.

Function AgeInYears(start_date As Variant, end_date As Variant) As Variant 
    AgeInYears = Year(end_date) - Year(start_date) - _
    Abs(DateSerial(Year(end_date), Month(start_date), _
    Day(start_date)) > DateValue(end_date))
End Function

More Custom Excel Function Examples