Value of address function excel

The ADDRESS function in Excel enables users to create a cell reference by providing the row and column numbers of a cell. The function is particularly useful when working with large datasets or creating dynamic formulas that need to reference different cells based on changing criteria.

The ADDRESS function returns a text string that identifies the cell’s location in a worksheet in relative, mixed, or absolute format. The return result can be either an A1 type or R1C1 style.

Syntax

The syntax of the ADDRESS function is as follows.

=ADDRESS(row_num, column_num, [abs_num], [a1], [sheet_text])

The ADDRESS function accepts five arguments out of which two are mandatory and the remaining are optional. Details of each argument are mentioned below for a thorough understanding.

Arguments:

‘row_num‘ -This is a required argument that specifies the row number of the cell of which we want to create a reference. It can be a direct value or a cell reference containing the value. The row number must be a positive integer.

‘column_num‘ – This is also a required argument that specifies the column number of the cell of which we want to create a reference. The column number must be a positive integer and it can either be a direct value or a cell reference containing the value.

‘abs_num‘ – This is an optional argument that specifies the type of reference that we want to create. Depending on the input value from 1 – 4, the return cell reference can be a relative, absolute, or combination reference.

The default value of the abs_num argument is 1 which refers to the absolute cell reference ($A$1). If abs_num is set to 2, the returned reference is a mixed reference with an absolute row and relative column (A$1). If the value of the abs_num is 3, the resulting cell reference is again a mixed reference with relative row and absolute column ($A1). Lastly, if the abs_num value is 4, the return cell reference is completely relative (A1).

‘a1‘ – This is another optional argument that specifies the reference style we want to use. It is a boolean argument where the default value is 1 or TRUE which indicates an A1 style reference (e.g., A1, B2, C3). If the value of the a1 argument is 0 or FALSE, the reference is returned in R1C1 style (e.g., R1C1, R2C3, R3C4) where R means row and C means column.

‘sheet_text – This last argument is also an optional argument that contains the worksheet name to be used as a reference. The default value of the argument is the current worksheet. If we wish to refer to an external worksheet, the input value of the sheet_text argument must be the sheet name enclosed in double quotes.

Important Characteristics of the ADDRESS Function

Some of the noteworthy features of the ADDRESS function are as follows.

• The resulting cell reference of the ADDRESS function is always a text string.
• If the value of the row_num or column_num argument is zero or negative, the ADDRESS function throws a #VALUE! error.
• When the value of the abs_num argument is anything other than 1-4, the function returns a #VALUE! error.

Examples of ADDRESS Function

ADDRESS function is a powerful tool used when dealing with several worksheets and large datasets. Using the examples mentioned below, let’s discover more applications of the said function.

Example 1 – Simple Use of ADDRESS Function

In this example, we will explore the various arguments of the ADDRESS function and its usage by providing examples with different input values. This will allow us to gain a comprehensive understanding of how to utilize each argument and achieve the intended result.

Each column in the example displays distinct input values for each argument, providing a clear visual representation of the various options available for customization of the ADDRESS function. To showcase the role of the optional arguments, we have set the row and column numbers to 2 (as shown in columns B and C) in all the examples. Row 2 and column 2 refer to cell B2. Let’s see what types of cell references we can get for B2 with and without ADDRESS function’s different optional arguments.

In the first example, the ADDRESS function is used with only the mandatory arguments. The row and column numbers are set to 2, and the remaining arguments will assume their default values. The resulting output is a simple absolute reference in A1 style, which denotes the second column ‘B’ with the second row 2, resulting in the output «$B$2».

In the next two examples, the ADDRESS function is used with the abs_num argument set to 2 and 3, respectively. As a result, a mixed cell reference is generated i.e. B2. In the fourth example, the abs_num argument is set to 4, resulting in a relative reference to the second row and second column, which is «B2». These examples showcase the versatility of the abs_num argument in customizing the type of cell reference generated by the ADDRESS function.

The next two examples will help us understand the usage of the a1 argument. The row and column numbers are set to 2. In both cases, the value of the a1 argument is 0. When the abs_num is set to 1, the function returns an absolute cell reference in R1C1 style whereas when it is set to 4, the function results in a relative cell reference in R1C1 style which is «R[2]C[2]».

The last example generates an absolute reference in A1 style that points to cell B2, with the added text string «ADDRESS Function» as the sheet name.

Now that we have covered the basic functionality of the ADDRESS function, let’s explore more examples where we combine it with other functions such as INDIRECT and MATCH. This will allow us to further enhance the flexibility and usefulness of the ADDRESS function in different contexts.

Example 2 – Finding Address of First Cell in Range

When dealing with large data, it is often a neat trick to determine the address of the first and the last cell of the range. The ADDRESS function can be used to get the cell reference pointing to the first and the last cell. To better understand how it works, we have a sample data set containing the country names, their capital, and their currency.

