What is excel vba array

This post provides an in-depth look at the VBA array which is a very important part of the Excel VBA programming language. It covers everything you need to know about the VBA array.

We will start by seeing what exactly is the VBA Array is and why you need it.

Below you will see a quick reference guide to using the VBA Array.  Refer to it anytime you need a quick reminder of the VBA Array syntax.

The rest of the post provides the most complete guide you will find on the VBA array.

Related Links for the VBA Array

Loops are used for reading through the VBA Array:
For Loop
For Each Loop

Other data structures in VBA:
VBA Collection – Good when you want to keep inserting items as it automatically resizes.
VBA ArrayList – This has more functionality than the Collection.
VBA Dictionary – Allows storing a KeyValue pair. Very useful in many applications.

The Microsoft guide for VBA Arrays can be found here.

A Quick Guide to the VBA Array

Download the Source Code and Data

Please click on the button below to get the fully documented source code for this article.

What is the VBA Array and Why do You Need It?

A VBA array is a type of variable. It is used to store lists of data of the same type. An example would be storing a list of countries or a list of weekly totals.

In VBA a normal variable can store only one value at a time.

In the following example we use a variable to store the marks of a student:

' Can only store 1 value at a time
Dim Student1 As Long
Student1 = 55

If we wish to store the marks of another student then we need to create a second variable.

In the following example, we have the marks of five students:

We are going to read these marks and write them to the Immediate Window.

Note: The function Debug.Print writes values to the Immediate  Window. To view this window select View->Immediate Window from the menu( Shortcut is Ctrl + G)

As you can see in the following example we are writing the same code five times – once for each student:

' https://excelmacromastery.com/
Public Sub StudentMarks()

    ' Get the worksheet called "Marks"
    Dim sh As Worksheet
    Set sh = ThisWorkbook.Worksheets("Marks")
    
    ' Declare variable for each student
    Dim Student1 As Long
    Dim Student2 As Long
    Dim Student3 As Long
    Dim Student4 As Long
    Dim Student5 As Long

    ' Read student marks from cell
    Student1 = sh.Range("C" & 3).Value
    Student2 = sh.Range("C" & 4).Value
    Student3 = sh.Range("C" & 5).Value
    Student4 = sh.Range("C" & 6).Value
    Student5 = sh.Range("C" & 7).Value

    ' Print student marks
    Debug.Print "Students Marks"
    Debug.Print Student1
    Debug.Print Student2
    Debug.Print Student3
    Debug.Print Student4
    Debug.Print Student5

End Sub

The following is the output from the example:

The problem with using one variable per student is that you need to add code for each student. Therefore if you had a thousand students in the above example you would need three thousand lines of code!

Luckily we have arrays to make our life easier. Arrays allow us to store a list of data items in one structure.

The following code shows the above student example using an array:

' ExcelMacroMastery.com
' https://excelmacromastery.com/excel-vba-array/
' Author: Paul Kelly
' Description: Reads marks to an Array and write
' the array to the Immediate Window(Ctrl + G)
' TO RUN: Click in the sub and press F5
Public Sub StudentMarksArr()

    ' Get the worksheet called "Marks"
    Dim sh As Worksheet
    Set sh = ThisWorkbook.Worksheets("Marks")

    ' Declare an array to hold marks for 5 students
    Dim Students(1 To 5) As Long

    ' Read student marks from cells C3:C7 into array
    ' Offset counts rows from cell C2.
    ' e.g. i=1 is C2 plus 1 row which is C3
    '      i=2 is C2 plus 2 rows which is C4
    Dim i As Long
    For i = 1 To 5
        Students(i) = sh.Range("C2").Offset(i).Value
    Next i

    ' Print student marks from the array to the Immediate Window
    Debug.Print "Students Marks"
    For i = LBound(Students) To UBound(Students)
        Debug.Print Students(i)
    Next i

End Sub

The advantage of this code is that it will work for any number of students. If we have to change this code to deal with 1000 students we only need to change the (1 To 5) to (1 To 1000) in the declaration. In the prior example we would need to add approximately five thousand lines of code.

Let’s have a quick comparison of variables and arrays. First we compare the declaration:

        ' Variable
        Dim Student As Long
        Dim Country As String

        ' Array
        Dim Students(1 To 3) As Long
        Dim Countries(1 To 3) As String

Next we compare assigning a value:

        ' assign value to variable
        Student1 = .Cells(1, 1) 

        ' assign value to first item in array
        Students(1) = .Cells(1, 1)

Finally we look at writing the values:

        ' Print variable value
        Debug.Print Student1

        ' Print value of first student in array
        Debug.Print Students(1)

As you can see, using variables and arrays is quite similar.

The fact that arrays use an index(also called a subscript) to access each item is important. It means we can easily access all the items in an array using a For Loop.

Now that you have some background on why arrays are useful let’s go through them step by step.

Two Types of VBA Arrays

There are two types of VBA arrays:

1. Static – an array of fixed length.
2. Dynamic(not to be confused with the Excel Dynamic Array) – an array where the length is set at run time.

The difference between these types is mostly in how they are created. Accessing values in both array types is exactly the same. In the following sections we will cover both of these types.

VBA Array Initialization

A static array is initialized as follows:

' https://excelmacromastery.com/
Public Sub DecArrayStatic()

    ' Create array with locations 0,1,2,3
    Dim arrMarks1(0 To 3) As Long

    ' Defaults as 0 to 3 i.e. locations 0,1,2,3
    Dim arrMarks2(3) As Long

    ' Create array with locations 1,2,3,4,5
    Dim arrMarks3(1 To 5) As Long

    ' Create array with locations 2,3,4 ' This is rarely used
    Dim arrMarks4(2 To 4) As Long

End Sub

As you can see the length is specified when you declare a static array. The problem with this is that you can never be sure in advance the length you need. Each time you run the Macro you may have different length requirements.

If you do not use all the array locations then the resources are being wasted. So if you need more locations you can use ReDim but this is essentially creating a new static array.

The dynamic array does not have such problems. You do not specify the length when you declare it. Therefore you can then grow and shrink as required:

' https://excelmacromastery.com/
Public Sub DecArrayDynamic()

    ' Declare  dynamic array
    Dim arrMarks() As Long

    ' Set the length of the array when you are ready
    ReDim arrMarks(0 To 5)

End Sub

The dynamic array is not allocated until you use the ReDim statement. The advantage is you can wait until you know the number of items before setting the array length. With a static array you have to state the length upfront.

To give an example. Imagine you were reading worksheets of student marks. With a dynamic array you can count the students on the worksheet and set an array to that length. With a static array you must set the length to the largest possible number of students.

Assigning Values to VBA Array

To assign values to an array you use the number of the location. You assign the value for both array types the same way:

' https://excelmacromastery.com/
Public Sub AssignValue()

    ' Declare  array with locations 0,1,2,3
    Dim arrMarks(0 To 3) As Long

    ' Set the value of position 0
    arrMarks(0) = 5

    ' Set the value of position 3
    arrMarks(3) = 46

    ' This is an error as there is no location 4
    arrMarks(4) = 99

End Sub

The number of the location is called the subscript or index. The last line in the example will give a “Subscript out of Range” error as there is no location 4 in the array example.

VBA Array Length

There is no native function for getting the number of items in an array. I created the ArrayLength function below to return the number of items in any array no matter how many dimensions:

' https://excelmacromastery.com/
Function ArrayLength(arr As Variant) As Long

    On Error Goto eh
    
    ' Loop is used for multidimensional arrays. The Loop will terminate when a
    ' "Subscript out of Range" error occurs i.e. there are no more dimensions.
    Dim i As Long, length As Long
    length = 1
    
    ' Loop until no more dimensions
    Do While True
        i = i + 1
        ' If the array has no items then this line will throw an error
        Length = Length * (UBound(arr, i) - LBound(arr, i) + 1)
        ' Set ArrayLength here to avoid returing 1 for an empty array
        ArrayLength = Length
    Loop

Done:
    Exit Function
eh:
    If Err.Number = 13 Then ' Type Mismatch Error
        Err.Raise vbObjectError, "ArrayLength" _
            , "The argument passed to the ArrayLength function is not an array."
    End If
End Function

You can use it like this:

' Name: TEST_ArrayLength
' Author: Paul Kelly, ExcelMacroMastery.com
' Description: Tests the ArrayLength functions and writes
'              the results to the Immediate Window(Ctrl + G)
Sub TEST_ArrayLength()
    
    ' 0 items
    Dim arr1() As Long
    Debug.Print ArrayLength(arr1)
    
    ' 10 items
    Dim arr2(0 To 9) As Long
    Debug.Print ArrayLength(arr2)
    
    ' 18 items
    Dim arr3(0 To 5, 1 To 3) As Long
    Debug.Print ArrayLength(arr3)
    
    ' Option base 0: 144 items
    ' Option base 1: 50 items
    Dim arr4(1, 5, 5, 0 To 1) As Long
    Debug.Print ArrayLength(arr4)
    
