Week of the month in excel

22 Responses

1. Hi,

   I need to know how to execute the below condition in excel through formulas mentioned in this forum-
   E.g. 29th Oct 2018 to 30th Oct 2018 should fall in first week of November instead of Week 5 of October. In other words, my Week is starting on Saturday, So Oct 2018 will have 4 weeks only and date 29th Oct to 2nd Nov, 2018 should fall in Week 1 of November. The formula I am using as of now is as below –
   =IF(K89=”No Date”,”No Week”,CONCAT(“Week “,WEEKNUM(I89-1)-WEEKNUM(I89-DAY(I89)-6)))

   Please help.

   1. Hi Manoj,
      The WEEKNUM function has an optional argument that lets you specify which day should be treated as the start of the week. To tell WEEKNUM to use Saturday as the first day of the week, use a formula like: =WEEKNUM(I89,16)

      The ‘magic number’ 16 indicates that Saturday should be the start of the week, but you can see a list of all of the week start options in Excel’s help files.

2. So I have been trying to use the function to track two rolling week dates in excel, and the issue is that i cant get it to work consistently.

   I am tracking Mondays, so using the 2 code.
   The issue is that i need it to accurately roll from identifying the week span of wk5-wk1 to wk1-wk2 and so on. But because of how the week dates are spread apart if i set the spacing so that the mondays get tracked it will either show wk4-wk1 to wk1-wk2 or it will do wk5-wk1 to wk2-wk2.
   Can you help me fix this?

   1. Hi Jacob,
      I’m afraid I’m having some trouble understanding your question, but it might help to know that there are two different algorithms that the WEEKNUM function can use. If you use 21 instead of 2 the function will use the alternate system of week numbers. You can find more information in the help file.

3. Hi, when I am calculating the week number of 09/27/2019, using =WEEKNUM(A1,2)-WEEKNUM(DATE(YEAR(A1),MONTH(A1),1),2)+1 then the result shows 5. But as per the Indian calendar, it should be 4. How can i get it?

   1. Hi Abhishek,

      The second parameter of the WEEKNUM function offers the choice of two different systems of week numbering. The formula shown above uses system 1, which treats the week containing the 1st of January as the first week of the year.
      My guess is that the Indian calendar may use system 2, which treats the week containing the first Thursday of the year as the first week of the year.

      You can easily modify the formula to use system 2 by changing it to:
      =WEEKNUM(A1,21)-WEEKNUM(DATE(YEAR(A1),MONTH(A1),1),21)+1

      Unfortunately this still seems to return a 5 for the date you mentioned, so my guess is that you may need one of the other options. There are a total of 10 different options that you can use to control how the week number is calculated and you can find them all listed on Microsoft’s help page for the WEEKNUM function.

      1. Great. It works for me.

4. How do I create a formula that will calculate a monthly date? I need the formula to work so that the date will always be the 2nd week of the month on a Thursday throughout the year (and the next year etc)

   1. Hi Sally

      Our Book “Excel 2019 Construction Kit #1: Calendar and Year Planner” contains many advanced date/time calculations (such as calculating the current phase of the moon from a date).

      One of the problems solved in the book is to calculate the dates of public holidays. A common format for a public holiday is:

      The [Nth] [Day Name] in [Month Name]

      For example, Martin Luther King day is the third Monday in January.

      Finding dates such as the second Thursday in January is very simple for humans to understand but is a little more challenging for Excel. The problem arises because months have a variable number of days and can begin on a different day each year.

      Session 4 of the book suggests three different ways to solve this problem.

      1. By combining the DATE, WEEKDAY and MOD functions.
      2. By combining the DATE, CHOOSE and WEEKDAY functions.
      3. A novel generic solution that uses a simple four argument function call to return the correct answer.

      The first two methods are quite complex but the last makes this type of calculation very simple. The book explains in simple terms how each method can be implemented and how the functions work but, since you asked, here are the formulas (in the context of Martin Luthor King day which falls on the third Monday in January).

      Solution 1. =DATE(CalendarYear,1,15)+ MOD(7-WEEKDAY(DATE(CalendarYear,1,15),3),7)
      Solution 2. =DATE(CalendarYear,1,15)+CHOOSE(7-WEEKDAY(DATE(CalendarYear,1,15),3),1,2,3,4,5,6,0)

      The named range CalendarYear in the example above is the year under consideration.

      For Solution 3 you’d have to study Session 4 in the above book but it enables the same result with a very simple function call by moving much of the logic to a separate table (without any use of macros or VBA code).

      Best Regards

      Mike Smart