To get the address of the intended cells, we require input values of the first two arguments of the ADDRESS function which are row_num and column_num. We can use a combination of ROW, COLUMN, and MIN functions to get the values of the said arguments.

The ROW and COLUMN functions will return the row and column numbers from the given range. When wrapped in the MIN function, we will get the smallest row and column number. Let’s put the concept in Excel form. The formula used will be as follows.

=ROW(B4:D18)

Now that we have all the row numbers from the cell range, using the MIN function, we can fetch the smallest row number. The formula will be as follows.

=MIN(ROW(B4:D18))

Now that we have the first or smallest row number, we can use this as an input value for the first argument row_num. Using the same logic, we can find the first column number using the following formula.

=COLUMN(B4:D18)

Adding the MIN function to the above formula, we will have the smallest or the first column number in the cell range.

=MIN(COLUMN(B4:D18))

Now that we have both the input values, let’s compile the final formula.

=ADDRESS(MIN(ROW(B4:D18)),MIN(COLUMN(B4:D18)))

That’s how you get the address of the first cell from a cell range using the ADDRESS function.

Example 2.1 – Finding Address of Last Cell in Range

Using the same logic, we can also determine the address of the last cell from a cell range. The only difference would be that then we were trying to locate the smallest or the first row or column number for the first cell address, whereas, for the last cell address, we will locate the maximum or the last row and column number.

In Excel form, the function will look like this.

=ADDRESS(MAX(ROW(B4:D18)),MAX(COLUMN(B4:D18)))

Here, we have the reference of the last cell in A1 form. If we wish to get the desired cell reference in R1C1 style, we can set the value of the a1 argument to 0. The updated formula will be as follows.

=ADDRESS(MAX(ROW(B4:D18)),MAX(COLUMN(B4:D18)),1,0)

When dealing with large datasets, the R1C1 referencing is easier to understand. Try to find the first and last cell addresses on a bigger database while practicing.

Example 3 – Getting Cell Value with Given Row and Column

In this example, we have a dataset of random color names. By entering the row and column number, we want to extract the value from that cell. This can be helpful when we randomly wish to extract a value from a larger dataset.

The user can enter any row number and column number in cells G1 and G2, respectively. Using the ADDRESS function, combined with the INDIRECT function, we can pull out the value from the intended cell. The INDIRECT function will take the resulting text string from the ADDRESS function and return the value of the corresponding cell.

The formula used will be as follows.

=INDIRECT(ADDRESS(G1,G2))

This is an excellent way of also creating dynamic cell references and extracting data from large datasets. A similar result can also be achieved using INDEX and MATCH functions.

Now, what if instead of row and column numbers, the user wishes to determine the position of the largest value in a dataset? Let’s find out in the next example.

Example 4 – Extracting Cell Address with Highest Value

In this scenario, we have the data containing monthly sales made by each salesman. Usually, such datasets are large, and it is difficult to find the exact cell reference to the desired data. Here, we wish to find the highest sales done each month and pull out its exact cell reference.

To find the highest sales value in a month, we need to find the largest value in columns C. The formula used will be as follows.

=MAX(C3:C12)

Now that we have the highest sales value for January month. We can use the MATCH function to find the position of the highest value in that column. The formula used will be as follows.

=MATCH(MAX(C3:C12),C:C,0)

We now know that in January month, the highest sales value lies on row 11. We can now use the ADDRESS function to extract the exact cell reference using the return value of the MATCH function as the input value for row_num and stating column_num as per the month which will be 3 for January. The formula used will be as follows.

=ADDRESS(MATCH(MAX(C3:C12),C:C,0),3)

We now have the desired result. We can go a step ahead and extract the name of the salesperson who made the highest sales each month.

To get that information, instead of using the column_num for the month, we can use 2 as the input value for column_num and then wrap it in the INDIRECT function as we did in the above example. The formula used will be as follows.

=INDIRECT(ADDRESS(MATCH(MAX(C3:C12),C:C,0),2))

Using the same logic, we can also extract the cell address with the lowest value in a dataset.

Explore more useful ways to use the ADDRESS function in Excel, while we curate yet another intriguing Excel function for you.

This tutorial demonstrates how to use the ADDRESS Function in Excel and Google Sheets to return a cell address as text.

What is the ADDRESS Function?

The ADDRESS Function Returns a cell address as text.

Usually, in a spreadsheet, we provide a cell reference, and a value from that cell is returned. Instead, the ADDRESS Function builds the name of a cell.

The address can be relative or absolute, in A1 or R1C1 style, and may or may not include the sheet name.

ADDRESS – Basic Example

Let’s say that we want to build a reference to the cell in 4^th column and 1^st row, aka cell D1. We can use the layout pictured here:

Our formula in  A3 is simply

=ADDRESS(B1, B2)

Note: By default the ADDRESS Function returns an absolute cell reference. By updating an optional argument we can change the cell references from absolute to relative. Let’s review this and other inputs to the ADDRESS Function…

ADDRESS Function Syntax and Inputs:

=ADDRESS(row_num,column_num,abs_num,C1,sheet_text)

row_num – The row number for the reference. Example: 5 for row 5.

col_num – The column number for the reference. Example: 5 for Column E. You can not enter “E” for column E

abs_num –  [optional] A number representing if the reference should have absolute or relative row/column references. 1 for absolute. 2 for absolute row/relative column. 3 for relative row/absolute column. 4 for relative.

a1 –  [optional]. A number indicating whether to use standard (A1) cell reference format or R1C1 format. 1/TRUE for Standard (Default). 0/FALSE for R1C1.

sheet_text – [optional] The name of the worksheet to use. Defaults to current sheet.

ADDRESS with INDIRECT

We can combine ADDRESS with the INDIRECT Function. Consider this layout, where we have a list of items in column D.

We can generate a reference to D1 like so

=ADDRESS(B1, B2)
=$D$1

By putting the address function inside an INDIRECT function, we’ll be able to use the generated cell reference and use it in a practical way. The INDIRECT will take the reference of “$D$1” and use it to fetch the value from that cell.

=INDIRECT(ADDRESS(B1, B2)
=INDIRECT($D$1)
="Apple"

Note: While the above gives a good example of making the ADDRESS Function useful, it’s not a good formula to use normally. It required two functions, and because of the INDIRECT it will be volatile in nature. A better alternative would have been to use the INDEX Function like this:

=INDEX(1:1048576, B1, B2)

Address of Specific Value

Sometimes when you have a large list of items, you need to know the location of an item in the list. Consider this table of scores from students. We’ve gone ahead and calculated the min, median, and max values of these scores in cells E2:G2.

Let’s say we wanted to find these values. We have a two options:

• Filter our table for each of these items.
• Use the MATCH Function with ADDRESS. Remember that MATCH will return the relative position of a value within a range.

Our formula in E3 then is:

=ADDRESS(MATCH(E2, $B:$B, 0), 2)

We can copy this same formula across to G3, and only the E2 reference will change since it’s the only relative reference. Looking back at E3, the MATCH function was able to find the value of 98 in the 5^th row of column B. Our ADDRESS function then used this to build the full address of “$B$5”.

Translate Column Letters from Numbers

So far, all of the examples have returned an absolute reference. Let’s return a relative reference instead.

Below, in column B, we want to calculate the column letter corresponding to the column number in column A.

We will use the ADDRESS Function to return a reference on row 1 in relative format, and then we’ll remove the “1” from the text string so that we just have the letter(s) left. Consider in our table row 3, where our input is 13. Our formula in B3 is

=SUBSTITUTE(ADDRESS(1, A3, 4), "1", "")

Note that we’ve given the 3^rd argument within the ADDRESS function, which controls the relative vs. absolute referencing. The ADDRESS function will output “M1”, and then the SUBSTITUTE function removes the “1” so that we are left with just the “M”.

Find the Address of Named Ranges

In Excel, you can name range or ranges of cells, allowing you to simply refer to the named range instead of the cell reference.

Most named ranges are static, meaning they always refer to the same range. However, you can also create dynamic named ranges that change in size based on some formula(s).

With a dynamic named range, you might need to know the exact address that your named range is pointing to. We can do this with the ADDRESS Function.

In this example, we’ll look at how to define the address for our named range called “Grades”.

Let’s bring back our table from before:

To get the address of a range, you need to know the top left cell and the bottom left cell. The first part is easy enough to accomplish with the help of the ROW and COLUMN functions. Our formula in E1 can be

=ADDRESS(ROW(Grades), COLUMN(Grades))

The ROW Function returns the row of the first cell in our range (which will be 1), and the COLUMN will do the same similarly for the column (also 1).

This formula will get the bottom-right cell

=ADDRESS(ROWS(Grades)-ROW(Grades)+1, COLUMNS(Grades)-COLUMN(Grades)+1)

We used the ROWS and COLUMNS functions to calculate the height and width of the range. By subtracting the first row and column numbers, we calculate the last cell in the range

Finally, to put it all together into a single string, we can simply concatenate the values together with a colon in the middle. Formula in E3 can be

=E1 & ":" & E2

Note: While we were able to determine the address of the range, our ADDRESS function determined whether to list the references as relative or absolute. Your dynamic ranges will have relative references that this technique won’t pick up.

2^nd Note: This technique only works on a continuous names range. If you had a named range that was defined as something like this formula

=A1:B2, A5:B6

then the technique above would result in errors.

ADDRESS function in Google Sheets

The ADDRESS function works exactly the same in Google Sheets as in Excel.

Purpose 

Return value 

Usage notes 

=ADDRESS(1,1) // returns $A$1
=ADDRESS(1,1,4) // returns A1
=ADDRESS(100,26,4) // returns Z100
=ADDRESS(1,1,1,FALSE) // R1C1
=ADDRESS(1,1,4,TRUE,"Sheet1") // returns Sheet1!A1