End Sub

Using the Array and Split function

You can use the Array function to populate an array with a list of items. You must declare the array as a type Variant. The following code shows you how to use this function.

    Dim arr1 As Variant
    arr1 = Array("Orange", "Peach","Pear")

    Dim arr2 As Variant
    arr2 = Array(5, 6, 7, 8, 12)

The array created by the Array Function will start at index zero unless you use Option Base 1 at the top of your module. Then it will start at index one. In programming, it is generally considered poor practice to have your actual data in the code. However, sometimes it is useful when you need to test some code quickly.

The Split function is used to split a string into an array based on a delimiter. A delimiter is a character such as a comma or space that separates the items.

The following code will split the string into an array of four elements:

    Dim s As String
    s = "Red,Yellow,Green,Blue"

    Dim arr() As String
    arr = Split(s, ",")

The Split function is normally used when you read from a comma-separated file or another source that provides a list of items separated by the same character.

Using Loops With the VBA Array

Using a For Loop allows quick access to all items in an array. This is where the power of using arrays becomes apparent. We can read arrays with ten values or ten thousand values using the same few lines of code. There are two functions in VBA called LBound and UBound. These functions return the smallest and largest subscript in an array. In an array arrMarks(0 to 3) the LBound will return 0 and UBound will return 3.

The following example assigns random numbers to an array using a loop. It then prints out these numbers using a second loop.

' https://excelmacromastery.com/
Public Sub ArrayLoops()

    ' Declare  array
    Dim arrMarks(0 To 5) As Long

    ' Fill the array with random numbers
    Dim i As Long
    For i = LBound(arrMarks) To UBound(arrMarks)
        arrMarks(i) = 5 * Rnd
    Next i

    ' Print out the values in the array
    Debug.Print "Location", "Value"
    For i = LBound(arrMarks) To UBound(arrMarks)
        Debug.Print i, arrMarks(i)
    Next i

End Sub

The functions LBound and UBound are very useful. Using them means our loops will work correctly with any array length. The real benefit is that if the length of the array changes we do not have to change the code for printing the values. A loop will work for an array of any length as long as you use these functions.

Using the For Each Loop with the VBA Array

You can use the For Each loop with arrays. The important thing to keep in mind is that it is Read-Only. This means that you cannot change the value in the array.

In the following code the value of mark changes but it does not change the value in the array.

    For Each mark In arrMarks
        ' Will not change the array value
        mark = 5 * Rnd
    Next mark

The For Each is loop is fine to use for reading an array. It is neater to write especially for a Two-Dimensional array as we will see.

    Dim mark As Variant
    For Each mark In arrMarks
        Debug.Print mark
    Next mark

Using Erase with the VBA Array

The Erase function can be used on arrays but performs differently depending on the array type.

For a static Array the Erase function resets all the values to the default. If the array is made up of long integers(i.e type Long) then all the values are set to zero. If the array is of strings then all the strings are set to “” and so on.

For a Dynamic Array the Erase function DeAllocates memory. That is, it deletes the array. If you want to use it again you must use ReDim to Allocate memory.

Let’s have a look an example for the static array. This example is the same as the ArrayLoops example in the last section with one difference – we use Erase after setting the values. When the value are printed out they will all be zero:

' https://excelmacromastery.com/
Public Sub EraseStatic()

    ' Declare  array
    Dim arrMarks(0 To 3) As Long

    ' Fill the array with random numbers
    Dim i As Long
    For i = LBound(arrMarks) To UBound(arrMarks)
        arrMarks(i) = 5 * Rnd
    Next i

    ' ALL VALUES SET TO ZERO
    Erase arrMarks

    ' Print out the values - there are all now zero
    Debug.Print "Location", "Value"
    For i = LBound(arrMarks) To UBound(arrMarks)
        Debug.Print i, arrMarks(i)
    Next i

End Sub

We will now try the same example with a dynamic. After we use Erase all the locations in the array have been deleted. We need to use ReDim if we wish to use the array again.

If we try to access members of this array we will get a “Subscript out of Range” error:

' https://excelmacromastery.com/
Public Sub EraseDynamic()

    ' Declare  array
    Dim arrMarks() As Long
    ReDim arrMarks(0 To 3)

    ' Fill the array with random numbers
    Dim i As Long
    For i = LBound(arrMarks) To UBound(arrMarks)
        arrMarks(i) = 5 * Rnd
    Next i

    ' arrMarks is now deallocated. No locations exist.
    Erase arrMarks

End Sub

Increasing the length of the VBA Array

If we use ReDim on an existing array, then the array and its contents will be deleted.

In the following example, the second ReDim statement will create a completely new array. The original array and its contents will be deleted.

' https://excelmacromastery.com/
Sub UsingRedim()

    Dim arr() As String
    
    ' Set array to be slots 0 to 2
    ReDim arr(0 To 2)
    arr(0) = "Apple"
    
    ' Array with apple is now deleted
    ReDim arr(0 To 3)

End Sub

If we want to extend the length of an array without losing the contents, we can use the Preserve keyword.

When we use Redim Preserve the new array must start at the same starting dimension e.g.

We cannot Preserve from (0 to 2) to (1 to 3) or to (2 to 10) as they are different starting dimensions.

In the following code we create an array using ReDim and then fill the array with types of fruit.

We then use Preserve to extend the length of the array so we don’t lose the original contents:

' https://excelmacromastery.com/
Sub UsingRedimPreserve()

    Dim arr() As String
    
    ' Set array to be slots 0 to 1
    ReDim arr(0 To 2)
    arr(0) = "Apple"
    arr(1) = "Orange"
    arr(2) = "Pear"
    
    ' Reset the length and keep original contents
    ReDim Preserve arr(0 To 5)

End Sub

You can see from the screenshots below, that the original contents of the array have been “Preserved”.

Word of Caution: In most cases, you shouldn’t need to resize an array like we have done in this section. If you are resizing an array multiple times then you may want to consider using a Collection.

Using Preserve with Two-Dimensional Arrays

Preserve only works with the upper bound of an array.

For example, if you have a two-dimensional array you can only preserve the second dimension as this example shows:

' https://excelmacromastery.com/
Sub Preserve2D()

    Dim arr() As Long
    
    ' Set the starting length
    ReDim arr(1 To 2, 1 To 5)
    
    ' Change the length of the upper dimension
    ReDim Preserve arr(1 To 2, 1 To 10)

End Sub

If we try to use Preserve on a lower bound we will get the “Subscript out of range” error.

In the following code we use Preserve on the first dimension. Running this code will give the “Subscript out of range” error:

' https://excelmacromastery.com/
Sub Preserve2DError()

    Dim arr() As Long
    
    ' Set the starting length
    ReDim arr(1 To 2, 1 To 5)
    
    ' "Subscript out of Range" error
    ReDim Preserve arr(1 To 5, 1 To 5)

End Sub

When we read from a range to an array, it automatically creates a two-dimensional array, even if we have only one column.

The same Preserve rules apply. We can only use Preserve on the upper bound as this example shows:

' https://excelmacromastery.com/
Sub Preserve2DRange()

    Dim arr As Variant
    
    ' Assign a range to an array
    arr = Sheet1.Range("A1:A5").Value
    
    ' Preserve will work on the upper bound only
    ReDim Preserve arr(1 To 5, 1 To 7)

End Sub

Sorting the VBA Array

There is no function in VBA for sorting an array. We can sort the worksheet cells but this could be slow if there is a lot of data.

The QuickSort function below can be used to sort an array.

' https://excelmacromastery.com/
Sub QuickSort(arr As Variant, first As Long, last As Long)
  
  Dim vCentreVal As Variant, vTemp As Variant
  
  Dim lTempLow As Long
  Dim lTempHi As Long
  lTempLow = first
  lTempHi = last
  
  vCentreVal = arr((first + last)  2)
  Do While lTempLow <= lTempHi
  
    Do While arr(lTempLow) < vCentreVal And lTempLow < last
      lTempLow = lTempLow + 1
    Loop
    
    Do While vCentreVal < arr(lTempHi) And lTempHi > first
      lTempHi = lTempHi - 1
    Loop
    
    If lTempLow <= lTempHi Then
    
        ' Swap values
        vTemp = arr(lTempLow)

        arr(lTempLow) = arr(lTempHi)
        arr(lTempHi) = vTemp
      
        ' Move to next positions
        lTempLow = lTempLow + 1
        lTempHi = lTempHi - 1
      
    End If
    
  Loop
  
  If first < lTempHi Then QuickSort arr, first, lTempHi
  If lTempLow < last Then QuickSort arr, lTempLow, last
  
