What is the function of filter in excel

The FILTER function «filters» a range of data based on supplied criteria. The result is an array of matching values from the original range. In plain language, the FILTER function will extract matching records from a set of data by applying one or more logical tests. Logical tests are supplied as the include argument and can include many kinds of formula criteria. For example, FILTER can match data in a certain year or month, data that contains specific text, or values greater than a certain threshold.

The FILTER function takes three arguments: array, include, and if_empty. Array is the range or array to filter. The include argument should consist of one or more logical tests. These tests should return TRUE or FALSE based on the evaluation of values from array. The last argument, if_empty, is the result to return when FILTER finds no matching values. Typically this is a message like «No records found», but other values can be returned as well. Supply an empty string («») to display nothing.

The results from FILTER are dynamic. When values in the source data change, or the source data array is resized, the results from FILTER will update automatically. Results from FILTER will «spill» onto the worksheet into multiple cells.

Basic example

To extract values in A1:A10 that are greater than 100:

=FILTER(A1:A10,A1:A10>100)

To extract rows in A1:C5 where the value in A1:A5 is greater than 100:

=FILTER(A1:C5,A1:A5>100)

Notice the only difference in the above formulas is that the second formula provides a multi-column range for array. The logical test used for the include argument is the same.

Note: FILTER will return a #CALC! error if no matching data is found

Filter for Red group

In the example shown above, the formula in F5 is:

=FILTER(B5:D14,D5:D14=H2,"No results")

Since the value in H2 is «red», the FILTER function extracts data from array where the Group column contains «red». All matching records are returned to the worksheet starting from cell F5, where the formula exists.

Values can be hardcoded as well. The formula below has the same result as above with «red» hardcoded into the criteria:

=FILTER(B5:D14,D5:D14="red","No results")

No matching data

The value for is_empty is returned when FILTER does not find matching results. If a value for if_empty is not provided, FILTER will return a #CALC! error if no matching data is found:

=FILTER(range,logic) // #CALC! error

Often, is_empty is configured to provide a text message to the user:

=FILTER(range,logic,"No results") // display message

To display nothing when no matching data is found, supply an empty string («») for if_empty:

=FILTER(range,logic,"") // display nothing

Values that contain text

To extract data based on a logical test for values that contain specific text, you can use a formula like this:

=FILTER(rng1,ISNUMBER(SEARCH("txt",rng2)))

In this formula, the SEARCH function is used to look for «txt» in rng2, which would typically be a column in rng1. The ISNUMBER function is used to convert the result from SEARCH into TRUE or FALSE. Read a full explanation here.

Filter by date

FILTER can be used with dates by constructing logical tests appropriate for Excel dates. For example, to extract records from rng1 where the date in rng2 is in July you can use a generic formula like this:

=FILTER(rng1,MONTH(rng2)=7,"No data") 

This formula relies on the MONTH function to compare the month of dates in rng2 to 7.  See full explanation here.

Multiple criteria

At first glance, it’s not obvious how to apply multiple criteria with the FILTER function. Unlike older functions like COUNTIFS and SUMIFS, which provide multiple arguments for entering multiple conditions, the FILTER function only provides a single argument, include, to target data. The trick is to create logical expressions that use Boolean algebra to target the data of interest and supply these expressions as the include argument. For example, to extract only data where one value is «A» and another is greater than 80, you can use a formula like this:

=FILTER(range,(range="A")*(range>80),"No data")

The math operation of addition (*) joins the two conditions with AND logic: both conditions must be TRUE in order for FILTER to retrieve the data. See a detailed explanation here.

Complex criteria

To filter and extract data based on multiple complex criteria, you can use the FILTER function with a chain of expressions that use boolean logic. For example, the generic formula below filters based on three separate conditions: account begins with «x» AND region is «east», and month is NOT April.

=FILTER(data,(LEFT(account)="x")*(region="east")*NOT(MONTH(date)=4))

