Vba word значения таблицы - Word и Excel - помощь в работе с программами

title	ms.prod	ms.assetid	ms.date	ms.localizationpriority
Working with tables	word	cf0858b7-6b39-4c90-552e-edb695b5cda3	06/08/2019	medium

This topic includes Visual Basic examples related to the tasks identified in the following sections.

Creating a table, inserting text, and applying formatting

The following example inserts a four-column, three-row table at the beginning of the active document. The For Each…Next structure is used to step through each cell in the table. Within the For Each…Next structure, the InsertAfter method of the Range object is used to add text to the table cells (Cell 1, Cell 2, and so on).

Sub CreateNewTable() 
 Dim docActive As Document 
 Dim tblNew As Table 
 Dim celTable As Cell 
 Dim intCount As Integer 
 
 Set docActive = ActiveDocument 
 Set tblNew = docActive.Tables.Add( _ 
 Range:=docActive.Range(Start:=0, End:=0), NumRows:=3, _ 
 NumColumns:=4) 
 intCount = 1 
 
 For Each celTable In tblNew.Range.Cells 
  celTable.Range.InsertAfter "Cell " & intCount 
  intCount = intCount + 1 
 Next celTable 
 
 tblNew.AutoFormat Format:=wdTableFormatColorful2, _ 
 ApplyBorders:=True, ApplyFont:=True, ApplyColor:=True 
End Sub

Inserting text into a table cell

The following example inserts text into the first cell of the first table in the active document. The Cell method returns a single Cell object. The Range property returns a Range object. The Delete method is used to delete the existing text and the InsertAfter method inserts the «Cell 1,1» text.

Sub InsertTextInCell() 
 If ActiveDocument.Tables.Count >= 1 Then 
  With ActiveDocument.Tables(1).Cell(Row:=1, Column:=1).Range 
   .Delete 
   .InsertAfter Text:="Cell 1,1" 
  End With 
 End If 
End Sub

Returning text from a table cell without returning the end of cell marker

The following example returns and displays the contents of each cell in the first row of the first document table.

Sub ReturnTableText() 
 Dim tblOne As Table 
 Dim celTable As Cell 
 Dim rngTable As Range 
 
 Set tblOne = ActiveDocument.Tables(1) 
 For Each celTable In tblOne.Rows(1).Cells 
  Set rngTable = ActiveDocument.Range(Start:=celTable.Range.Start, _ 
  End:=celTable.Range.End - 1) 
  MsgBox rngTable.Text 
 Next celTable 
End Sub

Sub ReturnCellText() 
 Dim tblOne As Table 
 Dim celTable As Cell 
 Dim rngTable As Range 
 
 Set tblOne = ActiveDocument.Tables(1) 
 For Each celTable In tblOne.Rows(1).Cells 
  Set rngTable = celTable.Range 
  rngTable.MoveEnd Unit:=wdCharacter, Count:=-1 
  MsgBox rngTable.Text 
 Next celTable 
End Sub

Converting existing text to a table

The following example inserts tab-delimited text at the beginning of the active document and then converts the text to a table.

Sub ConvertExistingText() 
 With Documents.Add.Content 
  .InsertBefore "one" & vbTab & "two" & vbTab & "three" & vbCr 
  .ConvertToTable Separator:=Chr(9), NumRows:=1, NumColumns:=3 
 End With 
End Sub

Returning the contents of each table cell

The following example defines an array equal to the number of cells in the first document table (assuming Option Base 1). The For Each…Next structure is used to return the contents of each table cell and assign the text to the corresponding array element.

Sub ReturnCellContentsToArray() 
 Dim intCells As Integer 
 Dim celTable As Cell 
 Dim strCells() As String 
 Dim intCount As Integer 
 Dim rngText As Range 
 
 If ActiveDocument.Tables.Count >= 1 Then 
  With ActiveDocument.Tables(1).Range 
   intCells = .Cells.Count 
   ReDim strCells(intCells) 
   intCount = 1 
   For Each celTable In .Cells 
    Set rngText = celTable.Range 
    rngText.MoveEnd Unit:=wdCharacter, Count:=-1 
    strCells(intCount) = rngText 
    intCount = intCount + 1 
   Next celTable 
  End With 
 End If 
End Sub

Copying all tables in the active document into a new document

This example copies the tables from the current document into a new document.

Sub CopyTablesToNewDoc() 
 Dim docOld As Document 
 Dim rngDoc As Range 
 Dim tblDoc As Table 
 
 If ActiveDocument.Tables.Count >= 1 Then 
  Set docOld = ActiveDocument 
  Set rngDoc = Documents.Add.Range(Start:=0, End:=0) 
  For Each tblDoc In docOld.Tables 
   tblDoc.Range.Copy 
   With rngDoc 
    .Paste 
    .Collapse Direction:=wdCollapseEnd 
    .InsertParagraphAfter 
    .Collapse Direction:=wdCollapseEnd 
   End With 
  Next 
 End If 
End Sub

[!includeSupport and feedback]

Источник

Silvermatic

3 / 3 / 0

Регистрация: 27.02.2014

Сообщений: 36

09.03.2014, 19:01. Показов 20901. Ответов 16

Метки нет (Все метки)

Уже третий день не могу вникнуть в VBA в Word при работе с таблицами. Контрольная подвисла, время начинает поджимать, но нужно разобраться, а не банально копипастом все делать.

Задание вкратце:
В документе ворда есть таблица в ячейках которой содержится что угодно. Нужно макросом прошустрить выделенные клетки (по-умолчанию область прямоугольная), обработать только ячейки в которых содержатся цифры. Для каждого столбца необходимо вычислить среднее значение. Все средние значения вывести в строке, вставленной ниже выделенной области в соответствующих столбцах.