End Sub

You can use this function like this:

' https://excelmacromastery.com/
Sub TestSort()

    ' Create temp array
    Dim arr() As Variant
    arr = Array("Banana", "Melon", "Peach", "Plum", "Apple")
  
    ' Sort array
    QuickSort arr, LBound(arr), UBound(arr)

    ' Print arr to Immediate Window(Ctrl + G)
    Dim i As Long
    For i = LBound(arr) To UBound(arr)
        Debug.Print arr(i)
    Next i

End Sub

Passing the VBA Array to a Sub

Sometimes you will need to pass an array to a procedure. You declare the parameter using parenthesis similar to how you declare a dynamic array.

Passing to the procedure using ByRef means you are passing a reference of the array. So if you change the array in the procedure it will be changed when you return.

Note: When you use an array as a parameter it cannot use ByVal, it must use ByRef. You can pass the array using ByVal making the parameter a variant.

' https://excelmacromastery.com/
' Passes array to a Function
Public Sub PassToProc()
    Dim arr(0 To 5) As String
    ' Pass the array to function
    UseArray arr
End Sub

Public Function UseArray(ByRef arr() As String)
    ' Use array
    Debug.Print UBound(arr)
End Function

Returning the VBA Array from a Function

It is important to keep the following in mind. If you want to change an existing array in a procedure then you should pass it as a parameter using ByRef(see last section). You do not need to return the array from the procedure.

The main reason for returning an array is when you use the procedure to create a new one. In this case you assign the return array to an array in the caller. This array cannot be already allocated. In other words you must use a dynamic array that has not been allocated.

The following examples show this

' https://excelmacromastery.com/
Public Sub TestArray()

    ' Declare dynamic array - not allocated
    Dim arr() As String
    ' Return new array
    arr = GetArray

End Sub

Public Function GetArray() As String()

    ' Create and allocate new array
    Dim arr(0 To 5) As String
    ' Return array
    GetArray = arr

End Function

Using a Two-Dimensional VBA Array

The arrays we have been looking at so far have been one-dimensional arrays. This means the arrays are one list of items.

A two-dimensional array is essentially a list of lists. If you think of a single spreadsheet row as a single dimension then more than one column is two dimensional. In fact a spreadsheet is the equivalent of a two-dimensional array. It has two dimensions – rows and columns.

One small thing to note is that Excel treats a one-dimensional array as a row if you write it to a spreadsheet. In other words, the array arr(1 to 5) is equivalent to arr(1 to 1, 1 to 5) when writing values to the spreadsheet.

The following image shows two groups of data. The first is a one-dimensional layout and the second is two dimensional.

To access an item in the first set of data(1 dimensional) all you need to do is give the row e.g. 1,2, 3 or 4.

For the second set of data (two-dimensional), you need to give the row AND the column. So you can think of 1 dimensional being multiple columns and one row and two-dimensional as being multiple rows and multiple columns.

Note: It is possible to have more than two dimensions in an array. It is rarely required. If you are solving a problem using a 3+ dimensional array then there probably is a better way to do it.

You declare a two-dimensional array as follows:

Dim ArrayMarks(0 To 2,0 To 3) As Long

The following example creates a random value for each item in the array and the prints the values to the Immediate Window:

' https://excelmacromastery.com/
Public Sub TwoDimArray()

    ' Declare a two dimensional array
    Dim arrMarks(0 To 3, 0 To 2) As String

    ' Fill the array with text made up of i and j values
    Dim i As Long, j As Long
    For i = LBound(arrMarks) To UBound(arrMarks)
        For j = LBound(arrMarks, 2) To UBound(arrMarks, 2)
            arrMarks(i, j) = CStr(i) & ":" & CStr(j)
        Next j
    Next i

    ' Print the values in the array to the Immediate Window
    Debug.Print "i", "j", "Value"
    For i = LBound(arrMarks) To UBound(arrMarks)
        For j = LBound(arrMarks, 2) To UBound(arrMarks, 2)
            Debug.Print i, j, arrMarks(i, j)
        Next j
    Next i

End Sub

You can see that we use a second For loop inside the first loop to access all the items.

The output of the example looks like this:

How this Macro works is as follows:

• Enters the i loop
• i is set to 0
• Entersj loop
• j is set to 0
• j is set to 1
• j is set to 2
• Exit j loop
• i is set to 1
• j is set to 0
• j is set to 1
• j is set to 2
• And so on until i=3 and j=2

You may notice that LBound and UBound have a second argument with the value 2. This specifies that it is the upper or lower bound of the second dimension. That is the start and end location for j. The default value 1 which is why we do not need to specify it for the i loop.

Using the For Each Loop

Using a For Each is neater to use when reading from an array.

Let’s take the code from above that writes out the two-dimensional array

    ' Using For loop needs two loops
    Debug.Print "i", "j", "Value"
    For i = LBound(arrMarks) To UBound(arrMarks)
        For j = LBound(arrMarks, 2) To UBound(arrMarks, 2)
            Debug.Print i, j, arrMarks(i, j)
        Next j
    Next i

Now let’s rewrite it using a For each loop. You can see we only need one loop and so it is much easier to write:

    ' Using For Each requires only one loop
    Debug.Print "Value"
    Dim mark As Variant
    For Each mark In arrMarks
        Debug.Print mark
    Next mark

Using the For Each loop gives us the array in one order only – from LBound to UBound. Most of the time this is all you need.

Reading from a Range to the VBA Array

If you have read my previous post on Cells and Ranges then you will know that VBA has an extremely efficient way of reading from a Range of Cells to an Array and vice versa

' https://excelmacromastery.com/
Public Sub ReadToArray()

    ' Declare dynamic array
    Dim StudentMarks As Variant

    ' Read values into array from first row
    StudentMarks = Range("A1:Z1").Value

    ' Write the values back to the third row
    Range("A3:Z3").Value = StudentMarks

End Sub

The dynamic array created in this example will be a two dimensional array. As you can see we can read from an entire range of cells to an array in just one line.

The next example will read the sample student data below from C3:E6 of Sheet1 and print them to the Immediate Window:

' https://excelmacromastery.com/
Public Sub ReadAndDisplay()

    ' Get Range
    Dim rg As Range
    Set rg = ThisWorkbook.Worksheets("Sheet1").Range("C3:E6")

    ' Create dynamic array
    Dim StudentMarks As Variant

    ' Read values into array from sheet1
    StudentMarks = rg.Value

    ' Print the array values
    Debug.Print "i", "j", "Value"
    Dim i As Long, j As Long
    For i = LBound(StudentMarks) To UBound(StudentMarks)
        For j = LBound(StudentMarks, 2) To UBound(StudentMarks, 2)
            Debug.Print i, j, StudentMarks(i, j)
        Next j
    Next i

End Sub

As you can see the first dimension(accessed using i) of the array is a row and the second is a column. To demonstrate this take a look at the value 44 in E4 of the sample data. This value is in row 2 column 3 of our data. You can see that 44 is stored in the array at StudentMarks(2,3).

You can see more about using arrays with ranges in this YouTube video

How To Make Your Macros Run at Super Speed

If your macros are running very slow then you may find this section very helpful. Especially if you are dealing with large amounts of data. The following is a very well-kept secret in VBA

Updating values in arrays is exponentially faster than updating values in cells.

In the last section, you saw how we can easily read from a group of cells to an array and vice versa. If we are updating a lot of values then we can do the following:

1. Copy the data from the cells to an array.
2. Change the data in the array.
3. Copy the updated data from the array back to the cells.

For example, the following code would be much faster than the code below it:

' https://excelmacromastery.com/
Public Sub ReadToArray()

    ' Read values into array from first row
    Dim StudentMarks  As Variant
    StudentMarks = Range("A1:Z20000").Value

    Dim i As Long
    For i = LBound(StudentMarks) To UBound(StudentMarks)
        ' Update marks here
        StudentMarks(i, 1) = StudentMarks(i, 1) * 2
        '...
    Next i

    ' Write the new values back to the worksheet
    Range("A1:Z20000").Value = StudentMarks

End Sub

' https://excelmacromastery.com/
Sub UsingCellsToUpdate()
    
    Dim c As Variant
    For Each c In Range("A1:Z20000")
        c.Value = ' Update values here
    Next c
    
End Sub

