Vba excel разделить строку по словам

Использование функции Split в VBA Excel, ее синтаксис и параметры. Значения, возвращаемые функцией Split. Примеры использования.

Функция Split предназначена в VBA Excel для разделения строки на подстроки по специальным меткам — разделителям. Разделителем может быть как отдельный символ, так и строка из нескольких символов. Функция Split по своему действию является обратной функции Join, которая создает одну строку из массива подстрок.

Синтаксис функции

Split (Expression,[Delimiter],[Limit],[Compare])

Обязательным параметром функции Split является Expression. Если остальные параметры явно не указаны, используются их значения по умолчанию.

Параметры функции

Параметр	Описание	Значение по умолчанию
Expression	Строка, содержащая подстроки и разделители	Нет
Delimiter	Разделитель, представляющий один или более символов	Пробел
Limit	Максимальное число подстрок, на которые должна быть разделена входная строка	-1
Compare*	Определяет, какое используется сравнение, двоичное — CompareMethod.Binary (0) или текстовое — CompareMethod.Text (1)	0

*Если используется двоичное сравнение (0 или CompareMethod.Binary), функция чувствительна к регистру букв. Если используется текстовое сравнение (1 или CompareMethod.Text), функция не чувствительна к регистру букв.

Возвращаемые значения

Функция Split возвращает одномерный массив с индексацией от нуля, который содержит указанное параметром Limit число подстрок. Чаще всего, функция Split используется со значением параметра Limit по-умолчанию, равному -1, когда возвращаются все найденные в исходной строке подстроки.

---

Пример 1

Sub Test1() Dim a() As String a = Split(«vremya ne zhdet») MsgBox a(0) & vbNewLine & a(1) & vbNewLine & a(2) End Sub

Результат в MsgBox:

vremya
ne
zhdet

В первом примере используются Delimiter и Limit по-умолчанию.

---

Пример 2

Sub Test2() Dim a() As String a = Split(«vremya-ne-zhdet»,«-«, 2) MsgBox a(0) & vbNewLine & a(1) End Sub

Результат в MsgBox:

vremya
ne-zhdet

Во втором примере Delimiter = «-«, а Limit = 2.

---

Для присваивания результатов функции Split используется предварительно объявленный текстовый динамический массив, который можно использовать в строке присваивания с пустыми скобками или без них. В представленных выше примерах массив указан без скобок.

Вы можете скопировать коды из приведенных примеров в модуль VBA своей рабочей книги Excel, посмотреть, как они работают. Поэкспериментируйте, подставляя свои данные, чтобы на практике ознакомиться с возможностями функции Split.

VBA Split Function

The VBA Split function splits a string of text into substrings based on a specific delimiter character (e.g. a comma, space, or a colon). It is easier to use than writing code to search for the delimiters in the string and then extracting the values.

It could be used if you are reading in a line from a Comma-Separated Value (CSV file) or you have a mailing address that is all on one line, but you want to see it as multiple lines.

The syntax is:

Split expression, delimiter[optional], limit[optional], compare[optional]

The VBA Split function has four parameters:

• Expression – The string of text that you wish to split into different parts.
• Delimiter (optional)– string or non-printable character – Defines the delimiter character that is going to be used for the split. If no delimiter character is provided then the default of a space is used.
• Limit (optional) – number – Defines how many splits will be made. If blank, all available splits will be made within the string. If it is set to 1, then no splits will be made.  Basically, it enables you to separate out a specific number of values starting at the beginning of the string e.g. where the string is very long and you only need the first three splits.
• Compare (optional) – If your delimiter is a text character then this is used to toggle whether the delimiter is case-sensitive or not. Values are vbBinaryCompare ( case-senstiive) and vbTextCompare (not-case sensitive).

The split function always returns an array.

Simple Example of the Split Function

Sub SplitExample()
'Define variables
Dim MyArray() As String, MyString As String, I As Variant
'Sample string with space delimiters
MyString = "One Two Three Four"
'Use Split function to divide up the component parts of the string
MyArray = Split(MyString)
'iterate through the array created to show each value
For Each I In MyArray
    MsgBox I
Next I
End Sub

In this example, no delimiter is specified because all the words have a space in between them, so the default delimiter (space) can be used.

The array has no dimensions, and is set as a string. The variable I, which is used in the For…Next loop must be dimensioned as a variant.

When this code is run, it will show four message boxes, one for each of the splits e.g. One, Two, Three. Four.

Note that if there is a double space between the words in the string, this will be evaluated as a split, although with nothing in it. This may not be the result that you want to see.

You can fix this problem by using the Replace function to replace any double spaces with a single space:

MyString = Replace(MyString, "  ", " ")

A trailing or leading space can also cause problems by producing an empty split.  These are often very difficult to see. You can remove these extraneous spaces by using the Trim Function:

MyString = Trim(MyString)

Using the Split Function with a Delimiter Character

We can use a delimiter of a semi-colon (;). This is frequently found in email address strings to separate the addresses. You may have an email sent to you which is shared with a number of colleagues and you want to see a list in your worksheet of who it has gone to. You can easily copy the email addresses from the email ‘To’ or ‘Copy’ boxes and into your code.

Sub SplitBySemicolonExample()
'Define variables
Dim MyArray() As String, MyString As String, I As Variant, N As Integer
'Sample string with semi colon delimiters
MyString = "john@myco.com;jane@myco.com;bill@myco.com;james@myco.com"
'Use Split function to divide up the component parts of the string
MyArray = Split(MyString, ";")
'Clear the worksheet
ActiveSheet.UsedRange.Clear
'iterate through the array
For N = 0 To UBound(MyArray)
'Place each email address into the first column of the worksheet
    Range("A" & N + 1).Value = MyArray(N)
Next N
End Sub

Note that a For…Next loop is used to iterate through the array. The first element in the array always starts at zero, and the Upper Bound Function is used to get the maximum number of elements.

After running this code, your worksheet will look like this:

Using a Limit Parameter in a Split Function

The limit parameter allows a specific number of splits to be done from the start of the string.  Unfortunately, you cannot provide a start position or a range of splits to be done, so it is fairly basic. You can build your own VBA code to create a function to do this, and this will be explained later in this article.