Что сделано на данный момент:

Visual Basic

Sub NewRowWithResults()
Dim xxx As Column
Dim yyy As Cell
Dim sum As Integer
Dim cnt As Integer
 
 
For Each xxx In Selection.Range.Columns
    sum = 0
    cnt = 0
    For Each yyy In xxx.Cells
        If IsNumeric(yyy.Range.Text) Then
            sum = sum + yyy.Range.Text
            cnt = cnt + 1
        End If
    Next yyy
    ActiveDocument.Tables(1).Cell(1, 9).Range = sum
    ActiveDocument.Tables(1).Cell(1, 10).Range = cnt
Next xxx
 
'ActiveDocument.Tables(1).Cell(1, 9).Range = sum
'ActiveDocument.Tables(1).Cell(1, 10).Range = cnt
'Selection.InsertRowsBelow 1
End Sub

В данном примере выделаю 1 столбец и запускаю макрос. Проблема в том, что sum = 0 и cnt = 0 тоже.
Судя по продолжительности моргания выделенной области, могу предположить, что макрос перебирает все ячейки таблицы, а не только выделенного региона.

Прошу вашей помощи.

15136 / 6410 / 1730

Регистрация: 24.09.2011

Сообщений: 9,999

09.03.2014, 19:26

Сообщение от Silvermatic

Проблема в том, что sum = 0 и cnt = 0 тоже

Текст ячейки всегда содержит в конце 2 символа chr(13)+chr(7), поэтому IsNumeric(yyy.Range.Text) всегда False.
Поскольку «нужно разобраться» , решение приводить не буду.

Сообщение от Silvermatic

могу предположить, что макрос перебирает все ячейки таблицы

Чтобы не гадать, поставьте в цикл yyy.select и пройдите по шагам — F8.

Sasha_Smirnov

5561 / 1367 / 150

Регистрация: 08.02.2009

Сообщений: 4,107

Записей в блоге: 30

09.03.2014, 20:58

Сообщение было отмечено как решение

Решение

Поэкспериментировав в окне Immediate, пока сделал такой вот набросок:

Visual Basic

'Здесь надо выделить область в таблице Word
 
Sub AverageOfSelectedColumn()
Dim x1, x2, y1, y2
''вставка таблицы X на Y
'ActiveDocument.Tables.Add Selection.Range, 5, 5
 
    'координаты выделения
    x1 = Selection.Columns.First.Index
    x2 = Selection.Columns.Last.Index
    y1 = Selection.Rows.First.Index
    y2 = Selection.Rows.Last.Index
    
    Selection.Rows.Last.Range.Rows.Add 'добавление строки под выделением
    
    ActiveDocument.Tables(1).Cell(y2 + 1, x1).Formula "=Average(above)"
End Sub

Миниатюры

Silvermatic

3 / 3 / 0

Регистрация: 27.02.2014

Сообщений: 36

09.03.2014, 21:06

[ТС]

Сообщение от Казанский

yyy.Range.Text преобразовать и перенести в массив чаров, определить длину и затереть 2 последних символа?

Сообщение от Казанский

Чтобы не гадать, поставьте в цикл yyy.select и пройдите по шагам — F8.

Как и подозревал, проходит по всей таблице…
Тут трабла даже в другом. Изначально пробовал определить границы выделенной области таким способом:

Visual Basic

dim cb as integer ' column - begin
dim ce as integer ' column - end
dim rb as integer ' row - begin
dim re as integer ' row - end
 
cb = Selection.Range.FirstColumn
ce = Selection.Range.Columns.Count
 
rb = Selection.Range.FirstRow
re = Selection.Range.Rows.Count

Со строками все определялось нормально, а со столбцами не проходило — значения были от 1(cb) до 10(ce), т.е. прорабатывали все столбцы таблицы, а не те что были выделены.

Sasha_Smirnov

5561 / 1367 / 150

Регистрация: 08.02.2009

Сообщений: 4,107

Записей в блоге: 30

09.03.2014, 21:12

Вот наиболее близкий к заданию код. По крайней мере — по координатам выделения.

Visual Basic

Sub AveragesOfSelectedColumns()
Dim x1, x2, y1, y2, j
    'координаты выделения
    x1 = Selection.Columns.First.Index
    x2 = Selection.Columns.Last.Index
    y1 = Selection.Rows.First.Index
    y2 = Selection.Rows.Last.Index
    
    Selection.Rows.Last.Range.Rows.Add 'добавление строки под выделением
    
    For j = x1 To x2
        ActiveDocument.Tables(1).Cell(y2 + 1, j).Formula _
        "=sum(above)" & "/" & y2 - y1 + 1
    Next
End Sub

Поле {=sum(above)}*, конечно, суммирует всё, что сверху — ну это так, просто демо.
___________________
* в таблице его код (после прогона данного примера) можно посмотреть по Alt-F9

Silvermatic

3 / 3 / 0

Регистрация: 27.02.2014

Сообщений: 36

09.03.2014, 21:19

[ТС]

Сообщение от Sasha_Smirnov

Вот наиболее близкий к заданию код. По крайней мере — по координатам выделения.

Я уже опробовал ваш код.
Границы выделенной области определяются устойчиво.

Вопрос по вставке строки под выделенной областью. Такой вариант чем-нибудь плох?

Visual Basic

1	Selection.InsertRowsBelow 1

Он нормально работает, но вдруг есть тонкости…

Казанский

15136 / 6410 / 1730

Регистрация: 24.09.2011

