Vba listbox in word

• 
• VBForums
• Visual Basic
• Office Development
• [Word] [VBA] populate listbox in userform with excel database

1. Nov 4th, 2019, 07:02 AM

   
   

   #1

   

   Thread Starter

   
   New Member
   

   

   ---

   [Word] [VBA] populate listbox in userform with excel database
   

   Hello,

   i am having trouble with a userform i am trying to create.

   I want to populate a listbox in a userform in word with data that comes from an excel workbook.
   I have two listboxes.
   The first listbox get populated during userform initializiation.
   The second userform then gets populated with items from an excel workbook based on the selection that is made in the first listbox.

   I searched the internet for solutions and came across this thread:
   http://www.vbforums.com/showthread.p…ith-excel-data

   I am fairly new to VBA and i can’t quite figure out how to implement this code into my userform.
   The Data from the workbook recides on differents worksheets.

   As an easy example:

   Listbox1 containsitems get added during initialization)
   Animals
   Cities
   Software

   The Excel Workbook has three Worksheets:
   Animals
   Cities
   Software

   Each worksheet contains datasets in Column A only. But the amount of data varies.

   How would the code from that thread needed to be adjusted in order to make it work for me?

   I would appreciate it if someone would take the time to help me out with this problem.

   ---

2. Nov 5th, 2019, 05:21 AM

   
   

   #2

   Re: [Word] [VBA] populate listbox in userform with excel database
   

   you can try like

   Code:

   Option Explicit
   Dim wb As Object
   
   Public Sub UserForm_Initialize()
       Dim sh As Object
   Set wb = GetObject("C:TempNew folderTestDatabase.xlsx")
   For Each sh In wb.sheets
       ListBox1.AddItem sh.Name
   Next
   End Sub
   
   
   Private Sub ListBox1_Click()
   Dim sh As Object, lrow As Long, rw As Long
   ListBox2.Clear
   Set sh = wb.sheets(ListBox1.Text)
   lrow = sh.Cells(sh.Rows.Count, 1).End(-4162).Row
   For rw = 1 To lrow
       ListBox2.AddItem sh.Cells(rw, 1)
   Next
   
   End Sub
   
   Private Sub UserForm_Terminate()
   wb.Application.Quit
   Set wb = Nothing
   End Sub

   as this is fairly simple, i changed this from using ADO, if the data became much more complex and you want to run queries on the data the ADO would be better, but for what you want so far this is fine

   change the pathfilename of your xlsx to suit, i opted to make the loading of listbox1 dynamic, if you add extra sheets or rename any the listbox is automatically correct when opening the userform, i have used late binding of excel workbook, so no reference is required and left the connection open until the userform is closed, rather than keep opening a connection

   i do my best to test code works before i post it, but sometimes am unable to do so for some reason, and usually say so if this is the case.
   Note code snippets posted are just that and do not include error handling that is required in real world applications, but avoid On Error Resume Next

   dim all variables as required as often i have done so elsewhere in my code but only posted the relevant part

   come back and mark your original post as resolved if your problem is fixed
   pete

   ---

3. Nov 6th, 2019, 04:13 AM

   
   

   #3

   

   Thread Starter

   
   New Member
   

   

   ---

   Re: [Word] [VBA] populate listbox in userform with excel database
   

   Hello,

   thanks for your reply.
   I implemented your code into my document and ran into the following error.

   Filename or class name not found during Automation operation (Error 432)
   The GetObject function requires either a valid file name with a path specification, or the name of a class that is registered with the system.

   The yellow marked Code while debugging is:

   Code:

       Set wb = GetObject("C:tempfindingsDB.xlsx")

   Hovering over it, it tells me:
   I double checked the path to the file for any typos and the path is correct.
   What else could be causing this issue?

   Here is the complete Code with all changes (not much has changed).

   Code:

   Option Explicit
   Public Sub UserForm_Initialize()
       Dim sh, wb As Object
       
       Set wb = GetObject("C:tempfindingsDB.xlsx")
       For Each sh In wb.Sheets
           ListBox5.AddItem sh.Name
       Next
   End Sub
   
   Private Sub ListBox5_Click()
   Dim sh As Object, wb As Object, lrow As Long, rw As Long
   ListBox6.Clear
   Set sh = wb.Sheets(ListBox5.Text)
   lrow = sh.Cells(sh.Rows.Count, 1).End(-4162).Row
   For rw = 1 To lrow
       ListBox6.AddItem sh.Cells(rw, 1)
   Next
   End Sub
   
   Private Sub UserForm_Terminate()
   Dim wb As Object
   wb.Application.Quit
   Set wb = Nothing
   End Sub

   ---