Sub SplitWithLimitExample()
'Create variables
Dim MyArray() As String, MyString As String, I As Variant, N As Integer
'Sample string with comma delimiters
MyString = "One,Two,Three,Four,Five,Six"
'Use Split function to divide up the component parts of the string
MyArray = Split(MyString, ",", 4)
'Clear the worksheet
ActiveSheet.UsedRange.Clear
'Iterate through the array
For N = 0 To UBound(MyArray)
    'Place each split into the first column of the worksheet
    Range("A" & N + 1).Value = MyArray(N)
Next N
End Sub

After you run this code, your worksheet will look like this:

Only the first three split values are shown separately. The later three values are shown as one long string and do not get split.

If you choose a limit value that is greater than the number of delimiters within a string, this will not produce an error.  The string will be split into all its component parts as if the limit value had not been provided.

Using the Compare Parameter in a Split Function

The Compare parameter determines if the delimiter is case-sensitive or not. This is not applicable if the delimiters are commas, semi-colons, or colons.

Note: Instead, you can always place Option Compare Text at the top of your module to eliminate case-sensitivity for the entire module.

Sub SplitByCompareExample()
'Create variables
Dim MyArray() As String, MyString As String, I As Variant, N As Integer
'Sample string with X delimiters
MyString = "OneXTwoXThreexFourXFivexSix"
'Use Split function to divide up the component parts of the string
MyArray = Split(MyString, "X", , vbBinaryCompare)
'Clear the worksheet
ActiveSheet.UsedRange.Clear
'iterate through the array
For N = 0 To UBound(MyArray)
    'Place each split into the first column of the worksheet
    Range("A" & N + 1).Value = MyArray(N)
Next N
End Sub

In this example, the string to be split uses the ‘X’ character as a delimiter. However, in this string, there is a mixture of upper and lower case ‘X’ characters. The Compare parameter in the Split function uses an upper case ‘X’ character.

If the Compare parameter is set to vbBinaryCompare, then the lower case ‘x’ characters will be ignored and your worksheet will look like this:

If the Compare parameter is set to vbTextCompare, then the lower case ‘x’ characters will be used in the split and your worksheet will look like this:

Note that the value at cell A6 is truncated because it contains a lower case ‘x’ character. Because the split is not case sensitive, any delimiter which forms part of a sub string will cause a split to happen.

This is an important point to bear in mind when using a text delimiter and vbTextCompare. You can easily end up with the wrong result.

Using Non-Printable Characters as the Delimiter Character

You can use non printable characters as the delimiter, such as a carriage return (a line break).

Here we use the vbCr to specify a carriage return.

Sub SplitByNonPrintableExample()
'Create variables
Dim MyArray() As String, MyString As String, I As Variant, N As Integer
'Sample string with carriage return delimiters
MyString = "One" & vbCr & "Two" & vbCr & "Three" & vbCr & "Four" & vbCr & "Five" & vbCr & "Six"
'Use Split function to divide up the component parts of the string
MyArray = Split(MyString, vbCr, , vbTextCompare)
'Clear the worksheet
ActiveSheet.UsedRange.Clear
'Iterate through the array
For N = 0 To UBound(MyArray)
    'Place each split into the first column of the worksheet
    Range("A" & N + 1).Value = MyArray(N)
Next N
End Sub

In this example, a string is built up using vbCr (carriage return character) as the delimiter.

When this code is run, your worksheet will look like this:

VBA Coding Made Easy

Stop searching for VBA code online. Learn more about AutoMacro — A VBA Code Builder that allows beginners to code procedures from scratch with minimal coding knowledge and with many time-saving features for all users!

Learn More

Using the Join Function to Reverse a Split

The Join function will re-join all the elements of an array, but using a specified delimiter. If no delimiter character is specified then a space will be used.

Sub JoinExample()
'Create variables
Dim MyArray() As String, MyString As String, I As Variant, N As Integer
Dim Target As String
'Sample string with comma delimiters
MyString = "One,Two,Three,Four,Five,Six"
'Place MyString at cell A1
Range("A1").Value = MyString
'Use Split function to divide up the component parts of the string
MyArray = Split(MyString, ",")
'Use Join function to re-create the original string using a semi colon delimiter
Target = Join(MyArray,”;”)
'Place the result string at cell A2
Range("A2").Value = Target
End Sub

This code splits a string with comma delimiters into an array, and joins it back together using semi-colon delimiters.

After running this code your worksheet will look like this:

Cell A1 has the original string with comma delimiters, and cell A2 has the new joined string with semi-colon delimiters.

Using the Split Function to do a Word Count

Bearing in mind that a string variable in Excel VBA can be up to 2Gb long, you can use the split function to do word count in a piece of text.  Obviously, Microsoft Word does it automatically, but this could be useful for a simple text file or text copied from another application.

Sub NumberOfWordsExample()
'Create variables
Dim MyArray() As String, MyString As String
'Sample string with space delimiters
MyString = "One Two Three Four Five Six"
'Remove any double spaces
MyString = Replace(MyString, "  ", " ")
'Remove any leading or trailing spaces
MyString = Trim(MyString)
'Use Split function to divide up the component parts of the string
MyArray = Split(MyString)
'Show number of words using the UBound function
MsgBox "Number of Words " & UBound(MyArray) + 1
End Sub

One of the dangers of this word count code is that it will be thrown by double spaces and leading and trailing spaces.  If these are present, they will be counted as extra words, and the word count will end up as inaccurate.

The code uses the Replace and Trim functions to remove these extra spaces.

The final code line displays the number of words found by using the UBound function to get the maximum element number of the array and then incrementing it by 1. This is because the first array element begins at zero.

Splitting an Address into Worksheet Cells

Mail addresses are often long strings of text with comma delimiters. You may well want to split each part of the address into a separate cell.

Sub AddressExample()
'Create variables
Dim MyArray() As String, MyString As String, N As Integer
'Set up string with Microsoft Corporation Address
MyString = "Microsoft Corporation, One Microsoft Way, Redmond, WA 98052-6399 USA"
'Use the split function to divide the string using a comma delimiter
MyArray = Split(MyString, ",")
'Clear the worksheet
ActiveSheet.UsedRange.Clear
'iterate through the array
For N = 0 To UBound(MyArray)
     'Place each split into the first column of the worksheet
    Range("A" & N + 1).Value = MyArray(N)
