Visual basic excel value

VBA Value

The journey of VBA starts with knowing how the values get stored in the cells. Therefore, knowing VALUE function under VBA is of more importance. After studying about VBA VALUE property, you will be able to know how the values get stored under VBA. This article explains all the types of VALUE function in VBA like how the value gets stored in cells, hot to set the value, how to insert the value and many more.

How to Use Excel VBA Value Function?

We will learn how to use VBA Value function with few examples in Excel.

You can download this VBA Value Excel Template here – VBA Value Excel Template

Example #1 – Set Cell Value using Range.Value function

Setting of cell/s value using Range. Value function roughly consists of two important steps:

• Setting the range where you want the value to be stored.
• Assigning a value to the range set.

Follow the below steps to set value in Excel VBA:

Step 1: Insert a new module under Visual Basic Editor (VBE).

Step 2: Define a new sub-procedure under the inserted module so that a macro can be stored in it.

Code:

Sub VBA_Value_Ex1()

End Sub

Step 3: Define a new variable as a range which can be used to define a range where you wanted to store the value.

Code:

Sub VBA_Value_Ex1()

Dim setValue_Var As Range

End Sub

Step 4: With the help of the VBA RANGE function, assign the cells in the range to a variable defined with the help of the assignment operator.

Code:

Sub VBA_Value_Ex1()

Dim setValue_Var As Range
Set setValue_Var = ThisWorkbook.Worksheets("Setting_Cell_Value_1").Range("A1")

End Sub

Step 5: Now, use Range.Value property to be able to assign value to the range defined. Type the variable name “setValue_Var” under which the range is defined.

Sub VBA_Value_Ex1()

Dim setValue_Var As Range
Set setValue_Var = ThisWorkbook.Worksheets("Setting_Cell_Value_1").Range("A1")
setValue_Var

End Sub

Step 6: Put a dot (.) after variable to be able to select the IntelliSense list of functions available for this range variable defined.

Code:

Sub VBA_Value_Ex1()

Dim setValue_Var As Range
Set setValue_Var = ThisWorkbook.Worksheets("Setting_Cell_Value_1").Range("A1")
setValue_Var.

End Sub

Step 7: Drag down through the list and select “Value” function to store the value under this range variable.

Code:

Sub VBA_Value_Ex1()

Dim setValue_Var As Range
Set setValue_Var = ThisWorkbook.Worksheets("Setting_Cell_Value_1").Range("A1")
setValue_Var.Value

End Sub

Step 8: Assign “Welcome to the world of VBA!” as value to this range using assignment operator.

Code:

Sub VBA_Value_Ex1()

Dim setValue_Var As Range
Set setValue_Var = ThisWorkbook.Worksheets("Setting_Cell_Value_1").Range("A1")
setValue_Var.Value = "Welcome to the world of VBA!"

End Sub

Step 9: We are done with the coding part. Run this code by hitting F5 or Run button under VBE and see the output.

You also can assign the value to a range of cells. All you have to do is while setting the range for the output you will give one-dimensional array instead of a single cell reference.

Step 10: In the same code above, change the Range from “A1” to “A1: A5”.

Code:

Sub VBA_Value_Ex1()

Dim setValue_Var As Range
Set setValue_Var = ThisWorkbook.Worksheets("Setting_Cell_Value_1").Range("A1:A5")
setValue_Var.Value = "Welcome to the world of VBA!"

End Sub

Step 11: Hit F5 or Run button and see the output.

Example #2 – Set Cell Value using VBA Cells Property

This is another method for setting the cell value under VBA. Unlike the RANGE function, cells do not even need them. Value operator to be able to set value for the specific cell/s.

Follow the below steps to set the cell value in Excel VBA:

Step 1: Insert a new module under VBE where you can start writing your new piece of code.

Step 2: Add new sub-procedure under module inserted, where you can store your macro code in.

Code:

Sub VBA_Value_Ex2()

End Sub

Step 3: Start typing thisWorkbook.Worksheet to access the sheet named “Setting_Cell_Value_2”.

Code:

Sub VBA_Value_Ex2 ()

ThisWorkbook.worksheets

End Sub

Step 4: Mention the sheet name under parentheses in double quotes.