5. Want to calculate attendance on weekly basis. Week starts from Monday and ends on Friday. How I will get numbers of days student is present in a week

   1. Hi Komal

      This is quite easy to do using Excel 365’s SUMPRODUCT dymanic array function. The use of SUMPRODUCT is quite quirky but is explained in depth in the Excel 365 Expert Skills book. It is hard to guess the exact result you are trying to achieve without understanding the structure of your workbook but, in short, you’d begin by creating custom logic arrays to identify the values you wanted to sum and then use one or more SUMPRODUCT functions to sum the rows and columns you had identified.

      If you read and understand the dynamic array session in the Excel 365 Expert Skills book and are still unable to solve the problem feel free to e-mail me an I’ll point you in the right direction.

6. How to know the nth occurrence of a day of a given date is either 1st, 2nd, 3rd, 4th or 5th in a month?
   e.g.
   29-May-2020 = 5th occurrence of Friday
   15-May-2020 = 3rd Occurrence of Friday in May month.

   1. Hi Quadeer,

      See my answer to Sally above that includes the answer to your question.

7. Hi Simon,
   I am trying to find out how many weeks in Aug 2020 and weeks should be started from Monday. when i am using above formula its showing week count 6 but as per Aug month it has 5 weeks. Could you please help me.

   1. Hi Shankar

      Here are the week numbers for 1-Aug-2020 and 31-Aug-2020 (obtained with the ISOWEEKNUM formula that regards the first day of the week as Monday and treats the first week of the the year containing a Thursday as week number 1). The ISO standard is the most widely used week numbering standard.

      

      Monday 31st August 2020 is correctly the sixth week number occurring in the month.

      Your question highlights how important it is to define terminology precisely when designing information systems as “week of the month” is not a carefully enough defined term.

      The question you are receiving the correct answer to is:

      How many different week numbers could any date during this month fall into?
      The correct answer to this question (for Aug 2020) is six.

      The question you are asking might be:
      How many full weeks (Mon-Sat) were there in August 2020?
      The correct answer to this question is four.

      Or it might also be:

      How many Mondays were there in Aug 2020?
      The correct answer to this question is five.

      With the above information I’m sure you can re-phrase your requirement “I am trying to find out how many weeks in Aug 2020” to one of the above three questions. I’m sure you’ll then have no difficulty in creating a formula that finds the right answer.

      Mike Smart