See this page for a full explanation. Building criteria with logical expressions is an elegant and flexible approach that can be extended to handle many complex scenarios. See below for more examples.

Notes

1. FILTER can work with both vertical and horizontal arrays.
2. The include argument must have dimensions compatible with the array argument, otherwise FILTER will return #VALUE!
3. If the include array includes any errors, FILTER will return an error.

The FILTER function is an Excel function that lets you fetch or «filter» a data set based on the criteria supplied via an argument. The FILTER function was introduced in Office 365 and will not be accessible in Office 2019 or earlier versions.

FILTER is an in-built worksheet function and belongs to Excel’s new Dynamic Arrays function category. The FILTER function returns an array of values that are spilled onto your worksheet unless the function is nested to relay the output to another function.

FILTER is a dynamic function. This means when you alter the values in the source data or resize the source data array, the Excel FILTER function will automatically update the returned values.

Syntax

The syntax of the Filter function is as follows:

=FILTER(array, include, [if_empty])

Arguments:

array – This is a required argument where you specify the range or array that you want to filter.
include – This is a required argument where you supply the filtering criteria as a Boolean array.
if_empty – This is an optional argument where you specify a value that the function should return if none of the entries meet the supplied criteria.

Important Characteristics of the FILTER function

• You can use the FILTER function for filtering both horizontal as well as vertical arrays.
• When you use the FILTER function between two separate workbooks, ensure that both of them are open. If they are not, the function will return a #REF! error.
• Since the FILTER function spills the output (assuming your data is so organized), ensure that you have sufficient empty cells to the right and below. If you do not, the function will return a #SPILL error.
• The FILTER function returns a #VALUE! error if the dimensions supplied in the include argument are incompatible with the array argument.
• The FILTER function was introduced in Office 365 and is not available in Office 2019 or earlier version.

Examples of the FILTER function

Let’s have a look at the examples of the FILTER function:

Example 1 – Plain-vanilla Version of the Filter function

Suppose we want a list of students that have Grade «A» in the data set.

In order to do this, we will input the entire data set, i.e., A2:C16, in the array argument.

In the include argument, we will input C2:C16=»A» which will produce a Boolean array that assigns TRUE for all ‘A’s.

The last argument (if_empty) is an optional string where you will let the formula know what it should return if it does not find any values. In our case, we use a text string «No matches», but you could also have the formula return nothing by passing an empty string («»).

So the final formula would be –

=FILTER(A2:C16,C2:C16="A","No matches")

If you prefer, you could also have a cell reference instead of adding a character or a text string in the include argument. For example, let’s say you write «A» in cell G6 and then input the include argument as C3:C17=G6.

So the formula would be –

=FILTER(A2:C17,C2:C17=G6,"No matches")

The FILTER function will also work smoothly for horizontally organized data sets. Just ensure that the width of ranges defined in the array and include arguments are the same.

Also, in case of no matching records the formula, returns the string no match as shown.

Since none of the students in the above dataset has Grade «D», the result is the «No matches» string.

Example 2 – FILTER function Used in Combination With the EXACT function

Nesting the EXACT function inside the FILTER function enables you to fetch an exact, case-sensitive match.

=FILTER(A2:C16,EXACT(A2:A16,"Bing"),"No matches")

The EXACT function has a simple role here and works as the include argument in the FILTER function. EXACT returns TRUE for an exactly matching string and FALSE otherwise. As such, the EXACT function will return 15 Boolean values (for each cell in the B2:B16 range), which in our case will look something like this:

{FALSE; FALSE; FALSE; FALSE; TRUE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE; FALSE}

At position 5, «Bing» is the only match and hence returns TRUE.

This array is relayed to the FILTER function as the include argument. Next, FILTER uses the array returned by EXACT to return only those rows that contain the string «Bing» (i.e., rows that have been assigned a TRUE value by the EXACT function).

Note: Please note that we can also get to the same output by just adding the condition (A2:A16)=»Bing» in the include argument, but in that case, the search will be case-insensitive.