Assigning from one set of cells to another is also much faster than using Copy and Paste:

' Assigning - this is faster
Range("A1:A10").Value = Range("B1:B10").Value

' Copy Paste - this is slower
Range("B1:B1").Copy Destination:=Range("A1:A10")

The following comments are from two readers who used arrays to speed up their macros

“A couple of my projects have gone from almost impossible and long to run into almost too easy and a reduction in time to run from 10:1.” – Dane

“One report I did took nearly 3 hours to run when accessing the cells directly — 5 minutes with arrays” – Jim

You can see more about the speed of Arrays compared to other methods in this YouTube video.

To see a comparison between Find, Match and Arrays it is worth checking out this post by Charles Williams.

Conclusion

The following is a summary of the main points of this post

1. Arrays are an efficient way of storing a list of items of the same type.
2. You can access an array item directly using the number of the location which is known as the subscript or index.
3. The common error “Subscript out of Range” is caused by accessing a location that does not exist.
4. There are two types of arrays: Static and Dynamic.
5. Static is used when the length of the array is always the same.
6. Dynamic arrays allow you to determine the length of an array at run time.
7. LBound and UBound provide a safe way of find the smallest and largest subscripts of the array.
8. The basic array is one dimensional. You can also have multidimensional arrays.
9. You can only pass an array to a procedure using ByRef. You do this like this: ByRef arr() as long.
10. You can return an array from a function but the array, it is assigned to, must not be currently allocated.
11. A worksheet with its rows and columns is essentially a two-dimensional array.
12. You can read directly from a worksheet range into a two-dimensional array in just one line of code.
13. You can also write from a two-dimensional array to a range in just one line of code.

What’s Next?

Free VBA Tutorial If you are new to VBA or you want to sharpen your existing VBA skills then why not try  The Ultimate VBA Tutorial.

Related Training: Get full access to the Excel VBA training webinars.

(NOTE: Planning to build or manage a VBA Application? Learn how to build 10 Excel VBA applications from scratch.)

Key Points

• Think of an array in VBA array as a mini database to store and organized data (Example: student’s name, subject, and scores).
• Before you use it, you need to declare an array; with its data type, and the number of values you want to store in it.

If you want to work with large data using VBA, then you need to understand arrays and how to use them in VBA codes, and in this guide, you will be exploring all the aspects of the array and we will also see some examples to use them.

What is an Array in VBA?

In VBA, an array is a variable that can store multiple values. You can access all the values from that array at once or you can also access a single value by specifying its index number which is the position of that value in the array. Imagine you have a date with student’s name, subject, and scores.

You can store all this information in an array, not just for one student but for hundreds. Here’s a simple example to explain an array.

In the above example, you have an array with ten elements (size of the array) and each element has a specific position (Index).

So, if you want to use an element that is in the eighth position you need to refer to that element using its index number.

The array that we have used in the above example is a single-dimension array. But ahead in this guide, we will learn about multidimensional arrays as well.

How to Declare an Array in VBA

As I mentioned above an array is the kind of variable, so you need to declare it using the keywords (Dim, Private, Public, and Static). Unlike a normal variable, when you declare an array you need to use a pair of parentheses after the array’s name.

Let’s say you want to declare an array that we have used in the above example.

Steps to declare an array.

Full Code

Sub vba_array_example()
Dim StudentsNames(10) As String
StudentsNames(0) = "Waylon"
StudentsNames(1) = "Morton"
StudentsNames(2) = "Rudolph"
StudentsNames(3) = "Georgene"
StudentsNames(4) = "Billi"
StudentsNames(5) = "Enid"
StudentsNames(6) = "Genevieve"
StudentsNames(7) = "Judi"
StudentsNames(8) = "Madaline"
StudentsNames(9) = "Elton"
End Sub

Quick Notes

• In the above code, first, you have the Dim statement that defines the one-dimensional array which can store up to 10 elements and has a string data type.
• After that, you have 10 lines of code that define the elements of an array from 0 to 9.

Array with a Variant Data Type

While declaring an array if you omit to specify the data type VBA will automatically use the variant data type, which causes slightly increased memory usage, and this increase in memory usage could slow the performance of the code.

So, it’s better to define a specific data type when you are declaring an array unless there is a need to use the variant data type.

Returning Information from an Array

As I mentioned earlier to get information from an array you can use the index number of the element to specify its position. For example, if you want to return the 8th item in the area that we have created in the earlier example, the code would be:

In the above code, you have entered the value in cell A1 by using item 8 from the array.

Use Option Base 1

I’m sure you have this question in your mind right now why we’re started our list of elements from zero instead of one?

Well, this is not a mistake.

When programming languages were first constructed some carelessness made this structure for listing elements in an array. In most programming languages, you can find the same structure of listing elements.

However, unlike most other computer languages, In VBA you can normalize the way the is index work which means you can make it begins with 1. The only thing you need to do is add an option-based statement at the start of the module before declaring an array.

Now this array will look something like the below:

Searching through an Array

When you store values in an array there could be a time when you need to search within an array.

In that case, you need to know the methods that you can use. Now, look at the below code that can help you to understand how to search for a value in an array.

Sub vba_array_search()

'this section declares an array and variables _
that you need to search within the array.
Dim myArray(10) As Integer
Dim i As Integer
Dim varUserNumber As Variant
Dim strMsg As String

'This part of the code adds 10 random numbers to _
the array and shows the result in the _
immediate window as well.
For i = 1 To 10
myArray(i) = Int(Rnd * 10)
Debug.Print myArray(i)
Next i

'it is an input box that asks you the number that you want to find.
Loopback:
varUserNumber = InputBox _
("Enter a number between 1 and 10 to search for:", _
"Linear Search Demonstrator")

'it's an IF statement that checks for the value that you _
have entered in the input box.
If varUserNumber = "" Then End
If Not IsNumeric(varUserNumber) Then GoTo Loopback
If varUserNumber < 1 Or varUserNumber > 10 Then GoTo Loopback

'message to show if the value doesn't found.
strMsg = "Your value, " & varUserNumber & _
", was not found in the array."

'loop through the array and match each value with the _
the value you have entered in the input box.
For i = 1 To UBound(myArray)
If myArray(i) = varUserNumber Then
strMsg = "Your value, " & varUserNumber & _
", was found at position " & i & " in the array."
Exit For
End If
Next i

'message box in the end
MsgBox strMsg, vbOKOnly + vbInformation, "Linear Search Result"

End Sub

1. In the first part of the code, you have variables that you need to use in the code further.
2. After that, the next part is to generate random numbers by using RND to get you 10 values for the array.
3. Next, an input box to let enter the value that you want to search within the array.
4. In this part, you have a code for the string to use in the message box if the value you have entered is not found.
5. This part of the code uses a loop to loop through each item in the array and check if the value that you have entered is in the array or not.
6. The last part of the code shows you a message about whether a value is found or not.

In VBA, an Array is a single variable that can hold multiple values.  Think of an array like a range of cells: each cell can store a value. Arrays can be one-dimensional (think of a single column), two-dimensional (think of multiple rows & columns), or multi-dimensional.  Array values can be accessed by their position (index number) within the array.

VBA Array Quick Sheet

Arrays

VBA Array Quick Examples

Let’s look at a full example before we dive into specifics:

Sub ArrayExample()
    Dim strNames(1 to 4) as String

    strNames(1) = "Shelly"
    strNames(2) = "Steve"
    strNames(3) = "Neema"
    strNames(4) = "Jose"

    msgbox strNames(3)
End Sub

Here we’ve created the one-dimensional string array: strNames with size four (can hold four values) and assigned the four values. Last we display the 3rd value in a Message Box.

In this case, the benefit of using an Array is small: only one variable declaration is required instead of four.

However, let’s look at an example that will show the true power of an array:

Sub ArrayExample2()
    Dim strNames(1 To 60000) As String
    Dim i As Long

    For i = 1 To 60000
        strNames(i) = Cells(i, 1).Value
    Next i
End Sub

Here we’ve created an Array that can hold 60,000 values and we’ve quickly populated the array from Column A of a worksheet.

Array Benefits? – Speed!

You might think of Arrays similar to Excel worksheets:

• Each cell (or item in an array) can contain its own value
• Each cell (or item in an array) can be accessed by its row & column position.
  • Worksheet Ex.  cells(1,4).value = “Row 1, Column 4”
  • Array Ex.  arrVar(1,4) = “Row 1, Column 4”

So why bother with Arrays?  Why not just read and write values directly to cells in Excel?  One word: Speed!

Reading / Writing to Excel cells is a slow process. Working with Arrays is much faster!

Create / Declare an Array (Dim)