8. When the date is 08-01-2021 the result of the formula is -51.
   Can you please recheck the formula?
   The one is used is:
   =WEEKNUM(A1,2)–WEEKNUM(DATE(YEAR(A1),MONTH(A1),1),2)+1

   1. Hi Richard

      I’ve just tested this with both 1-Aug-21 and 8-Jan-21 in cell A1 (as it isn’t clear which part of the world you are in so your date could have two meanings). 1-Aug-21 returned 1 and 8-Jan-21 returned 2. The formula was:

      =WEEKNUM(A1,2)-WEEKNUM(DATE(YEAR(A1),MONTH(A1),1),2)+1

      I cannot understand how you were able to achieve a result of -51. Try copying and pasting the above formula into our own workbook. Perhaps this will enable you to solve the problem.

      1. Hi Mike,
         I am using this formula =WEEKNUM(A1,2)-WEEKNUM(DATE(YEAR(A1),MONTH(A1),1),2)+1

         to get week number. but its not working. my 1st start date is 1 March 2021 its starting from Monday, it should show 1 week from 1 to 7mar and 8mar to 14 mar as week 2 and onwards. when i reach to 29th march to 4th April it should show result as 1 week but instead of it its showing 5th week. again if i reach to 5th April to 11 April it should show 1st week but showing 2nd week.

         kindly help.

         1. Hi Sandeep

            Your formula calculates two numbers:

            1/ The week number that the first day of the month falls within. In the case of 1st April 2021 this is week 14 of the year (you have opted for System 1 when the week containing January 1st is considered the first week of the year and is numbered 1. You have also set the week to begin on Monday).

            1st Jan 2021 was a Friday so the first three days of 2021 were in Week 1 and then 4th Jan began Week 2.

            29 Mar -4 April is thus Week 14 of the year and 5 April to 11 April is Week 15.

            To determine the week number of the current month you are taking the week number of the year and subtracting the week number that the 1st of the month was within. In this case the 1-Apr-2021 is in week 14. For this reason 1-4 April 2021 fall in the 1st week of the month and the second week begins on 5th April 2021 so the results you are seeing are correct.

            There are many ways of defining the “Week of the month” used throughout the world. Your question highlights how important it is to define terminology precisely when designing information systems as “week of the month” is not a carefully enough defined term.

            I’m guessing that your actual requirement is:

            “Regard the 1st of each month, and the six days that follow, as “Week 1” and increment the week number every seven days. When the 1st of the next month comes around, reset week numbering to “Week 1 again”.

            This is easily done of course, using nothing fancier than a little math and a thorough understanding of Excel date serial numbers (covered extensively in both the Essential Skills and Expert skills books). Perhaps your requirement is different again? Whatever it is you should be able to design a solution using date serial number offsets, perhaps in conjunction with the WEEKNUM function.

            I hope that the above information enables you to design the solution that you need.

         2. Hi Sandeep

            The formula calculates two numbers:

            1/ The week number that the first day of the month falls within. In the case of 1st April 2021 this is week 14 of the year (you have opted for System 1 when the week containing January 1st is considered the first week of the year and is numbered 1. You have also set the week to begin on Monday).

            1st Jan 2021 was a Friday so the first three days of 2021 were in Week 1 and then 4th Jan began Week 2.
            29 Mar -4 April is thus Week 14 of the year and 5 April to 11 April is Week 15.

            To determine the week number of the current month you are taking the week number of the year and subtracting the week number that the 1st of the month was within. In this case the 1-Apr-2021 is in week 14. For this reason 1-4 April 2021 fall in the 1st week of the month and the second week begins on 5th April 2021 so the results you are seeing are correct.

            There are many ways of defining the “Week of the month” used throughout the world. Your question highlights how important it is to define terminology precisely when designing information systems as “week of the month” is not a carefully enough defined term.

            I’m guessing that your actual requirement is:

            “Regard the 1st of each month, and the six days that follow, as “Week 1” and increment the week number every seven days. When the 1st of the next month comes around, reset week numbering to “Week 1 again”.

            This is easily done of course, using nothing fancier than a little math and the date serial number (covered extensively in both the Essential Skills and Expert skills books). Perhaps your requirement is different again?

            I hope that the above information enables you to design the solution that you need.

