Vba excel скопировать range

Вырезание, перемещение, копирование и вставка ячеек (диапазонов) в VBA Excel. Методы Cut, Copy и PasteSpecial объекта Range, метод Paste объекта Worksheet.

Метод Range.Cut

Range.Cut – это метод, который вырезает объект Range (диапазон ячеек) в буфер обмена или перемещает его в указанное место на рабочем листе.

Синтаксис

Параметры

Параметры	Описание
Destination	Необязательный параметр. Диапазон ячеек рабочего листа, в который будет вставлен (перемещен) вырезанный объект Range (достаточно указать верхнюю левую ячейку диапазона). Если этот параметр опущен, объект вырезается в буфер обмена.

Для вставки на рабочий лист диапазона ячеек, вырезанного в буфер обмена методом Range.Cut, следует использовать метод Worksheet.Paste.

Метод Range.Copy

Range.Copy – это метод, который копирует объект Range (диапазон ячеек) в буфер обмена или в указанное место на рабочем листе.

Синтаксис

Параметры

Параметры	Описание
Destination	Необязательный параметр. Диапазон ячеек рабочего листа, в который будет вставлен скопированный объект Range (достаточно указать верхнюю левую ячейку диапазона). Если этот параметр опущен, объект копируется в буфер обмена.

Метод Worksheet.Paste

Worksheet.Paste – это метод, который вставляет содержимое буфера обмена на рабочий лист.

Синтаксис

Worksheet.Paste (Destination, Link)

Метод Worksheet.Paste работает как с диапазонами ячеек, вырезанными в буфер обмена методом Range.Cut, так и скопированными в буфер обмена методом Range.Copy.

Параметры

Параметры	Описание
Destination	Необязательный параметр. Диапазон (ячейка), указывающий место вставки содержимого буфера обмена. Если этот параметр не указан, используется текущий выделенный объект.
Link	Необязательный параметр. Булево значение, которое указывает, устанавливать ли ссылку на источник вставленных данных: True – устанавливать, False – не устанавливать (значение по умолчанию).

В выражении с методом Worksheet.Paste можно указать только один из параметров: или Destination, или Link.

Для вставки из буфера обмена отдельных компонентов скопированных ячеек (значения, форматы, примечания и т.д.), а также для проведения транспонирования и вычислений, используйте метод Range.PasteSpecial (специальная вставка).

Примеры

Вырезание и вставка диапазона одной строкой (перемещение):

Range(«A1:C3»).Cut Range(«E1»)

Вырезание ячеек в буфер обмена и вставка методом ActiveSheet.Paste:

Range(«A1:C3»).Cut ActiveSheet.Paste Range(«E1»)

Копирование и вставка диапазона одной строкой:

Range(«A18:C20»).Copy Range(«E18»)

Копирование ячеек в буфер обмена и вставка методом ActiveSheet.Paste:

Range(«A18:C20»).Copy ActiveSheet.Paste Range(«E18»)

Копирование одной ячейки и вставка ее данных во все ячейки заданного диапазона:

Range(«A1»).Copy Range(«B1:D10»)

---

Home / VBA / VBA Copy Range to Another Sheet + Workbook

To copy a cell or a range of cells to another worksheet you need to use the VBA’s “Copy” method. In this method, you need to define the range or the cell using the range object that you wish to copy and then define another worksheet along with the range where you want to paste it.

Copy a Cell or Range to Another Worksheet

Range("A1").Copy Worksheets("Sheet2").Range("A1")

1. First, define the range or the cell that you want to copy.
   
2. Next, type a dot (.) and select the copy method from the list of properties and methods.
   
3. Here you’ll get an intellisense to define the destination of the cell copied.
   
4. From here, you need to define the worksheet and then the destination range.
   

Now when you run this code, it will copy cell A1 from the active sheet to the “Sheet2”. There’s one thing that you need to take care that when you copy a cell and paste it to a destination it also pastes the formatting there.

But if you simply want to copy the value from a cell and paste it into the different worksheets, consider the following code.

Worksheets("Sheet2").Range("A1") = Range("A1").Value

This method doesn’t use the copy method but simply adds value to the destination worksheet using an equal sign and using the value property with the source cell.

Copy Cell from a Different Worksheet

Now let’s say you want to copy a cell from a worksheet that is not active at the time. In this case, you need to define the worksheet with the source cell. Just like the following code.

Worksheets("sheet1").Range("A1").Copy Worksheets("Sheet2").Range("A1")

Copy a Range of Cells

Range("A1:A10").Copy Worksheets("Sheet2").Range("A1:A10")
Range("A1:A10").Copy Worksheets("Sheet2").Range("A1")

Copy a Cell to a Worksheet in Another Workbook

When workbooks are open but not saved yet.

Workbooks("Book1").Worksheets("Sheet1").Range("A1").Copy _
Workbooks("Book2").Worksheets("Sheet1").Range("A1")

When workbooks are open and saved.

Workbooks("Book1.xlsx").Worksheets("Sheet1").Range("A1").Copy _
Workbooks("Book2.xlsx").Worksheets("Sheet1").Range("A1")

Copy a Cell to a Worksheet in Another Workbook which is Closed

'to open the workbook that is saved in a folder on your system _
change the path according to the location you have in your _
system
Workbooks.Open "C:UsersDellDesktopmyFile.xlsx"

'copies cell from the book1 workbook and copy and paste _
it to the workbook myFile
Workbooks("Book1").Worksheets("Sheet1").Range("A1").Copy _
Workbooks("myFile").Worksheets("Sheet1").Range("A1")

'close the workbook and after saving
Workbooks("myFile").Close SaveChanges:=True

Related: How to Open a Workbook using VBA in Excel

More Tutorials

• Count Rows using VBA in Excel
• Excel VBA Font (Color, Size, Type, and Bold)
• Excel VBA Hide and Unhide a Column or a Row
• Excel VBA Range – Working with Range and Cells in VBA
• Apply Borders on a Cell using VBA in Excel
• Find Last Row, Column, and Cell using VBA in Excel
• Insert a Row using VBA in Excel
• Merge Cells in Excel using a VBA Code
• Select a Range/Cell using VBA in Excel
• SELECT ALL the Cells in a Worksheet using a VBA Code
• ActiveCell in VBA in Excel
• Special Cells Method in VBA in Excel
• UsedRange Property in VBA in Excel