Code:

Sub VBA_Value_Ex2()

ThisWorkbook.Worksheets ("Setting_Cell_Value_2")

End Sub

Step 5: Use .Cells property to set the cell range from the given excel sheet.

Code:

Sub VBA_Value_Ex2()

ThisWorkbook.Worksheets("Setting_Cell_Value_2").Cells(1, 1)

End Sub

The first argument of the Cells property represents the rows and the second argument represents the column. Therefore, Cells(1, 1) means cell associated with the first row and first column of the sheet “Setting_Cell_Value_2”.

Step 6: Now, with the help of the assignment operator, assign a value to this cell set.

Code:

Sub VBA_Value_Ex2()

ThisWorkbook.Worksheets("Setting_Cell_Value_2").Cells(1, 1) = "VBA is Flexible."

End Sub

Have a look that we don’t need .Value function which we need to use while setting the value using Range function. Cells Method does not have such IntelliSense options.

Step 7: Hit F5 or Run button to run this code and see the output. You will see an output as shown in the screenshot below.

Example #3 – Get Cell Value in VBA

Until now, in two examples we have seen how to set value for a cell or range of cells. Now suppose a case is exactly reverse, we have to get the value assigned to a particular cell of an excel sheet. How can we get that? Let’s go through a step by step guide.

Suppose I have assigned a value as shown in the screenshot below under the first cell of column A in sheet “Getting_Cell_Value”.

Follow the below steps to get the cell value in Excel VBA:

Step 1: Insert a new module under VBE.

Step 2: Add a sub-procedure so that a macro can be stored as a code.

Code:

Sub VBA_Value_Ex3()

End Sub

Step 3: Define a new variable called Get_Value as a Variant using VBA Dim function.

Code:

Sub VBA_Value_Ex3()

Dim Get_Value As Variant

End Sub

Now, you have to assign the value present in cell A1 to the variable defined above.

Step 4: Type “Get_Value = ThisWorkbook.Worksheets”. This will allow the VBA compiler to access the excel sheet where your value is stored.

Code:

Sub VBA_Value_Ex3()

Dim Get_Value As Variant
Get_Value = ThisWorkbook.Worksheets

End Sub

Step 5: Mention the worksheet name under parentheses with quotations in which value is stored.

Code:

Sub VBA_Value_Ex3()

Dim Get_Value As Variant
Get_Value = ThisWorkbook.Worksheets("Getting_Cell_Value")

End Sub

Step 6: Now, use dot (.) Range method to provide the exact cell where value is stored under sheet named “Getting_Cell_Value”.

Code:

Sub VBA_Value_Ex3()

Dim Get_Value As Variant
Get_Value = ThisWorkbook.Worksheets("Getting_Cell_Value").Range("A1")

End Sub

Step 7: Finally, use dot (.) Value method so that the actual value under cell A1 can be accessed by the compiler.

Code:

Sub VBA_Value_Ex3()

Dim Get_Value As Variant
Get_Value = ThisWorkbook.Worksheets("Getting_Cell_Value").Range("A1").Value

End Sub

Step 8: As we have talked about, we need to get the value stored in cell A1. For that, use MsgBox to show the value of variable Get_Value (Which already have accessed the value typed in cell A1).

Code:

Sub VBA_Value_Ex3()

Dim Get_Value As Variant
Get_Value = ThisWorkbook.Worksheets("Getting_Cell_Value").Range("A1").Value
MsgBox Get_Value

End Sub

Step 9: Hit F5 or Run button to run this code, you will get the value present in cell A1 under the message box.

See, this was the value we have mentioned under cell A1 of sheet “Getting_Cell_Value”. Right?

Example #4 – Can we get Multiple Cell Values at a Time?

Let’s assume I have values stored in three different cells A1, A2, A3 as shown in the screenshot below:

Just don’t get confused if you see the text spread along columns A to E. it is just a visible layout (because I have merged the cells ) and the actual value is stored under cell A1, A2, A3 only.

Follow the below steps to use Excel VBA Value:

Step 1: Define a variable as a variant under a new sub-procedure in your VBA module.

Code:

Sub VBA_Value_Ex4()