Сообщений: 9,999

09.03.2014, 21:37

Мой вариант

Visual Basic

Sub bb()
Dim c As Cell, col1&, col2&
With Selection
  If Not .Information(wdWithInTable) Then
    MsgBox "Выделение не в таблице!", vbCritical
    Exit Sub
  End If
  col1 = .Cells(1).ColumnIndex
  col2 = .Cells(.Cells.Count).ColumnIndex
  ReDim sum(col1 To col2)
  For Each c In .Cells
    sum(c.ColumnIndex) = sum(c.ColumnIndex) + Val(c.Range.Text)
  Next
  With .Rows.Last.Range.Rows.Add 'Sasha_Smirnov
    For col1 = col1 To col2
      .Cells(col1).Range = sum(col1)
    Next
  End With
End With
End Sub

Добавлено через 8 минут
Чтобы работало с любым десятичным разделителем, строка 12

Visual Basic

1	sum(c.ColumnIndex) = sum(c.ColumnIndex) + Val(Replace(c.Range.Text, ",", "."))

3 / 3 / 0

Регистрация: 27.02.2014

Сообщений: 36

09.03.2014, 21:43

[ТС]

Казанский, твой вариант «прожует» ячейки в которых содержится текст или пустые ячейки?

По большому счету осталось определить что в ячейке находится именно число, а не что-либо другое.

15136 / 6410 / 1730

Регистрация: 24.09.2011

Сообщений: 9,999

09.03.2014, 21:49

Silvermatic, попробуй!
И поставь курсор в слово Val, нажми F1.

3 / 3 / 0

Регистрация: 27.02.2014

Сообщений: 36

09.03.2014, 23:53

[ТС]

Казанский, хоть и не совсем то, что нужно, но в таком виде будет достаточно съедобно, ибо лекций VBA не прочитали и 40%.
Благодарствую.

Sasha_Smirnov

5561 / 1367 / 150

Регистрация: 08.02.2009

Сообщений: 4,107

Записей в блоге: 30

10.03.2014, 00:11

Добил-таки свой эксселеподобный (с формулами) вариант. Разделитель дробей запятая.

Действует лишь на 1-ю таблицу в документе.

Visual Basic

Option Explicit
 
'здесь надо выделить область в таблице Word
 
Sub AveragesOfColumnsOfSelection()
Dim x1, x2, y1, y2, j
'выход при отсутствии Таблицы 1 и при выделении вне её
If ActiveDocument.Tables.Count = 0 Then Exit Sub
If Not Selection.InRange(ActiveDocument.Tables(1).Range) Then Exit Sub
 
    'координаты выделения
    x1 = Selection.Columns.First.Index
    x2 = Selection.Columns.Last.Index
    y1 = Selection.Rows.First.Index
    y2 = Selection.Rows.Last.Index
    
    Selection.Rows.Last.Range.Rows.Add 'добавление строки под выделением
    
    'перевод номера колонки (1, 2, 3, 4, …) в вид: a, b, c, d, … [не пригодился!]
    
    For j = 64 + x1 To 64 + x2                              'код буквы A = 64 + 1
        ActiveDocument.Tables(1).Cell(y2 + 1, j - 64).Formula _
        "=sum([" & Chr(j) & y1 & ":" & Chr(j) & y2 & "])" & "/" & y2 - y1 + 1
    Next
'в документе, если видны не вычисленные значения, а коды, надо нажать Alt-F9
End Sub

Миниатюры

Казанский

15136 / 6410 / 1730

Регистрация: 24.09.2011

Сообщений: 9,999

10.03.2014, 00:13

А, там же среднее надо было. Тогда так

Visual Basic

Sub bb()
Dim c As Cell, col1&, col2&, ci&, ct$
With Selection
  If Not .Information(wdWithInTable) Then
    MsgBox "Выделение не в таблице!", vbCritical
    Exit Sub
  End If
  col1 = .Cells(1).ColumnIndex
  col2 = .Cells(.Cells.Count).ColumnIndex
  ReDim sum(col1 To col2), cnt(col1 To col2)
  For Each c In .Cells
    ct = c.Range.Text
    ct = Left$(ct, Len(ct) - 2)
    If IsNumeric(ct) Then
      ci = c.ColumnIndex
      sum(ci) = sum(ci) + CDbl(ct)
      cnt(ci) = cnt(ci) + 1
    End If
  Next
  With .Rows.Last.Range.Rows.Add 'Sasha_Smirnov
    For col1 = col1 To col2
      If cnt(col1) > 0 Then .Cells(col1).Range = sum(col1) / cnt(col1)
    Next
  End With
End With
End Sub

3 / 3 / 0

Регистрация: 27.02.2014

Сообщений: 36

10.03.2014, 11:04

[ТС]

Спасибо за помощь, ребята. В коде разобрался, сделал на свой манер, все работает.

п.с. Сдать и забыть как страшный сон…

5561 / 1367 / 150

Регистрация: 08.02.2009

Сообщений: 4,107

Записей в блоге: 30

10.03.2014, 15:16

Можно ж было и удовольствие получить от постижения…

А любопытно было бы взглянуть, каков он ваш манер!

Silvermatic

3 / 3 / 0

Регистрация: 27.02.2014

Сообщений: 36

10.03.2014, 16:16

[ТС]

Сообщение от Sasha_Smirnov

Можно ж было и удовольствие получить от постижения…

Взглянув на количество объектов, их методов, свойств и параметров, на их замудреную иерархию…
Надо было в начале спросить что и какими функциями сделать, а логику заложить самостоятельно.

Сообщение от Sasha_Smirnov