Note: Arrays can have multiple “dimensions”. To keep things simple, we will start by only working with one-dimensional arrays. Later in the tutorial we will introduce you to multiple-dimension arrays.

Static Array

Static Arrays are arrays that cannot change size. Conversely, Dynamic Arrays can change size.  They are declared slightly differently. First, let’s look at static arrays.

Note: If your array won’t change in size, use a static array.

Declaring a static array variable is very similar to declaring a regular variable, except you must define the size of the array. There are several different ways to set the size of an array.

You can explicitly declare the start and end positions of an array:

Sub StaticArray1()

    'Creates array with positions 1,2,3,4
    Dim arrDemo1(1 To 4) As String
    
    'Creates array with positions 4,5,6,7
    Dim arrDemo2(4 To 7) As Long
    
    'Creates array with positions 0,1,2,3
    Dim arrDemo3(0 To 3) As Long

End Sub

Or you can enter only the array size:

Sub StaticArray2()

    'Creates array with positions 0,1,2,3
    Dim arrDemo1(3) As String

End Sub

Important! Notice that by default, Arrays start at position 0.  So Dim arrDemo1(3) creates an array with positions 0,1,2,3.

You can declare Option Base 1 at the top of your module so that the array starts at position 1 instead:

Option Base 1

Sub StaticArray3()

    'Creates array with positions 1,2,3
    Dim arrDemo1(3) As String

End Sub

However, I find that it’s much easier (and less confusing) to just explicitly declare the start and end positions of arrays.

Dynamic Array

Dynamic Arrays are arrays whose size can be changed (or whose size does not need to be defined).

There are two ways to declare a Dynamic Array.

Variant Arrays

The first way to declare a Dynamic Array is by setting the array to type Variant.

Dim arrVar() As Variant

With a Variant Array, you do not need to define the array size. The size will automatically adjust.  Just remember that the Array starts with position 0 (unless you add Option Base 1 to the top of your module)

Sub VariantArray()
    Dim arrVar() As Variant
    
    'Define Values (Size = 0,1,2,3)
    arrVar = Array(1, 2, 3, 4)
    
    'Change Values (Size = 0,1,2,3,4)
    arrVar = Array("1a", "2a", "3a", "4a", "5a")

    'Output Position 4 ("5a")
    MsgBox arrVar(4)

End Sub

Non-Variant Dynamic Arrays

With non-variant arrays, you must define the array size before assigning values to the array. However, the process to create the array is slightly different:

Sub DynamicArray1()
    Dim arrDemo1() As String

    'Resizes array with positions 1,2,3,4
    ReDim arrDemo1(1 To 4)
    
End Sub

First you declare the array, similar to the static array, except you omit the array size:

Dim arrDemo1() As String

Now when you want to set the array size you use the ReDim command to size the array:

'Resizes array with positions 1,2,3,4
ReDim arrDemo1(1 To 4)

ReDim resizes the array. Read below for the difference between ReDim and ReDim Preserve.

ReDim vs. ReDim Preserve

When you use the ReDim command you clear all existing values from the array.  Instead you can use ReDim Preserve to preserve array values:

'Resizes array with positions 1,2,3,4 (Preserving existing values)
ReDim Preserve arrDemo1(1 To 4)

Declaring Arrays Simplified

You might be feeling overwhelmed after reading everything above. To keep things simple, we will mostly work with static arrays for the rest of the article.

VBA Programming | Code Generator does work for you!

Set Array Values

Setting array values is very easy.

With a static array, you must define each position of the array, one at a time:

Sub ArrayExample()
    Dim strNames(1 to 4) as String

    strNames(1) = "Shelly"
    strNames(2) = "Steve"
    strNames(3) = "Neema"
    strNames(4) = "Jose"
End Sub

With a Variant Array you can define the entire array with one line (only practical for small arrays):

Sub ArrayExample_1Line()
    Dim strNames() As Variant

    strNames = Array("Shelly", "Steve", "Neema", "Jose")

End Sub

If you attempt to define a value for an array location that does not exist, you will receive a Subscript Out of Range error:

strNames(5) = "Shannon"

In the ‘Assign Range to Array’ section Below we’ll show you how to use a loop to quickly assign large numbers of values to arrays.

Get Array Value

You can fetch array values the same way.  In the example below we will write array values to cells:

    Range("A1").Value = strNames(1)
    Range("A2").Value = strNames(2)
    Range("A3").Value = strNames(3)
    Range("A4").Value = strNames(4)

Assign Range to Array

To assign a Range to an Array you can use a loop:

Sub RangeToArray()
    Dim strNames(1 To 60000) As String
    Dim i As Long

    For i = 1 To 60000
        strNames(i) = Cells(i, 1).Value
    Next i
End Sub

This will loop through cells A1:A60000, assigning the cell values to the array.

Output Array to Range

Or you can use a loop to assign an array to a range:

    For i = 1 To 60000
        Cells(i, 1).Value = strNames(i)
    Next i

This will do the reverse: assign array values to cells A1:A60000

2D / Multi-Dimensional Arrays

So far we’ve worked exclusively with single-dimensional (1D) arrays.  However, arrays can have up to 32 dimensions.

Think of a 1D array like a single row or column of Excel cells, a 2D array like an entire Excel worksheet with multiple rows and columns, and a 3D array is like an entire workbook, containing multiple sheets each containing multiple rows and columns (You could also think of a 3D array as like a Rubik’s Cube).

AutoMacro | Ultimate VBA Add-in | Click for Free Trial!

Multi-Dimensional Array Examples

Now let’s demonstrate examples of working with arrays of different dimensions.

1D Array Example

This procedure combines the previous array examples into one procedure, demonstrating how you might use arrays in practice.

Sub ArrayEx_1d()
    Dim strNames(1 To 60000) As String
    Dim i As Long
 
    'Assign Values to Array
    For i = 1 To 60000
        strNames(i) = Cells(i, 1).Value
    Next i
    
    'Output Array Values to Range
    For i = 1 To 60000
        Sheets("Output").Cells(i, 1).Value = strNames(i)
    Next i
End Sub

2D Array Example

This procedure contains an example of a 2D array:

Sub ArrayEx_2d()
    Dim strNames(1 To 60000, 1 To 10) As String
    Dim i As Long, j As Long
 
    'Assign Values to Array
    For i = 1 To 60000
        For j = 1 To 10
            strNames(i, j) = Cells(i, j).Value
        Next j
    Next i
    
    'Output Array Values to Range
    For i = 1 To 60000
        For j = 1 To 10
            Sheets("Output").Cells(i, j).Value = strNames(i, j)
        Next j
    Next i
End Sub

3D Array Example

This procedure contains an example of a 3D array for working with multiple sheets:

Sub ArrayEx_3d()
    Dim strNames(1 To 60000, 1 To 10, 1 To 3) As String
    Dim i As Long, j As Long, k As Long
 
    'Assign Values to Array
    For k = 1 To 3
        For i = 1 To 60000
            For j = 1 To 10
                strNames(i, j, k) = Sheets("Sheet" & k).Cells(i, j).Value
            Next j
        Next i
    Next k
    
    'Output Array Values to Range
    For k = 1 To 3
        For i = 1 To 60000
            For j = 1 To 10
                Sheets("Output" & k).Cells(i, j).Value = strNames(i, j, k)
            Next j
        Next i
    Next k
End Sub

AutoMacro | Ultimate VBA Add-in | Click for Free Trial!

Array Length / Size

So far, we’ve introduced you to the different types of arrays and taught you how to declare the arrays and get/set array values. Next we will focus on other necessary topics for working with arrays.

UBound and LBound Functions

The first step to getting the length / size of an array is using the UBound and LBound functions to get the upper and lower bounds of the array:

Sub UBoundLBound()
    Dim strNames(1 To 4) As String
    
    MsgBox UBound(strNames)
    MsgBox LBound(strNames)
End Sub

Subtracting the two (and adding 1) will give you the length:

GetArrLength = UBound(strNames) - LBound(strNames) + 1

Array Length Function

Here is a function to get a single-dimension array’s length:

Public Function GetArrLength(a As Variant) As Long
   If IsEmpty(a) Then
      GetArrLength = 0
   Else
      GetArrLength = UBound(a) - LBound(a) + 1
   End If
End Function

Need to calculate the size of a 2D array? Check out our tutorial: Calculate Size of Array.

Loop Through Array

There are two ways to loop through an array.  The first loops through the integers corresponding to the number positions of the array. If you know the array size you can specify it directly:

Sub ArrayExample_Loop1()
    Dim strNames(1 To 4) As String
    Dim i As Long

    strNames(1) = "Shelly"
    strNames(2) = "Steve"
    strNames(3) = "Neema"
    strNames(4) = "Jose"
    
    For i = 1 To 4
        MsgBox strNames(i)
    Next i
End Sub

However, if you don’t know the array size (if the array is dynamic), you can use the LBound and UBound functions from the previous section:

Sub ArrayExample_Loop2()
    Dim strNames(1 To 4) As String
    Dim i As Long

    strNames(1) = "Shelly"
    strNames(2) = "Steve"
    strNames(3) = "Neema"
    strNames(4) = "Jose"
    
    For i = LBound(strNames) To UBound(strNames)
        MsgBox strNames(i)
    Next i
End Sub

AutoMacro | Ultimate VBA Add-in | Click for Free Trial!

For Each Array Loop

The second method is with a For Each Loop. This loops through each item in the array:

Sub ArrayExample_Loop3()
    Dim strNames(1 To 4) As String
    Dim Item

    strNames(1) = "Shelly"
    strNames(2) = "Steve"
    strNames(3) = "Neema"
    strNames(4) = "Jose"
    
    For Each Item In strNames
        MsgBox Item
    Next Item
End Sub

The For Each Array Loop will work with multi-dimensional arrays in addition to one-dimensional arrays.

Loop Through 2D Array

You can also use the UBound and LBound functions to loop through a multi-dimensional array as well. In this example we will loop through a 2D array.  Notice that the UBound and LBound Functions allow you to specify which dimension of the array to find the upper and lower bounds (1 for first dimension, 2 for second dimension).

Sub ArrayExample_Loop4()
    Dim strNames(1 To 4, 1 To 2) As String
    Dim i As Long, j As Long

    strNames(1, 1) = "Shelly"
    strNames(2, 1) = "Steve"
    strNames(3, 1) = "Neema"
    strNames(4, 1) = "Jose"
    
    strNames(1, 2) = "Shelby"
    strNames(2, 2) = "Steven"
    strNames(3, 2) = "Nemo"
    strNames(4, 2) = "Jesse"
    
    For j = LBound(strNames, 2) To UBound(strNames, 2)
        For i = LBound(strNames, 1) To UBound(strNames, 1)
            MsgBox strNames(i, j)
        Next i
    Next j
End Sub

Other Array Tasks

Clear Array

To clear an entire array, use the Erase Statement:

Erase strNames

Usage Example:

Sub ArrayExample()
    Dim strNames(1 to 4) as String

    strNames(1) = "Shelly"
    strNames(2) = "Steve"
    strNames(3) = "Neema"
    strNames(4) = "Jose"

    Erase strNames
End Sub

Alternatively, you can also ReDim the array to resize it, clearing part of the array:

ReDim strNames(1 to 2)

This resizes the array to size 2, deleting positions 3 and 4.

AutoMacro | Ultimate VBA Add-in | Click for Free Trial!

Count Array

You can count the number of positions in each dimension of  an array using the UBound and LBound Functions (discussed above).

You can also count the number of entered items (or items that meet certain criteria) by looping through the array.

This example will loop through an array of objects, and count the number of non-blank strings found in the array:

Sub ArrayLoopandCount()
    Dim strNames(1 To 4) As String
    Dim i As Long, n As Long

    strNames(1) = "Shelly"
    strNames(2) = "Steve"
    
    For i = LBound(strNames) To UBound(strNames)
        If strNames(i) <> "" Then
            n = n + 1
        End If
    Next i
    
    MsgBox n & " non-blank values found."
End Sub

Remove Duplicates

At some point, you may want to remove duplicates from an Array. Unfortunately, VBA does not have a built-in feature to do this. However, we’ve written a function to remove duplicates from an Array (it’s too long to include in this tutorial, but visit the link to learn more).

Filter

The VBA Filter Function allows you to Filter an Array. It does so by creating a new array with only the filtered values.  Below is a quick example, but make sure to read the article for more examples for different needs.

Sub Filter_Match()
 
    'Define Array
    Dim strNames As Variant
    strNames = Array("Steve Smith", "Shannon Smith", "Ryan Johnson")
 
    'Filter Array
    Dim strSubNames As Variant
    strSubNames = Filter(strNames, "Smith")
    
    'Count Filtered Array
    MsgBox "Found " & UBound(strSubNames) - LBound(strSubNames) + 1 & " names."
 
End Sub

IsArray Function

You can test if a variable is an array using the IsArray Function:

Sub IsArrayEx()

    'Creates array with positions 1,2,3
    Dim arrDemo1(3) As String
    
    'Creates regular string variable
    Dim str As String
    
    MsgBox IsArray(arrDemo1)
    MsgBox IsArray(str)

End Sub

AutoMacro | Ultimate VBA Add-in | Click for Free Trial!

Join Array

You can quickly “join” an entire array together with the Join Function:

Sub Array_Join()
    Dim strNames(1 To 4) As String
    Dim joinNames As String

    strNames(1) = "Shelly"
    strNames(2) = "Steve"
    strNames(3) = "Neema"
    strNames(4) = "Jose"
    
    joinNames = Join(strNames, ", ")
    MsgBox joinNames
End Sub

Split String into Array

The VBA Split Function will split a string of text into an array containing values from the original string. Let’s look at an example:

Sub Array_Split()
    Dim Names() As String
    Dim joinedNames As String
    
    joinedNames = "Shelly,Steve,Nema,Jose"
    Names = Split(joinedNames, ",")

    MsgBox Names(1)
End Sub

Here we split this string of text “Shelly,Steve,Nema,Jose” into an array (size 4) using the a comma delimiter (,”).

Const Array

An Array cannot be declared as a constant in VBA. However, you can work around this by creating a function to use as an Array:

' Define ConstantArray
Function ConstantArray()
    ConstantArray = Array(4, 12, 21, 100, 5)
End Function

' Retrive ConstantArray Value
Sub RetrieveValues()
    MsgBox ConstantArray(3)
End Sub

Copy Array

There is no built-in way to copy an Array using VBA. Instead you will need to use a loop to assign the values from one array to another.

Sub CopyArray()

    Dim Arr1(1 To 100) As Long
    Dim Arr2(1 To 100) As Long
    Dim i As Long
    
    'Create Array1
    For i = 1 To 100
        Arr1(i) = i
    Next i
    
    'CopyArray1 to Array2
    For i = 1 To 100
        Arr2(i) = Arr1(i)
    Next i
    
    MsgBox Arr2(74)

End Sub

AutoMacro | Ultimate VBA Add-in | Click for Free Trial!

Transpose

There is no built-in VBA function to allow you to Transpose an array. However, we’ve written a function to Transpose a 2D Array. Read the article to learn more.

Function Return Array

A common question VBA developers have is how to create a function that returns an array. I think most of the difficulties are resolved by using Variant Arrays. We’ve written an article on the topic: VBA Function Return Array.

Using Arrays in Access VBA

Most of the Array examples above work exactly the same in Access VBA as they do in Excel VBA.   The one major difference is that when you wish to populate an array using Access data, you would need to loop through the RecordSet object rather than the Range object.

Sub RangeToArrayAccess()
   On Error Resume Next
   Dim strNames() As String
   Dim i As Long
   Dim iCount As Long
   Dim dbs As Database
   Dim rst As Recordset
   Set dbs = CurrentDb
   Set rst = dbs.OpenRecordset("tblClients", dbOpenDynaset)
   With rst
      .MoveLast
      .MoveFirst
      iCount = .RecordCount
      ReDim strNames(1 To iCount)
      For i = 1 To iCount
         strNames(i) = rst.Fields("ClientName")
         .MoveNext
      Next i
   End With
   rst.Close
   Set rst = Nothing
   Set dbs = Nothing
End Sub

Before I start, let me share a little secret with you… I really dislike VBA arrays.  There just seem to be too many oddities in how they work.  Compared with other programming languages, VBA seems to make arrays overly complicated.  If you feel the same, then you’re in the right place.  This post contains a lot of code examples, which will cover most of your use cases.

Thank you to Jon Peltier for suggesting how I can improve this post.

Download the example file

I recommend you download the example file for this post.  Then you’ll be able to work along with examples and see the solution in action, plus the file will be useful for future reference.

Download the file: 0017 VBA Arrays.zip

What is an array & when to use it?

An array is a list of variables of the same type.  For example, a list of supplier names would be an array.

Let’s assume we have a list of 5 suppliers that can change each month.  Look at the screenshot below as an example:

To hold the supplier list, we could create 5 variables, then assign values from a worksheet to each variable.  This is what the code might look like:

Sub ListSuppliers()