Dim Get_Value_2 As Variant

End Sub

Step 2: Use Range.Value method to retrieve the value of cells A1: A3 and assign to a new variable defined in the previous step.

Code:

Sub VBA_Value_Ex4()

Dim Get_Value_2 As Variant
Get_Value_2 = ThisWorkbook.Worksheets("Getting_Cell_Value_2").Range("A1:A3").Value

End Sub

Step 3: Finally, use the MsgBox function to display the values stored in cell A1: A3.

Code:

Sub VBA_Value_Ex4()

Dim Get_Value_2 As Variant
Get_Value_2 = ThisWorkbook.Worksheets("Getting_Cell_Value_2").Range("A1:A3").Value
MsgBox Get_Value_2

End Sub

Step 4: Hit F5 or Run button and see the output for this code.

You’ll get a Run-time error’13’: Type Mismatch. The reason behind getting this error is, we are defining a single variable and assigning values of a one-dimensional array (with three rows) to it. Which is logically not possible.

This is from this article. Let’s wrap the things up with some points to be remembered.

Things to Remember

You can’t set multiple cells value while using the VBA CELLS method, because it takes rows and columns as arguments. You can only specify the row number and column number in it.

You also can’t get values stored in multiple cells in a single message box. If you have to retrieve the range of values, you need to write the separate get arguments for each of the value.

Recommended Articles

This has been a guide to VBA Value. Here we have discussed how to use Excel VBA Value Function along with practical examples and downloadable excel template. You can also go through our other suggested articles –

1. VBA On Error
2. VBA Number Format
3. VBA VLOOKUP
4. VBA Function

In this VBA Tutorial, you learn how to set a cell’s or cell range’s value and get a cell’s or cell range’s value.

This VBA Tutorial is accompanied by Excel workbooks containing the macros and data I use in the examples below. You can get immediate access to these example workbooks by subscribing to the Power Spreadsheets Newsletter.

Use the following Table of Contents to navigate to the section that interests you.

Related VBA and Macro Tutorials

The following VBA and Macro Tutorials may help you better understand and implement the contents below:

• General VBA constructs and structures:
  • Begin working with macros here.
  • Learn about basic VBA constructs and structures here.
  • Learn how to enable or disable macros in Excel here.
  • Learn how to work with the Visual Basic Editor here.
  • Learn how to work with Sub procedures here.
  • Learn how to create object references here.
  • Learn several ways to refer to cell ranges here.
  • Learn how to work with properties here.
  • Learn how to declare and assign data to variables here.
  • Learn about VBA data types here.
  • Learn how to work with arrays here.
  • Learn how to work with R1C1-style references here.
  • Learn how to work with loops here.
• Practical VBA applications and macro examples:
  • Learn how to copy and paste values here.
  • Learn how to find the last row in a worksheet here.
  • Learn how to find the last column in a worksheet here.
  • Learn how to specify a column’s width here.
  • Learn how to convert strings to numbers here.

You can find additional VBA and Macro Tutorials in the Archives.

#1: Set cell value

VBA code to set cell value

To set a cell’s value with VBA, use a statement with the following structure:

Cell.ValueOrValue2 = CellValue

Process to set cell value

To set a cell’s value with VBA, follow these steps:

1. Identify and return a Range object representing the cell whose value you want to set (Cell).
2. Set the cell’s value with the Range.Value or Range.Value2 property (ValueOrValue2 = CellValue).

VBA statement explanation

1. Item: Cell.
   • VBA construct: Range object.
   • Description: Cell is a Range object representing the cell whose value you want to set.

     For purposes of returning such a Range object, work with constructs such as the Worksheet.Range, Worksheet.Cells, Application.ActiveCell, Application.Selection, Range.Range, Range.Cells, or Range.Offset properties.

     If you explicitly declare an object variable to represent Cell, use the Range object data type.

2. Item: Value or Value2.
   • VBA construct: Range.Value or Range.Value2 property.
   • Description: Both the Range.Value and Range.Value2 properties set the value of Cell.

     The difference between Range.Value and Range.Value2 is the data types they work with. Range.Value2 doesn’t use Currency nor Date. This difference is particularly important for purposes of getting a cell’s value. For a more detailed discussion of this topic, please refer to the appropriate section.

