Vba word selection in table

Selection object (Word)

Represents the current selection in a window or pane. A selection represents either a selected (or highlighted) area in the document, or it represents the insertion point if nothing in the document is selected. There can be only one Selection object per document window pane, and only one Selection object in the entire application can be active.

[!IMPORTANT]
This method has changed. Using VBA Selection commands like Selection.BoldRun on user selection with Comments no longer applies bold formatting on user-selected text or Selection.TypeTxt command or on user selection with Comments no longer inserts text.

Remarks

Use the Selection property to return the Selection object. If no object qualifier is used with the Selection property, Microsoft Word returns the selection from the active pane of the active document window. The following example copies the current selection from the active document.

The following example deletes the selection from the third document in the Documents collection. The document does not have to be active to access its current selection.

Documents(3).ActiveWindow.Selection.Cut

The following example copies the selection from the first pane of the active document and pastes it into the second pane.

ActiveDocument.ActiveWindow.Panes(1).Selection.Copy 
ActiveDocument.ActiveWindow.Panes(2).Selection.Paste

The Text property is the default property of the Selection object. Use this property to set or return the text in the current selection. The following example assigns the text in the current selection to the variable strTemp, removing the last character if it is a paragraph mark.

Dim strTemp as String 
 
strTemp = Selection.Text 
If Right(strTemp, 1) = vbCr Then _ 
 strTemp = Left(strTemp, Len(strTemp) - 1)

The Selection object has various methods and properties with which you can collapse, expand, or otherwise change the current selection. The following example moves the insertion point to the end of the document and selects the last three lines.

Selection.EndOf Unit:=wdStory, Extend:=wdMove 
Selection.HomeKey Unit:=wdLine, Extend:=wdExtend 
Selection.MoveUp Unit:=wdLine, Count:=2, Extend:=wdExtend

The Selection object has various methods and properties with which you can edit selected text in a document. The following example selects the first sentence in the active document and replaces it with a new paragraph.

Options.ReplaceSelection = True 
ActiveDocument.Sentences(1).Select 
Selection.TypeText "Material below is confidential." 
Selection.TypeParagraph

The following example deletes the last paragraph of the first document in the Documents collection and pastes it at the beginning of the second document.

With Documents(1) 
 .Paragraphs.Last.Range.Select 
 .ActiveWindow.Selection.Cut 
End With 
 
With Documents(2).ActiveWindow.Selection 
 .StartOf Unit:=wdStory, Extend:=wdMove 
 .Paste 
End With

The Selection object has various methods and properties with which you can change the formatting of the current selection. The following example changes the font of the current selection from Times New Roman to Tahoma.

If Selection.Font.Name = "Times New Roman" Then _ 
 Selection.Font.Name = "Tahoma"

Use properties like Flags, Information, and Type to return information about the current selection. Use the following example in a procedure to determine whether there is anything selected in the active document; if there is not, the rest of the procedure is skipped.

If Selection.Type = wdSelectionIP Then 
 MsgBox Prompt:="You have not selected any text! Exiting procedure..." 
 Exit Sub 
End If

Even when a selection is collapsed to an insertion point, it is not necessarily empty. For example, the Text property will still return the character to the right of the insertion point; this character also appears in the Characters collection of the Selection object. However, calling methods like Cut or Copy from a collapsed selection causes an error.

It is possible for the user to select a region in a document that does not represent contiguous text (for example, when using the Alt key with the mouse). Because the behavior of such a selection can be unpredictable, you may want to include a step in your code that checks the Type property of a selection before performing any operations on it (Selection.Type = wdSelectionBlock).

Similarly, selections that include table cells can also lead to unpredictable behavior. The Information property will tell you if a selection is inside a table (Selection.Information(wdWithinTable) = True). The following example determines if a selection is normal (for example, it is not a row or column in a table, it is not a vertical block of text); you could use it to test the current selection before performing any operations on it.