9. I’m getting odd results for May and Aug of 2021. I have a column (A) of Friday dates and I am trying to find which Friday of the month each of these dates represent – 1st friday of the month, 2nd friday of the month, etc. Tried each of these:
   =WEEKNUM(A2,1)-WEEKNUM(DATE(YEAR(A2),MONTH(A2),1),1)+1
   shows May 7 as 2nd week and the other May fridays are one week off
   =WEEKNUM(A2,2)-WEEKNUM(DATE(YEAR(A2),MONTH(A2),1),2)+1
   shows May 7 as 2nd week and Aug 6 as 2nd week and other fridays in those months are similarly one week off

   1. Hi Scott

      To set Friday as the first day in the week you need to use 15 as the second argument for the weeknum function:

      For Friday 7th May 2021

      =WEEKNUM(A2,15)

      … returns week 19 as Friday 7th May begins Week 19 (as May 2021 began on a Saturday)’

      =WEEKNUM(DATE(YEAR(A19),MONTH(A19),1),15)

      .. returns week 18 as (on 1st May 2021) the first Friday in May 2021 has not yet arrived.

      The sum 18-17 returns 1 making Friday 7th May 2021 as the first Friday in the month of May 2021.

      For your requirement you do not need to subtract one because you do not want the days prior to Friday to be regarded as week 1 of the month in question. Given this you should appreciate why:

      =WEEKNUM(A19,15)-WEEKNUM(DATE(YEAR(A19),MONTH(A19),1),15)

      … will correctly identify 7th May 2021 as being the first Friday in May 2021.

I often find myself getting data out of one system or another (or multiple systems, and then combining them) as “daily” data — a series of metrics by day for a sequence of days. Sometimes, I work with that data at a daily level, but, often, I want to roll the data up by week, by month, or by some other time period.

For instance, if I want to look at the data weekly, I’ll use either the last day of the week or the first day of the week and then use a formula in a new column to convert each actual day to the “week” in which it falls:

In the example above, 1/15/2013 is a Tuesday that falls in a week that ends on Saturday, 1/19/2013. The same holds true for Wednesday (1/16), Thursday (1/17), Friday (1/18), and Saturday (1/19). As soon as get to 1/20/2013 (Sunday), I’m in a new week — a week that ends on 1/26/2013. Make sense?

By adding this column, I can create a pivot table that can easily generate weekly data for whatever metrics are in the spreadsheet.

This approach works for a number of different ways you might need to roll up daily data, so I thought a post that walks through some of the more common ones and the formula to carry out each conversion was in order. I’ve put all of the examples in this post in a downloadable spreadsheet that you can check out and play around with.

Day of Week

The WEEKDAY() function returns a number — 1, 2, 3, 4, 5, 6, or 7. But, what if you actually want the day of the week in plain English?

You can use the CHOOSE() function and hard code values. Or, you can make a separate table that maps a number to each weekday and use VLOOKUP to populate the values. I’m not going to discuss either of those approaches…because my preferred approach is to use the TEXT() function.

For the fully written out weekday (“$A3” is the cell with 1/15/2013 in it — you would just drag this formula down, or, if you’re using an Excel Table, it would autofill):

=TEXT($A3,”dddd”)

For the 3-letter weekday:

=TEXT($A3,”ddd”)

Easy-peasy, no?

Note: If you simply want the date to be displayed as the weekday, you don’t need a formula at all — you can simply change the cell formatting to a custom format of “dddd” (for the full weekday) or “ddd” (for the 3-letter weekday). If you do that, the display of the data will be as a weekday, but the underlying value will still be the actual date. This formula actually makes the value the weekday. Depending on what your needs are, one approach or the other will make more sense.

Convert to “Week Of”

The example I started this post with is converting each day to be the day that ends the week or the day that starts the week. To do this, you can use the WEEKDAY() function. The easiest way to understand how this works out is to write out (or put in Excel) a series of dates and then write the numbers 1 through 7 as you go down the dates. The farther you go into a week, the bigger the WEEKDAY() value is. So, if you subtract the WEEKDAY() value from the actual date, you will get the same value 7 days in a row, at which point the value will “jump” seven days. Make sense (it’s confusing…until it’s not)?

So, to convert a date to be the Saturday of the week the date falls in, use this formula (the “+7” just keeps the converted value from being the Saturday of the previous week):

=$A3-WEEKDAY($A3)+7

It’s the same idea if you wanted to use the first day of the week, with the week defined as starting on Sunday:

=$A3-WEEKDAY($A3)+1

Obviously, you can use this basic formula for whatever “week” criteria you want. You just have to either think about it really hard…or experiment until it’s doing what you want.