А любопытно было бы взглянуть, каков он ваш манер!

Почему же и не показать? Смотрите…

Visual Basic

Sub NewRowWithResults()
Dim rb As Integer
Dim re As Integer
Dim cb As Integer
Dim ce As Integer
Dim cl As Cell, ct$
 
If Not Selection.Information(wdWithInTable) Then
    MsgBox "Выделение за пределами таблицы!", vbCritical
    Exit Sub
End If
 
rb = Selection.Rows.First.Index
re = Selection.Rows.Last.Index
cb = Selection.Columns.First.Index
ce = Selection.Columns.Last.Index
 
Selection.InsertRowsBelow 1
 
For i = cb To ce
    sum = 0
    cnt = 0
    For j = rb To re
        ct = ActiveDocument.Tables(1).Cell(j, i).Range.Text
        ct = Left$(ct, Len(ct) - 2)
        If IsNumeric(ct) Then
          sum = sum + CDbl(ct)
          cnt = cnt + 1
        End If
    Next j
    If sum <> 0 Then
        ActiveDocument.Tables(1).Cell(re + 1, i).Range = sum / cnt
    End If
Next i
End Sub

Ах, да, вот еще хотел уточнить что объявляется в этой строке? В смысле ни что объявляется, а что за объявление «ct$»?

Visual Basic

1	Dim cl As Cell, ct$

И как вычеркнуть из этого объявления переменную cl. ct$, как я понял, что-то вроде указателя в Си?

15136 / 6410 / 1730

Регистрация: 24.09.2011

Сообщений: 9,999

10.03.2014, 18:28

Dim ct$ это сокращенная запись Dim ct As String.
Несколько наиболее популярных типов в VB/VBA имеют символы для обозначения типа.
См. F1 — String Data Type, Integer Data Type и т.д.

3 / 3 / 0

Регистрация: 27.02.2014

Сообщений: 36

10.03.2014, 19:38

[ТС]

Сообщение от Казанский

Dim ct$ это сокращенная запись Dim ct As String.

Значит примерно правильно понял. Спасибо за объяснения.

Источник

Создание таблиц в документе Word из кода VBA Excel. Метод Tables.Add, его синтаксис и параметры. Объекты Table, Column, Row, Cell. Границы таблиц и стили.

Работа с Word из кода VBA Excel
Часть 4. Создание таблиц в документе Word
[Часть 1] [Часть 2] [Часть 3] [Часть 4] [Часть 5] [Часть 6]

Таблицы в VBA Word принадлежат коллекции Tables, которая предусмотрена для объектов Document, Selection и Range. Новая таблица создается с помощью метода Tables.Add.

Синтаксис метода Tables.Add

Expression.Add (Range, Rows, Columns, DefaultTableBehavior, AutoFitBehavior)

Expression – выражение, возвращающее коллекцию Tables.

Параметры метода Tables.Add

Range – диапазон, в котором будет создана таблица (обязательный параметр).
Rows – количество строк в создаваемой таблице (обязательный параметр).
Columns – количество столбцов в создаваемой таблице (обязательный параметр).
DefaultTableBehavior – включает и отключает автоподбор ширины ячеек в соответствии с их содержимым (необязательный параметр).
AutoFitBehavior – определяет правила автоподбора размера таблицы в документе Word (необязательный параметр).

Создание таблицы в документе

Создание таблицы из 3 строк и 4 столбцов в документе myDocument без содержимого и присвоение ссылки на нее переменной myTable:

With myDocument

Set myTable = .Tables.Add(.Range(Start:=0, End:=0), 3, 4)

End With

Создание таблицы из 5 строк и 4 столбцов в документе Word с содержимым:

With myDocument

myInt = .Range.Characters.Count — 1

Set myTable = .Tables.Add(.Range(Start:=myInt, End:=myInt), 5, 4)

End With

Для указания точки вставки таблицы присваиваем числовой переменной количество символов в документе минус один. Вычитаем единицу, чтобы исключить из подсчета последний знак завершения абзаца (¶), так как точка вставки не может располагаться за ним.

Последний знак завершения абзаца всегда присутствует в документе Word, в том числе и в новом без содержимого, поэтому такой код подойдет и для пустого документа.

При создании, каждой новой таблице в документе присваивается индекс, по которому к ней можно обращаться:

myDocument.Tables(индекс)

Нумерация индексов начинается с единицы.

Отображение границ таблицы

Новая таблица в документе Word из кода VBA Excel создается без границ. Отобразить их можно несколькими способами:

Вариант 1
Присвоение таблице стиля, отображающего все границы:

myTable.Style = «Сетка таблицы»

Вариант 2
Отображение внешних и внутренних границ в таблице:

With myTable

.Borders.OutsideLineStyle = wdLineStyleSingle

.Borders.InsideLineStyle = wdLineStyleSingle

End With

Вариант 3
Отображение всех границ в таблице по отдельности:

With myTable

.Borders(wdBorderHorizontal) = True

.Borders(wdBorderVertical) = True

.Borders(wdBorderTop) = True

.Borders(wdBorderLeft) = True

.Borders(wdBorderRight) = True

.Borders(wdBorderBottom) = True

End With

Присвоение таблицам стилей

Вариант 1

myTable.Style = «Таблица простая 5»

Чтобы узнать название нужного стиля, в списке стилей конструктора таблиц наведите на него указатель мыши. Название отобразится в подсказке. Кроме того, можно записать макрос с присвоением таблице стиля и взять название из него.

Вариант 2

myTable.AutoFormat wdTableFormatClassic1

Выбирайте нужную константу с помощью листа подсказок свойств и методов – Auto List Members.