If Selection.Type <> wdSelectionNormal Then 
 MsgBox Prompt:="Not a valid selection! Exiting procedure..." 
 Exit Sub 
End If

Because Range objects share many of the same methods and properties as Selection objects, using Range objects is preferable for manipulating a document when there is not a reason to physically change the current selection. For more information about Selection and Range objects, see Working with the Selection object and Working with Range objects.

Methods

• BoldRun
• Calculate
• ClearCharacterAllFormatting
• ClearCharacterDirectFormatting
• ClearCharacterStyle
• ClearFormatting
• ClearParagraphAllFormatting
• ClearParagraphDirectFormatting
• ClearParagraphStyle
• Collapse
• ConvertToTable
• Copy
• CopyAsPicture
• CopyFormat
• CreateAutoTextEntry
• CreateTextbox
• Cut
• Delete
• DetectLanguage
• EndKey
• EndOf
• EscapeKey
• Expand
• ExportAsFixedFormat
• ExportAsFixedFormat2
• Extend
• GoTo
• GoToEditableRange
• GoToNext
• GoToPrevious
• HomeKey
• InRange
• InsertAfter
• InsertBefore
• InsertBreak
• InsertCaption
• InsertCells
• InsertColumns
• InsertColumnsRight
• InsertCrossReference
• InsertDateTime
• InsertFile
• InsertFormula
• InsertNewPage
• InsertParagraph
• InsertParagraphAfter
• InsertParagraphBefore
• InsertRows
• InsertRowsAbove
• InsertRowsBelow
• InsertStyleSeparator
• InsertSymbol
• InsertXML
• InStory
• IsEqual
• ItalicRun
• LtrPara
• LtrRun
• Move
• MoveDown
• MoveEnd
• MoveEndUntil
• MoveEndWhile
• MoveLeft
• MoveRight
• MoveStart
• MoveStartUntil
• MoveStartWhile
• MoveUntil
• MoveUp
• MoveWhile
• Next
• NextField
• NextRevision
• NextSubdocument
• Paste
• PasteAndFormat
• PasteAppendTable
• PasteAsNestedTable
• PasteExcelTable
• PasteFormat
• PasteSpecial
• Previous
• PreviousField
• PreviousRevision
• PreviousSubdocument
• ReadingModeGrowFont
• ReadingModeShrinkFont
• RtlPara
• RtlRun
• Select
• SelectCell
• SelectColumn
• SelectCurrentAlignment
• SelectCurrentColor
• SelectCurrentFont
• SelectCurrentIndent
• SelectCurrentSpacing
• SelectCurrentTabs
• SelectRow
• SetRange
• Shrink
• ShrinkDiscontiguousSelection
• Sort
• SortAscending
• SortByHeadings
• SortDescending
• SplitTable
• StartOf
• ToggleCharacterCode
• TypeBackspace
• TypeParagraph
• TypeText
• WholeStory

Properties

• Active
• Application
• BookmarkID
• Bookmarks
• Borders
• Cells
• Characters
• ChildShapeRange
• Columns
• ColumnSelectMode
• Comments
• Creator
• Document
• Editors
• End
• EndnoteOptions
• Endnotes
• EnhMetaFileBits
• ExtendMode
• Fields
• Find
• FitTextWidth
• Flags
• Font
• FootnoteOptions
• Footnotes
• FormattedText
• FormFields
• Frames
• HasChildShapeRange
• HeaderFooter
• HTMLDivisions
• Hyperlinks
• Information
• InlineShapes
• IPAtEndOfLine
• IsEndOfRowMark
• LanguageDetected
• LanguageID
• LanguageIDFarEast
• LanguageIDOther
• NoProofing
• OMaths
• Orientation
• PageSetup
• ParagraphFormat
• Paragraphs
• Parent
• PreviousBookmarkID
• Range
• Rows
• Sections
• Sentences
• Shading
• ShapeRange
• Start
• StartIsActive
• StoryLength
• StoryType
• Style
• Tables
• Text
• TopLevelTables
• Type
• WordOpenXML
• Words
• XML