3. Item: =.
   • VBA construct: Assignment operator.
   • Description: The = operator assigns the value returned by the expression on its right (CellValue) to the property on its left (Cell.ValueOrValue2).
4. Item: CellValue.
   • VBA construct: New value of Range.Value or Range.Value2 property.
   • Description: CellValue is the new value you specify for Cell. You can specify, among others, numeric values or text strings.

Macro examples to set cell value

The following macro example sets a cell’s (myCellSetValue) value to the string “set cell value with Range.Value” with the Range.Value property.

Sub setCellValue()
    'source: https://powerspreadsheets.com/
    'sets a cell's value
    'for further information: https://powerspreadsheets.com/excel-vba-value-value2/

    'declare object variable to hold reference to cell where you write the value
    Dim myCellSetValue As Range

    'identify cell where you set the value
    Set myCellSetValue = ThisWorkbook.Worksheets("set cell value").Range("A7")

    'set cell value with Range.Value property
    myCellSetValue.Value = "set cell value with Range.Value"

End Sub

The following macro example sets a cell’s (myCellSetValue2) value to the string “set cell value with Range.Value2” with the Range.Value2 property.

Sub setCellValue2()
    'source: https://powerspreadsheets.com/
    'sets a cell's value
    'for further information: https://powerspreadsheets.com/excel-vba-value-value2/

    'declare object variable to hold reference to cell where you write the value
    Dim myCellSetValue2 As Range

    'identify cell where you set the value
    Set myCellSetValue2 = ThisWorkbook.Worksheets("set cell value").Range("A11")

    'set cell value with Range.Value2 property
    myCellSetValue2.Value2 = "set cell value with Range.Value2"

End Sub

Effects of executing macro example to set cell value

The following GIF illustrates the results of executing the first macro example, which works with the Range.Value property. The value of cell A7 is set to the string “set cell value with Range.Value”.

The following GIF illustrates the results of executing the second macro example, which works with the Range.Value2 property. The value of cell A11 is set to the string “set cell value with Range.Value2”.

#2: Set cell range value

VBA code to set cell range value

To set a cell range’s value with VBA, use a statement with the following structure:

CellRange.ValueOrValue2 = CellRangeValue

Process to set cell range value

To set a cell range’s value with VBA, follow these steps:

1. Identify and return a Range object representing the cell range whose value you want to set (CellRange).
2. Set the cell range’s value with the Range.Value or Range.Value2 property (ValueOrValue2 = CellRangeValue).

VBA statement explanation

1. Item: CellRange.
   • VBA construct: Range object.
   • Description: CellRange is a Range object representing the cell range whose value you want to set.

     For purposes of returning such a Range object, work with constructs such as the Worksheet.Range, Worksheet.Cells, Application.Selection, Range.Range, Range.Cells, Range.Offset or Range.Resize properties.

     If you explicitly declare an object variable to represent CellRange, use the Range object data type.

2. Item: ValueOrValue2.
   • VBA construct: Range.Value or Range.Value2 property.
   • Description: Both the Range.Value and Range.Value2 properties set the value of CellRange.

     The difference between Range.Value and Range.Value2 is the data types they work with. Range.Value2 doesn’t use Currency nor Date. This difference is particularly important for purposes of getting a cell range’s value. For a more detailed discussion of this topic, please refer to the appropriate section.

3. Item: =.
   • VBA construct: Assignment operator.
   • Description: The = operator assigns the value returned by the expression on its right (CellRangeValue) to the property on its left (CellRange.ValueOrValue2).
4. Item: CellRangeValue.
   • VBA construct: New value of Range.Value or Range.Value2 property.
   • Description: CellRangeValue is the new value you specify for CellRange. You can specify, among others, numeric values or text strings.

Macro examples to set cell range value

The following macro example sets a cell range’s (myCellRangeSetValue) value to the string “set cell range value with Range.Value” with the Range.Value property.