'Create the variables
Dim Supplier1 As String
Dim Supplier2 As String
Dim Supplier3 As String
Dim Supplier4 As String
Dim Supplier5 As String

'Assign values to the suppliers
Supplier1 = ActiveSheet.Range("A2").Offset(0, 0).Value2
Supplier2 = ActiveSheet.Range("A2").Offset(1, 0).Value2
Supplier3 = ActiveSheet.Range("A2").Offset(2, 0).Value2
Supplier4 = ActiveSheet.Range("A2").Offset(3, 0).Value2
Supplier5 = ActiveSheet.Range("A2").Offset(4, 0).Value2

End Sub

That doesn’t seem too bad, does it?  Now imagine we have to list 1,000 suppliers, or 10,000 suppliers; that’s going to be a very dull day of coding.  Unless, of course, we use an array.

Also, what if we have an unknown number of suppliers.  What are we going to do then?  We would need create more variables than we need just to ensure there is enough space.  Again we can turn to a VBA array.

Look at the code below; it creates an array to hold 10,000 suppliers, populated from 10,000 cells in column A. You don’t need to understand it at this stage; instead, just be impressed with how neat and tidy it is. It’s difficult to believe that a VBA array containing a list of 10,000 items takes less code than a list of five variables.

Sub ListSuppliersArray()

Dim Suppliers(1 To 10000) As String
Dim i As Long

For i = LBound(Suppliers) To UBound(Suppliers)

    Suppliers(i) = ActiveSheet.Range("A2").Offset(i - 1, 0).Value2

Next i

End Sub

Using the VBA above, it doesn’t matter if there are 1, 20, 50, 1,000, or 10,000 items, the code will be the same length.  This is the advantage of arrays; we don’t have to write the same code over and over.  Instead we can write one piece of code which add all of the items into an array.

But, it doesn’t end there.  If the values to assign are in a contiguous range, we can reduce the code to just a few lines.  Look at the macro below; a range of 10,000 cells is assigned to a Variant variable type, which automatically creates an array of 10,000 items (no looping required).  Amazing stuff, right?

Sub ListSuppliersArray()

Dim Suppliers As Variant

Suppliers = ActiveSheet.Range("A2:A10001").Value2

End Sub

OK, now we understand the benefits of VBA arrays, let’s learn how to use them.

Static vs. dynamic Arrays

Arrays come in two forms:

• Static – an array with a fixed number of elements
• Dynamic – an array where the number of elements is determined as the macro runs.

The difference between the two is how they are created. After that, accessing values, looping through elements and other actions are exactly the same.

Declaring an array as a variable

Arrays are declared in the same way as single value variables.  The critical difference is that when declaring an array parentheses are often used after the variable name.

Declare a single variable

'Declare a string as a single variable
Dim myVariable As String

Declare an array variable

'Declare a string as an array
Dim myArray(1 to 5) As String

Arrays, like other variables can be any variable type.  Integers, strings, objects and ranges, etc., can all be included in an array.

Using variant as an array

A variable declared as a Variant can hold any data type.  Interestingly, a Variant type can also become an array if we assign an array to it.

Look at the code below.  First, a standard variable with a Variant data type is created, then an array is assigned to the variable.  As a result, the variable has become an array, and can be treated the same as other arrays.

Dim arrayAsVariant As Variant 
arrayAsVariant = Array("Alpha", "Bravo", "Charlie")

Create a static array

The following macro creates a static array with 5 elements (1, 2, 3, 4 & 5).

Sub CreateStaticArray()

'Create a static array with 5 elements (1, 2, 3, 4, 5)
Dim arr(1 To 5) As Long

End Sub

By default, arrays have base 0, which means they start counting at 0, rather than 1.  The following macro creates a static array with 6 elements (0, 1, 2, 3, 4, 5).  Notice that the array is created with 5 inside the parentheses, but because of base 0, there are actually 6 elements created.

Sub CreateStaticArrayStartingAtZero()

'Create a static array with 6 elements (0, 1, 2, 3, 4, 5)
Dim arr(5) As Long

End Sub

We can turn arrays into base 1 (i.e., counting starts at 1) by inserting the following code at the top of the code module.

Option Base 1

Create a static two-dimension array

Arrays can contain multiple dimensions (or sub-arrays).  This is much like having data in rows and column.  In the code below, we have created a static array of 3 elements, each of which is its own array containing another 3 elements.

Sub Create2DimensionStaticArray()

Dim arr(1 To 3, 1 To 3) As String

arr(1, 1) = "Alpha"
arr(1, 2) = "Apple"
arr(1, 3) = "Ant"
arr(2, 1) = "Bravo"
arr(2, 2) = "Ball"
arr(2, 3) = "Bat"
arr(1, 1) = "Charlie"
arr(2, 2) = "Can"
arr(3, 3) = "Cat"

End Sub

We’re not limited to just two dimensions, VBA allows us up to 60!  I don’t think I’ve very used more than 3, but it’s good to know that there are so many spare.

Create a dynamic array

The problem with static arrays is that we need to know how many elements are required when we create the array.  But often we don’t know the number of elements, or maybe we want to add and remove elements from the array as we go.  Instead, we can turn to dynamic arrays.

NOTE – The term “dynamic array” in Excel and VBA is not the same; they are entirely different methodologies.

The following macro initially creates a dynamic array with no size.  Then, later in the macro, the array is resized, using ReDim, to create 5 elements, starting at 1.

Sub CreateDynamicArray()

'Create the array
Dim arr() As Long

'Resize the array later in the macro
ReDim arr(1 To 5)

End Sub

A dynamic array can be resized many times during macro execution (we will see this later in this post).

Index locations

Each element of an array has an index number (i.e., the position in the array).

Index of the first element

The following macro displays the index number of the first element in an array.

Sub GetIndexOfFirstElement()

'Create the array
Dim arr As Variant
arr = Array("Alpha", "Bravo", "Charlie")

'Get the index number of the first element
MsgBox LBound(arr)

End Sub

LBound() is a function which returns the lowest item in the array.

Index of the last element

The following macro displays the index number of the last element in an array.

Sub GetIndexOfLastElement()

'Create the array
Dim arr As Variant
arr = Array("Alpha", "Bravo", "Charlie")

'Get the index number of the last item element
MsgBox UBound(arr)

End Sub

UBound() is a function which returns the highest item in the array.

Assigning values to an array

After creating an array, whether dynamic or static, we need a way to assign values to the individual elements.

Assign values to elements individually

The following macro creates a static array, then assigns values to each element individually.

Sub AssignFixedValuesToArray()

Dim arr(1 To 5) As String

arr(1) = "Alpha"
arr(2) = "Bravo"
arr(3) = "Charlie"
arr(4) = "Delta"
arr(5) = "Echo"

End Sub

Assign values to elements with an array list

The following macro demonstrates how to assign values to a dynamic array based on a list of values.

Sub AssignValuesFromListToArray()

'Type must be Variant for method to work
Dim arr As Variant
arr = Array("Alpha", "Bravo", "Charlie")

End Sub

The Array() command is a short way to add values to an array.

Assign values to elements with a string

The following macro splits a string into an array.

Sub SplitStringIntoArray()

Dim arr As Variant
Dim myString As String

'Create list with a by common seperator between each element
myString = "Alpha, Bravo, Charlie, Delta, Echo"

'Turn the list into an array
arr = Split(myString, ", ")

End Sub

Assign values to elements from a range

The following macro creates a 2-dimensional array directly from a range.

Sub ReadRangeToArray()

Dim arr As Variant
arr = ActiveSheet.Range("A1:C3").Value2

End Sub

When using this method, the created array will always contain two-dimensions (just like the rows and column from the range).  So, even if the source range is a single row or column, the array will still contain two-dimensions.

Convert arrays to string and ranges

Having got an array, we can then convert it into either a string or display the values in a range.

Convert array to string

The following code creates an array, then uses the Join function to convert it into a string.

Sub JoinArrayIntoString()

Dim arr As Variant
Dim joinedString As String

'Create an array
arr = Array("Alpha", "Bravo", "Charlie")

'Turn array into a string, each item separated by a comma
joinedString = Join(arr, " ,")

End Sub

Convert array to range

A 2-dimensional array can be written to the cells in a worksheet in either a horizontal or vertical direction.

Sub WriteArrayToRange()

Dim arr As Variant
arr = Array("Alpha", "Bravo", "Charlie", "Delta", "Echo")

'Write array across columns
ActiveSheet.Range("D1:H1") = arr

'Alternative, write an array down rows
'ActiveSheet.Range("D1:D5") = Application.Transpose(arr)

End Sub

Looping through each element in an array