• VBA AutoFit (Rows, Column, or the Entire Worksheet)
• VBA ClearContents (from a Cell, Range, or Entire Worksheet)
• VBA Enter Value in a Cell (Set, Get and Change)
• VBA Insert Column (Single and Multiple)
• VBA Named Range | (Static + from Selection + Dynamic)
• VBA Range Offset
• VBA Sort Range | (Descending, Multiple Columns, Sort Orientation
• VBA Wrap Text (Cell, Range, and Entire Worksheet)
• VBA Check IF a Cell is Empty + Multiple Cells

⇠ Back to What is VBA in Excel

Helpful Links – Developer Tab – Visual Basic Editor – Run a Macro – Personal Macro Workbook – Excel Macro Recorder – VBA Interview Questions – VBA Codes

This article covers everything you need to know about Excel VBA Copy methods.

By “Excel VBA Copy Methods”, I mean the different methods you can use to copy data from one range or worksheet to another.

In this article, I’m going to show you the fastest and most efficient way to copy and filter data no matter what your task is.

I say “Copy and Filter” because in most cases you will want to filter the data before you copy it. If you just want to copy data from one place to another then I cover that too.

The article is broken down as follows:

1. 1. Which Excel VBA Copy and Filter method is the fastest(section 6) – What the professionals know and how you can use it to your advantage.
   2. How to pick the best Excel VBA copy method for each task(section 7) – miss this and you’re wasting countless hours of your time.
   3. How to ensure your application runs at its optimal speed(section – It’s not hard to do once you know the secret.
   4. The Copy and Filter methods explained with full code examples(sections 9 and 10) – Learn these methods and watch your macros run like magic.

Useful Links

The following are some related articles with more information about certain topics:

Ranges and Cells
Arrays
Dictionary
For Loop
For Each Loop
The Workbook object
The Worksheet object

Glossary

Range.Value2 – returns the underlying value in the call. Value is similar but slower and may not return the correct value if there is currency or data formatting. See this article for more information.

ADO – stands for ActiveX Database Objects. It is a library that allows us to run queries on databases. We can also use it with Excel spreadsheets.

The Webinar

Members of the Webinar Archives can access the webinar for this article by clicking on the image below.

(Note: Website members have access to the full webinar archive.)

Download the Source Code and Data

In this article I will be using the following dataset:

Unless specified, most examples will use the 2 worksheets:

1. 1. 1. • Transactions – contains the above data.
         • Report – the data will be copied to this worksheet.

How to use this article

In the next section you can see how the different VBA Copy Methods compare in terms of speed. This is vital when you are determining which one to use.

You can use section 4 to help you determine which method you should use based on your requirements.

Section 5 shows you the basic ground work you should have in your application.

The rest of the article provides a description and code example of each method.

Which Excel VBA Copy Method is the Fastest?

In this section you will see how the different methods compare in terms of speed.

Using the fastest method is vital when dealing with large amounts of data. As you can see from the results, some of the methods are incredibly slow.

I have run speed tests on the different methods to see which methods are the fastest for different types of tasks.

I ran the tests on 20000 , 100000 and 200000 records. You can see the average results for each method in milliseconds in the tables below:

Copying Data By Rows

In this test, I filtered by rows that contain a given first name in the first column. About 1% of the records will match the criteria and will be copied. So for 20000 records, there will be 200 records copied.

You can see that using Autofilter and Advanced filter are the fastest methods for copying and filtering rows.

At the other end you can see that a For Loop with Range.Copy takes almost 215 times longer than using AutoFilter. I didn’t even run the 200,000 test for this as I expected it would take 15 minutes plus!

Copying Data By Individual Cells

In this tests we want to copy some of the cells but not the entire row. In most cases we need to copy the cells individually so this makes it more complicated than copying an entire row. This may seem counter intuitive at first that copying serveral cells requires more work than the copying the entire row.

Using the Advanced Filter is the clear winner here. Autofilter doesn’t have it’s own copy method so after filtering we have to copy the data using some other method.

Advanced Filter automatically copies the data and we can specify the columns we want to be copied. Advanced filter then takes care of the rest.

I have created two different methods of copying using AutoFilter for individual rows. The methods may be faster or slower depending on the number of columns:

1. 1. 1. • The Copy Columns method would be slower with more columns to copy.
         • The Delete Columns method would be slower with more columns to delete.

Copying Data and Summing Totals

In these tests we are summing data for a particular item. Summing means to get the total amount of a given column for a particular item. For example, getting the total volume for “Laptop Model A”.

There are 3 VBA copy methods that we can use to do this. These are:

1. 1. 1. 1. Pivot Tables
         2. For Loop with a Dictionary
         3. ADO(ActiveX Database Objects)

Using a Pivot Table is the fastest method for summing data. There is not much difference between the other two methods.

The downside of the Pivot Table is that the code may be slightly complex for a new user. ADO is very flexible but it does require knowledge of SQL(Structured Query Language).

Copying and Transposing Data

Both methods here are pretty fast. If you are doing a large volume of transpose copies then Application.Transpose tends to be quicker than PasteSpecial Transpose.

Which Excel VBA Copy Method Should I Use?

With so many different methods, you may be feeling overwhelmed. Don’t worry, in this section I will provide a complete guide to selecting the correct Excel VBA copy method to use.

Note that you can download the source code for this post from the start or end of this post. This is an invaluable with of practicing the method shown here.

Straight Copy with no Filter

To copy without any filter use the copy by assignment method like this:

shWrite.Range("F1:G4").Value2 = shRead.Range("A1:B4").Value2

Filter columns(AND Logic) and Copy Rows

Advanced Filter is the fastest and easiest method to use if you want to filter by column values using AND logic:

e.g Item is “Laptop Model A” And Volume is greater than 20

Filter columns(OR Logic) and Copy Rows

Advanced Filter is the fastest method to do an OR filter. It’s not possible to do this with AutoFilter.

e.g Item is “Laptop Model A” Or Volume > 20″

Filter and Copy Individual Columns

Sometimes you will not want to copy the entire row. Instead you may want to copy individual columns. Advanced Filter is fastest VBA Copy method for doing this.

e.g. return the columns Item, Volume and Sales where Item is “Laptop Model A” And Volume > 20″

Sum totals for individual items

If you want to get the total amount for each item then using a Pivot Table is faster than the other two methods. ADO(ActiveX Database Objects) is slightly faster than using the For Loop with the Dictionary.

Using a Pivot Table is very flexible. Once you create the table it pretty easy to display the data in many different ways. The downside is that the code may be a bit complex for a VBA beginner.

ADO is much more flexible but requires some knowledge of SQL(a database query language). It also requires using an external library which may be a bit advanced for a VBA beginner.

Using the For Loop and a Dictionary requires more code and is less flexible. But it is still pretty fast for up to 200,000 records and doesn’t require any SQL or external libraries.

Transpose

Transposing means to copy data so that the rows become columns and the columns become rows

There are two methods of transposing data:

1. Range.Copy and Transpose using PasteSpecial.
2. Assignment and Transpose using Application.Transpose.

There is not much difference between these in terms of speed. However, if your application is doing multiple transpose operations then Range.Copy tends to be much slower.

Before You Start Copying and Filtering

No matter which Excel VBA Copy method we use there are some tasks we must perform first.

These include getting the range of data, turning off certain Excel functionality etc.

We will look at these tasks in this section.

The first thing we will look at is the mistake that most VBA beginners make – using Select.

Never Use Select

When copying data in Excel VBA, don’t use Select – ever!

A big mistake that new VBA users make is thinking that they need to select the cell or range before they copy it.

For example

shRead.Activate
shRead.Range("A1").Select
shWrite.Activate
Selection.Copy ActiveSheet.Range("H1")

Keep these two important things in mind before you use VBA to copy data:

1. You don’t need to select the cell or range of cells.
2. You don’t need to select or activate the worksheet.

You will see Select used in many places online. But you don’t need to use it for copying cells – ever!

Speed Up Your Code

If you want your code to run fast then it is important to turn off certain VBA functionality at the start of our code. We then turn it back on, at the end of our code.

We can use the following subs to do this:

' Procedure : TurnOffFunctionality
' Source    : www.ExcelMacroMastery.com
' Author    : Paul Kelly
' Purpose   : Turn off automatic calculations, events and screen updating
' https://excelmacromastery.com/
Public Sub TurnOffFunctionality()
    Application.Calculation = xlCalculationManual
    Application.DisplayStatusBar = False
    Application.EnableEvents = False
    Application.ScreenUpdating = False
End Sub

' Procedure : TurnOnFunctionality
' Source    : www.ExcelMacroMastery.com
' Author    : Paul Kelly
' Purpose   : turn on automatic calculations, events and screen updating
' https://excelmacromastery.com/
Public Sub TurnOnFunctionality()
    Application.Calculation = xlCalculationAutomatic
    Application.DisplayStatusBar = True
    Application.EnableEvents = True
    Application.ScreenUpdating = True
End Sub

We can use them like this

Sub Main()

    ' Turn off at the start
    TurnOffFunctionality
    
    ' Your code here
    
    ' Turn back on at the end
    TurnOnFunctionality

End Sub

Sometimes when you run your code, it won’t reach the TurnOnFunctionality code.

This could because of an error or because you stop the code at a certain point and don’t restart.

If this happens you can turn everything on again by clicking in the TurnOnFunctionality sub and pressing F5.

Get the correct worksheet

When copying data, we need to specify the range which we will copy from. When using VBA we need to select the worksheet before we can select the range. There are many ways of selecting the worksheet which can be confusing.

I have broken it down into three scenarios:

1. The worksheet is in the same workbook as the code.
2. The worksheet is in a different workbook but we only want to read from it.
3. The worksheet is in a different workbook but we want to write to it.

You can see the code for each of these scenarios in the next subsections:

The worksheet is in the current workbook

The worksheet is in the current workbook so we can use either:

1. The code name of the worksheet.
2. The worksheet name: ThisWorkbook.Worksheets(“worksheet name”).

In the screenshot below we have changed the codename and worksheet name:

We would use the following code to reference the sheet

' https://excelmacromastery.com/
Sub WorksheetCodeName()

    Dim shRead As Worksheet
    
    ' Use the code name
    Set shRead = CodeName
    
    ' OR
    
    ' Use the worksheet name
    Set shRead = ThisWorkbook.Worksheets("SheetName")
    
End Sub

The worksheet is in a different workbook – reading only

If the worksheet is in a different workbook than the code, then we need to open the workbook. In this case we will only be reading from the worksheet so we can simply make it read-only.

Then it doesn’t matter if it’s already open. Making it read-only also prevents us from accidentally changing the data in the workbook.

' WorksheetRead()
'
' HOW TO RUN:
' 1. Place this code in a new workbook and save it as a .xlsm file.
' 2. Create a workbook called Writedata.xlsx and place it in the same
'    folder as the workbook you just created.
' 3. Place any value in cell A1 on sheet1 from Writedata.xlsx.
' 4. Run the code(Press F5).
'
' RESULT: The value in cell A1 on sheet1 from Writedata.xlsx
'         will be displayed in a message box.
' https://excelmacromastery.com/
Sub WorksheetRead()

    ' Get the full filename and path of "WriteData.xlsx"
    Dim sFilename As String
    sFilename = _
         ThisWorkbook.Path & Application.PathSeparator & "WriteData.xlsx"

    ' Open workbook as read-only and store in variable wk
    Dim wk As Workbook
    Set wk = Workbooks.Open(sFilename, ReadOnly:=True)

    ' Store the worksheet Sheet1 in the variable shRead
    Dim shRead As Worksheet
    Set shRead = wk.Worksheets("Sheet1")
    
    ' Print the value from the worksheet cell A1
    If IsEmpty(shRead.Range("A1").Value2) Then
        MsgBox "No value was found in cell Sheet1:A1 of WriteData.xlsx."
    Else
        MsgBox "The value found in Sheet1:A1 is of WriteData.xlsx is: " _
            & shRead.Range("A1").Value2
    End If
    
    wk.Close SaveChanges:=False
End Sub

The worksheet is in a different workbook – reading and writing

Just like the last example, the worksheet is in a different workbook than the code. In this case we want to write to the worksheet in the workbook.

We first check if the workbook is already open, and if so we display a message informing the user to close it before running the code again:

' WorksheetWrite()
'
' HOW TO RUN:
' 1. Place this code in a new workbook and save it as a .xlsm file.
' 2. Create a workbook called Writedata.xlsx and place it in the same
'    folder as the workbook you just created.
' 3. Click in the WorksheetWrite sub and press F5 to run the code.
' 4. Open the Writedata.xlsx and check if the value was correctly
'    written to cell A1 in sheet1.
'
' RESULT: If the file is already open then and error message will be
'         displayed to the user asking them to close the file.
'         If the file is not already open then the value 99 will be
'         written to cell A1 on sheet1 of Writedata.xlsx.
' https://excelmacromastery.com/
Sub WorksheetWrite()

    Dim sFilename As String
    sFilename = _
         ThisWorkbook.Path & Application.PathSeparator & "WriteData.xlsx"

    ' Ensure that the workbook is not already open
    If IsWorkBookOpen("WriteData.xlsx") Then
        MsgBox "Please close workbook " & sFilename & " and try again."
        Exit Sub
    End If

    ' Open workbook and store in variable wk
    Dim wk As Workbook
    Set wk = Workbooks.Open(sFilename, ReadOnly:=False)

    ' Store the worksheet Sheet1 in the variable shRead
    Dim shRead As Worksheet
    Set shRead = wk.Worksheets("Sheet1")
    
    ' Write a value to the worksheet cell A1
    shRead.Range("A1").Value2 = Now

    ' Close the file when finished with it
    wk.Close saveChanges:=True
    
End Sub

' Helper function to check if workbook is already open
Function IsWorkBookOpen(strBookName As String) As Boolean
    
    Dim oBk As Workbook
    
    On Error Resume Next
    Set oBk = Workbooks(strBookName)
    On Error GoTo 0
    
    If Not oBk Is Nothing Then
        IsWorkBookOpen = True
    End If
    
End Function

Now that we can get any worksheet we require, we can focus on how to copy the data.

Get the Data Range

In many online Excel VBA Copy examples, you will see a fixed range like Range(“A1:D6”).

When dealing with real-world applications it is rare that the data will be of a fixed size.

For example, imagine you stored student marks for each class in a worksheet. Obviously, each class will have a different number of students. Each time you read a worksheet you cannot be sure in advance what the range will be.

Your code should be able to figure out the full range of data, even if the size changes each time it runs.

There are two types of data:

1. Rectangular data where the data is in a list of rows with no blank rows or columns.
2. Fragmented data where the data may contain blank rows or columns.

Using CurrentRegion

The CurrentRegion property of Range is very useful for returning the entire range of data. CurrentRegion returns all the adjacent data from a given range.

You can see the CurrentRegion in Excel by selecting a cell and pressing Ctrl + Shift + *.

In the screenshot below you can see two groups of adjacent data. By selecting any cell with data and pressing Ctrl + Shift + *, Excel will select all the data in that group. This is the current region.

We can also use the CurrentRegion in VBA:

The Current region will work as long as there are no blank rows or columns between the data.

' CurrentRegion()
'
' HOW TO RUN:
' 1. Create a worksheet called "CurrentRegion".
' 2. Add data to all cells in the range B3:D14.
' 3. Run this sub(F5).
'
' RESULT: The current region for B3, C9 and D14 will
'         be displayed in the Immediate Window(Ctrl + G).
' https://excelmacromastery.com/
Sub CurrentRegion()

     ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("CurrentRegion")
    
    Dim rg1 As Range, rg2 As Range, rg3 As Range
    
    ' Get the current region
    ' All the below examples with return B3:D14
    Set rg1 = shRead.Range("B3").CurrentRegion
    Set rg2 = shRead.Range("C9").CurrentRegion
    Set rg3 = shRead.Range("D14").CurrentRegion
    
    ' Display the addresses to the Immediate Window(Ctrl + G)
    Debug.Print "B3 CurrentRegion is: " & rg1.Address
    Debug.Print "C9 CurrentRegion is: " & rg2.Address
    Debug.Print "D14 CurrentRegion is: " & rg3.Address

End Sub

Using End with xlUp and xlToLeft

If there are blank rows and/or blank columns then CurrentRegion will not return all the data.

For example, in the data shown here there are blank rows and a blank column:

We need to get the last row with data and/or the last column with data. We can then use these cells to build our Range.

' UseLastRowCol()
'
' HOW TO RUN:
' 1. Create a worksheet called "Fragmented".
' 2. Add any data to the cells A1:E13 but make sure you
'    have the same blank cells as in the above screenshot.
' 3. Run this sub(F5)
'
' RESULT: The range A1:E13 will be displayed in the
'         Immediate Window(Ctrl + G).
' https://excelmacromastery.com/
Sub UseLastRowCol()

     ' Get the worksheet
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Fragmented")
    
    Dim lastRow As Long, lastCol As Long
        
    ' Get the last cell with data in column A
    lastRow = shRead.Cells(shRead.Rows.count, 1).End(xlUp).row
    
    ' Get the last cell with data in row 1
    lastCol = shRead.Cells(1, shRead.Columns.count).End(xlToLeft).column
    
    Dim rg As Range
    With shRead
        ' Get the full range of data from A1 to last row and column
        Set rg = .Range(.Cells(1, 1), .Cells(lastRow, lastCol))
    End With
    
    ' Print the rg address(i.e. A1:E13) to the Immediate Window(Ctrl + G)
    Debug.Print "The range of data is: " & rg.Address

End Sub

Excel VBA Copy Methods

In this section we are going to look at the copying methods.

There are three ways of copying data in VBA:

1. The Range.Copy function
2. The assignment operator(i.e. equals sign)
3. The Range.CopyFromRecordset function(ADO only)

In the following sub sections we will look at these in turn. We will be using these Excel VBA copy methods with the different filter methods.

Range.Copy

We can use the Copy method of the Range to copy data.

' https://excelmacromastery.com/
Sub SimpleCopy()

     ' Get the worksheet
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    ' Copy the data from A1:D1 to H1:K1
    shRead.Range("A1:D1").Copy Destination:=shRead.Range("H1")
    
    ' Using Destination is optional
    shRead.Range("A1:D1").Copy shRead.Range("H1")

End Sub

We can copy between worksheets using this Excel VBA method. The only thing that will change in the code is the worksheets that we use.

' UsingRangeCopy()
'
' HOW TO RUN:
' 1. Create a workbook called Data.xlsx and place it in the same
'    folder as the workbook with the code.
' 2. Rename sheet1 to "CustomerData".
' 3. Add data to the range A1:D19.
' 4. Save the file.
' 5. Have a worksheet called "Report" in the current workbook
' 6. Click in this sub and press F5 to run
'
' RESULT: The data in the range A1:D19 from the CustomerData
'          worksheet in Data.xlsx will have been copied to
'         the Report worksheet in the current workbook.
' https://excelmacromastery.com/
Sub UsingRangeCopy()

    Dim sFilename As String
    sFilename = _
            ThisWorkbook.Path & Application.PathSeparator & "Data.xlsx"

    ' Open a workbook called Data.xlsx from the current folder
    Dim wk As Workbook
    Set wk = Workbooks.Open(sFilename, ReadOnly:=True)
    
    ' shRead stores the worksheet CustomerData
    ' shWrite store the Report sheet
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = wk.Worksheets("CustomerData")
    Set shWrite = ThisWorkbook.Worksheets("Report")

    ' Clear the data from the report worksheet
    shWrite.Cells.Clear

    ' Copy from CustomerData to Report
    shRead.Range("A1:D19").Copy shWrite.Range("A1")
    
    ' Activate the report worksheet
    shWrite.Activate
    
    ' Close the "Data.xlsx" workbook
    wk.Close

End Sub

This Range.Copy method copies everything. In other words it will copy values, formulas, formats etc.

If we only want to copy the data we can use the PasteSpecial property of Range.

Using PasteSpecial

We can use PasteSpecial with Range.Copy to paste the values only

' https://excelmacromastery.com/
Sub UsingPasteSpecial()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    ' Clear any existing data from report
    shWrite.Cells.Clear
    
    ' This will copy the values only
    shRead.Range("A1:E13").Copy
    shWrite.Range("A1").PasteSpecial xlPasteValues
    
End Sub

You can also copy formats, formulas and comments using PasteSpecial. You can read more about it here.

Range.Copy and Transpose

Transposing data means that the rows become columns and the columns become rows:

We can use the Range.PasteSpecial function to transpose data:

' https://excelmacromastery.com/
Sub RangeCopy_Transpose()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transpose")
    
    ' Clear any existing data
    shRead.Range("F1:I2").Clear
    
    ' This will copy from A1:B4 to F1:I2
    shRead.Range("A1:B4").Copy
    shRead.Range("F1").PasteSpecial Transpose:=True
    
End Sub

Copying by Assignment

We can assign values using the equals sign in VBA.

We can copy values from one range to another using assignment.

The value to the right of the equals is placed in cell to the left of the equals as you can see in these examples:

' https://excelmacromastery.com/
Sub AssignExamples()"
    
    ' Copy a value to a cell
    Range("A1").Value2 = 56
    Range("A2").Value2 = "Mary"
    
    ' Copy cell to cell
    Range("G1").Value2 = Range("F1").Value2
    Range("G2").Value2 = Range("F2").Value2
    
    ' Copy multiple cells - the source and destination range
    ' must be the same size
    Range("A1:C5").Value2 = Range("D1:F5").Value2
    
End Sub

The code below shows an example of copying the data from the data shown in the screenshot at the start of this section.

We will copy the range A1:D11 on the worksheet Transactions to the range A1:D11 on worksheet Report.

' UsingAssignment()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' RESULT: The data will be copied from the Transaction worksheet
'         to the report worksheet
' https://excelmacromastery.com/
Sub UsingAssignment()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "dd/mm/yyyy"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        .Columns(4).NumberFormat = "0"
        .Columns(5).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Copy the data
    shWrite.Range("A1:D11").Value2 = shRead.Range("A1:D11").Value2

End Sub

The key thing to remember about assigning values is that the destination must be the same size as the source.

If it is smaller than the source range then not all the data will be written.

If it is bigger than the source then there will be #N/A errors in the extra cells.

Assignment with Transpose

We can use the WorksheetFunction.Transpose function to transpose using the assignment operator(i.e. equals sign) to copy:

' https://excelmacromastery.com/
Sub TransposeAssign()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transpose")
    
    ' Clear any existing data
    shRead.Range("F1:I2").Clear
    
    shRead.Range("F1:I2").Value2 = _
            WorksheetFunction.Transpose(shRead.Range("A1:B4").Value2)

End Sub

Using Range.CopyFromRecordset

A Recordset is the collection of data we get when we run a database query.

We can run database queries on worksheet data using ADO (ActiveX Data Objects).

We will look at this Excel VBA Copy method in more detail in the ADO section below.

Excel VBA Filter Methods

Whenever you are copying data in VBA you will almost always apply some type of filter. This could be selection rows based on certain criteria or it could be summing data.

In this section, we are going to look at the various ways of filtering data. If you want working examples using the Filter methods then you can download the source code at the top or bottom of this post.

Filtering using For and If

The most common way of filtering data in VBA is using a For Loop and If Statement.

This is the least flexible and most long-winded method of filtering data in VBA. By long-winded, I mean that it requires lots of code compared to the other methods.

Using For and IF is the method you will see used the most in examples or in legacy VBA code.

We use the For Loop to read through data one row at a time. For each row, we will use the If Statement to check for certain criteria.

Here is a simple outline:

' https://excelmacromastery.com/
Sub ForIf_Basic()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    Dim i As Long
    For i = 1 To 13
        If shRead.Range("A" & i).Value2 = "Laptop Model A" Then
            ' Code for copying here
        End If
    Next i
    
End Sub

We can use both And and Or operators in the if statement.

Here are some examples:

If Item = "Laptop Model A" And Volume > 20 Then

If Item = "Laptop Model A" Or Volume > 20 Then

If Item = "Laptop Model A" Or Item = "Laptop Model B" Then

How to Copy Rows

The following code reads through the data. It checks each line to see if the first cell contains “Laptop Model A” .

If the row with these criteria is found, the row will be copied to the output worksheet.

The first version of the code below will use Range.Copy and the second will use the assign copy method:

' For_RangeCopy()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' https://excelmacromastery.com/
Sub For_RangeCopy()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    Dim shWrite As Worksheet
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    With shWrite

        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "dd/mm/yyyy"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        .Columns(4).NumberFormat = "0"
        .Columns(5).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Read through the data
    Dim i As Long, row As Long
    row = 1
    For i = 1 To rg.Rows.count
        
        If rg.Cells(i, 1).Value2 = "Laptop Model A" Or i = 1 Then
            
            ' Copy using Range.Copy
            rg.Rows(i).Copy
            shWrite.Range("A" & row).PasteSpecial xlPasteValues
            
            ' move to the next output row
            row = row + 1
            
        End If
        
    Next i
    
End Sub

' For_Assign()
'
' Requirements:
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' https://excelmacromastery.com/
Sub For_Assign()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    Dim shWrite As Worksheet
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    With shWrite

        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "dd/mm/yyyy"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        .Columns(4).NumberFormat = "0"
        .Columns(5).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Read through the data
    Dim i As Long, row As Long
    row = 1
    For i = 1 To rg.Rows.count
        
        If rg.Cells(i, 1).Value2 = "Laptop Model A" Or i = 1 Then
           
            ' Get the destination range
            Dim rgDest As Range
            Set rgDest = _
                shWrite.Range("A" & row).Resize(1, rg.Columns.count)
            
            ' Copy using Assignment
            rgDest.Value2 = rg.Rows(i).Value2
            
            ' move to the next output row
            row = row + 1
            
        End If
        
    Next i
    
End Sub

In the above code, we use Range.Resize when copying by assignment. You can read more about this here.

Using an Array to Read Faster

If you are reading through a lot of data then reading directly from the worksheet range is very slow.

It is much quicker to copy the data to an array and then read through that array. Then when we are finished, we write the array back to the worksheet

We cannot use Range.Copy because it obviously can only be used on an actual range.

Let’s update our last example so it will use an array:

' https://excelmacromastery.com/
Sub ForUsingArray_Assign()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    Dim shWrite As Worksheet
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    ' Copy the range to an array
    Dim arr As Variant
    arr = shRead.Range("A1").CurrentRegion.Value2
    
    With shWrite
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "dd/mm/yyyy"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        .Columns(4).NumberFormat = "0"
        .Columns(5).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Read through the data
    Dim i As Long, j As Long
    Dim row As Long, Columns As Long
    row = 1
    For i = LBound(arr) To UBound(arr)
        
        ' If "Laptop Model A" or header row then copy
        If arr(i, 1) = "Laptop Model A" Or i = 1 Then
            
            ' Copy each column
            For j = LBound(arr, 2) To UBound(arr, 2)
                shWrite.Cells(row, j).Value2 = arr(i, j)
            Next j
            
            ' move to the next output row
            row = row + 1
            
        End If
        
    Next i
    
End Sub

We could also use the Worksheet Function Index to copy. However, it is incredibly slow. In the speed tests it was over 4000 times slower than using the AutoFilter.

' Copy using Index
Columns = UBound(arr, 2)
shRepAssign.Range("A" & row).Resize(1, Columns).Value2 = _
        Application.WorksheetFunction.Index(arr, i, 0)

Copying Individual Fields

Copying individual items in a row is actually very straightforward.

We simply copy each cell individually:

' For_Assign_Individual()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' https://excelmacromastery.com
Sub For_Assign_Individual()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    Dim shWrite As Worksheet
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    With shWrite
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Read through the data
    Dim i As Long, rgWrite As Range, row As Long
    row = 1
    For i = 1 To rg.Rows.count
    
        ' If "Laptop Model A" or the header row
        If rg.Cells(i, 1).Value2 = "Laptop Model A" Or i = 1 Then
    
            ' Copy from column A to column A
            shWrite.Cells(row, 1).Value2 = rg.Cells(i, 1).Value2
            
            ' Copy from column E to column B
            shWrite.Cells(row, 2).Value2 = rg.Cells(i, 5).Value2
            
            ' Move to the next row for writing
            row = row + 1
        
        End If
        
    Next i

End Sub

The method below using Range.Copy – it is very slow so it is best to avoid using it.

' WARNING: DON'T USED THIS METHOD - IT IS INCREDIBLY SLOW
' https://excelmacromastery.com/
Sub For_RangeCopy_Individual()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    Dim shWrite As Worksheet
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    ' Read through the data
    Dim i As Long, rgWrite As Range, row As Long
    row = 1
    For i = 1 To rg.Rows.count
    
        ' If "Laptop Model A" or the header row
        If rg.Cells(i, 1).Value2 = "Laptop Model A" Or i = 1 Then
    
            ' Copy using Range.Copy
            rg.Cells(i, 1).Copy
            shWrite.Range("A" & row).PasteSpecial xlPasteValues
            
            rg.Cells(i, 5).Copy
            shWrite.Range("B" & row).PasteSpecial xlPasteValues
            
            ' Move to the next row for writing
            row = row + 1
        
        End If
        
    Next i

In this example we use an array with the For loop to copy. It is the fastest way to copy individual columns using the For loop but it is still way slower than using the AutoFilter.

' ForUsingArray_Assign_Individual()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' https://excelmacromastery.com/
Sub ForUsingArray_Assign_Individual()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    Dim shWrite As Worksheet
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Get the range
    Dim arr As Variant
    arr = shRead.Range("A1").CurrentRegion.Value2
    
    ' Read through the data
    Dim i As Long, rgWrite As Range, row As Long
    row = 1
    For i = LBound(arr) To UBound(arr)
    
        ' If "Laptop Model A" or the header row
        If arr(i, 1) = "Laptop Model A" Or i = 1 Then
    
            ' Copy from column A to column A on the report worksheet
            shWrite.Cells(row, 1).Value2 = arr(i, 1)
            
            ' Copy from column E to column B on the report worksheet
            shWrite.Cells(row, 2).Value2 = arr(i, 5)
            
            ' Move to the next row for writing
            row = row + 1
        
        End If
        
    Next i

End Sub

If the original data has a lot of columns and you only require a few of them, then this method may be as fast as AutoFilter but you will need to test both methods.

Summing Totals

In the data shown below we want to get the total sales for each item:

Our result should look like this:

Summing data like this is much trickier than simply filtering data.

For each item, we need to store a running total somewhere. Each time we read an item we need to either create a new entry or add the current sales amount to the existing entry.

The easiest way to do this is to use a Dictionary.

You can see the code to do this below. You will notice that it is split into two parts:

• In part one we read the values from the worksheet to the dictionary.
• In part two we write the values from the dictionary to the worksheet.

' ForDictionary_Assign_Sum()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' IMPORTANT: Add the Dictionary reference to use the dictionary
'            Tools->Reference and check "Microsoft Scripting Runtime"
' https://excelmacromastery.com/
Sub ForDictionary_Assign_Sum()

    ' PART 1 - Read the data
    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    ' Create the dictionary
    Dim dict As New Dictionary
    
    ' Read through the data
    Dim i As Long, Item As String, Sales As Long
    For i = 2 To rg.Rows.count
        ' Store the values in a variable
        Item = rg.Cells(i, 1).Value2
        Sales = rg.Cells(i, 5).Value2
        
        ' The item will be automatically added if it doesn't exist
        dict(Item) = dict(Item) + Sales
    Next i
    
    ' PART 2 - Write the data
    Dim shWrite As Worksheet
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "$#,##0;[Red]$#,##0"
        
        ' Write header
        .Cells(1, 1).Value2 = "Item"
        .Cells(1, 2).Value2 = "Sales"
        
    End With
    
    Dim key As Variant, row As Long
    row = 2
    ' Read through each item in the Dictionary
    For Each key In dict.Keys
    
        shWrite.Cells(row, 1) = key
        shWrite.Cells(row, 2) = dict(key)
        
        row = row + 1
    Next key
    
End Sub

Summing Multiple Totals

In the previous example we were summing one item. This time we are going to sum the volume and the price fields.

The Dictionary stores a key and a value. If we want to store more than one value then we use a class module.

In the next example, I have split up the code into procedures to make it easier to read and to be more flexible:

' Class Module: clsSales
Public Items As String
Public Volume As Long
Public Sales As Long

' https://excelmacromastery.com/
Sub CreateReport()

    ' Declare a Dictionary variable
    Dim dict As Dictionary

    ' Read the data to the Dictionary
    Set dict = ReadData
    
    ' Write the Data from the Dictionary to the Worksheet
    WriteData dict

End Sub

' Read the data from the worksheet into a Dictionary
'
' IMPORTANT: Add the Dictionary reference to use the dictionary
' Tools->Reference and check "Microsoft Scripting Runtime"
' https://excelmacromastery.com/
Private Function ReadData() As Dictionary
    
    ' Create the dictionary
    Dim dict As New Dictionary
    
    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    ' Read through the data
    Dim i As Long, Item As String, Volume As Long, Sales As Long
    Dim oSales As clsSales, oSalesCurrent As clsSales
    For i = 2 To rg.Rows.count

        Item = rg.Cells(i, 1).Value2
        Volume = rg.Cells(i, 4).Value2
        Sales = rg.Cells(i, 5).Value2
        
        ' Check if the Item has already been added
        If dict.Exists(Item) = False Then
            ' Add Item and new class module object
            Set oSales = New clsSales
            dict.Add Item, oSales
        End If
        
        ' Get the current item
        Set oSalesCurrent = dict(Item)
        
        ' Update the data
        With oSalesCurrent
            .Volume = .Volume + Volume
            .Sales = .Sales + Sales
        End With
        
    Next i
    
    Set ReadData = dict
    
End Function

' Write the summed data to the worksheet
' https://excelmacromastery.com/
Sub WriteData(dict As Dictionary)

    Dim shWrite As Worksheet
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "0"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        
        ' Write header
        .Cells(1, 1).Value2 = "Item"
        .Cells(1, 2).Value2 = "Volume"
        .Cells(1, 3).Value2 = "Sales"
        
    End With
    
    Dim key As Variant, oData As clsSales, row As Long
    row = 2
    
    ' Read through each item in the Dictionary
    For Each key In dict.Keys
    
        Set oData = dict(key)
        
        shWrite.Cells(row, 1) = key
        shWrite.Cells(row, 2) = oData.Volume
        shWrite.Cells(row, 3) = oData.Sales
        
        row = row + 1
        
    Next key
    
End Sub

Using AutoFilter

The methods that we have looked at so far require a lot of code.

There is actually a much simpler way of reading and filtering data. We can use the AutoFilter. This is the filter we use in Excel to filter data. Once the data is filtered we can easily copy and paste it.

In terms of speed, AutoFilter came out on top in the speed tests that I performed. It is the best one to use for selecting or copying either rows or individual columns.

These are some examples of using AutoFilter in VBA:

' Field 1 = "Ipsum Corporation" and field 3 >=50
rg.AutoFilter Field:=1, Criteria1:="Ipsum Corporation" _ 
       , Operator:=xlAnd, Field:=3, Criteria1:=">=50"

' Field 1 starts with "I"
rg.AutoFilter Field:=1, Criteria1:="I*"

' Field 1 ends with "Ltd"
rg.AutoFilter Field:=1, Criteria1:="*Ltd"

' Field 1 contains "Su"
rg.AutoFilter Field:=1, Criteria1:="*Su*"

' Field 1 does not contain "Su"
rg.AutoFilter Field:=1, Criteria1:="<>*Su*"

' Get the top 10 items based on the value in Field 3
rg.AutoFilter Field:=3, Criteria1:="10", Operator:=xlTop10Items

' Field 3 is in the value list of 100,17 and 2
rg.AutoFilter Field:=3, Criteria1:=Array("100", "17", "2") _
     , Operator:=xlFilterValues

Now that we understand the basics, let’s look at some practical examples of using AutoFilter.

How to Copy Rows

Using AutoFilter is the fastest way to copy filtered rows of data.

Let’s use AutoFilter to copy all the rows that contain “Laptop Model A”.

The following code shows how to do this:

' AutoFilter_RangeCopy_Row()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' https://excelmacromastery.com/
Sub AutoFilter_RangeCopy_Row()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "dd/mm/yyyy"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        .Columns(4).NumberFormat = "0"
        .Columns(5).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    ' Remove any existing filters
    rg.AutoFilter
    
    ' Apply the Autofilter
    rg.AutoFilter Field:=1, Criteria1:="Laptop Model A"
    
    ' Copy the data using Range Copy
    shRead.Range("A1").CurrentRegion.SpecialCells(xlCellTypeVisible).Copy
    shWrite.Range("A1").PasteSpecial xlPasteValues
    
    ' Remove any existing filters
    rg.AutoFilter
    
    ' Active the output sheet so it is visible
    shWrite.Activate

End Sub

We can also use assign to copy the data. It is almost as fast but requires slightly more complex code.

It is actually not necessary to use this code but I am including it for completeness:

' AutoFilter_Assign_Row()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' https://excelmacromastery.com/
Sub AutoFilter_Assign_Row()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "dd/mm/yyyy"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        .Columns(4).NumberFormat = "0"
        .Columns(5).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
        
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    ' Remove any existing filters
    rg.AutoFilter
    
    ' Apply the Autofilter
    rg.AutoFilter Field:=1, Criteria1:="Laptop Model A"
     
    ' Get the read range
    Dim rgRead As Range
    Set rgRead = _
        shRead.Range("A1").CurrentRegion.SpecialCells(xlCellTypeVisible)

    Dim rgRow As Range, row As Long
    row = 1
    ' Read through each row
    For Each rgRow In rgRead.Rows
        
        ' Copy the row
        shWrite.Cells(row, 1).Resize(1, rgRead.Columns.count).Value2 _
                   = rgRow.Value2
        
        ' move to the next output row
        row = row + 1
        
    Next rgRow
    
    ' Remove any existing filters
    rg.AutoFilter

End Sub

Using AutoFilter code is much easier to write because we don’t need a For Loop and an If Statement. We can filter the data in just one line.

Copying Individual Fields

Copy individual cells is more long winded than copying the row.

It may seem counter intuitive at first but we have to specify the cells we are copying. With a row, we can just copy the entire thing.

There are 2 main ways we can do this:

1. Copy the individual columns from the filtered data.
2. Copy filtered data and delete the columns that are not required.

Copy the Columns

The first method is the most basic way to do this. We simple copy each column that we require

' AutoFilter_CopyColumns()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' Details: Use AutoFilter with Range.Copy to filter and copy individual
'          column data.
'          The resulting data should contain the columns Items and Sales.
' https://excelmacromastery.com/
Sub AutoFilter_CopyColumns()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    ' Remove any existing filters
    rg.AutoFilter
    
    ' Apply the Autofilter
    rg.AutoFilter Field:=1, Criteria1:="Laptop Model A"
    
    Dim arr As Variant
    arr = Array(1, 5)
    
    ' Remove unnecessary columns
    Dim i As Long, column As Long
    column = 1
    For i = LBound(arr) To UBound(arr)
        rg.Cells(1, arr(i)).EntireColumn.Copy
        shWrite.Cells(1, column).PasteSpecial xlPasteValues
        column = column + 1
    Next i
    
    ' Remove any existing filters
    rg.AutoFilter
    
End Sub

Copy and Delete Unwanted Columns

The second method is the fastest for data with a reasonable number of columns. We simply copy all the data and delete the columns we don’t need:

' AutoFilter_DeleteColumns()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' Details: Use AutoFilter with Range.Copy to filter and copy individual
'          column data.
'          Copy the entire data and then delete the unnecessary columns.
'          The result should be Item and Sales columns only.
' https://excelmacromastery.com/
Sub AutoFilter_DeleteColumns()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    ' Remove any existing filters
    rg.AutoFilter
    
    ' Apply the Autofilter
    rg.AutoFilter Field:=1, Criteria1:="Laptop Model A"

    ' Copy the filtered data to the output worksheet
    rg.SpecialCells(xlCellTypeVisible).Copy
    shWrite.Range("A1").PasteSpecial xlPasteValues
    
    ' Remove unnecessary columns
    Dim rgOut As Range, i As Long
    Set rgOut = shWrite.Range("A1").CurrentRegion
    For i = rgOut.Columns.count To 1 Step -1
        Select Case i
            Case 1, 5
            Case Else
                rgOut.Columns(i).EntireColumn.Delete
        End Select
    Next i
    
    ' Remove any existing filters
    rg.AutoFilter
    
End Sub

Summing Totals

We cannot use the Filters to sum data. We need to use either a For Loop with a Dictionary or ADO.

Using Advanced Filter

See the main article on Advanced Filter here

Advanced Filter has 4 major advantages over AutoFilter:

1. It has more advanced filtering.
2. It can automatically copy the results to another range.
3. When copying the results it automatically copies the format.
4. You can select specific columns and the order of columns.

The AutoFilter has a drawback when filtering data. We cannot use the logic:

If Value1 is in Column1 OR Value2 is in Column2

For example, we cannot say we want all the records where the Item is “Laptop Model A” or Volume > 6.

We can use the AdvancedFilter to get around this. AdvancedFilter is very similar to AutoFilter. The major difference is that the criteria must be a range on the worksheet.

The screenshot below shows how to use AND. It means item is “Laptop Model A” and Volume > 16. The Criteria Range for this must be G1:K2.

The result of using these criteria is:

The screenshot below shows how to use OR. It means item is “Laptop Model A” OR Volume > 16. The Criteria Range for this must be G1:K3.

The result of using these criteria is

The code below shows how we create an advanced filter for the above and criteria.

Range("A1:D12").AdvancedFilter Action:=xlFilterInPlace _
     , CriteriaRange:=Range("G1:K2")

For OR it would be

Range("A1:D12").AdvancedFilter Action:=xlFilterInPlace _
     , CriteriaRange:=Range("G1:K3")

Important: You will notice here that the Criteria range is different for the two examples. Make sure that you don’t have a blank line in the criteria (e.g. G1:K4 instead of G1:K3). This will result in all records being returned i.e. no filter being applied.

How to Copy Rows

Advanced filter will not only automatically copy the results for us. It is also the fastest VBA method for copying and filter in most scenarios.

We simple set the Action parameter to xlFilterCopy and set the CopyToRange parameter to the output range:

' ----------------------------------------------------------------
' Procedure Name: AdvancedFilterExample
' Purpose: An example of using the Advanced Filter to copy rows
'
' Result: The result depends on the values set in the criteria range
'         G to K columns on the "Transaction Filter" worksheet.
' Website: https://excelmacromastery.com/
' ----------------------------------------------------------------
' https://excelmacromastery.com/
Sub AdvancedFilterExample()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions Filter")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    ' Clear any existing data
    shWrite.Cells.Clear

    ' Remove the any existing filters
    If shRead.FilterMode = True Then
        shRead.ShowAllData
    End If
    
    ' Get the source data range
    Dim rgData As Range, rgCriteria As Range
    Set rgData = shRead.Range("A1").CurrentRegion
    
    ' IMPORTANT: Do not have any blank rows in the criteria range
    Set rgCriteria = shRead.Range("G1:K2")
   
    ' Apply the filter
    rgData.AdvancedFilter Action:=xlFilterCopy, CriteriaRange:=rgCriteria _
                , CopyToRange:=shWrite.Range("A1")

 End Sub

Copying Individual Fields

To copy specific columns is pretty simple. We place the columns in our output range and Advanced Filter will only write data to this columns.

For example, If we only want the Item and Sales columns then we need to make two changes to Advanced filter example above:

1. Set the Headers before we run advanced filter.
2. Set the CopyToRange parameter to include the Range of headers.

We can see the updated code here:

' ----------------------------------------------------------------
' Procedure Name: AdvancedFilter_Columns
' Purpose: Uses Advanced Filter to copy individual columns
'
' Result: The result will be the Item and Sales column in the Report
'         worksheet.
' Website: https://excelmacromastery.com/
' ----------------------------------------------------------------
' https://excelmacromastery.com/
Sub AdvancedFilter_Columns()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions Filter")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    ' Clear any existing data
    shWrite.Cells.Clear
    
    ' Specify the output columns
    shWrite.Range("A1").Value2 = "Item"
    shWrite.Range("B1").Value2 = "Sales"

    ' Remove the filter
    If shRead.FilterMode = True Then
        shRead.ShowAllData
    End If
    
    ' Get the source data range
    Dim rgData As Range, rgCriteria As Range
    Set rgData = shRead.Range("A1").CurrentRegion
    
    ' IMPORTANT: Do not have any blank rows in the criteria range
    Set rgCriteria = shRead.Range("G1:K2")
   
    ' Apply the filter
    rgData.AdvancedFilter Action:=xlFilterCopy, CriteriaRange:=rgCriteria _
                , CopyToRange:=shWrite.Range("A1:B1")

End Sub

Using ADO and SQL

ADO is an external Library that allows us to perform queries on databases. It stands for ActiveX Database Objects.

ADO can also perform queries on data in worksheets. This means we can do very powerful queries that run very fast.

Just like using AutoFilter and Advanced filter, we can use most of the same VBA code each time. The main difference will be the query line. The disadvantage is that it requires some basic knowledge of SQL.

If you want to see working examples using ADO and SQL then you can download the source code at the top or bottom of this post.

The following code returns all the records where the item is “Laptop Model A”:

' ReadFromWorksheetADO()

'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' Details: Returns all the records for item "Laptop Model A".
' https://excelmacromastery.com/
Sub ReadFromWorksheetADO()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "dd/mm/yyyy"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        .Columns(4).NumberFormat = "0"
        .Columns(5).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' To add ADO reference select Tools->Reference and
    ' check "Microsoft ActiveX Data Objects Objects 6.1 Library"
    Dim conn As New ADODB.Connection
    conn.Open "Provider=Microsoft.ACE.OLEDB.12.0;" & _
        "Data Source=" & ThisWorkbook.FullName & ";" & _
            "Extended Properties=""Excel 12.0;HDR=Yes;"";"

    ' Store the query in a string
    Dim query As String
    query = "Select * from [" & shRead.name _
                    & "$] Where Item='Laptop Model A' "
    
    ' Run the query and store in a recordset
    Dim rs As New Recordset
    rs.Open query, conn

    ' Write header
    Dim i As Long
    For i = 0 To rs.Fields.count - 1
        shWrite.Cells(1, i + 1).Value2 = rs.Fields(i).name
    Next i
    
    ' Write data
    shWrite.Range("A2").CopyFromRecordset rs
    
    ' Close the connection
    conn.Close
    
End Sub

Here are some examples of ADO queries

' Item is "Laptop Model A" AND the volume is greater than or equal 20
query = "Select Item,Day,Price,Volume,Sales from [Transactions$] " _
         & " Where Item = 'Laptop Model A' and Volume>=20"

' Item is "Laptop Model A" OR the volume is greater than or equal 20
query = "Select Item,Day,Price,Volume,Sales from [Transactions$] " _
         & " Where Item = 'Laptop Model A' or Volume>=20"

' Item starts with "Laptop"  
query = "Select Item,Day,Price,Volume,Sales from [Transactions$] " _
         & " Where Item like 'Laptop%' "   

' Item Ends with "Model A"
query = "Select Item,Day,Price,Volume,Sales from [Transactions$] " _
         & " Where Item like '%Model A' "

' Item contains "top"
query = "Select Item,Day,Price,Volume,Sales from [Transactions$] " _
         & " Where Item like '%top%' "

 ' Item does not contain "top"
query = "Select Item,Day,Price,Volume,Sales from [Transactions$] " _
         & " Where Item Not like '%top%' "

' Return the total volume for each monitor type
query = "Select Item, Sum(Volume) As [Total Vol] from [Transactions$] " _
         & " Where Item like 'Monitor%' " _
         & " Group by Item"

It is important to note that for multiple queries you don’t need to connect to the workbook each time.

One connection to the workbook is enough. Then you can run all your queries. When your queries are finished you can close the connection.

The following outline shows what I mean:

' Open the connection
Dim conn As New ADODB.Connection
conn.Open "Provider=Microsoft.ACE.OLEDB.12.0;" & _
    "Data Source=" & ThisWorkbook.FullName & ";" & _
        "Extended Properties=""Excel 12.0;HDR=Yes;"";"

' Run all queries
...
...

' When finished close the connection
conn.Close

How to Copy Rows Using ADO

Copying a row is pretty straightforward using ADO.

There is a function Range.CopyFromRecordset which writes out the entire data from the query.

This is very convenient but it doesn’t copy the header and it is slower than many other methods.

In the code below we write out all the items that are “Laptop Model A”:

' ADO_CopyRow()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' Details: Returns the records for item "Laptop Model A".
' https://excelmacromastery.com/
Sub ADO_CopyRow()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions Filter")
    Set shWrite = ThisWorkbook.Worksheets("Report")
     
    With shWrite
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "dd/mm/yyyy"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        .Columns(4).NumberFormat = "0"
        .Columns(5).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' To add ADO reference select Tools->Reference and
    ' check "Microsoft ActiveX Data Objects Objects 6.1 Library"
    Dim conn As New ADODB.Connection
    conn.Open "Provider=Microsoft.ACE.OLEDB.12.0;" & _
        "Data Source=" & ThisWorkbook.FullName & ";" & _
            "Extended Properties=""Excel 12.0;HDR=Yes;"";"

    ' Store the query in a string
    Dim query As String
    query = "Select Item,Day,Price,Volume,Sales from [" & shRead.name _
            & "$] Where Item='Laptop Model A' "
    
    Dim rs As New Recordset
    rs.Open query, conn
    
    ' Write header
    Dim i As Long
    For i = 0 To rs.Fields.count - 1
        shWrite.Cells(1, i + 1).Value2 = rs.Fields(i).name
    Next i
    
    ' Write data
    shWrite.Range("A2").CopyFromRecordset rs
    
    conn.Close
    
End Sub

Copying Individual Fields

Copying individual fields using ADO couldn’t be simpler.

We specify the fields we want in the Select statement:

' Select all the fields
sQuery = "Select Item,Day,Price,Volume,Sales from [Transactions$]"

' Select Item and Sales
sQuery = "Select Item,Sales from [Transactions$]"

 ' Select Volume
sQuery = "Select Volume from [Transactions$]"

 ' Select Price, Item - changes order of fields
sQuery = "Select Item,Price from [Transactions$]"

Summing Totals

Summing totals is also simple. It only requires adding a Group By statement to the query

Let’s get the total volume and sales for each item:

' ADO_SumColums()'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' Details: Returns the total sales amount for each item.
' https://excelmacromastery.com/
Sub ADO_SumColums()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions Filter")
    Set shWrite = ThisWorkbook.Worksheets("Report")
     
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "0"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' To add ADO reference select Tools->Reference and
    ' check "Microsoft ActiveX Data Objects Objects 6.1 Library"
    Dim conn As New ADODB.Connection
    conn.Open "Provider=Microsoft.ACE.OLEDB.12.0;" & _
        "Data Source=" & ThisWorkbook.FullName & ";" & _
            "Extended Properties=""Excel 12.0;HDR=Yes;"";"

    ' Store the query in a string
    Dim query As String
    query = "Select Item,Sum(Volume) As [Total Volume] " _
        & ",Sum(Sales) As [Total Sales] " _
        & "from [" & shRead.name & "$] Group By Item "
    
    Dim rs As New Recordset
    rs.Open query, conn
    
    ' Write header
    Dim i As Long
    For i = 0 To rs.Fields.count - 1
        shWrite.Cells(1, i + 1).Value2 = rs.Fields(i).name
    Next i
    
    ' Write data
    shWrite.Range("A2").CopyFromRecordset rs
    
    conn.Close
    
End Sub

Pivot Table

Using a Pivot Table is a very powerful way to sum data. It is faster than using the other summing methods.

It is more flexible than using For with a Dictionary but easier to use than ADO as no knowledge of SQL is necessary.

We don’t actually need a copy method with the Pivot Table. We just need to specify range where the Pivot table will be created.

Summing Data

The Pivot Table automatically sums values.

We have rows and value fields in a Pivot Table. We can use these to sum data.

1. The Row field is the thing that we plan to get the total of e.g. Items.
2. The Value field is the value that we wish to sum e.g. Volume, Sales.

We can set these fields like this:

' Set the Row fields
.PivotFields("Item").Orientation = xlRowField

' Set the Value fields
.PivotFields("Volume").Orientation = xlDataField
.PivotFields("Sales").Orientation = xlDataField

The full PivotTable code looks like this:

' https://excelmacromastery.com/
Sub PivotTable_Sum()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
   
    ' Clear any existing pivot tables
    Dim piv As PivotTable
    For Each piv In shWrite.PivotTables
        piv.TableRange2.Clear
    Next piv
    
    ' Clear the data in output worksheet
    .Cells.ClearContents
  
    ' Create the cache
    Dim ptCache As PivotCache
    Set ptCache = ThisWorkbook.PivotCaches.Create( _
        SourceType:=xlDatabase _
        , SourceData:=rg _
        , Version:=xlPivotTableVersion15)
    
    ' Create the table
    Dim ptTable As PivotTable
    Set ptTable = shWrite.PivotTables.Add( _
             PivotCache:=ptCache _
            , TableDestination:=shWrite.Range("A1"))
    
    ' Set the name and style
    ptTable.name = "pvItems"
    ptTable.TableStyle2 = "PivotStyleDark14"
    
    ' Set the fields
    Dim ptField As PivotField
    With ptTable

        ' Set the rows fields
        .PivotFields("Item").Orientation = xlRowField
        
        ' Set the data(value) fields
        .PivotFields("Volume").Orientation = xlDataField
        .PivotFields("Sales").Orientation = xlDataField
        
    End With
    
End Sub

If we want to filter with the PivotTable then it is a bit long winded as we have to set each item individually.

To add a filter we can use the code below. Add this code before the “End With” line in the above code.

' Filter items
Dim pvItem As PivotItem
For Each pvItem In .PivotFields("Item").PivotItems
    If pvItem.Caption = "Laptop Model A" Then
        pvItem.Visible = True
    Else
        pvItem.Visible = False
    End If
Next pvItem

Conclusion

That concludes this article on copying and filtering data using the different Excel VBA Copy methods.

If you think something is missing or you have any questions or queries then please leave a comment below.

What’s Next?

Free VBA Tutorial If you are new to VBA or you want to sharpen your existing VBA skills then why not try out the The Ultimate VBA Tutorial.

Related Training: Get full access to the Excel VBA training webinars and all the tutorials.

(NOTE: Planning to build or manage a VBA Application? Learn how to build 10 Excel VBA applications from scratch.)

Bottom line: Learn 3 different ways to copy and paste cells or ranges in Excel with VBA Macros.  This is a 3-part video series and you can also download the file that contains the code.

Skill level: Beginner

Copy & Paste: The Most Common Excel Action

Copy and paste is probably one of the most common actions you take in Excel.  It’s also one of the most common tasks we automate when writing macros.

There are a few different ways to accomplish this task, and the macro recorder doesn’t always give you the most efficient VBA code.

In the following three videos I explain:

• The most efficient method for a simple copy and paste in VBA.
• The easiest way to paste values.
• How to use the PasteSpecial method for other paste types.

You can download the file I use in these videos below.  The code is also available at the bottom of the page.

Video #1: The Simple Copy Paste Method

You can watch the playlist that includes all 3 videos at the top of this page.

Video #2: An Easy Way to Paste Values

Video #3: The PasteSpecial Method Explained

VBA Code for the Copy & Paste Methods

Download the workbook that contains the code.

'3 Methods to Copy & Paste with VBA
'Source: https://www.excelcampus.com/vba/copy-paste-cells-vba-macros/
'Author: Jon Acampora

Sub Range_Copy_Examples()
'Use the Range.Copy method for a simple copy/paste

    'The Range.Copy Method - Copy & Paste with 1 line
    Range("A1").Copy Range("C1")
    Range("A1:A3").Copy Range("D1:D3")
    Range("A1:A3").Copy Range("D1")
    
    'Range.Copy to other worksheets
    Worksheets("Sheet1").Range("A1").Copy Worksheets("Sheet2").Range("A1")
    
    'Range.Copy to other workbooks
    Workbooks("Book1.xlsx").Worksheets("Sheet1").Range("A1").Copy _
        Workbooks("Book2.xlsx").Worksheets("Sheet1").Range("A1")

End Sub


Sub Paste_Values_Examples()
'Set the cells' values equal to another to paste values

    'Set a cell's value equal to another cell's value
    Range("C1").Value = Range("A1").Value
    Range("D1:D3").Value = Range("A1:A3").Value
     
    'Set values between worksheets
    Worksheets("Sheet2").Range("A1").Value = Worksheets("Sheet1").Range("A1").Value
     
    'Set values between workbooks
    Workbooks("Book2.xlsx").Worksheets("Sheet1").Range("A1").Value = _
        Workbooks("Book1.xlsx").Worksheets("Sheet1").Range("A1").Value
        
End Sub


Sub PasteSpecial_Examples()
'Use the Range.PasteSpecial method for other paste types

    'Copy and PasteSpecial a Range
    Range("A1").Copy
    Range("A3").PasteSpecial Paste:=xlPasteFormats
    
    'Copy and PasteSpecial a between worksheets
    Worksheets("Sheet1").Range("A2").Copy 
    Worksheets("Sheet2").Range("A2").PasteSpecial Paste:=xlPasteFormulas
    
    'Copy and PasteSpecial between workbooks
    Workbooks("Book1.xlsx").Worksheets("Sheet1").Range("A1").Copy
    Workbooks("Book2.xlsx").Worksheets("Sheet1").Range("A1").PasteSpecial Paste:=xlPasteFormats
    
    'Disable marching ants around copied range
    Application.CutCopyMode = False

End Sub

Paste Data Below the Last Used Row

One of the most common questions I get about copying and pasting with VBA is, how do I paste to the bottom of a range that is constantly changing?  I first want to find the last row of data, then copy & paste below it.

To answer this question, I created a free training video on how to paste data below the last used row in a sheet with VBA.  Can I send you the video?  Please click the image below to get the video.

Free Training on Macros & VBA

The 3 videos above are from my VBA Pro Course.  If you want to learn more about macros and VBA then checkout my free 3-part video training series.

I will also send you info on the VBA Pro Course, that will take you from beginner to expert.  Click the link below to get instant access.

Free Training on Macros & VBA

Please leave a comment below with any questions.  Thanks!

На чтение 3 мин. Просмотров 51.7k.

Итог: Изучите 3 различных способа копирования и вставки ячеек или диапазонов в Excel с помощью макросов VBA. Это серия из трех частей, также вы сможете скачать файл, содержащий код.

Уровень мастерства: Начинающий

Копировать и вставить: наиболее распространенное действие Excel

Копирование и вставка, вероятно, является одним из самых
распространенных действий в Excel. Это также одна из самых распространенных
задач, которые мы автоматизируем при написании макросов.

Есть несколько различных способов выполнить эту задачу, и устройство записи макросов не всегда дает вам наиболее эффективный код VBA.

В следующих трех видео я объясняю:

• Самый эффективный метод для простого копирования
  и вставки в VBA.
• Самый простой способ вставить значения.
• Как использовать метод PasteSpecial для других
  типов вставок.

Видео № 1: Простой метод «Копировать-вставить»

Видео лучше всего просматривать в полноэкранном HD.

Sub Примеры_копирования_диапазона()
'Используйте метод Range.Copy для простого копирования / вставки

    'Метод Range.Copy - копирование и вставка с 1 строкой
    Range("A1").Copy Range("C1")
    Range("A1:A3").Copy Range("D1:D3")
    Range("A1:A3").Copy Range("D1")
    
    'Range.Copy с одного листа на другой
    Worksheets("Лист1").Range("A1").Copy Worksheets("Лист2").Range("A1")
    
    'Range.Copy с одного файла (на другой
    Workbooks("План.xlsx").Worksheets("Лист1").Range("A1").Copy _
        Workbooks("Факт.xlsx").Worksheets("Лист1").Range("A1")

End Sub

Видео № 2: Простой способ вставить значения

Sub Копируем_только_значения()
'Установите значения ячеек равными другим, чтобы вставить значения

'Устанавливает равенство одного диапазона другому
    Range("C1").Value = Range("A1").Value
    Range("D1:D3").Value = Range("A1:A3").Value
     
'Равенство значений между листами
    Worksheets("Лист1").Range("A1").Value = Worksheets("Лист2").Range("A1").Value
     
'Равенство значений между книгами
    Workbooks("Факт.xlsx").Worksheets("Лист1").Range("A1").Value = _
        Workbooks("План.xlsx").Worksheets("Лист1").Range("A1").Value
        
End Sub

Видео № 3: Метод PasteSpecial

Sub Копируем_с_помощью_специальной_вставки()
'Используйте метод Range.PasteSpecial для выбора типа вставки

 'Копируем и вставляем через СпецВставку
Range("A1").Copy
Range("A5").PasteSpecial Paste:=xlPasteFormats

'Используем спецвставку между листами
Worksheets("Лист1").Range("A2").Copy
Worksheets("Лист2").Range("A2").PasteSpecial Paste:=xlPasteFormulas

'Используем спецвставку между файлами
Workbooks("План.xlsx").Worksheets("Лист1").Range("A3").Copy
Workbooks("Факт.xlsx").Worksheets("Лист1").Range("A1").PasteSpecial Paste:=xlPasteFormats

'Убираем "бегающих муравьёв" после копирования (очищаем буфер обмена)
Application.CutCopyMode = False    
   
End Sub

Вставить данные ниже последней заполненной строки

Один из самых распространенных вопросов, которые я получаю о копировании и вставке с помощью VBA: «Как мне вставить данные в конец таблицы? «

Сначала нужно найти последнюю заполненную строку данных, а затем скопировать и вставить ниже неё.

Переходите по ссылке, чтобы научиться 3 способам поиска последней заполненной ячейки

• 

Description:

Copying Data from One Range to Another range is most commonly performed task in Excel VBA programming. We can copy the data, Formats, Formulas or only data from particular range in Excel Workbook to another range or Sheet or Workbook.

This example to show you how to copy data from one Range to another using Excel VBA. This is one of the frequently used codes in the VBA, we often do this activity, copying the data from one range to another range in a worksheet.r

Copy Data from One Range to Another in Excel VBA- Solution(s):

You can use Copy method of a range to copy the data from one range to another range.

Copy Data from One Range to Another in Excel VBA – An Example

The following example will show you copying the data from one range to another range in a worksheet using Excel VBA.

Code:

'In this example I am Copying the Data from Range ("A1:B10") to Range(E1")
Sub sbCopyRange()

'Method 1
Range("A1:B10").Copy Destination:=Range("E1")
'Here the first part is source range, 
'and the second part is target range or destination.
'Target can be either one cell or same size of the source range.

'Method 2
Range("A1:B10").Copy
Range("E1").Select
ActiveSheet.Paste

'In the second method, first we copy the source data range
'Then we select the destination range
'Target can be either one cell or same size of the source range.
'Then we paste in the active sheet, so that it will paste from active range

Application.CutCopyMode = False

End Sub

Instructions:

1. Open an excel workbook
2. Enter some data in Sheet1 at A1:B10
3. Press Alt+F11 to open VBA Editor
4. Insert a Module for Insert Menu
5. Copy the above code and Paste in the code window
6. Save the file as macro enabled workbook
7. Press F5 to run it

Now you should see the required data (from Range A1 to B10 ) is copied to the target range (Range E1 to F10).

Effortlessly Manage Your Projects and Resources

120+ Professional Project Management Templates!

A Powerful & Multi-purpose Templates for project management. Now seamlessly manage your projects, tasks, meetings, presentations, teams, customers, stakeholders and time. This page describes all the amazing new features and options that come with our premium templates.

Save Up to 85% LIMITED TIME OFFER

All-in-One Pack
120+ Project Management Templates

Essential Pack
50+ Project Management Templates

Excel Pack
50+ Excel PM Templates

PowerPoint Pack
50+ Excel PM Templates

MS Word Pack
25+ Word PM Templates

Ultimate Project Management Template

Ultimate Resource Management Template

Project Portfolio Management Templates

Related Posts

• • Description:
  • Copy Data from One Range to Another in Excel VBA- Solution(s):

VBA Reference

Effortlessly
Manage Your Projects

120+ Project Management Templates

Seamlessly manage your projects with our powerful & multi-purpose templates for project management.

120+ PM Templates Includes:

57 Comments

1. How to copy excel cell to excel another cell

2. PNRao
   April 1, 2014 at 9:46 AM — Reply

   Hi,
   You can use Cells(1,1).Copy Destination:=Cells(1,2) to copy the data from one cell to another cell, it is same as copying a range from to another range.

   Thanks-PNRao!

3. Amit Shah
   October 30, 2014 at 7:07 AM — Reply

   Hi, please help me on my data. Cell A1 has a roll number and cell C1 has the name. But my data is not continues. There are blanks and some miscellaneous data also. I want is, if A1 has roll number then copy the name from C1 and paste in F1 cell. Please help me with the coding.

   Thanks
   Amit

4. Galo
   November 20, 2014 at 3:36 AM — Reply

   Hello, please your help.

   How do I copy a range of cells from workshhet1 to worksheet2 based on the name of a column in worksheet1?

   For example I have in WS1 a column named “Items”. I want the macro in WS2 to look for the column “Items” in WS1 and copy such column´s data in WS2.

5. Amol
   January 5, 2015 at 1:38 PM — Reply

   Its working perfect , but my cells contain formula in it and this methods not working to move data from cells have formula in it . please help me in this .

6. PNRao
   January 6, 2015 at 8:04 PM — Reply

   Hi Amol,

   When you have the formulas in the Cell, you can do the paste special as values: Here the Simple example to copy the data (cells or range) with formulas:

   Range(“B5:B6”).Copy
   Range(“J5”).PasteSpecial (xlPasteValues)

   Thanks-PNRao!

7. Hi Valli or Anyone,

   Please help, On sheet-1 I have an data entry field. I want my macro to copy any data I place on the cell on sheet-1 and paste it to the cells in sheet-2. I works on the first line however, I want the next data to copied and pasted on the next Row in sheet-2

   Example:
   Sheet 1 Row1 Column 1 Data Field: JUN
   Sheet 2 Row1 Column 1: JUN
   Sheet 1 Row1 Column 1 Data Field: RAJAUDAIYAR
   Sheet 2 Row2 Column 1: RAJAUDAIYAR
   Sheet 1 Row1 Column 1 Data Field: PNRAO
   Sheet 2 Row2 Column 1: PNRAO
   Sheet 1 Row1 Column 1 Data Field: AMIT SHAH
   Sheet 2 Row3 Column 1: AMITH SHAH

8. PNRao
   January 19, 2015 at 6:42 PM — Reply

   Hi Jun,
   It seems like you want to synchronize the Worksheet2 with Worksheet1.
   Place the below code in the Sheet1 Code module:

   Private Sub Worksheet_Change(ByVal Target As Range)
   Sheets("Sheet2").Range(Target.Address) = Range(Target.Address)
   End Sub
   

   Please feel free to ask me if you are looking for something else.

   Thanks-PNRao!

9. Hi PNRao,

   I tried using the script you gave but I encountered errors.

   Here is what I wanted to do actually.

   In sheet1 cell A1 I am using it as a entry field. Let say I type in your name PNRao then I will have a click button that will paste it to Sheet2 cell A1. Then I will type in my name on shee1 cell A1 Jun and click on the button. I will then paste my name on Sheet2 cell A2.

   My statement may be confusing, sorry.

10. PNRao
    January 23, 2015 at 10:43 AM — Reply

    Hi Jun,

    Assign this macro to your button click:

    Sub btnClikToEnter()
    'Find last used row in sheet 2
    lastRow = ActiveSheet.Cells.SpecialCells(xlLastCell).Row
     lRow = ActiveSheet.Cells.SpecialCells(xlLastCell).Row
     Do While Application.CountA(ActiveSheet.Rows(lRow)) = 0 And lRow <> 1
     lRow = lRow - 1
     Loop
     lastRow = lRow
     
     If Sheets("Sheet2").Range("A1") = " And lastRow = 1 Then
      Sheets("Sheet2").Range("A1") = Sheets("Sheet1").Range("A1")
     Else
     Sheets("Sheet2").Range("A" & lastRow + 1) = Sheets("Sheet1").Range("A1")
     End If
    End Sub
    

    Thanks-PNRao!

11. boskey
    March 10, 2015 at 1:04 PM — Reply

    hi,
    i m working in solar industry, i have a problem related to data.i have two excel file i st have the particular data with data and second one containing all year data.so i have to merge means particular dates data from excel 2 to excel 1 ..how do i do thisin easy manner

12. Khaled
    March 13, 2015 at 9:09 AM — Reply

    please check the last row in the following code, it contains error but I cant find

    Sub copyDataFromMultipleWorkbooksIntoMaster()

    Dim FolderPath As String, Filepath As String, Filename As String

    FolderPath = “C:workexcel_tutorialsuppliers”

    Filepath = FolderPath & “*.xls*”

    Filename = Dir(Filepath)

    Dim lastrow As Long, lastcolumn As Long

    Do While Filename “”
    Workbooks.Open (FolderPath & Filename)
    ‘Range(“A2:D2″).Copy
    lastrow = ActiveSheet.Cells(Rows.count, 1).End(xlUp).Row
    lastcolumn = ActiveSheet.Cells(1, Columns.count).End(xlToLeft).Column
    Range(Cells(2, 1), Cells(lastrow, lastcolumn)).Copy
    Application.DisplayAlerts = False
    ActiveWorkbook.Close

    erow = Sheet1.Cells(Rows.count, 1).End(xlUp).Offset(1, 0).Row

    ‘If we wanted to paste data of more than 4 columns we would define a last column here also
    ‘lastcolumn = ActiveSheet.Cells(1, Columns.count).End(xlToLeft).Column
    ‘ActiveSheet.Paste Destination:=Worksheets(“Sheet1″).Range(Cells(erow, 1),
    Cells(erow, lastcolumn))
    ActiveSheet.Paste Destination:=Worksheets(“Sheet1″).Range(Cells(erow, 1),
    Cells(erow, 4))

    Filename = Dir

    Loop

    End Sub

13. jen
    March 15, 2015 at 10:36 PM — Reply

    Hi,

    I want to copy data from multiple cells of one sheet into a single cell in another sheet,
    For example is cells A1- apple
    B1 – orange
    C1 – grape.
    I want cell A1 in sheet 2 to have apple,orange,grape

    How to write macor for this please

14. Sanchit
    March 16, 2015 at 2:54 PM — Reply

    Hi,
    I used the above method to insert the columns from another sheet. It worked perfectly well.

    I used the button click to copy columns from another sheet. Now I want to insert checkboxes against those copied columns on the option click.
    Also I want the checkbox to be checked in one case and unchecked if in another case.
    Please help me with that!!!

15. PNRao
    March 21, 2015 at 2:45 PM — Reply

    You can use below syntax to copy and paste:

    Method1:
    Range(“YourSourceRange”).Copy Destination:=Range(“YourDestionationRange”)
    Example:
    Range(“A1:D5”).Copy Destination:=Range(“E5”)

    Method 2:
    Range(“YourSourceRange”).Copy
    Range(“YourDestionationRange”).Select
    Activesheet.Paste
    Example:
    Range(“A1:D5”).Copy
    Range(“E5”).Select
    Activesheet.Paste

    Hope this helps! Thanks-PNRao!

16. PNRao
    March 21, 2015 at 2:51 PM — Reply

    Hi Jen,
    You can use the below code:

    Sub sbConcatenateCells()
        Sheet2.Range("A1") = Sheet1.Range("A1") & "," & Sheet1.Range("B1") & "," & Sheet1.Range("C1")
    End Sub
    

    Thanks-PNRao!

17. uday
    April 7, 2015 at 1:18 PM — Reply

    Hi All,

    Can anyone help me in printing data from one filed to another field using a button in the same worksheet

    Thanks

18. Dragony2000
    April 12, 2015 at 10:12 AM — Reply

    I make find code to select multiple cells i wanna copy the selected cells to another rows in the same column

    i mean if searching catch C1 , M1 , R1 it copies automatically in ( C5, M5, R5) and fill until (C9, M9 , R9)

19. Teecee
    April 29, 2015 at 2:30 PM — Reply

    I would like to add a function to my Excel workbook something like as follows:
    set(destination,source) {destination.value=source.value; current_cell.value=source.value}

    The current cell would be the cell that contains the usage of the “set” function along with the needed arguments. It’s output result isn’t actually necessary though, what is important is the ability to transfer values to another cell range.

20. khine su win
    May 13, 2015 at 1:32 PM — Reply

    How to copy excel file data only by avoiding formula?
    I want to copy only data to another file.
    Please let me know the way.
    Thank you.

    Khine Su Win

21. PNRao
    May 13, 2015 at 8:46 PM — Reply

    Hi Khine su win,
    Here is the code to copy the range A1 to C10 and paste at D1:
    Paste:=xlPasteValues option allow you to copy only the values and paste.

    Sub CopyTheDataAndPasteOnlyValues() '
        Range("A1:C10").Copy
        Range("D1").PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
            :=False, Transpose:=False
    End Sub
    

    Thanks-PNRao!

22. rajni kumar
    May 14, 2015 at 7:30 PM — Reply

    Hi PNRao,
    I have a requirement to move the data from columns into rows, and also I need parameterized the starting point of the columns that are to be converted into rows. Find below my example

    raw data
    FName LName Num1 Num2 Num3
    rajni kumar 10 11 23
    David Betts 5 3 8

    to covert like this
    FName LName Values
    rajni kumar 10
    rajni kumar 11
    rajni kumar 23
    David betts 5
    David betts 3
    David betts 8

    Please can you help or give in some guidance I can try few options.

23. khine su win
    May 15, 2015 at 7:39 AM — Reply

    Hi PNRao!

    Thank for your answer.
    Please may i ask another question.
    I want to copy entire excel file but i need only data.
    I mean that wnat to copy data by avoiding formula.
    And then, i also don’t want to open excel file when do copy data.
    Please let me know the way.
    Thank you.

    Khine Su Win

24. tejas
    May 15, 2015 at 2:45 PM — Reply

    how to copy the values column wise present in the sheet1 and paste each column values in the different sheets in the workbook.

25. Tommy
    May 27, 2015 at 3:52 AM — Reply

    Hello..

    I have 4 columns in sheet 1. I want to match a value in column A, and match a value in column B. Once both values match at a row X, I want to copy column C, rowX to rowX+1 and copy column D, row X to rowX+1 and paste them into a certain cells in Sheet 2.

    Please advice. Thank you,

26. Nits
    June 22, 2015 at 9:00 PM — Reply

    Hi,

    I wanted little assistance in the issue I’m facing currently.
    I have 2 sheets, (A) Master Data Sheet (B) Detailed Activities.
    Master Data sheet will have all the process name and there corresponding activities along with some other details in other column. (Basically

    the Database)
    I have 4 columms in Master Data Sheet namely Process name, Activity, Activity Owner and Hours.
    In the Detailed Activities sheet there are multiple coloumns including the columns present in the Master Data Sheet. (i.e. Process name,

    Activity, Activity Owner and Hours.)

    Issue:

    When I enter a process name in the Detailed Activities Sheet in “Process Name”, I want to autopopulate the corresponding Activity, Activity

    Owner and Hours column in the Scheduler Sheet.
    Then when a enter another process name below the previos process name entered the corresponding columns should get auto populated.(As

    per the details mentioned in the Master Data Sheet).

    I made this code but I have given specific range. The following code is only for 1 process name. (Thats why i gave specific range)
    I want to code for atleast 40 processes and I should be able to enter one range below the other.

    For Detailed Activity Sheet
    Column C = Process name
    Column L = Activity
    Column M = Activity Owner
    Column N = Hours

    For Master Data Sheet
    Column A = Process name
    Column B = Activity
    Column C = Acivity Owner
    Column D = Hours

    Private Sub Worksheet_Change(ByVal Target As Range)
    Application.EnableEvents = False
    Select Case Range(“C2”).Value

    Case “Transfer”

    Sheets(“Detailed Activities”).Range(“L2:L12”).Value = Sheets(“Master Data Sheet”).Range(“B2:B12”).Value
    Sheets(“Detailed Activities”).Range(“M2:M12”).Value = Sheets(“Master Data Sheet”).Range(“C2:C12”).Value
    Sheets(“Detailed Activities”).Range(“N2:N12”).Value = Sheets(“Master Data Sheet”).Range(“D2:D12”).Value
    Sheets(“Detailed Activities”).Range(“D2:D12”).Value = “-”
    Sheets(“Detailed Activities”).Range(“E2:E12”).Value = “-”
    Sheets(“Detailed Activities”).Range(“I2:I12”).Value = “-”
    Sheets(“Detailed Activities”).Range(“J2:J12”).Value = “-”

    Case ” ”

    Sheets(“Detailed Activities”).Range(“L2:L12″).Value = ” ”
    Sheets(“Detailed Activities”).Range(“M2:M12″).Value = ” ”
    Sheets(“Detailed Activities”).Range(“N2:N12″).Value = ” ”

    Case ”

    Sheets(“Detailed Activities”).Range(“L2:L12″).Value = ” ”
    Sheets(“Detailed Activities”).Range(“M2:M12″).Value = ” ”
    Sheets(“Detailed Activities”).Range(“N2:N12″).Value = ” ”

    Case Else

    Sheets(“Detailed Activities”).Range(“L2:L12”).Value = “Please enter a valid Process Name to update the Activities”
    Sheets(“Detailed Activities”).Range(“M2:M12”).Value = “Please enter a valid Process Name to update the Activity Owner”
    Sheets(“Detailed Activities”).Range(“N2:N12”).Value = “Please enter a valid Process Name to calculate estimated HRS”

    End Select
    Application.EnableEvents = True
    End Sub

    For transfer process, there are 10 rows of Acitvity, Activity owner and hours.
    So when i enter ” Transfer” in the process column in the Detailed activities sheet, the code should search the keyword “transfer” in the

    master data shet and then copy the corresponding number of rows of Activity, activity owner and hrs from master data sheet to detailed

    activities sheet.
    Then when I enter another process name the same function should be carried out again.

    Please advise.

    Kind Regards,
    Nits.

27. esskaybee
    July 1, 2015 at 9:46 AM — Reply

    Sub abcd()
    ‘ Get customer workbook…
    Dim customerBook As Workbook
    Dim filter As String
    Dim caption As String
    Dim customerFilename As String
    Dim customerWorkbook As Workbook
    Dim targetWorkbook As Workbook

    ‘ make weak assumption that active workbook is the target
    Set targetWorkbook = Application.ActiveWorkbook

    ‘ get the customer workbook
    filter = “Text files (*.xlsx),*.xlsx”
    caption = “Please Select an input file ”
    customerFilename = Application.GetOpenFilename(filter, , caption)

    Set customerWorkbook = Application.Workbooks.Open(customerFilename)

    ‘ assume range is A1 – C10 in sheet1
    ‘ copy data from customer to target workbook
    Dim targetSheet As Worksheet
    Set targetSheet = targetWorkbook.Worksheets(1)
    Dim sourceSheet As Worksheet
    Set sourceSheet = customerWorkbook.Worksheets(1)

    targetSheet.Range(“A1”, “C10”).Value = sourceSheet.Range(“A1”, “C10”).Value

    targetSheet.UsedRange.AutoFilter Field:=1, Criteria1:=Array(“A123”, “A234”, “A128”, “A129”), Operator:=xlFilterValues, VisibleDropDown:=False

    ‘ Close customer workbook
    customerWorkbook.Close
    End Sub

28. Preet
    August 10, 2015 at 5:54 PM — Reply

    I am struggling with copying data from master file to rest of tabs based on filter. Assuming i have master sheet with column name application and my tabs are arranged with column names, i wanted to copy data from master sheet to corresponding tabs of each application, with keeping master data as well. Also if something is present in master tab but not in application tab, that row must be moved to separate tab i created. This tab is common to all application tab. Reason being, this master sheet is going to get updated everyday and i want my tabs to have current data but keeping the old one in misc tab. I will really appreciate the help. Thanks.

29. Ajay
    September 2, 2015 at 12:19 PM — Reply

    Hi Sir,

    With below mention code i able to copy data from _Update Sheet To Master Sheet but In _Update Sheet My Data have formula so i not getting the desire result because formula is getting copied in Master Sheet so please help me

    Sub CopyRangeFromSheet1toSheet2()
    Dim lastRow As Long
    lastRow = Sheets(“Master Sheet”).Range(“A100000”).End(xlUp).Row + 1 ‘ then next free row in sheet2
    Sheets(“_Update”).Range(“A3:F3”).Copy Destination:=Sheets(“Master Sheet”).Range(“C” & lastRow)
    End Sub

    Best Regards
    Ajay

30. PNRao
    September 2, 2015 at 11:14 PM — Reply
31. Shally
    June 24, 2016 at 2:59 PM — Reply

    Hello,

    I just started doing macros and I need to do a task which includes changing the values automatically if there is a change in 1 cell. For example if I change a value from 1 to 0 in cell A1 then which ever cell I want to put that 1 from cell A1 automatically goes to the different cell and the value there increases.

32. Priya K
    August 5, 2016 at 12:51 PM — Reply

    hi

    I used the code provided by you as i have similar query. But what it does is it only copies into rows and then whatever entered gets overwritten in row 2 of sheet2.

33. SP
    November 17, 2016 at 10:11 AM — Reply

    Hi, I need to paste different cells in a one sheet to another sheet with same formatting and add the next set of results one below another in sheet 2

34. Aissa
    March 8, 2017 at 1:27 PM — Reply

    Thanks for your great answers
    The code works very well and I am in a need to use the same way to copy data from a closed csv file to an active worksheet.

    Would you help?

    thanks

35. Viral
    March 21, 2017 at 11:51 AM — Reply

    I have the VBA Code below,

    which ask the use to select the folder from the system, then the code runs and ckecks the excel file, if the folder have the excel file then it will copy and paste the same in the macro file “Copy and paste.xlsx”.

    Now there can be 1 excel file or more than 1.

    Private Sub CommandButton1_Click()
    Sheets(“Sheet1”).Select
    Dim wb As Workbook
    Dim myPath As String
    Dim myFile As String
    Dim myExtension As String
    Dim FldrPicker As FileDialog
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    Application.Calculation = xlCalculationManual
    Set FldrPicker = Application.FileDialog(msoFileDialogFolderPicker)
    With FldrPicker
    .Title = “Select A Target Folder”
    .AllowMultiSelect = False
    If .Show -1 Then GoTo NextCode
    myPath = .SelectedItems(1) & ”
    End With

    NextCode:
    myPath = myPath
    If myPath = ” Then GoTo ResetSettings
    myExtension = “*.xlsx”
    myFile = Dir(myPath & myExtension)
    Do While myFile ”
    Set wb = Workbooks.Open(Filename:=myPath & myFile)

    With Workbooks(myFile)
    With .Range(“a2:BZ” & .Range(“B” & .Rows.Count).End(xlUp).Row)
    .Copy
    End With
    End With

    wb.Close SaveChanges:=False
    myFile = Dir
    Loop
    MsgBox “Task Complete!”
    ResetSettings:
    Application.EnableEvents = True
    Application.Calculation = xlCalculationAutomatic
    Application.ScreenUpdating = True

    End Sub

36. Iva
    April 14, 2017 at 7:44 PM — Reply

    Hi there:
    I need to copy an entire column to another one but just part of the data in each cell. is it possible to do that?
    For Example:
    Column 1 contains last name, name and I just want to copy last name (which is before the coma) to another range.

37. PNRao
    April 15, 2017 at 11:59 AM — Reply

    Hi, Can do this by looping through the each row and split the data, and get the first part.

    But this will slow down the process when you have data in more Rows.

    Here is my suggested approach to Copy the Data (First part of the String in a Column) to another Column.

    I am adding a temporary sheet and copy the required column to the temporary sheet. And splitting the Column by Comma. Then Copying the First Column to required sheet and Column.

    Sub sbCopyOnlyFirstPartOfTheColumn()
    
    'Add a Temporary Sheet
    Set tempSht = Worksheets.Add
    
    'Copy the required Column to Temporary Sheet
        Sheets("Sheet1").Columns("A:A").Copy Destination:=tempSht.Range("A1")
    
    'Split the Column Data with Comma Delimeter
    tempSht.Columns("A:A").TextToColumns Destination:=Range("A1"), DataType:=xlDelimited, _
            TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, _
            Semicolon:=False, Comma:=True, Space:=False, Other:=False, FieldInfo _
            :=Array(Array(1, 1), Array(2, 1)), TrailingMinusNumbers:=True
        
    'Now Copy the First Column (first Part) into reqired Sheet and Column
    'This will copy to Sheet2 and Paste at F Column
    tempSht.Columns("A:A").Copy Destination:=Sheets("Sheet2").Range("F1")
        
    'Delete the Temporary Sheet
    Application.DisplayAlerts = False
        tempSht.Delete
    Application.DisplayAlerts = True
    End Sub
    

    Thanks!

38. Bharath
    May 5, 2017 at 5:44 PM — Reply

    Hi Sir, i have data in sheet 1 and using VBA Codes to copy paste the data to sheet 2 but the problem is Copy paste is not taking place as per the invoice description. For example : Sheet one contains the following information Invoie Number, Date ,Amount and description and when i click on the command button it copy paste the date in sheet2 to respectively. but if the description is more than 2 lines that is where data is getting miss placed. Please suggest and thank you in advance.

39. Bharath
    May 5, 2017 at 5:47 PM — Reply

    Below is the codes currently iam using..

    Sheets(“Invoice”).Range(“Bqty”).Copy
    ‘Activate the destination worksheet
    Sheets(“Data”).Activate
    ‘Select the target range
    Worksheets(“Data”).Cells(Rows.Count, 9).End(xlUp).Offset(1, 0).PasteSpecial Paste:=xlPasteValues
    ‘PasteSpecial in the target destination

40. Sravanthi
    May 19, 2017 at 3:42 PM — Reply

    Dear Sir,

    How do I copy all the data from one sheet and create chart/pivot from the copies data and display the results in the second sheet.

    Thank you in advance for helping,

41. Sravanthi
    May 19, 2017 at 3:43 PM — Reply

    In continuation to my above query, I want to copy cells without mentioning the column/row numbers, e.g., if I have to work on different set of master data on a weekly basis with a same macro.

42. ahmad nuri
    May 27, 2017 at 9:33 AM — Reply

    how to set condition so that macro will work when meet the condition

43. Hariprashath
    June 7, 2017 at 10:16 AM — Reply

    Hi sir,

    How do i copy only particular data from a cell having common attributes?

    eg

    Check the below SLA job has been completed.

    Commands:
    motored -j 711_hari
    motored -j 711_ramnath
    motored -j 711_raviprasad

44. Baldev
    June 24, 2017 at 3:28 PM — Reply

    Dear Friend
    Am new in VB
    Request for code for copy from Sheet1 (Range A2:I2) Fixed row with change value by every 2 seconds (Its a pull data from one site used for stock exchange. These dynamic data need to paste to Sheet2 of same workbook as Value or in CSV format that to every time paste in next available row. Would you please guide for he same .
    With regards
    Baldev

45. Vida
    July 6, 2017 at 6:30 AM — Reply

    Hi!

    I’m having trouble with codes. I badly need your help.

    I wanted to copy paste only the Columns E to H from Sheet1 to Sheet2 Cell A2 IF in Column M of Sheet1 contains “Singapore” text and IF Column M contains “USA” text in Sheet3 Cell A2.

    I’ve already went through countless websites and still can’t find the codes.

    Thank you in advance!

46. PNRao
    July 17, 2017 at 2:32 PM — Reply

    You can Copy the Cells based on the conditions. Your question is quite confusing.

    I am assumining that you want to:
    Copy the Data from Sheet 1 to Sheet 2 (Columns E:H)
    Condition 1: Column M data in Sheet 1 should match the Value ‘Singapore’
    Condition 2: When Range A2 value in Sheet3 is ‘USA’

    Sub sbCopyData()
    
    lRow = 200 'Last Row with Data in sheet 1
    
    'Starts form Row 2
    kCntr = 2 'Start row to paste in Sheet1
    
    
    For iCntr = 2 To lRow 'Here 2 is Start Row of Sheet1
    
    If Sheets("Sheet1").Cells(iCntr, 13) = "Singapore" And Sheets("Sheet3").Range("A2") = "USA" Then
    'Here 13=M
    
    Sheets("Sheet1").Range("E" & iCntr & ":" & "H" & iCntr).Copy _
    Destination:=Sheets("Sheet2").Range("A" & kCntr)
    kCntr = kCntr + 1
    End If
    
    
    Next
    
    
    End Sub
    
    

    Hope this helps!

47. John
    October 24, 2017 at 11:55 PM — Reply

    This is what I currently have:

    Sub Match()
    Range(“F4:F” & Cells(Rows.Count, “F”).End(xlUp).Row).Copy Destination:=Range(“G4”)
    End Sub

    I want to copy and paste what is in F only if the cell in G is blank. Am currently stuck!

48. Naveen
    May 31, 2018 at 11:03 PM — Reply

    Hi

    How to data transfer one excel sheet to another excel sheet with formulas using VBA Code.code

    i tried below code data will transfer but formulas not .

    sub text()
    Range(“A1:A4”).copy
    sheet2.Activate
    range(“A1”).select
    Activesheet.paste
    End sub

49. elizabeth cendana
    June 23, 2018 at 4:11 PM — Reply

    Hi,
    Can you give me a code
    For a shape/ button that when clicked would autmtcally enter a letter at the desired cell.

    Example

    Button 1(anytime)

    When clicked will automatically paste at range D5

    Then another code for

    When the button whose range d4-d5 clicked
    Will autmcally be pasted on E5-E6

    Thank you

50. PNRao
    June 27, 2018 at 1:16 PM — Reply

    You can create button and assign the below macro to copy and paste:

    Sub sbButton1Clcik()
    'Copy the Data
    Range("C1").Copy ' Source Data to Copy
    
    Range("D5").Select 'Target Cell to Paste
    Activesheet.Paste
    End Sub
    

    You can create another button and assign the below macro to copy and paste:

    Sub sbButton2Clcik()
    'Copy the Data
    Range("C2").Copy ' Source Data to Copy
    
    Range("E5").Select 'Target Cell to Paste
    Activesheet.Paste
    End Sub
    

    Hope this helps!

51. Vinoth
    July 26, 2018 at 3:09 PM — Reply

    Hi Rao

    I have source excel sheet with tab named sheet1 . I need to search for the particular job names “JHL1999E” and “JLF1CRTW1”.then i need to start copying its corresponding data which starts from next to its immediate column.To make it clear in the JHL1999E is the position (3,2) ,i need the date to be copied from (3,3) till (3,7) .Like that i need to copy till the end of the row,There will be blank in the next row which denotes the end. Please help me in the coding.

52. sundar
    August 14, 2018 at 12:59 PM — Reply

    hi , i need data transfer from combobox and textbox as like journal entry for accounting system

    DATE PARTICULARS V.NO VOUCHER TYPE DEBIT(RS) CREDIT(RS)

    AND IT WILL BE WORK ON MULTIPLE DR.HAEDS AND CREDIT HEADS

    ACCOUNT HEAD…1 HARRY 40000
    2 SELINA 50000
    3 ALEX 60000

    BANK 100000
    CASH 25000
    CATHARIN 25000

    IF EMPTY IT SHOULD BE SIFT DATA WHEN THERE IS 2 TRANSACTION DR AND CR
    PLEASE HELP ME

53. Manjunath
    December 16, 2018 at 5:12 PM — Reply

    I want to copy Cell A5 and Cell F8 and paste into J17 and C16 .source and destination workbooks are different.

54. dev
    March 16, 2019 at 5:16 PM — Reply

    Sir I want to copy data from one work book to another daily

    1.from one workbook say name book1 (column Range is daily changing B,C,D,E so i need to prompt which column data to be select)
    2.copy data to be paste to another work book say book2(here also need to ask prompt at which range say D,E,F to be paste)

    plase provide script

55. AS
    September 12, 2019 at 4:59 PM — Reply

    Dear
    I want my macro to ask the user of the excel to type the date (month and year) because it’s changing evrery time we run the macro.

    BR,,,

56. prabhat anand
    January 22, 2020 at 9:07 PM — Reply

    Dear,
    I want a macro which can copy & paste from user defined Source Row/Column and paste in user defined destination like
    Range(“Ai : Xi)” where i is user defined.

    Row().entire function hangs when l run code for large data (rows more than 1000) .
    Please help

57. Rahul Agrawal
    April 1, 2020 at 10:11 AM — Reply

    Copy from sheet1 and paste in sheet2 and repeate … also copy from sheet2 to sheet1
    I wish to copy the specific cells values from sheet1 to sheet2 and calculations will happen and copy again data from Sheet2 to sheet1

    this process i wish to repeate for multiple line items in excel.

    PLease help with VBA