4. Nov 6th, 2019, 04:31 AM

   
   

   #4

   

   Thread Starter

   
   New Member
   

   

   ---

   Re: [Word] [VBA] populate listbox in userform with excel database
   

   *deleted* double post, sorry…

   ---

5. Nov 6th, 2019, 05:12 AM

   
   

   #5

   Re: [Word] [VBA] populate listbox in userform with excel database
   

   note where i dim wb, only in one place, though that should not cause your current error
   having wb dimensioned in each sub will cause errors and not work as intended
   also FYI items dimmed on one line still need to be typed individually, not just the last item
   Dim sh, wb As Object in this only wb is an object sh is just a default variant

   do you actually have a folder C:temp?
   i retested the code i posted, it worked correctly as intended, with your samples

   i do my best to test code works before i post it, but sometimes am unable to do so for some reason, and usually say so if this is the case.
   Note code snippets posted are just that and do not include error handling that is required in real world applications, but avoid On Error Resume Next

   dim all variables as required as often i have done so elsewhere in my code but only posted the relevant part

   come back and mark your original post as resolved if your problem is fixed
   pete

   ---

6. Nov 6th, 2019, 06:45 AM

   
   

   #6

   

   Thread Starter

   
   New Member
   

   

   ---

   Re: [Word] [VBA] populate listbox in userform with excel database
   

   Originally Posted by westconn1
   

   note where i dim wb, only in one place, though that should not cause your current error
   having wb dimensioned in each sub will cause errors and not work as intended
   also FYI items dimmed on one line still need to be typed individually, not just the last item
   Dim sh, wb As Object in this only wb is an object sh is just a default variant

   do you actually have a folder C:temp?
   i retested the code i posted, it worked correctly as intended, with your samples

   Ah ok thanks, i corrected that and wb is now dimensioned only outside of any sub.
   Thanks for the hint with dimmed items in one line, i did not know that.

   I got it working with the following code:

   Code:

   Option Explicit
   Dim wb As Object
   Dim xlApp As Object
   
   Public Sub UserForm_Initialize()
       Dim sh As Object
       Set xlApp = CreateObject("excel.Application")
       Set wb = xlApp.Workbooks.Open("C:tempfindingsDB.xlsx")
       wb.Application.Visible = False
       For Each sh In wb.Sheets
           ListBox5.AddItem sh.Name
       Next
   End Sub
   
   ...

   I don’t know why your method does not work for me.
   Would my workaround have any drawbacks in comparsion with your method?

   ***Edit

   I just found out that my solution does not work …
   Every time i click on a different item in listbox5, the code will try to open the workbook thus resulting in a prompt on the screen that it can only be opened as write-protected.

   Last edited by illogic; Nov 6th, 2019 at 07:37 AM.

   ---

7. Nov 7th, 2019, 03:10 AM

   
   

   #7

   Re: [Word] [VBA] populate listbox in userform with excel database
   

   Every time i click on a different item in listbox5, the code will try to open the workbook thus resulting in a prompt on the screen that it can only be opened as write-protected.

   that should not happen as the code should only open the workbook once in the initialize event

   there is no other place that the workbook is opened in my code, and it is closed when the userform terminates, so reopening the userform should not be a problem, unless the userform is ended without closing

   Would my workaround have any drawbacks in comparsion with your method?

   the only drawback would be if the workbook is already open, the getobject method will (should) work whether the workbook is open or not

   i do my best to test code works before i post it, but sometimes am unable to do so for some reason, and usually say so if this is the case.
   Note code snippets posted are just that and do not include error handling that is required in real world applications, but avoid On Error Resume Next

   dim all variables as required as often i have done so elsewhere in my code but only posted the relevant part

   come back and mark your original post as resolved if your problem is fixed
   pete

   ---