Next N
End Sub

Running this code will use the comma delimiter to put each line of the address into a separate cell:

If you only wanted to return the zip code (last array element), then you could use the code:

Sub AddressZipCodeExample()
'Create variables
Dim MyArray() As String, MyString As String, N As Integer, Temp As String
'Set up string with Microsoft Corporation Address
MyString = "Microsoft Corporation, One Microsoft Way, Redmond, WA 98052-6399 USA"
'Use the split function to divide the string using a comma delimiter
MyArray = Split(MyString, ",")
'Clear the worksheet
ActiveSheet.UsedRange.Clear
'Put the Zip Code at cell A1
Range("A1").Value = MyArray(UBound(MyArray))
End Sub

This will only use the last element in the array, which is found by using the UBound function.

On the other hand, you may wish to see all the lines in one cell so that they can be printed onto an address label:

Sub AddressExample()
'Create variables
Dim MyArray() As String, MyString As String, N As Integer, Temp As String
'Set up string with Microsoft Corporation Address
MyString = "Microsoft Corporation, One Microsoft Way, Redmond, WA 98052-6399 USA"
'Use the split function to divide the string using a comma delimiter
MyArray = Split(MyString, ",")
'Clear the worksheet
ActiveSheet.UsedRange.Clear
'iterate through the array
For N = 0 To UBound(MyArray)
     'place each array element plus a line feed character into a string
    Temp = Temp & MyArray(N) & vbLf
Next N
'Put the string onto the worksheet
Range("A1") = Temp
End Sub

This example works the same way as the earlier one, except that it creates a temporary string of all the array elements, but inserting a line feed character after each element.

The worksheet will look like this after the code has been run:

VBA Programming | Code Generator does work for you!

Split String into Worksheet Cells

You can copy the Split array into worksheet cells with just one command:

Sub CopyToRange()
'Create variables
Dim MyArray() As String, MyString As String
'Sample string with space delimiters
MyString = "One,Two,Three,Four,Five,Six"
'Use Split function to divide up the component parts of the string
MyArray = Split(MyString, ",")
'Copy the array into the worksheet
Range("A1:A" & UBound(MyArray) + 1).Value = WorksheetFunction.Transpose(MyArray)
End Sub

When this code has been run, your worksheet will look like this:

Creating a New Function to Allow Splitting from a Given Point

The Limit parameter in the Split function only allows you to specify an upper limit where you want the splitting to stop.  It always commences from the start of the string.

It would be very useful to have a similar function where you can specify the start point of the split within the string, and the number of splits that you want to see from that point onwards. It will also only extract the splits that you have specified into the array, rather than having an enormous string value as the last element in the array.

You can easily build a function (called SplitSlicer) yourself in VBA to do this:

Function SplitSlicer(Target As String, Del As String, Start As Integer, N As Integer)
'Create array variable
Dim MyArray() As String
'Capture the split using the start variable using the delimiter character
MyArray = Split(Target, Del, Start)
‘Check if the start parameter is greater than the number of splits – this can cause problems
If Start > UBound(MyArray) + 1 Then
	‘Display error and exit the function
    MsgBox "Start parameter is greater than number of splits available"
    SplitSlicer = MyArray
    Exit Function
End If
'Put the last array element into the string
Target = MyArray(UBound(MyArray))
    'Split the string using N as the limit
 MyArray = Split(Target, Del, N)
‘Check that the top limit is greater than zero as the code removes the last element
If UBound(MyArray) > 0 Then
'Use ReDim to remove the final element of the array
ReDim Preserve MyArray(UBound(MyArray) - 1)
End If
'Return the new array
SplitSlicer = MyArray
End Function

This function is built with four parameters:

• Target – string – this is the input string that you want to split
• Del – string or non-printable character – this is the delimiter character that you use e.g. comma, colon
• Start – number – this is the start split for your slice
• N – number – this is the number of splits that you want to do within your slice

None of these parameters are optional or have default values, but you can work that into the code for the function if you wish to extend it further.

The function uses the Split function to create an array using the Start parameter as the Limit.  This means that the array elements will hold the splits up to the start parameter, but the remainder of the string will be the last element, and will not be split.

The last element in the array is transferred back to a string using the UBound function to determine which element this is.

The string is then split again into the array, using N as the limit variable.  This means that splits will be done for the string up to position N, after which the rest of the string will form the last element in the array.

The ReDim statement is used to remove the last element as we only want the specific elements left in the array.  Note that the Preserve parameter is used, otherwise all data in the array will be lost.

The new array is then returned to the code that it was called from.

Note that the code is ‘error proofed’.  Users will often do strange things that you did not consider.  For example, if they try using the function with the Start or N parameter greater than the available number of splits in the string, this is likely to cause the function to fail.

Code is included to check the Start value, and also to make sure that there is an element that can be removed when the ReDim statement is used on the array.

Here is the code to test the function:

Sub TestSplitSlicer()
'Create variables
Dim MyArray() As String, MyString As String
'Define sample string with comma delimiters
MyString = "One,Two,Three,Four,Five,Six,Seven,Eight,Nine,Ten"
'Use the Splitslicer function to define new array
MyArray = SplitSlicer(MyString, ",", 4, 3)
'Clear the active sheet
ActiveSheet.UsedRange.Clear
'Copy the array into the worksheet
Range("A1:A" & UBound(MyArray) + 1).Value = WorksheetFunction.Transpose(MyArray)
End Sub

Run this code and your worksheet will look like this:

Introduction

The VBA Split Function is used is to split a string of text into an array. The text is split based on a given delimiter – e.g. a comma, space, colon etc.

For example, imagine we have the following string:

“Apple:Orange:Pear:Plum”

You can see that each item separated by the colon sign. We call the colon sign the delimiter.

We can split this string into an array:

' https://excelmacromastery.com/
Sub SplitBasic()

    Dim arr() As String
    arr = Split("John:Jane:Paul:Sophie", ":")