Convert to Bi-Weekly Date

Sometimes, a company operates on a bi-weekly cycle in some ways. For instance, a lot of companies pay their employees every two weeks. WEEKDAY() doesn’t work for this, because it doesn’t tell you which of the two weeks a day falls into.

In this case, I use MOD(). This function is, basically, a “remainder” function, and its main use is to calculate the remainder when one number is divided by another (for instance, “=MOD(14,4)” returns “2” because, when you divide 14 by 4, you get a remainder of 2).

Well, Excel dates are, under the hood, just numbers. You don’t really need to know exactly what number a date is (although you can change the cell formatting to “Number” when a date is displayed and you will see the number). But, if you think about it, if you divide a date by 14, it’s going to have a remainder between 1 and 13. Let’s say the remainder is “2.” So, what will the remainder be if you divide the next day by 14? It will be “3.” And so on until you get to 13, at which point the next day, if divided by 14, will have a remainder of 0. Hmmm. This seems like we’ve recreated the WEEKDAY() function used above…but with a 14-day long period instead of 7-day one, right? Exactly!

So, if we wanted to convert a date to be the Saturday at the end of the bi-week period, it would be one of these two formulas (depending on which Saturday is the cutoff and which is the mid-period point):

=$A3-MOD($A3-1,14)+13

or

=$A3-MOD($A3-8,14)+13

If you wanted to use the start of the period, with the week starting on Sunday, then it would be one of these two formulas:

=$A3-MOD($A3-1,14)

or

=$A3-MOD($A3-8,14)

Again, it takes some experimentation if you want to adjust to other dates, but the “14” will not change as long as you’re working on bi-weekly periods.

Convert to Bi-Monthly Date

Sometimes (again, company pay periods are a good example), rather than using a bi-weekly calendar, you want to use a bi-monthly calendar — every date from the 1st through the 14th should be converted to the first day of the month, and every day from the 15th through the end of the month should be coded as the 15th. To do this, we use the DATE() function with an IF() statement for the day value:

=DATE(YEAR($A3),MONTH($A3),IF(DAY($A3)<15,1,15))

We know the year is the YEAR() of the date being converted, and we know the month is the MONTH() of the date being converted. But, we need to look at the day of the month and check if it is less than 15. If it is, then we return a day value of “1,” and, otherwise, we return a day value of “15.”

Convert to Monthly Date

Monthly is almost as common, if not moreso, than weekly. To convert to the first day of the month is a straightforward use of the DATE() function. We pull the year using the YEAR() function on the date we’re converting, the month using the MONTH() function on the date we’re converting, and then simply hard code the “day” as “1:”

=DATE(YEAR($A3),MONTH($A3),1)

But, what if we want to use the last day of the month? We can’t hard code the “day” value because that day could be 28, 29 (leap year), 30, or 31. Curse you, Gregorian calendar!!!

Well, actually, this isn’t all that complicated, either. Why? Because the last day of the month is always the day before the first day of the next month. Huh? That’s right. That’s how we get the last day of the month: we use the DATE() function to figure out the first day of the next month (by adding 1 to the MONTH() value)… and then subtract 1:

=DATE(YEAR($A3),MONTH($A3)+1,1)-1

How do you like them apples?! [idiom ref.]

As an interesting aside, it would be understandable if this formula broke for the month of December. In that case, you’re actually telling Excel to calculate a date where the month is “13.” Luckily, Excel figures out what you mean and winds up returning January 1 of the following year (from which the formula then subtracts one to return December 31st).

But, What About…

I’ve just scratched the surface with possible date conversions in this post. Hopefully, the different approaches I described will trigger an idea or two for your specific situation. But, if you’ve got one that is stumping you, leave a comment here and I’ll take a crack at it!

And, all of the examples here are included in this downloadable spreadsheet. You can change the “start date” in cell A3 and all of the subsequent dates will automatically update. Happy date converting!