Sub setCellRangeValue()
    'source: https://powerspreadsheets.com/
    'sets a cell range's value
    'for further information: https://powerspreadsheets.com/excel-vba-value-value2/

    'declare object variable to hold reference to cell range where you write the value
    Dim myCellRangeSetValue As Range

    'identify cell range where you set the value
    Set myCellRangeSetValue = ThisWorkbook.Worksheets("set cell value").Range("A15:C19")

    'set cell range value with Range.Value property
    myCellRangeSetValue.Value = "set cell range value with Range.Value"

End Sub

The following macro example sets a cell range’s (myCellRangeSetValue2) value to the string “set cell range value with Range.Value2” with the Range.Value2 property.

Sub setCellRangeValue2()
    'source: https://powerspreadsheets.com/
    'sets a cell range's value
    'for further information: https://powerspreadsheets.com/excel-vba-value-value2/

    'declare object variable to hold reference to cell range where you write the value
    Dim myCellRangeSetValue2 As Range

    'identify cell range where you set the value
    Set myCellRangeSetValue2 = ThisWorkbook.Worksheets("set cell value").Range("A23:C27")

    'set cell range value with Range.Value2 property
    myCellRangeSetValue2.Value = "set cell range value with Range.Value2"

End Sub

Effects of executing macro example to set cell range value

The following GIF illustrates the results of executing the first macro example, which works with the Range.Value property. The value of cells A15 to C19 is set to the string “set cell range value with Range.Value”.

The following GIF illustrates the results of executing the second macro example, which works with the Range.Value2 property. The value of cells A23 to C27 is set to the string “set cell range value with Range.Value2”.

#3: Get cell value

VBA code to get cell value

To get a cell’s value with VBA, use a statement with the following structure:

myVariable = Cell.ValueOrValue2

Process to get cell value

To get a cell’s value with VBA, follow these steps:

1. Identify and return a Range object representing the cell whose value you want to get (Cell).
2. Get the cell’s value with the Range.Value or Range.Value2 property (ValueOrValue2).
3. Assign the value returned by Range.Value or Range.Value to a variable (myVariable =).

VBA statement explanation

1. Item: myVariable.
   • VBA construct: Variable.
   • Description: myVariable is the variable you want to hold Cell’s value.

     If you explicitly declare myVariable, use a data type that’s capable of holding all the potential values that Cell may hold.

2. Item: =.
   • VBA construct: Assignment operator.
   • Description: The = operator assigns the value returned by the expression on its right (Cell.ValueOrValue2) to the variable on its left (myVariable).
3. Item: Cell.
   • VBA construct: Range object.
   • Description: Cell is a Range object representing the cell whose value you want to get.

     For purposes of returning such a Range object, work with constructs such as the Worksheet.Range, Worksheet.Cells, Application.ActiveCell, Application.Selection, Range.Range, Range.Cells, or Range.Offset properties.

     If you explicitly declare an object variable to represent Cell, use the Range object data type.

4. Item: ValueOrValue2.
   • VBA construct: Range.Value or Range.Value2 property.
   • Description: Both the Range.Value and Range.Value2 properties return the value of Cell.

     The difference between Range.Value and Range.Value2 is the data types they work with. Range.Value2 doesn’t use Currency nor Date. Therefore, if Cell’s number format is Date or Currency, Range.Value converts Cell’s value to the Date or Currency data type, as appropriate. Range.Value2 doesn’t carry out this conversion and, therefore, Range.Value2 generally returns such value as of the Double data type.

     The Currency data type stores numbers in an integer format scaled by 10,000. this results in a fixed-point number with 4 decimal digits. If Cell’s value contains more decimal places, Range.Value and Range.Value2 tend to return different values. Generally, if Cell’s value may contain more than 4 decimal places, Range.Value2 is more accurate.

Macro examples to get cell value

The following macro example:

1. Gets a cell’s (A7) value with the Range.Value property.
2. Assigns the cell’s value to a variable (myValue).
3. Displays a message box with the value held by the variable.

Sub getCellValue()
    'source: https://powerspreadsheets.com/
    'gets a cell's value
    'for further information: https://powerspreadsheets.com/excel-vba-value-value2/

    'declare variable to hold cell value
    Dim myValue As Variant

    'get cell value with Range.Value property and assign it to variable
    myValue = ThisWorkbook.Worksheets("get cell value").Range("A7").Value

    'display cell value
    MsgBox myValue