End Sub

Once it is in an array it is easy to access each item:

Glossary

Array – a structure for storing a group of similar variables.

Ubound – this function gives the last position of an array.

Lbound – this function gives the first position of an array. For an array, returned by the Split function, the first position is zero.

Instr – this function is used to search for a string within a string and return the position.

InStrRev – the same as Instr but searches a string from the end.

Split Syntax

Split expression, delimiter[optional], limit[optional], compare[optional]

Split Return Value

The Split function returns an array.

 Split Function Parameters

expression – this is the text string that is to be split.

delimiter [optional] – the character delimiter used in the string to separate each item. If you don’t use this parameter then VBA uses space as the delimiter.

limit [optional] – this allows us to set the number of items in the result. If we use 1 as the limit then no split takes place and the full string is returned.

compare [optional] – if we are using letters as the delimiter then this determines if we take the case of letters into consideration.

VBA Split – Simple Example

The following code shows an example of using the Split function and printing the result to the Immediate Window:

' https://excelmacromastery.com/
Sub VBA_Split_Print()

    Dim arr() As String
    ' Split the string to an array
    arr = Split("John:Jane:Paul:Sophie", ":")

    ' Print each item in the array to the Immediate Window(Ctrl + G)
    Dim name As Variant
    For Each name In arr
        Debug.Print name
    Next

End Sub

Output
John
Jane
Paul
Sophie

When we split the string into an array we have an item in each position in the array. This means we can easily access any item using the array position:

' https://excelmacromastery.com/
Sub VBA_Split_PrintArr()

    Dim arr() As String
    ' Split the string to an array
    arr = Split("John:Jane:Paul:Sophie", ":")

    Debug.Print arr(0) ' Print John
    Debug.Print arr(1) ' Print Jane
    Debug.Print arr(2) ' Print Paul
    Debug.Print arr(3) ' Print Sophie

End Sub

Split returns an array that starts at position zero. If we want to use a For statement to read through the array we can use LBound and UBound to give us the first and last positions of the array:

' https://excelmacromastery.com/
Sub VBA_Split_Print()

    Dim arr() As String
    ' Split the string to an array
    arr = Split("John:Jane:Paul:Sophie", ":")

    ' Print each item in the array to the Immediate Window(Ctrl + G)
    Dim i As Long
    For i = LBound(arr) To UBound(arr)
        Debug.Print arr(i)
    Next

End Sub

Split Limit Parameter

The Limit parameter is used to determine how items are placed in the array. In other words, how many items is the original string split into.

The table below shows the results of using different limits this sample string:

String	Limit	Result
«John:Jane:Paul:Sophie»	1	John:Jane:Paul:Sophie
«John:Jane:Paul:Sophie»	2	John Jane:Paul:Sophie
«John:Jane:Paul:Sophie»	3	John Jane Paul:Sophie
«John:Jane:Paul:Sophie»	4	John Jane Paul Sophie

You can try out the code for yourself:

' https://excelmacromastery.com/
Sub VBA_Split_Limit()

    Dim arr() As String
    ' Split the string to an array
    arr = Split("John:Jane:Paul:Sophie", ":", 1)

    ' Print each item in the array to the Immediate Window(Ctrl + G)
    Dim name As Variant
    For Each name In arr
        Debug.Print name
    Next

End Sub

Split Compare Parameter

The Compare parameter is used for delimiters that are made up of one or letters.

For example, imagine we want to use the letter x as a delimiter in the following string:

“12x34X45x”

1. If we want to split by x when lower case only – then we use vbBinaryCompare.
2. If we want to split by upper or lower case x – then we use vbTextCompare.
3. vbUseCompareOption is the default and tells split to use the module Compare settings. Read more about the module compare settings here.

The following code shows how we use the Compare parameter:

' https://excelmacromastery.com/
Sub VBA_Split_Compare()

    Dim arr() As String
    ' Split the string to an array - not case sensitive
    arr = Split("12x34X45", "x", , vbTextCompare)

    ' Print each item in the array to the Immediate Window(Ctrl + G)
    Dim name As Variant
    For Each name In arr
        Debug.Print name
    Next

End Sub

The following table shows the results from the different Compare arguments:

String	Delimiter	Compare Type	Result
«12x34X45»	x	vbCompareText	12 34 45
«12x34X45»	x	vbCompareBinary	12 34X45

Reversing Split

We can use the Join function to do the opposite of what the split function does. Join converts an array into a string and adds a given delimiter.

This can be useful as sometimes we may want to split a string, update one or more values in the array and then convert the array to a string.

This example shows how to use Join:

' https://excelmacromastery.com/
Sub UsingJoin()

    Dim arr As Variant
    
    ' create an array using the array function
    arr = Array("Apple", "Orange", "Pear")
    
    Dim s As String
    ' Covert the array to a string using the colon delimiter
    s = Join(arr, ":")
    
    ' Print the string to the Immediate Window(Ctrl + G)
    Debug.Print s

End Sub

See the section “Split Example – Using Join” for an example of using the Join function with the Split function.

Split Example – Names

A really great example of Split is when dealing with names.

Imagine we have the name “John Henry Smith” and we want to extract each name.

We can use Left and Instr to get the first name:

' https://excelmacromastery.com/
Sub Instr_Firstname()
    
    Dim s As String
    s = "John Henry Smith"
    
    ' Get the position of the first space
    Dim position As Long
    position = InStr(s, " ") - 1

    ' Prints John
    Debug.Print Left(s, position)

End Sub

To get the last name is a bit trickier:

' https://excelmacromastery.com/
Sub Instr_Lastname()
    
    Dim s As String
    s = "John Henry Smith"
    
    ' Get the position of the last space
    Dim position As Long, length As Long
    position = InStrRev(s, " ") - 1
    length = Len(s)
    
    ' Prints Smith
    Debug.Print Right(s, length - position)

End Sub

Getting names that are not in the first or last position gets very messy indeed. However,  using Split we can simplify the whole process:

' https://excelmacromastery.com/
Sub SplitName()

    Dim s As String: s = "John Henry Smith"
    
    Dim arr() As String
    
    arr = Split(s, " ")
    Debug.Print arr(0) ' John
    Debug.Print arr(1) ' Henry
    Debug.Print arr(2) ' Smith

