Vba excel скопировать столбец в другой столбец

asked Jan 2, 2010 at 4:38

The following works fine for me in Excel 2007.
It is simple, and performs a full copy (retains all formatting, etc.):

Sheets("Sheet1").Columns(1).Copy Destination:=Sheets("Sheet2").Columns(2)

«Columns» returns a Range object, and so this is utilizing the «Range.Copy» method. «Destination» is an option to this method — if not provided the default is to copy to the paste buffer. But when provided, it is an easy way to copy.

As when manually copying items in Excel, the size and geometry of the destination must support the range being copied.

answered Dec 18, 2012 at 1:19

If you have merged cells,

Sub OneCell()
    Sheets("Sheet2").range("B1:B3").value = Sheets("Sheet1").range("A1:A3").value
End Sub

that doesn’t copy cells as they are, where previous code does copy exactly as they look like (merged).

I’m not sure why you’d be getting subscript out of range unless your sheets weren’t actually called Sheet1 or Sheet2. When I rename my Sheet2 to Sheet_2, I get that same problem.

In addition, some of your code seems the wrong way about (you paste before selecting the second sheet). This code works fine for me.

Sub OneCell()
    Sheets("Sheet1").Select
    Range("A1:A3").Copy
    Sheets("Sheet2").Select
    Range("b1:b3").Select
    ActiveSheet.Paste
End Sub

If you don’t want to know about what the sheets are called, you can use integer indexes as follows:

Sub OneCell()
    Sheets(1).Select
    Range("A1:A3").Copy
    Sheets(2).Select
    Range("b1:b3").Select
    ActiveSheet.Paste
End Sub

answered Jan 2, 2010 at 4:46

asked Jan 13, 2015 at 8:54

Why not simply copy always the needed range?

Sub test()
Range("Z4:Z203").Select
Selection.Copy
Range("I5:I204").Select
ActiveSheet.Paste
End Sub

answered Jan 14, 2015 at 9:08

Working Environment: Excel 2013

Target: Copy C1:C9 to B11:B19. D1:D9 to B21:B29. E1:E9 to B31:B39…..

After copying all the range to column B, copy A1:A9 to A11:A19(A21:A29….)

My idea is that:
1. select a range by using something like

     range.end()

because in some of my sheets, there are only 4 test steps. so I need a syntax which can self inspect the used cells in a column.

1. do a range copy to column B.
2. leave 1 row in between considering about the page layout.

My piece of code is:

Worksheets("Master").Columns(3).UsedRange.Copy
Worksheets("Master").Range("B11").PasteSpecial

but seems like the Columns(i).UsedRange.Copy doesn’t work. the pastespecial works.

My question is：

How to select the used range in columns? The number of columns are not fixed which means some of the sheets have 40 columns, but some of the other have maybe 30.

Thanks!

I attached one screenshot of the sheet for your reference.

asked May 15, 2017 at 1:03

Assuming you do not have more data in the columns to be copied, this should work

Sub copyToOneColumn()
    Dim ws As Worksheet
    Set ws = ThisWorkbook.Sheets("Master")

    Dim startCol As Integer
    startCol = 3

    Dim endCol As Integer
    endCol = 10

    Dim startRange As Range
    Dim ra As Range


    For i = startCol To endCol
        Set startRange = ws.Range("A1").Offset(0, i - 1)
        Set ra = ws.Range(startRange, ws.Cells(Rows.Count, startRange.Column).End(xlUp))
        ra.Copy Destination:=ws.Range("B" & Rows.Count).End(xlUp).Offset(2, 0)
    Next i

End Sub

answered May 15, 2017 at 3:15

You can do a copy (not technically a copy as it doesn’t use the clipboard) directly like so:

Range("B1").Resize(Range("A1:A" & range("A" & Rows.Count).End(xlUp).Row).Rows.Count,1) = Range("A1:A" & range("A" & Rows.Count).End(xlUp).Row).Value

Effectively you are looking at B1 then resizing that to a range to be the number of columns in column A that are used with this: Range("A1:A" & range("A" & Rows.Count).End(xlUp).Row).Rows.Count

Then you are making this new range in column B = to the values of the same range in column A.

Note, this can be shortened if you are always starting at row 1 but the code I have given you will suffice if you start at a different row.

answered May 15, 2017 at 3:37

You may try something like this…

Sub CopyData()
Dim wsMaster As Worksheet
Dim lr As Long, lc As Long, r As Long, c As Long
Application.ScreenUpdating = False
Set wsMaster = Sheets("Master")
lr = wsMaster.Cells(Rows.Count, 1).End(xlUp).Row
lc = wsMaster.Cells(1, Columns.Count).End(xlToLeft).Column
r = lr + 2
If lr <= 9 Then
    For c = 3 To lc
        wsMaster.Range(wsMaster.Cells(1, c), wsMaster.Cells(lr, c)).Copy wsMaster.Range("B" & r)
        wsMaster.Range("A1:A" & lr).Copy wsMaster.Range("A" & r)
        r = wsMaster.Cells(Rows.Count, 2).End(xlUp).Row + 2
    Next c
End If
Application.ScreenUpdating = True
End Sub

answered May 15, 2017 at 4:40