Example 3 – Filtering with Wildcards Using the FILTER function

Let’s discuss some big-boy formulas now. The FILTER function does not in itself support wildcard characters, but we can input a logical test in the include argument to get the output we want.

We will nest the ISNUMBER and SEARCH functions, like so:

=FILTER(A2:A16,ISNUMBER(SEARCH("G*",A2:A16)),"No matches")

Let’s walk through each component of the formula and see what role they play. We will work out the SEARCH function’s output first. The search function is looking for any string in column A that has the letter «G». We have 3 last names that contain a G – Bing, Geller, and Green. Remember, that search function only returns the position of the searched character.

Therefore, wherever the SEARCH function finds a G, it will return a number (i.e., the position of G), while for others, you will get a #VALUE! error. If you want to perform a case-sensitive SEARCH, you can replace the SEARCH function with the FIND function. Let’s replace the SEARCH function’s return in our formula:

=FILTER (A2:A16, ISNUMBER ({#VALUE!, #VALUE!, #VALUE!, #VALUE!, 4, 1, 1, #VALUE!, #VALUE!, #VALUE!, #VALUE!, #VALUE!, #VALUE!, #VALUE!, #VALUE!), "No matches")

Next, we have the ISNUMBER function. ISNUMBER function has a simple role to play. It will look at the SEARCH function’s return and assign TRUE for results that are a number and FALSE for results that are not a number (i.e., are a #VALUE! error in our case).

If you follow what is happening in the formula so far, the remaining part is a cakewalk. The ISNUMBER function relays this output (i.e., 3 TRUEs for the numbers and 12 FALSEs for the #VALUE! errors) to the FILTER function. The FILTER function will then let only those data points make it to the final output, for which the result was TRUE.

So, as our final output, we should have 3 names – Bing, Geller, and Green.

Example 4 – FILTER function With Multiple Criteria (AND/OR operator)

We have so far not used the Scores column from our data set. Let’s remedy that, shall we?

So, here we are trying to find the students who have Grade «A» and a score of above 100.

We will first use the AND criteria, with an asterisk (*). To do this, we will extend the include argument using Boolean logic, like so:

=FILTER(A2:C16,(C2:C16=G6)*(B2:B16>100),"No matches")

Using the ‘*’ multiplies the Boolean values, where True equals 1, and False equals 0. So, when the expressions inside the parentheses are multiplied in the formula, there are two possibilities:

• You get a FALSE (or a 0): If the expressions inside both the parentheses return False (0*0) or one of them returns FALSE (0*1).
• You get a TRUE (or a 1): If the expressions inside both the parentheses return TRUE (1*1).

Therefore, when the first parenthesis finds an A and returns TRUE and the second parenthesis finds the score to be greater than 100 and returns TRUE as well, we will have our return (or get the string «No matches»). Using logical expressions like this is an efficient approach to filter criteria.

Much the same way, we can use the OR criteria by using a plus (+) between two parentheses in the include argument, like so:

=FILTER(A2:C16,(C2:C16=G6)+(B2:B16>100),"No matches")

This will get us all the students who either have Grade «A» or scores greater than 100.

Similar to what we saw for the AND criteria, we can get two possible outcomes when Boolean values in the include argument are added:

• You get a FALSE (or a 0): If the expressions inside both parentheses return a FALSE (0+0).
• You get a TRUE (or a 1): If the expression inside one of the parenthesis returns a TRUE (0+1) or both parentheses return a TRUE (1+1).

Wait, if both parentheses return 1, it will add up to 2, right?

Fortunately, that does not matter. Excel will consider anything that is 0 as FALSE, anything that is not 0 as TRUE.

This is how you can incorporate the AND or OR criteria in your formulas.

Example 5 – Filtering Duplicates Using the FILTER and COUNTIFS functions

If your data set is massive, it is quite likely that you may need to deal with duplicates. When a data point has more than a single instance, we can filter the duplicate instances by using a nested formula, like so:

=FILTER(A2:C20,COUNTIFS(A2:A20,A2:A20,B2:B20,B2:B20,C2:C20,C2:C20)>1,"No matches")

Essentially, we are using the COUNTIFS function to count the instances of data points and extracting those data points that occur more than once. By nesting the COUNTIFS function in the include argument, you are instructing the FILTER formula to include only those results that occur more than once (>1).

You can add or remove the number of columns passed to the COUNTIFS function for filtering duplicate data based on your own requirements.

The FILTER function will spill the return with duplicate instances into a range of cells, as shown in the image.

Recommended Reading: How to find duplicates in excel

Example 6 – Filtering Blank Records Using the FILTER function

We will revisit what we learned in a previous example where we discussed the use of AND criteria using an ‘*’. We will use a <> operator (i.e., not equal to) inside the parenthesis to check if a cell has an empty string («»), like so:

=FILTER(A2:C16,(A2:A16<>"")*(B2:B16<>"")*(C2:C16<>""),"No matches")

Here, we are checking the data points contained in the A, B, and C columns and retrieving only those data points that have a value in all three columns. To do this, we instruct Excel to check for empty cells by defining a column and checking for empty cells by adding a ‘<>’ (not equal to) operator and an empty string («»). To add an AND criteria, we will use a ‘*’ between the parenthesis.

If a cell in any of those columns is empty, the return will exclude that particular row entirely.

Example 7 – FILTER function Used in Combination with SUM, MIN, MAX, and AVERAGE functions

The FILTER function packs in a punch. In addition to performing a whole list of tasks discussed above, it is also capable of summarizing the data it returns after filtering.

To accomplish this, we will use the aggregation family of functions – like SUM, MIN, MAX, and AVERAGE.

It is actually pretty straightforward. All we need to do is relay the return from the FILTER function to any of the mentioned aggregation functions, like so:

=SUM(FILTER(B2:B16,C2:C16="A",0)) //Sum of Grade A scores
=MIN(FILTER(B2:B16,C2:C16="A",0)) //Min of Grade A scores
=MAX(FILTER(B2:B16,C2:C16="A",0)) //Max of Grade A scores
=AVERAGE(FILTER(B2:B16,C2:C16="A",0)) //Average of Grade A scores

Here, the FILTER function will include all rows that have the letter «A» and return 0 for rows that do not match. It will then pick up the values that correspond to «A» from column B. These values will be handed over to the aggregation functions, giving us our final output.

Note: It is important to specify the if_empty argument as 0. Using a string like «No matches» will result in a #VALUE! error, since the aggregation functions cannot handle strings in case of non-matching records.

Example 8 – FILTER function to return Non-Adjacent Columns

Let’s say we want just the Name and Score columns of students with Grade «A». How must we explain to the FILTER function that we want just these two columns when they are non-contagious?

While there is no separate formula to do this, we can accomplish this by sprinkling some logic into the FILTER function. We will nest one FILTER formula inside another FILTER formula and use Boolean values in the include argument of the outer FILTER formula to exclude the Names column, like so:

=FILTER(FILTER(A2:C16,C2:C16="A"),{1,0,1})

Let’s put this formula in words.

The nested (inner) FILTER function is just a simple formula, which we are comfortable with by now.

So, let’s jump over to the outer FILTER function.

The nested FILTER function works as the outer FILTER function’s array argument, informing the outer FILTER function that this is where I want the returned values to come from. The include argument is where the magic happens. We use «1, 0, 1» (alternatively, we could use TRUE, FALSE, TRUE) and let the outer FILTER function know that we want to include only the first and third columns.

Simple, isn’t it?

I hope I unraveled all the mysteries surrounding the brand new FILTER function and covered a little more as well. Incorporate these formulas into your worksheets, and you will become a FILTER function ninja in no time. I will see you soon with another intriguing Excel function, until then… sayonara.

Last year, Microsoft announced the introduction of a new group of functions in Excel, known as dynamic array functions. One of these – the FILTER function – is possibly the best of the lot.

The FILTER function will filter a list and return the results that meet the criteria that you specify. This criteria can include multiple conditions and also AND/OR criteria.

Note: The dynamic array formulas are coming soon to Excel 365 subscribers only. Perpetual Excel 2019 license will not have dynamic arrays included.

What Makes this Function so Useful

The filter tool is one of the most useful features of Excel.

Sure, it may not be as flashy as Power Query, PivotTables and advanced formulas. But you watch Excel users at work, and everybody filters lists.

Well, we will now have filtering in the shape of a formula. Meaning it is automated, can return results to wherever you want them, and can be used in other formulas and Excel features.

Yes, you heard me right. The FILTER function could be used in a Data Validation rule or within a SUM function for a new and improved SUMIFS. Opportunities are boundless.

It can also be used as a supercharged lookup formula. Most Excel users are very familiar with VLOOKUP. It’s awesome!

However, it has limitations. Always looks in the first column, can only return one result, only tests the one criteria (without outside help).

The FILTER function (as you will see) can test multiple criteria, and from any column. It can return one (if looking for a unique value), but also multiple results.

Back in March 2018, Gašper wrote a brilliant two part article on Merge Queries being an alternative to VLOOKUP. Well, there is now a powerful formula alternative.

Excel FILTER Function Syntax

The FILTER function needs the following information to work.

Array – This is the range or array of values that you want filtered, and returned by the FILTER function.

Include – The criteria that you want to filter the range or array by. This can be any expression that results in TRUE/FALSE. The height of the range tested must be equal to the one provided in the array argument.

If_empty – An optional argument. This is the value to return if no records meet the given criteria.

Excel FILTER Function Examples

Let’s look at some examples of the FILTER function in action.

A Simple Filter

We will start with a simple text filter and filter the data below to only see the employees from Washington.

The following formula returns all columns of data if “Washington” is found in column C. Notice the height of the Array and Include range of equal.

=FILTER(A2:F17,C2:C17=”Washington”,”No results”)

The results are positioned under the data set here for better visuals for the article. Filter function can return the results to a different sheet or workbook, no problem.

Formula was entered into cell A20 but spilled into the range A20:F23.

The spill range is identified by a blue border.

This spill effect is a unique feature of the new dynamic array formulas. The formula only resides (and be edited) in cell A20, but its results spill to the array of cells outside.

If there was content in the area it needed to use, a SPILL error would be shown.

This is caused below by the 0 in cell E22.

However it is easily fixed by simply deleting or moving the naughty content.

If you make a mistake in the formula criteria such as a mistype on a city name. You will receive the CALC! error

No Ctrl + Shift + Enter

Advanced Excel users will have probably worked with array formulas before. They can be very useful, but can also be awkward to create, especially for the inexperienced.

One of the aspects of them that can make them awkward, is the need to press Ctrl + Shift + Enter to execute them.

Good news! The FILTER function can work with and produce a range of results without the need for Ctrl + Shift + Enter.

The VLOOKUP Alternative

I have mentioned how FILTER can be an alternative to the many uses of the ever popular VLOOKUP function.

Now this article would be mega if we went through all the possible cases, so let’s just see it performing a classic VLOOKUP scenario.

We would like to return the information for employee B140.

The following FILTER function is entered in cell B20.

=FILTER(B2:F17,A2:A17=A20,”No match”)

There are lots of take-aways from this example.

We can see the FILTER function returning information from columns B:F, but testing column A. So the criteria range does not need to be included in the returned range.

We are also testing a value from a cell (A20).

And final we have a built-in error response. If no value is found then the text “No match” is returned.

No IFNA or IFERROR functions needed.

With Aggregation Calculations

How about combining the FILTER function with an aggregation function such as SUM, COUNT or AVERAGE. That would be cool.

In this example, we will return the average salary for employees at the London office.

The following formula is entered in cell I3.

=AVERAGE(FILTER(F2:F17,C2:C17=H3,0))

The FILTER function returned the array of values from column F that met the criteria, and the AVERAGE function performed its task on them.

If no results are returned, the value of 0 is shown.

We rely so much on functions such as SUMIFS, COUNTIFS, SUMPRODUCT, AGGREGATE, VLOOKUP and the INDEX & MATCH combo.

And here we are seeing a new function with the ability to take on the tasks we have relied on these different functions for.

So far, we have only performed one logical test in the FILTER criteria. So, lets round this article off by exploring multiple conditional filters.

Multiple Criteria – AND Logic

Let’s begin by using AND logic for two columns of data. We want to return the employees from the London office, who have joined since the 1^st January 2017.

The following formula is entered into cell A20 to return 3 employees details.

=FILTER(A2:F17,(C2:C17=”London”)*(D2:D17>=DATE(2017,1,1)),”No results”)

The multiply operator (*)  is used to perform AND logic tests, and each Boolean expression is enclosed in its own set of brackets.

If you have used array formulas or functions like SUMPRODUCT before, this approach will not be new. But here is a breakdown if your interested in how it works.

The two conditions are both evaluated resulting in True, and false for each employee.

=FILTER(A2:F17,

{FALSE;FALSE;FALSE;FALSE;TRUE;TRUE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;TRUE;TRUE;FALSE}*

{TRUE;FALSE;FALSE;FALSE;TRUE;TRUE;TRUE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE}

,”No results”)

Two arrays containing the results of the conditions are then multiplied producing a 1 only where there is a True for both arrays.

=FILTER(A2:F17,{0;0;0;0;1;1;0;0;0;0;0;0;0;1;0;0},”No results”)

The 1’s represent the 3 employees returned by the FILTER function.

This is how it looks if we break it down into three separate calculations next to the data set.

You can include more than two conditions by continuing the same logic of surrounding each expression in its own brackets and using the multiply operator.

Multiple Criteria – OR Logic

OR logic can be used in the FILTER function in the same manner but using the plus operator (+) instead.

Let’s return the employees from both the Sydney and the Toronto offices.

=FILTER(A2:F17,(C2:C17=”Sydney”)+(C2:C17=”Toronto”),”No results”)

The breakdown from this is the same as before, however the two arrays are added to each other.

And this is how it works. But really just remember that you multiply for AND logic and add for Or logic.

You can also see in this example that the last few results do not have the correct formatting for the date and salary values. Although the dynamic formulas automatically spill into ranges, you will still need to format the cells just like with regular formulas.

Using AND and OR logic in the FILTER Function

Ok, let’s finish off by combining the two logics into one FILTER function.

We will combine the two examples we have done so far and return all employees from both the Sydney and Toronto offices whom started since the 1^st January 2017.

=FILTER(A2:F17,((C2:C17=”Sydney”)+(C2:C17=”Toronto”))*(D2:D17>=DATE(2017,1,1)),”No results”)

Notice the OR logical test has been enclosed in another set of brackets here. This is important.

Remember the mathematical rules that multiplication takes priority over addition. Without the brackets around the OR logic, the formula would return the employees from Toronto who started since the 1^st January 2017, and then all the Sydney employees.

=FILTER(A2:F17,(C2:C17=”Sydney”)+(C2:C17=”Toronto”)*(D2:D17>=DATE(2017,1,1)),”No results”)

It would fail to test the Sydney employees against the start date.

We would need to specify the OR logic first, then only the once since that start date.

=FILTER(A2:F17,((C2:C17=”Sydney”)+(C2:C17=”Toronto”))*(D2:D17>=DATE(2017,1,1)),”No results”)

The FILTER function is worth exploring further because it has huge potential to assist us in our Excel endeavours.

Especially when it is combined with the other dynamic array functions such as SORT and UNIQUE, and also existing functions as shown in this article such as AVERAGE.