End Sub

We actually don’t need to use an array as we can see in the next example. It is not efficient to call the Split function 3 times instead of 1 but it does look nice in this example:

' https://excelmacromastery.com/
Sub SplitName()

    Dim s As String: s = "John Henry Smith"
    
    Debug.Print Split(s, " ")(0) ' John
    Debug.Print Split(s, " ")(1) ' Henry
    Debug.Print Split(s, " ")(2) ' Smith

End Sub

Split Example – Filenames

In the next example we use Split to get the extension part of a filename:

' https://excelmacromastery.com/
Sub GetFileExt()

    ' Create an array of filenames for our test
    Dim myFiles As Variant
    myFiles = Array("my resume.xlsx", "myresume2.doc", "my resume latest ver.pdf")

    Dim file As Variant, arr() As String
    ' Read through the filenames
    For Each file In myFiles
        ' Split by the period
        arr = Split(file, ".")
        ' Use Ubound to get the last position in the array
        Debug.Print arr(UBound(arr))
    Next file

End Sub

Here is an interesting one you can try for yourself. Given a full file name, try to write code to extract the filename without the extension or folder.

For example for “C:MyDocsJanMyResume.Doc” we want to extract MyResume.

' https://excelmacromastery.com/
Sub GetFilenamePart()

    ' Create an array of filenames for our test
    Dim myFiles As Variant
    myFiles = Array("C:MyDocsJanMyResume.Doc" _
                , "C:MyMusicSongslovesong.mp3" _
                , "D:MyGamesGamesSavedsavedbattle.sav")

    Dim file As Variant, arr() As String
    ' Read through the filenames
    For Each file In myFiles
        
        ' Split by the period
        arr = Split(file, ".")
        
        ' Split by the folder separator /
        arr = Split(arr(0), Application.PathSeparator)
        
        Debug.Print arr(UBound(arr))
    
    Next file

End Sub

Output

MyResume
lovesong
savedbattle

Split Example – Copy to a Range

Because the result of Split is an array, we easily copy it to a range.

' https://excelmacromastery.com/
Sub VBA_Split_Range()

    Dim s As String
    s = "001,John Smith,New York,067435334"
    
    ' write the values to cells A1 to D1
    Sheet1.Range("A1:D1").Value = Split(s, ",")
    
    ' write the values to cells A1 to A4
    Sheet1.Range("A1:A4").Value = WorksheetFunction.Transpose(Split(s, ","))

End Sub

Split Example – Count Items

If we want to count the number of items in a delimited string we can use Split to do this for us.

We simply split the string and then use the Ubound function to give us back the number of items. We saw already that UBound is used to give us back the last position in an array. Because, the array start at zero, we need to add one to get the number of items.

' https://excelmacromastery.com/
Sub Split_Count()
    
    Dim s As String
    s = "Apple,Orange,Mango,Peach,Plum,Banana,Pear"

    Debug.Print "number of items:" & UBound(Split(s, ",")) + 1

End Sub

Split Example – Using Join

This is an interesting one that you may want to try yourself. Take the three strings below:

123.3456.96.345
1234.1156.7.345
1273.9998.123.345

We want to add one to the third number in each string. For example, the first string should become  123.3456.97.345.

Before you try yourself, I will give one hint. You can use the Join function to reverse the Split operation. It takes a array and delimiter and creates a string.

You can start with this code:

' https://excelmacromastery.com/
Sub UpdateNumber()

    ' Create an array of number for our test
    Dim myNums As Variant
    myNums = Array("123.3456.99.345" _
                , "1234.1156.7.98" _
                , "1273.9998.123.3235")

    ' Read through the strings
    Dim i As Long, arr() As String
    For i = LBound(myNums) To UBound(myNums)
        
        ' add your code here

    Next i
    
    ' Print the updated array to the Immediate Window(Ctrl+G)
    Debug.Print vbNewLine & "Printing new array"
    For i = LBound(myNums) To UBound(myNums)
        Debug.Print myNums(i)
    Next i

End Sub

This is how to do it:

' https://excelmacromastery.com/
Sub UpdateNumber()

    ' Create an array for our test
    Dim myNums As Variant
    myNums = Array("123.3456.99.345" _
                , "1234.1156.7.98" _
                , "1273.9998.123.3235")

    ' Read through the strings
    Dim i As Long, arr() As String
    For i = LBound(myNums) To UBound(myNums)
        
        ' Split the string to an array
        arr = Split(myNums(i), ".")
        
        ' Add one to the number
        arr(2) = arr(2) + 1
        
        ' convert the array back to a string
        myNums(i) = Join(arr, ".")

    Next i
    
    ' Print the updated array to the Immediate Window(Ctrl+G)
    Debug.Print vbNewLine & "Printing new array"
    For i = LBound(myNums) To UBound(myNums)
        Debug.Print myNums(i)
    Next i

End Sub

 Output

123.3456.100.345
1234.1156.8.345
1273.9998.124.345

Further Reading

The Ultimate Guide to VBA String Functions

Extracting using the Split function

VBA Arrays

VBA For Loop

Microsoft Docs – Split function

If you would like to see some real-world examples of using Split, you will find them in the post How to Easily Extract From Any String Without Using VBA InStr.

What’s Next?

Free VBA Tutorial If you are new to VBA or you want to sharpen your existing VBA skills then why not try out the The Ultimate VBA Tutorial.

Related Training: Get full access to the Excel VBA training webinars and all the tutorials.

(NOTE: Planning to build or manage a VBA Application? Learn how to build 10 Excel VBA applications from scratch.)

You can use Visual Basic for Applications (VBA), Microsoft’s programming language for the MS Office suite software, to greatly enhance the capability of Excel. You can write macros, or programs that can help you repeat previously performed tasks, using VBA. Macros can really improve your productivity and cut down on the time you spend doing things manually. This VBA tutorial gives some good examples of how you can use VBA to help automate things.