End Sub

The following macro example:

1. Gets a cell’s (A7) value with the Range.Value2 property.
2. Assigns the cell’s value to a variable (myValue2).
3. Displays a message box with the value held by the variable.

Sub getCellValue2()
    'source: https://powerspreadsheets.com/
    'gets a cell's value
    'for further information: https://powerspreadsheets.com/excel-vba-value-value2/

    'declare variable to hold cell value
    Dim myValue2 As Variant

    'get cell value with Range.Value2 property and assign it to variable
    myValue2 = ThisWorkbook.Worksheets("get cell value").Range("A7").Value2

    'display cell value
    MsgBox myValue2

End Sub

Effects of executing macro example to get cell value

The following GIF illustrates the results of executing the first macro example, which works with the Range.Value property. The message box displays the value of cell A7.

Notice that cell A7 is formatted as currency. The Range.Value property converts the cell’s value to the Currency data type, which results in a fixed-point number with 4 decimal digits. Therefore, the message box displays a value with only 4 decimal places, instead of the 10 decimal places that the original value in cell A7 has.

The following GIF illustrates the results of executing the second macro example, which works with the Range.Value2 property. The message box displays the value of cell A7.

The Range.Value2 property doesn’t work with the Currency data type. Therefore, the message box displays all the (10) decimal places that the original value in cell A7 has.

#4: Get cell range value

VBA code to get cell range value

To get a cell range’s value with VBA, use a statement with the following structure:

Dim myArray() As Variant
myArray = CellRange.ValueOrValue2

Process to get cell range value

To get a cell range’s value with VBA, follow these steps:

1. Declare an array of the Variant data type (myArray).
2. Identify and return a Range object representing the cell range whose value you want to get (CellRange).
3. Get the cell range’s value with the Range.Value or Range.Value2 property.
4. Assign the value returned by Range.Value or Range.Value to the previously-declared array (myArray =).

VBA statement explanation

Line #1: Dim myArray As Variant

1. Item: Dim myArray() As Variant.
   • VBA construct: Dim statement.
   • Description: The Dim statement declares an array (myArray) as of the Variant data type.

     myArray is the array you want to hold CellRange’s values.

Line #2: myArray = CellRange.ValueOrValue2

1. Item: myArray.
   • VBA construct: Array.
   • Description: myArray is the array you want to hold CellRange’s values.
2. Item: =.
   • VBA construct: Assignment operator.
   • Description: The = operator assigns the values returned by the expression on its right (CellRange.ValueOrValue2) to the array on its left (myArray).
3. Item: CellRange.
   • VBA construct: Range object.
   • Description: CellRange is a Range object representing the cell range whose values you want to get.

     For purposes of returning such a Range object, work with constructs such as the Worksheet.Range, Worksheet.Cells, Application.Selection, Range.Range, Range.Cells, Range.Offset or Range.Resize properties.

     If you explicitly declare an object variable to represent CellRange, use the Range object data type.

4. Item: ValueOrValue2.
   • VBA construct: Range.Value or Range.Value2 property.
   • Description: Both the Range.Value and Range.Value2 properties return the values in CellRange.

     The difference between Range.Value and Range.Value2 is the data types they work with. Range.Value2 doesn’t use Currency nor Date. Therefore, if CellRange’s number format is Date or Currency, Range.Value converts the values in CellRange to the Date or Currency data type, as appropriate. Range.Value2 doesn’t carry out this conversion and, therefore, Range.Value2 generally returns such values as of the Double data type.

     The Currency data type stores numbers in an integer format scaled by 10,000. this results in a fixed-point number with 4 decimal digits. If CellRange’s values contain more decimal places, Range.Value and Range.Value2 tend to return different values. Generally, if CellRange’s values may contain more than 4 decimal places, Range.Value2 is more accurate.

Macro examples to get cell range value

The following macro example:

1. Gets a cell range’s (A11 to C15) values with the Range.Value property.
2. Assigns the cell range’s values to an array (myValuesArray).
3. Loops through each value in the array.
4. Displays a message box with each value it loops through.