There are two ways to loop through the elements of an array:

• For loop – Using the LBound and UBound functions to determine the number of times to loop
• For Each loop – Loops through every item in the array

NOTE – The For Each loop can only read the elements in an array; it cannot be used to change the values assigned to elements.

For loop: single-dimension array

The following example creates a single dimension array, then loops through each element in the array.

Sub ForLoopThroughArray()

Dim arr As Variant
Dim i As Long

arr = Array("Alpha", "Bravo", "Charlie", "Delta", "Echo")

'Loop from the LowerBound to UpperBound items in array
For i = LBound(arr) To UBound(arr)

    MsgBox arr(i)

Next i

End Sub

For loop: multi-dimension array

A For loop can also be used for multi-dimension arrays, as shown in the code below.

Sub ForLoopThrough2DimensionArray()

Dim arr(1 To 3, 1 To 3) As String
Dim i As Long
Dim j As Long

arr(1, 1) = "Alpha"
arr(1, 2) = "Apple"
arr(1, 3) = "Ant"
arr(2, 1) = "Bravo"
arr(2, 2) = "Ball"
arr(2, 3) = "Bat"
arr(3, 1) = "Charlie"
arr(3, 2) = "Can"
arr(3, 3) = "Cat"

For i = LBound(arr) To UBound(arr)

    For j = LBound(arr, 2) To UBound(arr, 2)

        MsgBox arr(i, j)

    Next j

Next i

End Sub

For Each loop: single-dimension array

The For Each loop works on a single or multi-dimension array.  However, it can only read data from an array, it cannot assign values to an array.

Sub ForEachLoopThroughArray()

Dim arr As Variant
Dim arrElement As Variant

arr = Array("Alpha", "Bravo", "Charlie", "Delta", "Echo")

'Loop through array using For Each method
For Each arrElement In arr

    MsgBox arrElement

Next arrElement

End Sub

For Each loop: multi-dimension array

The example below is to illustrate that the For Each loop is identical for both single and multi-dimension arrays.

Sub ForEachLoopThrough2DimensionArray()

Dim arr(1 To 3, 1 To 3) As String
Dim arrElement As Variant

arr(1, 1) = "Alpha"
arr(1, 2) = "Apple"
arr(1, 3) = "Ant"
arr(2, 1) = "Bravo"
arr(2, 2) = "Ball"
arr(2, 3) = "Bat"
arr(3, 1) = "Charlie"
arr(3, 2) = "Can"
arr(3, 3) = "Cat"

'Loop through array
For Each arrElement In arr

    MsgBox arrElement

Next arrElement

End Sub

Check if a value is in an array

We often need to search an array to discover if an item exists.  The following is a reusable function for searching through an array for a specific value.

The result of the function can be:

• True = The value searched is in the array
• False = The value searched is not in the array

The function takes two arguments (1) the array and (2) the value to find.

Function IsValueInArray(arr As Variant, find As Variant) As Boolean

Dim arrElement As Variant

'Loop through array
For Each arrElement In arr

    If arrElement = find Then
        IsValueInArray = True
        Exit Function
    End If

Next arrElement

IsValueInArray = False

End Function

The following is an example of how to call the function above; it tells the function to search for the string “Bravo” within the array.  The result returned is True if found, or False if not.

Sub UseFunctionValueInArray()

Dim arr As Variant
Dim arrElement As Variant

arr = Array("Alpha", "Bravo", "Charlie", "Delta", "Echo")

MsgBox IsValueInArray(arr, "Bravo")

End Sub

Find the index of an element in an array

In the previous sections we returned True of False depending on if an item exists.  But often that is not enough, we want to know where it is in the array.  The following is a reusable function which finds a value in an array, then returns the index position:

The result of the function can be:

• Number returned = The index position of the searched value
• False = The value searched was not found

The function takes two arguments the value to find and the array to search.

Function PositionInArray(arr As Variant, find As Variant) As Variant

Dim i As Long

For i = LBound(arr) To UBound(arr)

    If arr(i) = find Then

        PositionInArray = i
        Exit Function

    End If

Next i

PositionInArray = False

End Function

The following shows how to use the function above; if the string “Bravo” is found within the array, it will return the index position, or False if not found.

Sub UseFunctionPositionInArray()

Dim arr As Variant
Dim arrElement As Variant

arr = Array("Alpha", "Bravo", "Charlie", "Delta", "Echo")

MsgBox PositionInArray(arr, "Bravo")

End Sub

Resizing an array

As we’ve seen above, dynamic arrays are declared without a size.  Then later in the code, ReDim is used to size the array.  ReDim can be used many times during the macro to resize a dynamic array.

Static arrays cannot be resized, trying to do so, leads to an error.

When resizing an array with ReDim, the assigned values will be cleared out. To keep the existing values we must use the ReDim Preserve command.

Resize and blank values

The macro below creates, then resizes an array.  After that, the code loops through the array to demonstrate that folowing a ReDim the the values are cleared.

Sub ResizeArraySize()

Dim arr As Variant
Dim arrElement As Variant

arr = Array("Alpha", "Bravo", "Charlie", "Delta", "Echo")

'Array will resize by lose all previous values
ReDim arr(0 To 5)

'Loop through array using For Each method - all elements blank
For Each arrElement In arr

    MsgBox arrElement

Next arrElement

End Sub

Resize array and keep existing values

The following macro creates, then resizes an array using ReDim Preserve.  As the For Each loop demonstrates, by using ReDim Preserve, the values are maintained.

Sub ResizeArraySizeKeepValues()

Dim arr As Variant
Dim arrElement As Variant

arr = Array("Alpha", "Bravo", "Charlie", "Delta", "Echo")

'Array will resize by lose all previous values
ReDim Preserve arr(0 To 5)

'Add additional value into the array
arr(5) = "Foxtrot"

'Loop through array using For Each method - all elements blank
For Each arrElement In arr

    MsgBox arrElement

Next arrElement

End Sub

Sorting array order

The following function sorts an array alphabetically.  The function takes a single argument, the array to be sorted.

Function SortingArrayBubbleSort(arr As Variant)

Dim i As Long
Dim j As Long
Dim temp As Variant

For i = LBound(arr) To UBound(arr) - 1

    For j = i + 1 To UBound(arr)

        If arr(i) > arr(j) Then

            temp = arr(j)
            arr(j) = arr(i)
            arr(i) = temp

        End If

    Next j

Next i

SortingArrayBubbleSort = arr

End Function

The following is an example of how to use the function above.

Sub CallBubbleSort()

Dim arr As Variant
arr = Array("Charlie", "Delta", "Bravo", "Echo", "Alpha")

arr = SortingArrayBubbleSort(arr)

End Sub

Reverse array order

The function below reverses the order of an array.  The function takes the name of an array as the only argument.

Function ReverseArray(arr As Variant)

Dim temp As Variant
Dim i As Long
Dim arrSize As Long
Dim arrMid As Long

arrSize = UBound(arr)
arrMid = (UBound(arr) - LBound(arr))  2 + LBound(arr)

For i = LBound(arr) To arrMid

    temp = arr(arrSize)
    arr(arrSize) = arr(i)
    arr(i) = temp
    arrSize = arrSize - 1

Next i

ReverseArray = arr

End Function

The code below is an example of how to use the function above.

Sub CallReverseArray()

Dim arr As Variant
arr = Array("Alpha", "Bravo", "Charlie", "Delta", "Echo")

arr = ReverseArray(arr)

End Sub

Filter an array

Along with LBound, UBound, Split and Join, another useful built-in function is Filter.

The Filter function returns an array that includes only the elements which contain a sub-string.  In the example below the filteredArr array only includes the elements which contain the letter “o”,

Sub FilterArray()

Dim arr As Variant
Dim filteredArr As Variant
Dim arrElement As Variant

arr = Array("Alpha", "Bravo", "Charlie", "Delta", "Echo")

'Filter array for any elements with the letter "o"
filteredArr = Filter(arr, "o")

'Loop through the filtered array
For Each arrElement In filteredArr

    MsgBox arrElement

Next arrElement

End Sub

The Filter function has 4 arguments:

Filter(SourceArray, Match, [Include], [CompareType])

• SourceArray – the original array
• Match – the substring to match
• Include (default is True if the argument is excluded)
  • True = include the matched items
  • False = exclude the matched items
• CompareType Include (default is 0 if the argument is excluded):
  • 0 = vbBinaryCompare – The match is case sensitive
  • 1 = vbTextCompare – The match is not case sensitive

Conclusion

Hopefully, this post covers most of your needs.  However, VBA arrays are a vast topic, so make use of online forums to ask specific questions which this post doesn’t answer.