See also

• Word Object Model Reference

[!includeSupport and feedback]

Add Table to Word Document

This simple macro will add a table to your Word document:

Sub VerySimpleTableAdd()
    Dim oTable As Table
    Set oTable = ActiveDocument.Tables.Add(Range:=Selection.Range, NumRows:=3, NumColumns:=3)
End Sub

Select Table in Word

This macro will select the first table in the active Word document:

Sub SelectTable()
'selects first table in active doc
    If ActiveDocument.Tables.Count > 0 Then    'to avoid errors we check if any table exists in active doc
        ActiveDocument.Tables(1).Select
    End If
End Sub

Loop Through all Cells in a Table

This VBA macro will loop through all cells in a table, writing the cell count to the cell:

Sub TableCycling()
' loop through all cells in table
    Dim nCounter As Long    ' this will be writen in all table cells
    Dim oTable As Table
    Dim oRow As Row
    Dim oCell As Cell

    ActiveDocument.Range.InsertParagraphAfter    'just makes new para athe end of doc, Table will be created here
    Set oTable = ActiveDocument.Tables.Add(Range:=ActiveDocument.Paragraphs.Last.Range, NumRows:=3, NumColumns:=3)    'create table and asign it to variable
    For Each oRow In oTable.Rows    ' outher loop goes through rows
        For Each oCell In oRow.Cells    'inner loop goes
            nCounter = nCounter + 1    'increases the counter
            oCell.Range.Text = nCounter    'writes counter to the cell
        Next oCell
    Next oRow

    'display result from cell from second column in second row
    Dim strTemp As String
    strTemp = oTable.Cell(2, 2).Range.Text
    MsgBox strTemp
End Sub

Create Word Table From Excel File

This VBA example will make a table from an Excel file:

Sub MakeTablefromExcelFile()
'advanced
    Dim oExcelApp, oExcelWorkbook, oExcelWorksheet, oExcelRange
    Dim nNumOfRows As Long
    Dim nNumOfCols As Long
    Dim strFile As String

    Dim oTable As Table    'word table
    Dim oRow As Row    'word row
    Dim oCell As Cell    'word table cell
    Dim x As Long, y As Long    'counter for loops

    strFile = "c:UsersNenadDesktopBookSample.xlsx"    'change to actual path
    Set oExcelApp = CreateObject("Excel.Application")
    oExcelApp.Visible = True
    Set oExcelWorkbook = oExcelApp.Workbooks.Open(strFile)    'open workbook and asign it to variable
    Set oExcelWorksheet = oExcelWorkbook.Worksheets(1)    'asign first worksheet to variable
    Set oExcelRange = oExcelWorksheet.Range("A1:C8")
    nNumOfRows = oExcelRange.Rows.Count
    nNumOfCols = oExcelRange.Columns.Count

    ActiveDocument.Range.InsertParagraphAfter    'just makes new para athe end of doc, Table will be created here
    Set oTable = ActiveDocument.Tables.Add(Range:=ActiveDocument.Paragraphs.Last.Range, NumRows:=nNumOfRows, NumColumns:=nNumOfCols)    'create table and asign it to variable
    '***real deal, table gets filled here
    For x = 1 To nNumOfRows
        For y = 1 To nNumOfCols
            oTable.Cell(x, y).Range.Text = oExcelRange.Cells(x, y).Value
        Next y
    Next x
    '***
    oExcelWorkbook.Close False
    oExcelApp.Quit
    With oTable.Rows(1).Range    'we can now apply some beautiness to our table :)
        .Shading.Texture = wdTextureNone
        .Shading.ForegroundPatternColor = wdColorAutomatic
        .Shading.BackgroundPatternColor = wdColorYellow
    End With
End Sub