Sub getCellRangeValues()
    'source: https://powerspreadsheets.com/
    'gets a cell range's value
    'for further information: https://powerspreadsheets.com/excel-vba-value-value2/

    'declare Variant array to hold cell range values
    Dim myValuesArray() As Variant

    'declare variables to hold loop counters used to iterate through the individual values in the cell range
    Dim rowCounter As Long
    Dim columnCounter As Long

    'get cell range values with Range.Value property and assign them to array
    myValuesArray = ThisWorkbook.Worksheets("get cell value").Range("A11:C15").Value

    'loop through each value in array, step #1: loop through each value in first array dimension (rows)
    For rowCounter = LBound(myValuesArray, 1) To UBound(myValuesArray, 1)

        'loop through each value in array, step #2: loop through each value in second array dimension (columns)
        For columnCounter = LBound(myValuesArray, 2) To UBound(myValuesArray, 2)

            'display value loop is currently iterating through
            MsgBox myValuesArray(rowCounter, columnCounter)

        Next columnCounter

    Next rowCounter

End Sub

The following macro example:

1. Gets a cell range’s (A11 to C15) values with the Range.Value2 property.
2. Assigns the cell range’s values to an array (myValues2Array).
3. Loops through each value in the array.
4. Displays a message box with each value it loops through.

Sub getCellRangeValues2()
    'source: https://powerspreadsheets.com/
    'gets a cell range's value
    'for further information: https://powerspreadsheets.com/excel-vba-value-value2/

    'declare Variant array to hold cell range values
    Dim myValues2Array() As Variant

    'declare variables to hold loop counters used to iterate through the individual values in the cell range
    Dim rowCounter As Long
    Dim columnCounter As Long

    'get cell range values with Range.Value2 property and assign them to array
    myValues2Array = ThisWorkbook.Worksheets("get cell value").Range("A11:C15").Value2

    'loop through each value in array, step #1: loop through each value in first array dimension (rows)
    For rowCounter = LBound(myValues2Array, 1) To UBound(myValues2Array, 1)

        'loop through each value in array, step #2: loop through each value in second array dimension (columns)
        For columnCounter = LBound(myValues2Array, 2) To UBound(myValues2Array, 2)

            'display value loop is currently iterating through
            MsgBox myValues2Array(rowCounter, columnCounter)

        Next columnCounter

    Next rowCounter

End Sub

Effects of executing macro example to get cell range value

The following GIF illustrates the results of executing the first macro example, which works with the Range.Value property. The message boxes display the values of cell A11 to C15.

Notice that the cell range is formatted as currency. The Range.Value property converts the cell range’s values to the Currency data type, which results in fixed-point numbers with 4 decimal digits. Therefore, the message boxes display values with a maximum of 4 decimal places, instead of the 10 decimal places that the original values in the cell range have.

The following GIF illustrates the results of executing the second macro example, which works with the Range.Value2 property. The message boxes display the values of cell A11 to C15.

The Range.Value2 property doesn’t work with the Currency data type. Therefore, the message boxes display all the (10) decimal places that the original values in the cell range have.

References to VBA Constructs Used in this VBA Tutorial

Use the following links to visit the appropriate webpage in the Microsoft Developer Network:

1. Identify the cell or cell range whose value you want to set or get:
   • Workbook object.
   • Application.ThisWorkbook property.
   • Application.ActiveWorkbook property.
   • Application.Workbooks property.
   • Worksheet object.
   • Application.ActiveSheet property.
   • Workbook.Worksheets property.
   • Range object.
   • Worksheet.Range property.
   • Worksheet.Cells property.
   • Application.ActiveCell property.
   • Application.Selection property.
   • Range.Range property.
   • Range.Cells property.
   • Range.Item property.
   • Range.Offset property.
   • Range.Resize property.
2. Set or get the value of a cell or cell range:
   • Range.Value property.
   • Range.Value2 property.
3. Work with variables, arrays and data types:
   • Dim statement.
   • Set statement.
   • = operator.
   • Loop through all the elements in an array:
     • For… Next statement.
     • LBound function.
     • UBound function.
   • Data types:
     • Currency data type.
     • Date data type.
     • Double data type.
     • Long data type.
     • Variant data type.
4. Display a message box:
   • MsgBox function.