Обращение к ячейкам таблицы

Обращение к ячейкам второй таблицы myTable2 в документе myDocument по индексам строк и столбцов:

myTable2.Cell(nRow, nColumn)

myDocument.Tables(2).Cell(nRow, nColumn)

nRow – номер строки;
nColumn – номер столбца.

Обращение к ячейкам таблицы myTable в документе Word с помощью свойства Cell объектов Row и Column и запись в них текста:

myTable.Rows(2).Cells(2).Range = _

«Содержимое ячейки во 2 строке 2 столбца»

myTable.Columns(3).Cells(1).Range = _

«Содержимое ячейки в 1 строке 3 столбца»

В таблице myTable должно быть как минимум 2 строки и 3 столбца.

Примеры создания таблиц Word

Пример 1
Создание таблицы в новом документе Word со сплошными наружными границами и пунктирными внутри:

Sub Primer1()

Dim myWord As New Word.Application, _

myDocument As Word.Document, myTable As Word.Table

Set myDocument = myWord.Documents.Add

myWord.Visible = True

With myDocument

Set myTable = .Tables.Add(.Range(0, 0), 5, 4)

End With

With myTable

.Borders.OutsideLineStyle = wdLineStyleSingle

.Borders.InsideLineStyle = wdLineStyleDot

End With

End Sub

В выражении myDocument.Range(Start:=0, End:=0) ключевые слова Start и End можно не указывать – myDocument.Range(0, 0).

Пример 2
Создание таблицы под ранее вставленным заголовком, заполнение ячеек таблицы и применение автосуммы:

Sub Primer2()

On Error GoTo Instr

Dim myWord As New Word.Application, _

myDocument As Word.Document, _

myTable As Word.Table, myInt As Integer

Set myDocument = myWord.Documents.Add

myWord.Visible = True

With myDocument

‘Вставляем заголовок таблицы

.Range.InsertAfter «Продажи фруктов в 2019 году» & vbCr

myInt = .Range.Characters.Count — 1

‘Присваиваем заголовку стиль

.Range(0, myInt).Style = «Заголовок 1»

‘Создаем таблицу

Set myTable = .Tables.Add(.Range(myInt, myInt), 4, 4)

End With

With myTable

‘Отображаем сетку таблицы

.Borders.OutsideLineStyle = wdLineStyleSingle

.Borders.InsideLineStyle = wdLineStyleSingle

‘Форматируем первую и четвертую строки

.Rows(1).Range.Bold = True

.Rows(4).Range.Bold = True

‘Заполняем первый столбец

.Columns(1).Cells(1).Range = «Наименование»

.Columns(1).Cells(2).Range = «1 квартал»

.Columns(1).Cells(3).Range = «2 квартал»

.Columns(1).Cells(4).Range = «Итого»

‘Заполняем второй столбец

.Columns(2).Cells(1).Range = «Бананы»

.Columns(2).Cells(2).Range = «550»

.Columns(2).Cells(3).Range = «490»

.Columns(2).Cells(4).AutoSum

‘Заполняем третий столбец

.Columns(3).Cells(1).Range = «Лимоны»

.Columns(3).Cells(2).Range = «280»

.Columns(3).Cells(3).Range = «310»

.Columns(3).Cells(4).AutoSum

‘Заполняем четвертый столбец

.Columns(4).Cells(1).Range = «Яблоки»

.Columns(4).Cells(2).Range = «630»

.Columns(4).Cells(3).Range = «620»

.Columns(4).Cells(4).AutoSum

End With

‘Освобождаем переменные

Set myDocument = Nothing

Set myWord = Nothing

‘Завершаем процедуру

Exit Sub

‘Обработка ошибок

Instr:

If Err.Description <> «» Then

MsgBox «Произошла ошибка: « & Err.Description

End If

If Not myWord Is Nothing Then

myWord.Quit

Set myDocument = Nothing

Set myWord = Nothing

End If

End Sub

Метод AutoSum суммирует значения в ячейках одного столбца над ячейкой с суммой. При использовании его для сложения значений ячеек в одной строке, результат может быть непредсказуемым.

Чтобы просуммировать значения в строке слева от ячейки с суммой, используйте метод Formula объекта Cell:

myTable.Cell(2, 4).Formula («=SUM(LEFT)»)

Другие значения метода Formula, применяемые для суммирования значений ячеек:

«=SUM(ABOVE)» – сумма значений над ячейкой (аналог метода AutoSum);
«=SUM(BELOW)» – сумма значений под ячейкой;
«=SUM(RIGHT)» – сумма значений справа от ячейки.

Источник

Коллекция
Tables.
Форматирование
таблицы.
Строки
и столбцы.
Ячейки.
Вычисления.

1.Коллекция Tables.

Таблица представляет собой
упорядоченную структуру, предназначенную для хранения организованных в виде
строк и столбцов наборов данных. Элемент таблицы, находящийся на пересечении
строки и столбца, называется ячейкой.

Таблица Word
имеет такую же структуру, как и электронная таблица Excel
– элемент таблицы, находящийся на пересечении строки и столбца, называется
ячейкой и идентифицируется по имени столбца и номеру строки.

В VBA для доступа к таблицам
используется объект Tables, являющийся семейством
объектов Table, каждый из которых связан с конкретной
таблицей. Для получения ссылки на семейство Tables
можно использовать свойство Tables объекта Document.

Общее число таблиц, имеющихся в
документе, содержится в свойстве Count. Для
получения доступа к конкретной таблице можно использовать метод Item, который является методом по умолчанию.

Синтаксис:

Set oblTable=objDocument.Tables.Item(Key)

