Vba word if exists

Today, I thought I’d demonstrate 2 distinct methods that can be used to validate whether a file exists or not.

• The VBA Dir Function
• The File System Object’s FileExist Method

Using The VBA Dir Function

'---------------------------------------------------------------------------------------
' Procedure : File_Exist
' Author    : Daniel Pineault, CARDA Consultants Inc.
' Website   : http://www.cardaconsultants.com
' Purpose   : Test for the existence of a file; Returns True/False
'               True  => File exists
'               False => File does not exist
' Copyright : The following is release as Attribution-ShareAlike 4.0 International
'             (CC BY-SA 4.0) - https://creativecommons.org/licenses/by-sa/4.0/
' Req'd Refs: None required
'
' Input Variables:
' ~~~~~~~~~~~~~~~~
' sFile     : Fully qualified path and filename to check for
'
' Usage:
' ~~~~~~
' ? File_Exist("C:TempFlow-Undo-Dont.jpg")
'   Returns -> True
'
' Revision History:
' Rev       Date(yyyy-mm-dd)        Description
' **************************************************************************************
' 1         2007-03-06              Initial Release
' 2         2022-11-24              Update Function header
'                                   Update Error Handler
'---------------------------------------------------------------------------------------
Function File_Exist(ByVal sFile As String) As Boolean
On Error GoTo Error_Handler

        File_Exist = (Len(Dir(sFile)) > 0)

Error_Handler_Exit:
    On Error Resume Next
    Exit Function
 
Error_Handler:
    MsgBox "The following error has occurred" & vbCrLf & vbCrLf & _
           "Error Source: File_Exist" & vbCrLf & _
           "Error Number: " & Err.Number & vbCrLf & _
           "Error Description: " & Err.Description & _
           Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
           , vbOKOnly + vbCritical, "An Error has Occurred!"
    Resume Error_Handler_Exit
End Function

Usage Example

If File_Exist("C:TempFlow-Undo-Dont.jpg") = True Then
    'Do something because the file exists
End If

Or

If File_Exist("C:TempFlow-Undo-Dont.jpg") = False Then
    MsgBox "The file could not be found!", vbCritical Or vbOKOnly, "Operation Aborted"
End If

Using The File System Object’s FileExist Method

'---------------------------------------------------------------------------------------
' Procedure : FSO_File_Exist
' Author    : Daniel Pineault, CARDA Consultants Inc.
' Website   : http://www.cardaconsultants.com
' Purpose   : Test for the existence of a file; Returns True/False
'               True  => File exists
'               False => File does not exist
' Copyright : The following is release as Attribution-ShareAlike 4.0 International
'             (CC BY-SA 4.0) - https://creativecommons.org/licenses/by-sa/4.0/
' Req'd Refs: None required
' Also check out: https://www.devhut.net/vba-fso-files-folders-drives-and-more/
'
' Input Variables:
' ~~~~~~~~~~~~~~~~
' sFile     : Fully qualified path and filename to check for
'
' Usage:
' ~~~~~~
' ? FSO_File_Exist("C:TempFlow-Undo-Dont.jpg")
'   Returns -> True
'
' Revision History:
' Rev       Date(yyyy-mm-dd)        Description
' **************************************************************************************
' 1         2022-11-24              Initial Release
'---------------------------------------------------------------------------------------
Function FSO_File_Exist(ByVal sFile As String) As Boolean
On Error GoTo Error_Handler
    #Const FSO_EarlyBind = False

    #If FSO_EarlyBind = True Then
        Dim oFSO              As Scripting.FileSystemObject
        Set oFSO = New FileSystemObject
    #Else
        Dim oFSO              As Object
        Set oFSO = CreateObject("Scripting.FileSystemObject")
    #End If

    FSO_File_Exist = oFSO.FileExists(sFile)

Error_Handler_Exit:
    On Error Resume Next
    Set oFSO = Nothing
    Exit Function

Error_Handler:
    MsgBox "The following error has occurred" & vbCrLf & vbCrLf & _
           "Error Source: FSO_File_Exist" & vbCrLf & _
           "Error Number: " & Err.Number & vbCrLf & _
           "Error Description: " & Err.Description & _
           Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
           , vbOKOnly + vbCritical, "An Error has occurred!"
    Resume Error_Handler_Exit
End Function

If you go the route of FSO, I’d recommend implementing Self-Healing Object Variables, so be sure to checkout:

Usage Example

If FSO_File_Exist("C:TempFlow-Undo-Dont.jpg") = True Then
    'Do something because the file exists
End If

Or

If FSO_File_Exist("C:TempFlow-Undo-Dont.jpg") = False Then
    MsgBox "The file could not be found!", vbCritical Or vbOKOnly, "Operation Aborted"
End If

Resources on the Subject

Please Note:
This article is written for users of the following Microsoft Word versions: 97, 2000, 2002, and 2003. If you are using a later version (Word 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Word, click here: Determining If a File Exists.

As you are programming your macros, you may have a need to determine if a particular file exists on disk. For instance, the purpose of your macro may be to open and read from a text file. Before doing so, you will want to check to see if the file exists, in order to avoid an error.

The following function can be used to check for the existence of a file. All you need to do is pass it the full filename as a string, and the macro returns either True (if the file exists) or False (if it doesn’t).

Function FileThere(FileName As String) As Boolean
    FileThere = (Dir(FileName) > "")
End Function

You can use the function similar to the following:

If FileThere("c:myfile.txt") Then
    '
    ' Do stuff here
    '
Else
    MsgBox "File Not There!"
End If

Author Bio

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He is president of Sharon Parq Associates, a computer and publishing services company. Learn more about Allen…