VBA is prebuilt into Microsoft Excel (and other office suite applications). To access VBA, you need to enable the developer tab first, if you haven’t already. Click on a spot on your ribbon (at the top) and choose the Customize the Ribbon option. By default, the Developer tab is unchecked. Enable it and click on Ok. A new tab should appear next to the View tab on top of your screen. This is the Developer tab, through which you can access VBA and Macros in general. The Developer tab lets you add VBA objects to your spreadsheet (you can check out this course to learn more about using VBA and Macros with Excel).

Like other programming languages, VBA lets you play around with strings and perform various operations on them. The split function is the function that lets you work with lengthy strings in Excel.If you’re new to VBA, or programming languages in general, and don’t know what strings are, we recommend you sign up for our Excel VBA beginner course for an introduction to the language.

The Excel VBA Split function was introduced in the year 2000, in response to a growing need to have a function that could handle large strings (for example, “John Harry David Smith” or “welcome to this tutorial”). The split function is used to split, or break, a string into manageable chunks.

If you’re familiar with Excel spreadsheets (if not, you can take a basic Excel course here), you know that sometimes parts of a long name get hidden – they can’t fit in the confines of a single cell. With the split function, what you can do is split the string into smaller parts and get them to occupy separate cells. For example, if you had a name “John Harry David Smith” and it was occupying cell A1, you can use the split function to separate the name and get it to occupy cells A1, B1, C1 and D1. Sounds useful, doesn’t it? Of course, this is just one of the uses of a split function.

VBA Split Syntax

What the split function does is split a string into an array and then returning that array. This array is one-dimensional. So how do you write a split function? The syntax for the split function is:

Split (string, delimiter, limit, compare)

Here, the string is the text you want to split. The “delimiter” will decide how the text will be split into parts. Usually, the space character “ “ occupies this part of the code. If you don’t define a delimiter, a space character “ “ will be used by default. The limit defines the number of the strings is allowed to divide into. By default, the limit is linked to the delimiter (default value of -1). This means that the delimiter part of the code will decide the number of parts the string gets divided into. The compare method lets you specify the method of comparison: binary (0) or text (1). You don’t have to specify the compare parameter either. By default, it will revert to binary (0).

Example 1

Let’s take a couple of examples to help you understand how the string function works. In the first example, let’s split the string “welcome to this tutorial” and print the words of the string separately (on a new line). The code for that is as follows:

Sub Example()
Dim text As String
Dim message As Variant
Dim a As Long
text = "welcome to this tutorial"
message = Split(text, " ")
For a = 0 To UBound(message)
Debug.Printmessage(a)
Next a
End Sub

Try running this code and see what happens. You will get the message “welcome to this tutorial” printed on 4 different lines.

So how does the code work exactly? First, we initialized text as a string variable, message as a variant variable and a as long variable. A variant variable is a necessity if you are working with the split function. It allows the string text to be treated as split-able. We followed the syntax and used the default delimiter “ “. Finally, we used a for loop to get the array printed on separate lines. 0 defines the starting position of the array and UBound defines the maximum (ending) position of the array.

Example 2

Now let’s write a program to separate a big name (John Harry David Smith) written on a single cell in Excel and get it printed on 4 different cells. Let’s write the name on cell A1 as in the image:

The code for  that is as follows:

Sub example()
Dim text As String
Dim a As Integer
Dim name As Variant
text = ActiveCell.Value
name = Split(text, " ")
For a = 0 To UBound(name)
Cells(1, a + 1).Value = name(a)
Next a
End Sub

The code in this example is similar to the code in the previous example. The ActiveCell.Value tells the computer to look for the active cell (A1) and get the string value written there. The split function is used exactly like we have in the previous example. The Cells(1, a + 1).Value part of the code accesses the first row (1) of the spreadsheet. The loop is used to run through the parts of the array and get the string separated and printed into different cells. The final result should look like this, once your run your code:

You can see how useful the split function is. You can also use the split function to omit unnecessary words or symbols (like the “.” character) from your string.

We recommend that you practice with the code we’ve given above to find out how to do that. Try to change the text entered and change the value of the delimiter, limit and compare parts of the split function syntax. Alternatively, you can sign up for our advanced Excel VBA course, where we teach you how to do that, and about using VBA efficiently in general.

When working with VBA in Excel, you may have a need to split a string into different parts based on a delimiter.

For example, if you have an address, you can use the VBA Split function to get different parts of the address that are separated by a comma (which would be the delimiter in this case).

SPLIT is an inbuilt string function in Excel VBA that you can use to split a text string based on the delimiter.

Excel VBA SPLIT Function – Syntax

Split ( Expression, [Delimiter], [Limit], [Compare] )

• Expression: This is the string that you want to split based on the delimiter. For example, in case of the address example, the entire address would be the ‘expression’. In case this is a zero-length string (“”) SPLIT function would return an empty array.
• Delimiter: This is an optional argument. This is the delimiter that is used to split the ‘Expression’ argument. In case of our address example, a comma is a delimiter that is used to split the address into different parts. If you don’t specify this argument, a space character is considered the default delimiter. In case you give a zero-length string (“”), the entire ‘Expression’ string is returned by the function.
• Limit: This is an optional argument. Here you specify the total number of substrings that you want to return. For example, if you only want to return the first three substrings from the ‘Expression’ argument, this would be 3. If you don’t specify this argument, the default is -1, which returns all the substrings.
• Compare: This is an optional argument. Here you specify the type of comparison you want the SPLIT function to perform when evaluating the substrings. The following options are available:
  • When Compare is 0: This is a Binary comparison. This means that if your delimiter is a text string (let’s say ABC), then this would be case-sensitive. ‘ABC’ would not be equal to ‘abc’.
  • When Compare is 1: This is a Text comparison. This means that if your delimiter is a text string (let’s say ABC), then even if you have ‘abc’ in the ‘Expression’ string, it would be considered as a delimiter.

Now that we have covered the basics of the SPLIT function, let’s see a few practical examples.

Example 1 – Split the Words in a Sentence

Suppose I have the text – “The Quick Brown Fox Jumps Over The Lazy Dog”.

I can use the SPLIT function to get each word of this sentence into as a separate item in an array.

The below code would to this:

Sub SplitWords()
Dim TextStrng As String
Dim Result() As String
TextStrng = "The Quick Brown Fox Jumps Over The Lazy Dog"
Result() = Split(TextStrng)
End Sub

While the code does nothing useful, it will help you understand what the Split function in VBA does.

Split function splits the text string and assigns each word to the Result array.

So in this case:

• Result(0) stores the value “The”
• Result(1) stores the value “Quick”
• Result(2) stores the value “Brown” and so on.

In this example, we have only specified the first argument – which is the text to be split. Since no delimiter has been specified, it takes space character as the default delimiter.

Example 2 – Count the Number of Words in a Sentence

You can use the SPLIT function to get the total number of words in a sentence. The trick here is to count the number of elements in the array that you get when you split the text.

The below code would show a message box with the word count:

Sub WordCount()
Dim TextStrng As String
Dim WordCount As Integer
Dim Result() As String
TextStrng = "The Quick Brown Fox Jumps Over The Lazy Dog"
Result = Split(TextStrng)
WordCount = UBound(Result()) + 1
MsgBox "The Word Count is " & WordCount
End Sub

In this case, the UBound function tells us the upper bound of the array (i.e., the maximum number of elements the array has). Since the base of the array is 0, 1 is added to get the total word count.

You can use a similar code to create a custom function in VBA that will take the text as input and return the word count.

The below code will create this function:

Function WordCount(CellRef As Range)
Dim TextStrng As String
Dim Result() As String
Result = Split(WorksheetFunction.Trim(CellRef.Text), " ")
WordCount = UBound(Result()) + 1
End Function

Once created, you can use the WordCount function just like any other regular function.

This function also handles leading, trailing and double spaces in between words. This has been made possible by using the TRIM function in the VBA code.

In case you want to learn more about how this formula works to count the number of words in a sentence or want to learn about a non-VBA formula way to get the word count, check out this tutorial.

Example 3 – Using a Delimiter Other than Space Character

In the previous two examples, we have only used one argument in the SPLIT function, and the rest were the default arguments.

When you use some other delimiter, you need to specify that in the SPLIT formula.

In the below code, the SPLIT function returns an array based on a comma as the delimiter, and then shows a message with each word in a separate line.

Sub CommaSeparator()
Dim TextStrng As String
Dim Result() As String
Dim DisplayText As String
TextStrng = "The,Quick,Brown,Fox,Jump,Over,The,Lazy,Dog"
Result = Split(TextStrng, ",")
For i = LBound(Result()) To UBound(Result())
DisplayText = DisplayText & Result(i) & vbNewLine
Next i
MsgBox DisplayText
End Sub

In the above code, I have used the For Next loop to go through each element of the ‘Result’ array assign it to the ‘DisplayText’ variable.

Example 4 – Divide an Address into three parts

With the SPLIT function, you can specify how many numbers of splits you want to get. For example, if I don’t specify anything, every instance of the delimiter would be used to split the string.

But if I specify 3 as the limit, then the string will be split into three parts only.

For example, if I have the following address:

2703 Winifred Way, Indianapolis, Indiana, 46204

I can use the Split function in VBA to divide this address into three parts.

It splits the first two based on the comma delimiter and remaining part becomes the third element of the array.

The below code would show the address in three different lines in a message box:

Sub CommaSeparator()
Dim TextStrng As String
Dim Result() As String
Dim DisplayText As String
TextStrng = "2703 Winifred Way, Indianapolis, Indiana, 46204"
Result = Split(TextStrng, ",", 3)
For i = LBound(Result()) To UBound(Result())
DisplayText = DisplayText & Result(i) & vbNewLine
Next i
MsgBox DisplayText
End Sub

One of the practical uses of this could be when you want to divide a single line address into the format shown in the message box. Then you can create a custom function that returns the address divided into three parts (with each part in a new line).

The following code would do this:

Function ThreePartAddress(cellRef As Range)
Dim TextStrng As String
Dim Result() As String
Dim DisplayText As String
Result = Split(cellRef, ",", 3)
For i = LBound(Result()) To UBound(Result())
DisplayText = DisplayText & Trim(Result(i)) & vbNewLine
Next i
ThreePartAddress = Mid(DisplayText, 1, Len(DisplayText) - 1)
End Function

Once you have this code in the module, you can use the function (ThreePartAddress) in the workbook just like any other Excel function.

This function takes one argument – the cell reference that has the address.

Note that for the resulting address to appear in three different lines, you need to apply the wrap text format to the cells (it’s in the Home tab in the Alignment group). If the ‘Wrap Text’ format is not enabled, you’ll see the entire address as one single line.

Example 5 – Get the City Name from the Address

With Split function in VBA, you can specify what part of the resulting array you want to use.

For example, suppose I am splitting the following address based on the comma as the delimiter:

2703 Winifred Way, Indianapolis, Indiana, 46204

The resulting array would look something as shown below:

{"2703 Winifred Way", "Indianapolis", "Indiana", "46204"}

Since this is an array, I can choose to display or return a specific part of this array.

Below is a code for a custom function, where you can specify a number and it will return that element from the array. For example, if I want the state name, I can specify 3 (as it’s the third element in the array).

Function ReturnNthElement(CellRef As Range, ElementNumber As Integer)
Dim Result() As String
Result = Split(CellRef, ",")
ReturnNthElement = Result(ElementNumber - 1)
End Function

The above function takes two arguments, the cell reference that has the address and the element number you want to return. The Split function splits the address elements and assigns it to the Result variable.

Then it returns the element number that you specified as the second argument. Note that since the base is 0, ElementNumber-1 is used to return the correct part of the address.

This custom formula is best suited when you have a consistent format in all the address – i.e., the city is always mentioned after the two commas. If the data is not consistent, you’ll not get the desired result.

In case you want the city name, you can use 2 as the second argument. In case you use a number that is higher than the total number of elements, it would return the #VALUE! error.

You can further simplify the code as shown below:

Function ReturnNthElement(CellRef As Range, ElementNumber As Integer)
ReturnNthElement = Split(CellRef, ",")(ElementNumber - 1)
End Function

In the above code, instead of using the Result variable, it only returns the specified element number.

So if you have Split(“Good Morning”)(0), it would only return the first element, which is “Good”.