Параметр Key,
является уникальным идентификатором каждой таблицы, хранящейся в объекте Tables.

Для создания новой таблицы
используется метод Add объекта Tables. Этот метод возвращает ссылку на созданную таблицу(Table).

objTables.Add (Range, NumRows,
NumColums)

Параметр Range
позволяет указать область документа, куда будет вставлена таблица. Если
параметр не пустой, т.е. имеется выделенная область, то она будет заменена
вставляемой таблицей.

Параметры NumRows,
NumColums позволяют указать на число строк и
столбцов таблицы.

Пример: создадим таблицу в
выделенном месте или там где стоит курсор.

2.Форматирование таблицы.

После создания таблицы ее можно
отформатировать нужным образом: добавить заливку, изменить формат границ,
изменить стиль и т.д.

В приложении Word
входит ряд готовых профессиональных шаблонов для форматирования таблиц, которые
позволяют значительно сэкономить время оформления таблицы.

Для их применения используется метод
AutoFormat.

objTable.AutoFormat(Format, [ApplyBorders,
ApplyShading, ApplyFont, ApplyColor, ApplyHeadingRows, ApplyLastRow, ApplyFirstColumn, ApplyLastColumn, AutoFit])

Параметр Format
содержит один из допустимых форматов. Список всех имеющихся форматов и
результат их применения можно увидеть в списке Стили таблицы окна диалога Автоформат таблицы (таблица®автоформат).

Параметр ApplyBorders
указывает, должны ли использоваться границы, установленные по умолчанию для
данного формата. Если True(значение по умолчанию), то
текущие границы будут заменены границами, предусмотренными в применяемом
автоформате.

Параметр ApplyShading
указывает, должна ли использоваться заливка. Если True
(значение по умолчанию), то для таблицы будет установлена заливка в
соответствии со значением, предусмотренном в
применяемом автоформате.

Параметр ApplyFont
указывает, должен ли изменятся шрифт таблицы. Если True, то для текста в таблице будет применен шрифт, предусмотренный
в применяемом автоформате.

Параметр ApplyColor
указывает на необходимость использования цветового оформления цветового
оформления таблицы. По умолчанию имеет значение True.

Параметр ApplyHeadingRows
указывает на необходимость изменения формата заголовков столбцов (первой строки
таблицы). По умолчанию имеет значение True.

Параметр ApplyLastRow
указывает на необходимость изменения формата последней строки таблицы. По
умолчанию имеет значение False, означающее, что
особый формат к последней строке не применяется.

Параметр ApplyFirstColumn
указывает на необходимость изменение формата первого столбца таблицы. По
умолчанию имеет значение True.

Параметр ApplyLastColumn
указывает на необходимость изменение формата последнего столбца таблицы. По умолчанию
имеет значение False, означающее, что особый формат к
последнему столбцу не применяется.

Параметр AutoFit
указывает на автоматический подбор ширины столбцов в зависимости от размещаемых
в них данных. По умолчанию имеет значение True.

Пример: применяем автоформат Классический2 к таблице, расположенной первой от начала
активного документа.

ActiveDocument.Tables(1).AutoFormat
Format:=WdTableFormat.wdTableFormatClassic2

Тип
используемого пользовательского форматирования содержится в свойстве AutoFormatType. Свойство возвращает одно из значений
типа wdTableFormat.

Для форматирования границ таблицы
используется свойство Borders, которое
возвращает ссылку на объект типа Вorders,
связанный с границами данной таблицы.

Синтаксис:

objTable.Borders

Пример: назначение первой таблице
в документе оформление границ.

With ActiveDocument.Tables(1).Borders

.OutsideLineStyle = wdLineStyleSingle внешние границы

.OutsideLineWidth =
wdLineWidth100pt

.InsideLineStyle = wdLineStyleSingle внутренние границы

.InsideLineWidth =
wdLineWidth300pt

End With

3.Строки и столбцы.

Таблица состоит из набора строк и
столбцов. Строки содержатся в семействе Rows, возвращаемое свойством Rows, а
столбцы – в семействе Columns, возврщаемое
свойством Columns.

Определенная строка или столбец связаны с объектами типа Row или Column. Доступ к конкретной строке или столбцу
осуществляется с помощью метода Item,
являющегося для объектов Rows и Columns методом
по умолчанию.

Индексация столбцов и строк
начинается с единицы. Индекс «единица» получает первая сверху строка и крайний
левый столбец. Индекс последней строки и столбца можно получить с помощью
свойства Count, которое возвращает количество
членов в коллекции.

Пример: выпадающее окно с
сообщением о количестве столбцов в таблице 1.

MsgBox ActiveDocument.Tables(1).Columns.Count

Для получения ссылок на первую
или последнюю строку (столбец) можно использовать свойства First и Last.

Для добавления в таблицу новых
строк (столбцов) используется метод Add.

Синтаксис:

ObjTable.Rows.Add (Before)

Параметр Before
– указывает, перед какой строкой будет вставлена строка. Если параметр опущен,
то строка добавляется в конец таблицы.

Пример:

Set tabv = ActiveDocument.Tables(1).Rows.Add(beforerow:=ActiveDocument.Tables(1).Rows(1))

Чтобы установить высоту строки,
используется метод SetHeight.

Синтаксис:

objRow.SetHeight(RowHeight, HeightRule)

параметр RowHeight
указывает на новую высоту строки в пунктах.

Параметр HeightRule
– указывает на способ изменения высоты:

WdRowHeightAtLeast
– размер, указанный в параметре RowHeigh, является
минимальным.

WdRowHeightAuto
— размер, указанный в параметре RowHeigh ,является
точным.