8. Nov 8th, 2019, 03:23 AM

   
   

   #8

   

   Thread Starter

   
   New Member
   

   

   ---

   Re: [Word] [VBA] populate listbox in userform with excel database
   

   I made some additional changes and it seems to work now. I don’t get any Errors so far.
   But before i got it working i tried the following.

   Your original code was (of course with a modified path and filename):

   Code:

   Set wb = GetObject("C:tempfindingsDB.xlsx")

   Resulted in this Error:

   Filename or class name not found during Automation operation (Error 432)
   The GetObject function requires either a valid file name with a path specification, or the name of a class that is registered with the system. This error has the following cause and solution:
   The name specified for file name or class in a call to the GetObject function could not be found. Check the names and try again. Make sure the name used for the class parameter matches that registered with the system.

   Then i researched this error and found out that i should use ClassID, so i changed the line of code to this:

   Code:

   Set wb = GetObject("C:TempfindingsDB.xlsx", "Excel.Workbook")

   Which now resulted in a different error:

   ActiveX component can’t create object or return reference to this object (Error 429)
   Creating objects requires that the object’s class be registered in the system registry and that any associated dynamic-link libraries (DLL) be available.

   Source: https://docs.microsoft.com/de-de/off…ectedfrom=MSDN

   Then with further research i found this solution, which currently works.
   Don’t know if there is going to be any problems with that, at least not for now.

   Code:

   Option Explicit
   Dim wb As Object
   Dim xlApp As Object
   
   Public Sub UserForm_Initialize()
       Dim sh As Object
       On Error Resume Next
   'Get running Excel application
       Set xlApp = GetObject(, "Excel.Application")
       If Err.Number <> 0 Then
           Err.Clear
   'If no existing Excel app running, launch one
           Set xlApp = CreateObject("Excel.Application")
           If Err.Number <> 0 Then
               MsgBox "Cannot start Excel."
               Exit Sub
           End If
       End If
       xlApp.Visible = False
   'Open workbook
       Set wb = xlApp.Workbooks.Open("C:TempfindingsDB.xlsx")
       
       For Each sh In wb.Sheets
           ListBox5.AddItem sh.Name
       Next
   End Sub

   If i run into any errors in the near future, i will report back, otherwise i will mark this thread as «Solved».

   btw. Using ADO is alot more work to implement?
   I read somewhere that its faster and such, so should i stick with this current solution?
   The excel database is going to have 5 sheets and more with each sheet containing data which will increase over time.

   Anyways, thanks for helping me out so far. I appreciate it.

   ---

9. Nov 8th, 2019, 03:59 AM

   
   

   #9

   Re: [Word] [VBA] populate listbox in userform with excel database
   

   so should i stick with this current solution?

   yes, unless you want to filter the data on multiple criteria, or the data is going to be thousands of rows
   it maybe possible to set the rowsource for the listbox which would probably be faster than looping though the rows and additems, though as an alternative you could assign the excel data to an array then loop through the array, this would be faster than the current code, but probably would not be noticeable in less than a couple of thousand rows, you could do some speed tests if it took your interest, i can give some code to do that

   the above code would still run into issues if the workbook is already open

   btw. Using ADO is alot more work to implement?

   not really much more, but in the existing scope probably overkill, also it depends what you want to do with the data beyond the existing request, excel automation and ADO can be run side by side, note also that while VBA is mostly backwards compatible, some code that can run in one version of excel may fail in the next

   the code i posted was tested, worked correctly without error, using office 2013 on win 10, i would be reasonably confident it would also work in office 2000 on XP, but i have no idea on later versions, i would have expected it to work, but that maybe the issue you are having

   i do my best to test code works before i post it, but sometimes am unable to do so for some reason, and usually say so if this is the case.
   Note code snippets posted are just that and do not include error handling that is required in real world applications, but avoid On Error Resume Next

   dim all variables as required as often i have done so elsewhere in my code but only posted the relevant part

   come back and mark your original post as resolved if your problem is fixed
   pete

   ---

• 
• VBForums
• Visual Basic
• Office Development
• [Word] [VBA] populate listbox in userform with excel database

Posting Permissions