Similarly, in the above code, it only returns the specified element number.

You May Also Like the Following Excel Tutorials:

• Excel VBA InStr Function – Explained with Examples.
• How to Sort Data in Excel using VBA (A Step-by-Step Guide).
• 7 Amazing Things Excel Text to Columns Can Do For You.
• How to Get the Word Count in Excel.
• VBA TRIM Function.

VBA Split function in Excel is categorizes as a Text/String function in VBA. It is a built-in function in MS Office Excel. It returns an array (one dimension )of sub strings based on a delimiter. It has one mandatory String parameter and three optional parameters.

VBA Split function use only in VBA function. We can’t use this function as an Excel worksheet function. The VBA Split function use in either procedure or function in a VBA editor window in Excel. We can use this VBA Split function any number of times in any number of procedures or functions. In the following section we learn what is the syntax and parameters of the Split function, where we can use this VBA Split function and real-time examples.

Table of Contents:

• Objective
• Syntax of VBA Split Function
• Parameters or Arguments
• Where we can apply or use the VBA Split Function?
• Example 1: Split the words in a statement using the space delimiter.
• Example 2: using the comma delimiter Split the Words in a statement
• Example 3: Split the Words in a statement using the semicolon delimiter
• Example 4: Count the number of words in a statement
• Instructions to Run VBA Macro Code
• Other Useful Resources

The syntax of the VBA Split function is

Split( Expression, [Delimiter], [Limit], [Compare] )

Note: This Split function returns an array of sub-strings.

Parameters or Arguments

There is one mandatory parameters and three optional arguments for the Split Function.
Where
Expression: The Expression is a mandatory string type argument. We use to split string into sub-strings based on a delimiter. If the specified expression is an empty, the VBA split function returns an empty array.

Delimiter: The Delimiter is an optional parameter. We use to separates the expression into sub-strings. Space (“ ”)character is a default parameter.

Limit: The Limit is an optional parameter. It specifies the maximum number of sub-strings to be returned. Default value is ‘-1’.

Compare: The Compare is an optional parameter. It specifies the type of comparison to evaluate the sub-strings. This argument can have anyone of the following value.

VBA Constant	Value	Description
vbUseCompareOption	-1	Performs a comparison using the Option Compare statement.
vbBinaryCompare	0	performs a binary comparison
vbTextCompare	1	performs a text comparison
vbDatabaseCompare	2	performs a database comparison. It applies only in MS Access.

Where we can apply or use the VBA Split Function?

We can use this VBA Split function in MS Office 365, MS Excel 2016, MS Excel 2013, 2011, Excel 2010, Excel 2007, Excel 2003, Excel 2016 for Mac, Excel 2011 for Mac, Excel Online, Excel for iPhone, Excel for iPad, Excel for Android tablets and Excel for Android Mobiles.

Example 1: Split the words in a statement using the space delimiter.

Here is a simple example of the VBA SPLIT function. This below example macro splits the string into sub-string using the space delimiter.

'Split the words in a statement using the space delimiter
Sub VBA_Split_Function_Ex1()
    
    'Variable declaration
    Dim sInput As String
    Dim sOutput() As String
    
    sInput = "Welcome to VBAF1"
    
    sOutput() = Split(sInput, " ")
       
    MsgBox " The first array value is : " & sOutput(0), vbInformation, "VBA Split Function"
    MsgBox " The second array value is : " & sOutput(1), vbInformation, "VBA Split Function"
    MsgBox " The third array value is : " & sOutput(2), vbInformation, "VBA Split Function"
    
End Sub

Output: Here is the screen shot of the first example output.

Example 2: Split the Words in a statement using the comma delimiter

Here is a simple example of the VBA SPLIT function. This below example macro splits the string into sub-string using the comma delimiter.

'Split the Words in a statement using the comma delimiter
Sub VBA_Split_Function_Ex2()

    'Variable declaration
    Dim sInput As String
    Dim sOutput() As String
    
    sInput = "ABC,BCD,CDA"
    
    sOutput() = Split(sInput, ",")
       
    MsgBox " The first array value is : " & sOutput(0), vbInformation, "VBA Split Function"
    MsgBox " The second array value is : " & sOutput(1), vbInformation, "VBA Split Function"
    MsgBox " The third array value is : " & sOutput(2), vbInformation, "VBA Split Function"

End Sub

Output: Here is the screen shot of the second example output.

Example 3: Split the Words in a statement using the semicolon delimiter

Here is a simple example of the VBA SPLIT function. This below example macro splits the string into sub-string using the semicolon delimiter.

'Split the Words in a statement using the semicolon delimiter
Sub VBA_Split_Function_Ex3()

    'Variable declaration
    Dim sInput As String
    Dim sOutput() As String
    
    sInput = "111;222;333"
    
    sOutput() = Split(sInput, ";")
       
    MsgBox " The first array value is : " & sOutput(0), vbInformation, "VBA Split Function"
    MsgBox " The second array value is : " & sOutput(1), vbInformation, "VBA Split Function"
    MsgBox " The third array value is : " & sOutput(2), vbInformation, "VBA Split Function"
End Sub

Output: Here is the screen shot of the third example output.

Example 4: Count the number of words in a statement

Here is a simple example of the VBA SPLIT function. This below example counting number of words in a string. It uses the Ubound of an array.

'Count the number of words in a statement
Sub VBA_Split_Function_Ex4()

    'Variable declaration
    Dim sInput As String
    Dim sOutput() As String
    
    sInput = "Welcome to VBAF1"
    
    sOutput() = Split(sInput, " ")
       
    MsgBox "Number of words in a statement : " & UBound(sOutput) + 1, vbInformation, "VBA Split Function"
    
End Sub

Output: Here is the screen shot of the fourth example output.

Instructions to Run VBA Macro Code or Procedure:

You can refer the following link for the step by step instructions.

Instructions to run VBA Macro Code

Other Useful Resources:

Click on the following links of the useful resources. These helps to learn and gain more knowledge.

VBA Tutorial VBA Functions List VBA Arrays in Excel Blog

VBA Editor Keyboard Shortcut Keys List VBA Interview Questions & Answers