WdRowHeightExactly
– автоматический подбор высоты строк (параметр RowHeigh
игнорируется).

Получить информацию о текущей
ширине строки и правиле ее изменения можно с помощью свойств Height и HeightRule.

Синтаксис:

objRow.
Height [=Height]

Параметр Height
(тип Single) позволяет задать необходимую высоту
строки в пунктах.

Синтаксис:

objRow.
HeightRule[=Rule]

Параметр Rule
указывает на правило изменения ширины ячейки:

• wdRowHeightAtLeast
— минимальная ширина, которая может быть назначена строке, указывается в
свойстве Height;

• wdRowHeightExactly
— ширина строки должна быть точно равна значению, указанному в свойстве Height;

• wdRowHeightAuto —
ширина строки подбирается автоматически в зависимости от размера используемого
шрифта или размера вставок.

Чтобы установить одинаковую
высоту всех строк, необходимо использовать метод DistributeHeight
объекта Rows.

objRows.
DistributeHeight

Для украшения текста документа
часто используются прием создания отступа между левой границы ячейки и текстом.
Этот прием часто применяют при создании таблиц на web-страницах. Для создания
отступа в ячейках таблицы можно использовать свойство SpaceBetweenColumns.
При использовании этого свойства в объекте Rows
выполняется добавление отступа во все ячейки таблицы, а при использовании в Row — только для ячеек данной строки.

Синтаксис

objRows.SpaceBetweenColumns[ = Space]

Параметр Space
(тип Single) позволяет указать на ширину отступа
в пунктах. Значение, передаваемое параметром Space,
не может быть меньше 0 и больше ширины ячейки.

В приведенном ниже примере
показан код, позволяющий создать в первой строке первой таблицы активного
документа отступ, равный 36 пунктам.

Пример

With ActiveDocument.Tables(l)

.Rows(l).SpaceBetweenColumns = InchesToPoints(0.5)

End With

Чтобы установить ширину столбца и
правило ее изменения применяется метод SetWidth.
Этот метод используется как в объекте типа Columns,
так и объекте типа Column. Если используется метод
объекта Columns, то изменения ширины касаются всех
столбцов, а если метод объекта Column— то только
данного столбца.

оbjColumns.SetWidth(ColumnWidth, RulerStyle)

Параметр ColumnWidth
(тип Single) указывает на новую ширину столбца в
точках, а параметр RulerStyle (тип WdRulerStyle) — на способ изменения ширины. Параметр RulerStyle может принимать следующие
значения:

• wdAdjustNone (значение по умолчанию) — ширина столбца
соответствует указанному значению. Изменение ширины столбца выполняется за
счет смещения левой или правой границы таблицы (столбца).

• wdAdjustSameWidth —
ширина столбца соответствует указанному значению. Изменение ширины выполняется
за счет смещения внутренних границ таблицы. Правая граница сохраняет свое
положение.

• wdAdjustFlrstColumn — ширина первого столбца соответствует
указанному значению. Изменение ширины выполняется за счет смещения правой
границы столбца. Размер остальных столбцов сохраняется. Если ширина превышает
суммарную ширину первой и второй ячеек, то происходит сдвиг правой границы
таблицы.

• wdAdjustProportional — ширина первого столбца соответствует
указанному значению. Размер остальных столбцов подбирается автоматически, так
чтобы общая ширина таблицы сохранилась.

• Для
получения информации о текущей ширине столбца можно использовать свойство Width.

• Синтаксис:

• ОbjColumns.Width[=Width]

• Параметр
Width (типа Single)
позволяет указать нужную ширину столбца.

• Чтобы
установить одинаковую ширину всех столбцов, необходимо использовать метод DistributeWidth объекта Columns.

• Objcolumns.DistributeWidth

• Для
автоматического подбора ширины столбцов используется метод AutoFit.

• ObjColumn.AutoFit

• Для
удаления строк (столбцов) используется метод Delete.

• 4.Ячейки.

• Доступ
к ячейкам данной строки или столбца осуществляется с помощью объекта Cells, который является семейством объектов Cell, связанных с конкретными ячейками.

• Синтаксис:

•
Set
objCells = objTables.Rows(key).Cells

• или

•
Set
objCells=objTables.Columns(key).Cells

• Здесь
objTables указывает на таблицу, с ячейками
которой будет выполняться работа, а key –
строка или столбец в таблице, ячейки которой входят в семейство Cells.

•

• Ссылку
на определенную ячейку можно получить с помощью метода Cell
объекта Table.

• Синтаксис:

• ObjTable.Cell (Row,Column)

Set instable = ActiveDocument.Tables.Add(Selection.Range, 4, 10)

Для добавления новой ячейки используется метод Add.

Синтаксис:

ObjCells.Add [(BeforeCell)]

Параметр BeforeCell
указывает на ячейку, перед которой должна быть вставлена новая ячейка. Если
параметр опущен, то ячейка вставляется в конец столбца (строки). Метод
возвращает ссылку на созданную ячейку.

Все ячейки таблицы имеют свой уникальный индекс. Для
получения ссылки на ячейку из определенного семейства используется ее
порядковый номер: крайняя правая (или верхняя) ячейка имеет номер один, а
последняя (нижняя) – значение, определяемое свойством Count
для данного объекта Cells.

Чтобы узнать положение текущей ячейки в строке или столбце,
можно использовать свойство RowIndex или ColumnIndex. Оба свойства возвращают ссылку
на объект типа Cell и предназначены только для
чтения.

Для выделения (активизации) текущей ячейки используется
метод Select.

Синтаксис:

objCell.Select

Для объединения нескольких ячеек в одну (инструмент слияния)
используется метод Merge.

Синтаксис:

ObjCell.Merge (MergeTo)

Параметр MergeTo (типа Cell)
содержит объект типа Cell (ячейка), с которым
выполняется слияние. Если указана ячейка, не имеющая общей
границы с текущей, то выполняется слияние всех ячеек, находящихся в
прямоугольнике, у которого данная ячейка и ячейка, указанная в параметре MergeTo, являются угловыми.

Для разбиения объединенных ячеек или одной ячейки на
несколько используется метод Split.

Синтаксис:

ObjCell.Split[(NumRows,NumColumns)]

Параметр NumRows (типа long) содержит значение,
указывающее на число строк, на которые должна быть разбита данная ячейка.
Параметр NumColumns (типа long)
содержит значение, указывающее на число столбцов, на которые должна быть
разбита данная ячейка.

Пример:

ActiveDocument.Tables(1).Cell(1, 1).Split 2, 3

5.Вычисления.

Вычисления в таблицах Word выполняются так же, как и в любых других электронных
таблицах. Разница заключается только в возможностях использования функций. По
умолчанию в Word
определенно не очень много функций, однако, используя возможности VBA по подключению
дополнительных библиотек, например библиотеки функций Excel, их число можно значительно
увеличить.

Для указания ячейке, что в ней будет выполнятся
вычисление, используется метод Formula
объекта Cell.

Синтаксис:

ObjCell.Formula (Formula, NumFormat)

Параметр Formula
содержит строковое выражение, описывающее используемое выражение. Параметр NumFormat
определяет числовой формат данных, которые будут отображены в данной ячейке.

При использовании стандартных инструментов вставки формул
эти выражения содержатся в соответствующих полях. Например,
выражение “=SUM(A4:C4)” позволяет отобразить значение,
получаемое в результате выполнения суммирования значений трех ячеек: А4, В4,
С4. Кроме непосредственной ссылки на конкретные ячейки можно использовать общие
ссылки, например на все ячейки, расположенные выше(Above) или левее (Left).

По умолчанию в таблицах Word можно использовать следующие функции:

• Abs(X) — возвращает абсолютное значение
числа или формулы (без знака);

• And(X;Y) — возвращает значение 1, если оба логических выражения, X и
У, истинны, или 0 (ноль), если хотя бы одно из них ложно;

• Average(List) — возвращает среднее значение из
списка значений List,

• Count (List) — возвращает
количество элементов в списке List;

• Defined(X) — возвращает значение 1, если
выражение X допустимо, или 0 (ноль), если выражение не может быть
вычислено;

• Fal se —
возвращает значение 0 (ноль);

• Int(X) — возвращает целую часть
числа или значения формулы X;

• Min(List) — возвращает наименьшее значение в
списке List;

• Max(List) — возвращает наибольшее значение в
списке List;

• Mod(X;Y) — возвращает остаток от деления X на Y;

• Not(X) — возвращает значение 0 (ложь), если
логическое выражение X истинно, или 1 (истина), если оно ложно;

• Or(X;Y) — возвращает значение 1 (истина),
если хотя бы одно из двух логических
выражений X и Y
истинно, или 0 (ложь), если оба ложны;

• Product (List) — возвращает произведение
значений, включенных в список List.
Например функция «= Product (1,3,7,9)» возвращает значение 189;

• Round(X; У) — возвращает значение X, округленное до
указанного десятичного разряда Y;

• Sign (X) — указывает
знак числа: возвращает значение 1, если X > О, или -1 в противном случае;

• Sum(List) — возвращает сумму
значений или формул, включенных в список. List;

• True — возвращает значение 1.

• Параметр
NumFormat,
является маской, которая определяет формат числовых значений. Эта маска
может содержать ряд специальных символов, которые приведены ниже.

• 0
(нуль) — возвращает цифру. Если полученное значение не содержит цифру в этой
позиции, то возвращается 0 (нуль). Например, если имеется выражение типа Formula:=»= 4 + 5″,
NumFormat:=
«00,00», то возвращаемое значение будет следующим: «09,00».

• #
— возвращает цифру. Если полученное значение не содержит цифру в этой позиции,
возвращается пробел. Например, Formula:=”=
11 + 5″, NumFormat:=
«###» возвращает значение «-15».

• х — если «х»
находится слева от десятичного разделителя, цифры расположенные слева от него,
отбрасываются, а если справа — то значение округляется до указанного знака.
Например, Formula:=»=
111053 + 111439″, NumFormat:= «x$$$» возвращает значение «492», аFormula:=»= 1/8″, NumFormat:=
«0,00x»
возвращает значение «0,125».

• .
или , (десятичный разделитель) —задает
положение десятичного разделителя. Например, выражение NumFormat:
= «###, 00») возвращает значение типа «495,47».

•       пробел
(разделитель групп разрядов) — разделяет число на группыпо   три
цифры   в   каждой.
Например,   выражение   NumForrcat:»###» возвращает значение
типа «2 456 800».

• минус)
— добавляет минус к отрицательным или пробел — ко всем остальным значениям.

• + (плюс) — добавляет плюс к положительным, минус к отрицательным
или пробел — к нулевым значениям.

• %,
$, * и т. д. — включает в значение указанный знак. Например, выражение (NumFormat:=
«##%») возвращает значение типа «33 %».

• Для
автоматического вычисления суммы значений можно использовать метод AutoSum.

• Синтаксис:

• ObjCell.AutoSum

• После
применения этого метода к данной ячейке в ней отображается значение, равное
сумме значений всех ячеек, расположенных выше или левее данной.