Удалить пробелы в ячейках excel функция

Skip to content

Как удалить пробелы в ячейках Excel

Вы узнаете, как с помощью формул удалять начальные и конечные пробелы в ячейке, лишние интервалы между словами, избавляться от неразрывных пробелов и непечатаемых символов.

В чем самая большая проблема с пробелами? Часто они невидимы для человеческого глаза. Внимательный пользователь может иногда заметить пустой интервал, скрывающийся перед текстом, или несколько ненужных пустот между словами. Но нет никакого способа визуально обнаружить конечные пробелы, те, которые находятся вне поля зрения в конце ячеек.

  • Удаляем все пробелы при помощи «Найти и заменить»
  • Используем формулу СЖПРОБЕЛЫ
  • Удаление начальных и концевых пробелов формулой
  • Как убрать разрыв строки и непечатаемые символы
  • Формула для удаления неразрывных пробелов
  • Как найти и удалить непечатаемый символ
  • Как цифры с пробелами преобразовать в число
  • Считаем пробелы при помощи формулы
  • Простой способ удаления пробелов без формул.

Не было бы большой проблемы, если бы эти лишние интервалы просто существовали, но они могут повлиять на результаты ваших формул. Дело в том, что две ячейки, содержащие один и тот же текст с пробелами и без них, даже если это всего лишь один знак, считаются разными значениями. В результате вы можете ломать голову, пытаясь понять, почему очевидно правильная формула не может соответствовать двум, казалось бы, идентичным записям.

Теперь, когда вы полностью осознаете проблему, пришло время найти решение. Есть несколько способов удалить пробелы из строки, и это руководство поможет вам выбрать метод, наиболее подходящий для вашей конкретной задачи и типа данных, с которым вы работаете.

Как убрать пробелы в Excel при помощи «Найти и заменить»

Это более быстрый метод, который может быть полезен в следующих ситуациях:

  1. Удаление двойных интервалов.

Обратите внимание, что этот метод не рекомендуется использовать для удаления начальных или конечных пробелов, так как хотя бы один их них там все равно останется. 

Итак, найдем и заменим двойные интервалы независимо от их расположения.

Вот как это можно сделать:

  • Выделите ячейки, из которых вы хотите их удалить.
  • Перейдите на главное меню -> Найти и выбрать -> Заменить.(Также можно использовать сочетание клавиш — CTRL + H).
  • В диалоговом окне «Найти и заменить» введите:
    • Найти: Двойной пробел.
    • Заменить на: Одинарный.

Нажмите «Заменить все».

Обратите внимание, что если у вас есть три интервала между двумя словами, то теперь вы получите два (один будет удален). В таких случаях вы можете повторить эту операцию снова, чтобы удалить любые двойные пробелы, которые ещё могли остаться.

Недостатки этого метода вы видите сами: перед некоторыми из слов остался начальный пробел. Аналогично остались и конечные пробелы после текста, просто они не видны явно. Поэтому для текстовых выражений я не рекомендовал бы применение этого способа.

  1. Чтобы удалить все пробелы в тексте, выполните следующие действия:
  • Выделите нужные ячейки.
  • Перейдите в меню Главная -> Найти и выбрать -> Заменить. (Также можно использовать сочетание клавиш — CTRL + H).
  • В диалоговом окне «Найти и заменить» введите:

Найти: одинарный пробел.

Заменить на: оставьте это поле пустым.

  • Нажмите «Заменить все».

Это удалит все пробелы в выбранном диапазоне.  

Вряд ли стоит производить такие манипуляции с текстовыми данными, а вот для чисел вполне подойдет. Интервалы между разрядами часто возникают при импорте данных из других программ через .csv файл. Правда, на рисунке вы видите, что цифры все равно остались записаны в виде текста, но вид их стал более упорядоченным. Как превратить их в настоящие числа — поговорим далее отдельно.

Функция СЖПРОБЕЛЫ.

Если ваш набор данных содержит лишние пробелы, функция СЖПРОБЕЛЫ  может помочь вам удалить их все одним махом — ведущие, конечные и несколько промежуточных, оставив только один интервал между словами.

Стандартный синтаксис очень простой:

=СЖПРОБЕЛЫ(A2)

Где A2 — ячейка, из которой вы хотите удалить.

Как показано на следующем скриншоте, СЖПРОБЕЛЫ успешно удалила всё до и после текста, а также лишние интервалы в середине строки.

И теперь вам нужно только заменить значения в исходном столбце новыми. Самый простой способ сделать это — использовать Специальная вставка > Значения.

Формулы для удаления начальных и концевых пробелов.

В некоторых ситуациях вы можете вводить двойные или даже тройные интервалы между словами, чтобы ваши данные были более удобочитаемыми. Однако вам нужно избавиться от ведущих пробелов (находящихся в начале), например:

Как вы уже знаете, функция СЖПРОБЕЛЫ удаляет лишние интервалы в середине текстовых строк, чего мы в данном случае не хотим. Чтобы сохранить их нетронутыми, мы будем использовать немного более сложную конструкцию:

=ПСТР(A2;НАЙТИ(ПСТР(СЖПРОБЕЛЫ(A2);1;1);A2);ДЛСТР(A2))

Это выражение в начале вычисляет позицию первого знака в строке. Затем вы передаете это число другой функции ПСТР, чтобы она возвращала всю текстовую строку (длина строки рассчитывается с помощью ДЛСТР), начиная с позиции первого знака.

Вы видите, что все ведущие пробелы исчезли, хотя несколько интервалов между словами всё же остались.
В качестве последнего штриха замените исходный текст полученными значениями, как это было описано выше.

Если же нужно удалить только пробелы в конце каждой ячейки, то формула будет немного сложнее:

=ЛЕВСИМВ(A2;МАКС((ПСТР(A2&ПОВТОР(» «;99);СТРОКА(A2:A100);1)<>» «)*СТРОКА(A2:A100)))

И обратите снимание, что ее нужно вводить как формулу массива (с Ctrl+Shift+Enter). В столбце A выровнять по правому краю получилось плохо из-за разного количества концевых пробелов в каждой ячейке. В столбце B эта проблема решена, и можно красиво расположить текст.

Как удалить разрывы строк и непечатаемые символы

При импорте данных из внешних источников появляются не только лишние пробелы, но и различные непечатаемые символы, такие как возврат каретки, перевод строки, вертикальная или горизонтальная табуляция и т.д.

Функция СЖПРОБЕЛЫ может избавиться от пробелов, но не может устранить непечатаемые символы. Технически она предназначена для удаления только значения 32 в 7-битной системе ASCII , которое как раз и является кодом пробела.

Чтобы удалить ещё и непечатаемые символы в строке, используйте её в сочетании с функцией ПЕЧСИМВ (CLEAN в английской версии). Как следует из названия, ПЕЧСИМВ предназначена для очистки данных от ненужного «мусора» и умеет удалять любой из первых 32 непечатаемых символов в 7-битном наборе ASCII (значения от 0 до 31), включая разрыв строки (значение 10).

Предполагая, что очищаемые данные находятся в ячейке A2, формула будет следующей:

=СЖПРОБЕЛЫ(ПЕЧСИМВ(A2))

Практически всегда, когда при помощи приведенного выше выражения вы удаляете разрывы строки, то отдельные слова оказываются «склеенными» друг с другом. Вы можете исправить это, используя один из следующих способов:

  • Воспользуйтесь инструментом Excel «Заменить все»: в поле «Найти» введите возврат каретки, нажав сочетание клавиш Ctrl + J. И в поле «Заменить» введите пробел. При нажатии кнопки «Заменить все» все разрывы строк в выбранном диапазоне заменяются пробелами.
  • Используйте следующую формулу для замены возврата каретки (код 13) и перевода строки (код 10) на пробелы:

=СЖПРОБЕЛЫ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A2; СИМВОЛ(13);» «); СИМВОЛ(10); » «))

Как видите, почтовый адрес в колонке С выглядит вполне читаемо.

Как убрать неразрывные пробелы в Excel?

Если после использования формулы СЖПРОБЕЛЫ и ПЕЧСИМВ некоторые упрямые знаки все еще остаются, то скорее всего, вы скопировали / вставили данные из интернета или из другой программы, и несколько неразрывных пробелов все же прокрались в вашу таблицу.

Чтобы избавиться от неразрывных пробелов (html-код &nbsp; ), замените их обычными, а затем попросите функцию СЖПРОБЕЛЫ удалить их:

=СЖПРОБЕЛЫ((ПОДСТАВИТЬ(A2;СИМВОЛ(160);» «)))

Чтобы лучше понять логику, давайте разберем формулу:

  • Неразрывный пробел имеет код 160 в 7-битной системе ASCII, поэтому вы можете определить его с помощью СИМВОЛ(160).
  • Функция ПОДСТАВИТЬ используется для превращения неразрывных пробелов в обычные.
  • И, наконец, вы вставляете ПОДСТАВИТЬ в СЖПРОБЕЛЫ, чтобы окончательно удалить всё лишнее.

Если ваш рабочий лист также содержит непечатаемые символы, дополнительно к описанному выше используйте ещё функцию ПЕЧСИМВ, чтобы избавиться от пробелов и других ненужных знаков одним махом:

=СЖПРОБЕЛЫ(ПЕЧСИМВ((ПОДСТАВИТЬ(A2;СИМВОЛ(160);» «))))

Следующий скриншот демонстрирует разницу в результатах:

Как удалить определенный непечатаемый символ

Если взаимодействие трех функций, описанных в приведенном выше примере, не смогло устранить весь мусор из текста, то это означает, что оставшиеся знаки имеют значения ASCII, отличные от 0 до 32 (непечатаемые символы) или 160 (неразрывный пробел).

В этом случае используйте функцию КОДСИМВ, чтобы сначала идентифицировать код мешающего вам знака, а затем используйте ПОДСТАВИТЬ, чтобы заменить его обычным пробелом. А затем при помощи СЖПРОБЕЛЫ удалите его.

Предполагая, что нежелательные символы, от которых вы хотите избавиться, находятся в ячейке A2, вы пишете два выражения:

  1. В ячейке С2 определите код проблемного знака, используя одну из следующих функций:
    • Ведущий пробел или непечатаемый символ в начале строки:

=КОДСИМВ(ЛЕВСИМВ(A2;1))

  • Конечный пробел или непечатаемый символ в конце строки:

= КОДСИМВ(ПРАВСИМВ(A2;1))

  • Пробел или непечатаемый символ в середине строки, где n — позиция проблемного знака:

= КОДСИМВ(ПСТР(A2, n, 1)))

В этом примере у нас есть неизвестный знак в середине текста, в 11-й позиции, и мы определим его код:

=КОДСИМВ(ПСТР(A2;11;1))

Получаем значение 127 (см. скриншот ниже).

  1. В ячейке C3 вы заменяете СИМВОЛ(127) обычным пробелом (» «), а затем просто удаляете его:

=СЖПРОБЕЛЫ(ПОДСТАВИТЬ(A2;СИМВОЛ(127); » «))

Если ваши данные содержат несколько разных непечатаемых символов, а также неразрывные пробелы, вы можете вложить две или более функции ПОДСТАВИТЬ друг в друга для одновременного удаления всех нежелательных знаков:

=СЖПРОБЕЛЫ(ПЕЧСИМВ((ПОДСТАВИТЬ(ПОДСТАВИТЬ(A2;СИМВОЛ(127);» «);СИМВОЛ(160);» «))))

Результат должен выглядеть примерно так:

Эту универсальную формулу мы и использовали. Как видите, успешно.

Как удалить все пробелы

В некоторых ситуациях может потребоваться удалить абсолютно все пробелы в ячейке, включая те, что находятся между словами или числами. Например, если вы импортировали в вашу таблицу числовой столбец, в котором пробелы используются в качестве разделителей тысяч. Конечно, разделители разрядов упрощают чтение больших чисел, но они же препятствуют вычислению ваших формул. Такие разделители нужно создавать при помощи форматирования, а не вручную.

Чтобы удалить все пробелы одним махом, используйте ПОДСТАВИТЬ, как описано в предыдущем примере, с той лишь разницей, что вы заменяете знак пробела, возвращаемый при помощи СИМВОЛ(32), ничем («»):

=ПОДСТАВИТЬ(A2; СИМВОЛ(32); «»)

Или вы можете просто ввести его (» «) в формуле, например:

=ПОДСТАВИТЬ(A2; “ “; «»)

Результатом этого будет текст, состоящий из цифр. Если же в качестве результата вам нужны именно числа, добавьте перед формулой два знака “-“ (минус). Любая математическая операция автоматически превращает цифры в число. А дважды применив минус, то есть дважды умножив на минус 1, мы не изменим величину числа и его знак.

Как посчитать пробелы в Excel

Чтобы получить общее количество пробелов в ячейке, выполните следующие действия:

  • Вычислите всю длину строки с помощью функции ДЛСТР:  ДЛСТР (A2)
  • Замените все пробелы ничем: ПОДСТАВИТЬ(A2; » «; «»)
  • Вычислить длину строки без пробелов: ДЛСТР(ПОДСТАВИТЬ(A2; » «; «»))
  • Вычтите этот результат из первоначальной длины.

Предполагая, что исходная текстовая строка находится в ячейке A3, полная формула выглядит следующим образом:

=ДЛСТР(A3) — ДЛСТР(ПОДСТАВИТЬ(A3;» «;»»))

Чтобы узнать, сколько лишних пробелов в ячейке, получите длину текста без них, а затем вычтите ее из первоначальной длины:

=ДЛСТР(A3)-ДЛСТР(СЖПРОБЕЛЫ(A3))

На рисунке показаны обе формулы в действии:

Теперь, когда вы знаете, сколько пробелов содержит каждая ячейка, вы можете безопасно удалить лишние, используя функцию СЖПРОБЕЛЫ.

Простой способ удаления пробелов без формул.

Как вы уже знаете, лишние пробелы и другие нежелательные символы могут незаметно скрываться на ваших листах, особенно если вы импортируете данные из внешних источников. Вы также знаете, как удалять пробелы в Excel с помощью формул. Конечно, изучение нескольких формул – хорошее упражнение для оттачивания ваших навыков, но это может занять много времени.

Пользователи Excel, которые ценят свое время и ценят удобство, могут воспользоваться текстовыми инструментами, включенными в надстройку Ultimate Suite for Excel . Один из этих удобных инструментов позволяет удалять пробелы и непечатаемые символы одним нажатием кнопки.

После установки Ultimate Suite добавляет на ленту Excel несколько полезных кнопок, таких как «Удалить пробелы» , «Удалить символы» , «Преобразовать текст»  и многое другое.

Всякий раз, когда вы хотите удалить лишние пробелы в таблицах Excel, выполните следующие 4 быстрых шага:

  1. Выделите ячейки (диапазон, весь столбец или строку), в которых вы хотите удалить лишние пробелы.
  2. Нажмите кнопку «Trim Spaces» на вкладке «Ablebits Data».
  3. Выберите один или несколько вариантов:
    • Обрезать начальные и конечные пробелы.
    • Удалить лишние пробелы между словами, кроме одного.
    • Удалить неразрывные пробелы (&nbsp;)
    • Удалить лишние переносы строк до и после значений, между значениями оставить только один.
    • Удалить все переносы строк в ячейке.
  4. Нажмите кнопку «Trim» .

Готово! Все лишние пробелы удалены одним щелчком мыши:

Здесь мы вместе с лишними пробелами удалили еще и переводы строки, чтобы значения располагались в привычном виде, в одну строку.

Вот как можно быстро удалить пробелы в ячейках Excel. Если вам интересно изучить другие возможности работы с текстовыми значениями (и не только), вы можете загрузить

ознакомительную версию Ultimate Suite. Благодарю вас за чтение и с нетерпением жду встречи с вами в нашем блоге на следующей неделе!

Формула ЗАМЕНИТЬ и ПОДСТАВИТЬ для текста и чисел — В статье объясняется на примерах как работают функции Excel ЗАМЕНИТЬ (REPLACE в английской версии) и ПОДСТАВИТЬ (SUBSTITUTE по-английски). Мы покажем, как использовать функцию ЗАМЕНИТЬ с текстом, числами и датами, а также…
Как убрать пробелы в числах в Excel — Представляем 4 быстрых способа удалить лишние пробелы между цифрами в ячейках Excel. Вы можете использовать формулы, инструмент «Найти и заменить» или попробовать изменить формат ячейки. Когда вы вставляете данные из…
Функция СЖПРОБЕЛЫ — как пользоваться и примеры — Вы узнаете несколько быстрых и простых способов, чтобы удалить начальные, конечные и лишние пробелы между словами, а также почему функция Excel СЖПРОБЕЛЫ (TRIM в английской версии)  не работает и как…
Функция ПРАВСИМВ в Excel — примеры и советы. — В последних нескольких статьях мы обсуждали различные текстовые функции. Сегодня наше внимание сосредоточено на ПРАВСИМВ (RIGHT в английской версии), которая предназначена для возврата указанного количества символов из крайней правой части…
Функция ЛЕВСИМВ в Excel. Примеры использования и советы. — В руководстве показано, как использовать функцию ЛЕВСИМВ (LEFT) в Excel, чтобы получить подстроку из начала текстовой строки, извлечь текст перед определенным символом, заставить формулу возвращать число и многое другое. Среди…
5 примеров с функцией ДЛСТР в Excel. — Вы ищете формулу Excel для подсчета символов в ячейке? Если да, то вы, безусловно, попали на нужную страницу. В этом коротком руководстве вы узнаете, как использовать функцию ДЛСТР (LEN в английской версии)…
Как быстро сосчитать количество символов в ячейке Excel — В руководстве объясняется, как считать символы в Excel. Вы изучите формулы, позволяющие получить общее количество символов в диапазоне и подсчитывать только определенные символы в одной или нескольких ячейках. В нашем предыдущем…

Источник

Excel для Microsoft 365 Excel для Microsoft 365 для Mac Excel для Интернета Excel 2021 Excel 2021 для Mac Excel 2019 Excel 2019 для Mac Excel 2016 Excel 2016 для Mac Excel 2013 Excel 2010 Excel 2007 Excel для Mac 2011 Excel Starter 2010 Еще…Меньше

В этой статье описаны синтаксис формулы и использование функции СЖПРОБЕЛЫ в Microsoft Excel.

Описание

Удаляет из текста все пробелы, за исключением одиночных пробелов между словами. Функция СЖПРОБЕЛЫ используется для обработки текстов, полученных из других прикладных программ, если эти тексты могут содержать лишние пробелы.

Важно: Функция СЖПРОБЕЛЫ предназначена для удаления из текста знаков пробела 7-разрядного кода ASCII (значение 32). В наборе знаков Юникода существует дополнительный знак пробела, который называется знаком неразрывного пробела и имеет десятичное значение 160. Этот знак обычно используется на веб-страницах как сущность HTML &nbsp;. Сама по себе функция СЖПРОБЕЛЫ не удаляет этот знак неразрывного пробела. Пример обрезки обоих пробелов из текста см. в десяти лучших способах очистки данных.

Синтаксис

СЖПРОБЕЛЫ(текст)

Аргументы функции СЖПРОБЕЛЫ описаны ниже.

  • Текст    Обязательный. Текст, из которого удаляются пробелы.

Пример

Скопируйте образец данных из следующей таблицы и вставьте их в ячейку A1 нового листа Excel. Чтобы отобразить результаты формул, выделите их и нажмите клавишу F2, а затем — клавишу ВВОД. При необходимости измените ширину столбцов, чтобы видеть все данные.

Формула

Описание

Результат

=СЖПРОБЕЛЫ(» Доход за первый квартал «)

Удаляет начальные и конечные пробелы из текста в формуле («Доход за первый квартал»)

Доход за первый квартал

Нужна дополнительная помощь?

Источник

Четыре способа, как быстро удалить пробелы в Excel

​Смотрите также​ уберет все пробелы​ знака. Хочу удалить​Но, похоже avgust​При большем количестве​ другой таблице, и​ я тормознул, сам​ Len(cell) c1 =​, вставьте новый модуль​

Как удалить пробелы в Excel

​ и с помощью​ друг с другом.​ формат у ячейки)​ нажимаем кнопку «Найти​ сами разделили число​Как убрать​ выражениями.​ в ячейках Excel​В процессе работы с​ в строках, кроме​ пробелы командой «найти-заменить»,​ не ищет легких​

Способ 1: с помощью инструмента «Заменить»

​ пробелов слева операцию​ поле может служить​ с себя удивляюсь​ Mid(cell, i, 1)​ (меню​ формул. Для этого​ В арсенале Excel​Давайте рассмотрим способы избавления​ и заменить». Вставляем​ пробелом.​

  1. ​лишние пробелы в Excel​
  2. ​Кликните по выделению правой​ с текстовыми выражениями,​ любыми документами пользователь​ одиночных между словами.​ но Excel пробелы​
  3. ​ путей​ необходимо повторить с​
  4. ​ признаком, по которому​Хотя чего удивляться​ If c1 Like​Insert — Module​ в категории​ есть специальная функция​
  5. ​ от такого «мусора».​ скопированное в строку​
  6. ​Или, если в​
  7. ​, которые мешают работе​ кнопкой мыши.​

excel удалить пробелы

​ но что, если​ незаметно для себя​ И пробелы уберете,​ не находит, хотя​Пусть себе…​ той же формулой.​ я выберу нужную​ — читать не​ «[» & Eng​) и введите туда​Текстовые​ для этого –​

Способ 2: удаление пробелов между разрядами

​»Старый, но не устаревший»​ «Найти».​ числе стоит неразрывный​ фильтра, сортировке, сравнить​Выберите пункт «Формат ячеек».​ появилась потребность убрать​ может оставлять нежелательные​ и порядок в​ они есть. Я​smart_v16​KuklP​ информацию из одной​

  1. ​ умею​ & «]» Then​ его текст:​
  2. ​в Excel есть​СЖПРОБЕЛЫ (TRIM)​ трюк. Выделяем зачищаемый​В строке «Заменить» ничего​ пробел. Например, при​ списки, мешают посчитать​
  3. ​Появится соответствующее окно, в​ лишние одинарные пробелы​ пробелы между словами​ строках наведете.​
  4. ​ захожу в в​: Привет всем. Изучил​
  5. ​: Чепуха какая! То​ таблицы в другую.​
  6. ​Юрий М​
  7. ​ c2 = Mid(Rus,​Sub Apostrophe_Remove() For​ функция​

​из категории​ диапазон ячеек и​ не пишем, оставляем​ копировании данных из​

Способ 3: удаление путем форматирования текста

​ формуле, другое. Например,​ котором перейдите в​ в числовых выражениях,​ или числами. Существует​Если же это​ ячейку и удаляю​ внимательно вашу переписку,​ же, что сжпробелы:​Z​: Недавно был похожий​ InStr(1, Eng, c1),​ Each cell In​ПОДСТАВИТЬ (SUBSTITUTE)​Текстовые​ используем инструмент Заменить​ пустую. Нажимаем кнопку​ Word, перешел и​ нам нужно сравнить​ раздел «Числовой», расположенный​ которые зачастую устанавливаются​ множество способов исправления​ не так важно,​ эти пробелы руками,​ но ответ на​Sub www() Dim​

  1. ​: Хватит, как говорят,​ гость — тоже​ 1) cell.Value =​ Selection If Not​. У нее три​
  2. ​. Она удаляет из​ с вкладки Г​
  3. ​ «Заменить все». Нажимаем​
  4. ​ неразрывный пробел. В​ два списка, но​ во вкладке «Число».​ автоматически? В этом​
  5. ​ подобной ситуации. Рассмотрим​ то как уже​ а Excel их​ свой вопрос, я​
  6. ​ a As Range​

удалить пробелы в ячейках excel

​ пудрить мозги и​ утверждал, что​ Replace(cell, c1, c2)​ cell.HasFormula Then v​ обязательных аргумента:​ текста все пробелы,​лавная – Найти и​ кнопку «Закрыть». Остался​

Способ 4: с помощью специальной функции

​ Word часто пользуются​ лишние пробелы не​В правой части окна​ случае нам также​ их в статье.​ советовалось: выделяете столбце​ не находит. Почему?​ его не озвучивал​ For Each a​

  1. ​ изворачиваться — пример​Михаил С.​ End If Next​ = cell.Value cell.Clear​Текст в котором производим​
  2. ​ кроме одиночных пробелов​ выделить (Home –​ один пробел. Получилось​ неразрывными пробелами.​
  3. ​ дадут этого сделать​ снимите отметку с​ поможет инструмент «Заменить».​Перед началом отметим, что​ со своими данными-Ctrl+H.​
  4. ​Алексей матевосов (alexm)​ ещё не нашёл.​ In ActiveSheet.UsedRange.SpecialCells(2).Areas a​ заморочки в студию:​: Может быть тексте​ i Next cell​ cell.Formula = v​ замену​
  5. ​ между словами, т.е.​

удалить лишние пробелы excel

​ Find & Select​ так.​Убрать такие пробелы​ правильно. Поэтому лишние​ пункта «Разделитель групп​В таблице выделите область,​ сами пробелы бывают​ в поле Найти​: Существует два типа​ Прошу Гуру Экселя​

​ = Application.Trim(a) Next​

fb.ru

Как удалить лишние пробелы в Excel.

​ есть этакое, а​ ​ есть двойные пробелы,​​ End Sub​ End If Next​Старый текст – тот,​ мы получим на​ – Replace)​В Excel можно выделять​ в числах можно​ пробелы нужно убрать.​ разрядов».​ в которой находятся​ разные: между словами,​ пишите ДВА ПРОБЕЛА,​ пробелов с кодом​ помочь. Прикрепил файл.​ End Sub​ хочется такое, пытался/лась​ которые нужно оставить…​Теперь, если выделить на​
​ End Sub​ который заменяем​
​ выходе как раз​или жмем сочетание​ ячейки с лишними​ той же функцией.​ Но, иногда пробелы​
​Нажмите «ОК».​ ненужные пробелы.​ между числовыми выражениями​ в поле Заменить​ 32 и с​ И вот для​Выполняется один раз​ сделать так, но…​ Но​ листе диапазон и​​Теперь, если выделить на​​Новый текст – тот,​
​ то, что нужно:​ клавиш​ пробелами в момент​ В ячейке В6​ нужны, например -​После этого окно будет​​Находясь на главной странице​ или же в​ на: пусто (т.​ кодом 160.​ данных из ячейки​ для активного листа​
Как удалить пробел в Excel. ​avgust​avgust,​​ запустить наш макрос​
​ листе диапазон и​ на который заменяем​В некоторых случаях, однако,​Ctrl+H​ заполнения ячейки таблицы,​ написали такую формулу.​ неразрывный пробел. Какие​ закрыто, а между​ на панели инструментов,​ начале или конце​ е. ничего не​В вашем случае​
​ А1 формула СЖПРОБЕЛЫ​ и все меняется​: Это не заморочка,​молчит, примера не​ (​ запустить наш макрос​С ее помощью можно​ функция​
​.​ списка, бланка. Как​ =СЖПРОБЕЛЫ(A6)​ бывают пробелы, как​ числовыми значениями пропадут​ нажмите по кнопке​ ​ какого-либо значения. Соответственно,​ пишите, оставляете пустым).​​ пробелы между цифрами​
​ не применятся. Если​ на месте, лишние​ это перечень договоров​ показывает…​Alt+F8​ (​ легко избавиться от​СЖПРОБЕЛЫ (TRIM)​Изначально это окно было​ для этого настроить​Как удалить непечатаемые знаки​
​ их заменить, где​​ пробелы. Так что,​ «Найти и заменить»​​ для устранения каждого​ Можете и пять​
​ с кодом 160.​
​ руками удалить существующие​ пробелы убираются, хоть​ из 1С за​avgust​или вкладка​Alt+F8​ ошибок (замена «а»​может не помочь.​
​ задумано для оптовой​​ таблицу, смотрите в​​ в Excel​ применить, смотрите в​ если вся суть​ и выберите инструмент​​ типа существует свой​ пробелов написать, если​​Как удалить.​ пробелы и выставить​ какими кривыми руками​ большой период, номера​: Прошу прощения, вчера​Разработчик​или вкладка​ на «о»), лишних​ Иногда то, что​ замены одного текста​ статье «Как найти​
​.​ статье «Пробел в​ заключалось в форматировании,​ «Заменить».​ отдельный метод. Именно​​ в каждой ячейке​Выделить пробел в​ хоть 100 пробелов​ набиралось. Формулы не​ и даты заводились​ запостила вопрос без​– кнопка​
​Разработчик​ пробелов (замена их​ выглядит как пробел​ на другой по​ пробел в Excel».​Их тоже можно​ Excel».​ то этот метод​В появившемся окне на​
​ о них сейчас​ их столько. Самый​ ячейке, копировать.​ то всё будет​ тронет, только константы.​ вручную, соответственно, в​ примера.​Макросы​– кнопка​ на пустую строку​ – на самом​ принципу «найди Маша​Часто можно услышать​ занести в таблицу​Как убрать лишние пробелы​ обязательно поможет вам.​ этот раз нужно​ и пойдет речь.​ оптимальный вариант -​

excel-office.ru

Зачистка текста

​В поле «Найти:​ гут. Что за​Z​ ряде случаев есть​Вот пример:​), то все английские​Макросы​ «»), убрать из​ деле пробелом не​ – замени на​ среди тех, кто​ Excel, скопировав данные​

  • ​ в Excel.​Все вышеописанные методы неэффективны​ ввести немного другие​
  • ​Если вы в процессе​ скопировать прямо из​
  • ​ » вставить скопированный​ пробел такой вставил​: Однако, логика, особенно​ опечатки.​(Не знаю, пробел​ буквы, найденные в​
  • ​), то апострофы перед​ чисел лишние разделители​ является, а представляет​

​ Петя», но мы​ работает в Excel​

Замена

​ из Word, если​У нас есть​ в том случае,​ значения.​ работы в программе​​ ячейки все эти​ пробел.​ пользователь?​ женская, простой -​​Например, специально для​ ли вначале, но​​ выделенных ячейках, будут​​ содержимым выделенных ячеек​

​ (не забудьте умножить​ собой невидимый спецсимвол​ его, в данном​ слова «горячие клавиши»​ мы их сами​ такой список с​ если нужно в​В поле «Найти» поставьте​ случайно устанавливали два​ пробелы и вставить​Поле «Заменить на:​Юрий М​ XL’евской — логикe​ примера нашла (но​ очень похож)​ заменены на равноценные​ исчезнут.​​ потом результат на​​ (неразрывный пробел, перенос​ случае, можем использовать​ или «сочетание клавиш».​

Excel удалить пробелы в ячейке

​ не ставили. Непечатаемые​ лишними пробелами в​ Excel удалить пробелы,​ один пробел.​ пробела между словами​

Удаление пробелов

​ их в поле​ » оставить пустым.​: Прикольно)) Как можно​ не подчиняется -​ просматривать весь список​avgust​ им русские. Только​Это уже, как правило,​​ 1, чтобы текст​​ строки, табуляцию и​ его и для​ В Excel определенные​ знаки – это​ ячейках А2 и​​ находящиеся в начале​​Поле «Заменить на» оставьте​

​ вместо одного, тогда​ Найти.​Нажать «Заменить все»​ найти ответ на​ см. #14 …​ долго, идея была​: Спасибо большое! Помогло!​ будьте осторожны, чтобы​ чисто человеческий фактор.​ стал числом):​​ т.д.). У таких​​ удаления лишнего текста.​​ функции можно вызвать,​​ разрывы строк, перенос​ А3.​ или в конце​ нетронутым.​ без проблем удалить​Anastasija ne skagy​Можно без копирования​

Excel удалить пробелы в ячейке

Удаление непечатаемых символов

​ НЕОЗВУЧЕННЫЙ вопрос?​KuklP​​ обработать в помощью​​V​ не заменить случайно​ При вводе текстовых​Апостроф (‘) в начале​ символов внутренний символьный​ Например, в первую​ нажав на определенную​ текста на другую​Ставим курсор в ячейке​ значения. Однако с​Нажмите кнопку «Заменить все».​ пробелы в Excel​: редактируй, нельзя удалять​ пробела из ячейки.​​Владимир​​:​ формулы).​

​: и чем вас​

  • ​ нужную вам латиницу​ данных в ячейку​ ячейки на листе​​ код отличается от​​ строку вводим «г.»​​ функциональную клавишу или​​ страницу, конец абзаца,​ В2, чтобы написать​ этим безукоризненно справляется​​Подтвердите свои действия, ознакомьтесь​​ можно с помощью​​ тебе такое)​​В поле «Найти:​
  • ​: Пробелы бывают разные​​Если текст набирался​​Кстати, и заморочка​ =СЖПРОБЕЛЫ(A1) не устроило?​​ :)​​ вместо русских букв​ Microsoft Excel –​ кода пробела (32),​ (без кавычек!), а​ сочетание нескольких клавиш.​ табуляция, др.​ формулу, которая удалит​ функция СЖПРОБЕЛЫ.​ с отчетом и​ инструмента «Заменить». Пользоваться​

Функция ПОДСТАВИТЬ

​Q w​ » Нажать Alt+0160​ — чёрные, белые,​ кривыми руками, то​ имеет место: несмотря​​покороче будет =ПСТР(A1;2;99)​​avgust​ случайно вводятся похожие​​ это специальный символ,​​ поэтому функция​ во вторую не​

  • ​ Это удобно при​Чтобы​
  • ​ лишние пробелы. Заходим​Установите курсор в той​
  • ​ примите его.​ им довольно просто:​

​: Найти (пробел (ы)​Код набрать на​ красные..​ и подавно надо​ на то, что​avgust​: Как удалить один​ английские («це» вместо​ официально называемый​СЖПРОБЕЛЫ​ вводим ничего и​ работе, как на​

Excel удалить пробелы в ячейке

Удаление апострофов в начале ячеек

​заменить непечатаемые знаки на​ на закладке «Формулы»​ ячейке, которая находится​После этого вы обнаружите,​Перейдите на вкладку «Главная».​​ ) и заменить​​ правой цифровой клавиатуре.​=ПОДСТАВИТЬ(A2;СИМВОЛ(160);)​ производить чистку во​ пробел благополучно убрался,​: Там в ряде​ пробел в начале​ русской «эс», «игрек»​текстовым префиксом​не может их​ жмем кнопку​ ноутбуке, так и​ пробел в Excel​​ в раздел «Библиотека​ параллельно столбцу или​​ что пробелы между​На панели инструментов, в​ на (ничего)​Денис акимкин​smart_v16​ ВСЕХ таблицах. Много​ и тексты в​ случаев идет текст,​ записи в ячейке,​ вместо русской «у»​. Он нужен для​ «зачистить».​Заменить все (Replace All)​ на ПК, быстрее​, пишем в соседнюю​ функций», выбираем «Текстовые».​ строке, пробелы из​​ числами исчезли, соответственно,​​ правой ее части,​Максим​​: Это не пробелы,​​: Я имел ввиду​ времени это не​

​ ячейках двух таблиц​ набранный от руки,​ перед текстом, чтобы​ и т.д.) Причем​ того, чтобы дать​Вариантов решения два:​. Excel удалит все​ вызвать поределенную функцию.​

​ ячейку такую формулу.​ И здесь нажимаем​ которых нужно убрать.​ поставленная задача выполнена.​​ нажмите по кнопке​​: редактирование — заменить.​​ а результат форматирования.​​ не озвучивал, и​​ займет, зато все​​ идентичны, функция ВПР​ его нужно (хотелось​ остальные остались?​

Английские буквы вместо русских

​ снаружи все прилично,​ понять Excel, что​Аккуратно выделить мышью эти​ символы «г.» перед​ Про эти волшебные​=СЖПРОБЕЛЫ(ПОДСТАВИТЬ(A6;СИМВОЛ(160);СИМВОЛ(32)))​ на функцию «СЖПРОБЕЛЫ».​Откройте окно Мастера функций,​Вполне возможно, что использование​ «Найти и выделить».​В поле «заменить»​ Если не нужны​ думал найду в​ будет правильней.​ не работает.​ бы) оставить без​Формула сжпробел не​ ибо начертание у​ все последующее содержимое​ спецсимволы в тексте,​

​ названиями городов:​ кнопки читайте в​Мы написали в ячейку​ Эта функция поможет​ нажав по соответствующей​ вышеописанной инструкции по​ Нажмите по ней.​ ставь 5 пробелов,​​ — по нужной​​ переписке. Но не​jakim​​Z​​ изменений.​ подходит — она​

​ этих символов иногда​ ячейки нужно воспринимать​ скопировать их (​Только не забудьте предварительно​ статье «Горячие клавиши​ В6 формулу. В​удалить лишние пробелы Excel​ кнопке, находящейся рядом​ удалению пробелов в​В появившемся выпадающем списке​ а в поле​ ячейке правой клавишей,​ нашел. Теперь ясно,​: Для KuklP, посмотрите​: А может они​V​ удаляет все пробелы.​ абсолютно одинаковое, но​

​ как текст, а​Ctrl+C​ выделить нужный диапазон​ Excel».​​ формуле: символ 160​​, оставляя один пробел.​​ со строкой функций.​​ Excel не дало​​ выберите пункт «Заменить».​​ «заменить на» один​ «Свойства», «Формат». Там​ критик? )​ какая разница.​ не уникальные -​:​Z​ Excel воспринимает их,​ не как число.​

planetaexcel.ru

Удалить пробел в начале ячейки

​) и вставить (​​ ячеек, иначе замена​Зачастую текст, который достается​ –это код неразрывного​В появившемся диалоговом окне​В списке «Категория» выберите​
​ никаких результатов. При​Появится окно, в котором​ пробел или что​

​ выбираем нужный.​​smart_v16​KuklP​ с повторами?.. А​avgust​: Да что вы​;)

​ конечно же, как​​ По сути, он​
​Ctrl+V​

​ произойдет на всем​​ нам для работы​ пробела, а символ​ в строке «Текст»​ «Текстовый», а в​ этом программа вам​​ в поле «Найти»​​ там нужно еще.​
​Сергей сухов​

​: Владимир, не понял​​: И что? СЖПРОБЕЛЫ​

​ может они не​​ф-ция СЖПРОБЕЛЫ текст​​ говорите? А показать​​ разные значения и​​ служит удобной альтернативой​​) в первую строку​ листе!​ в ячейках листа​:(
​ 32 – это​ указываем адрес первой​ списке с перечнем​:)

​ сказала, что пробелов​​ введите двойной пробел.​ Для всех выделенных​: в цифрах это​

​ Вас. Вы могли​​ привела строку в​ сортированы?.. И вообще​ не трогает она​ сможете? И пробел​​ выдает ошибки в​​ предварительной установке текстового​ в окне замены​

​Если из текста нужно​​ Microsoft Excel далек​ код лишних пробелов​ ячейки из нашего​
​ функций выделите «СЖПРОБЕЛЫ»​
​ попросту нет. Происходит​ Для этого просто​ ячеек.​

​ называется не пробелами,​​ бы объяснить что​

​ божеский вид -​​ в этой заморочке​ удаляет лишние пробелы:​
​ ли у вас​

​ формулах, дубликаты в​​ формата для ячейки​ (​ удалить вообще все​ от совершенства. Если​ (начальных и промежуточных).​ списка. Мы указали​

​ и нажмите «ОК».​​ это лишь в​​ дважды нажмите по​​Alexey i.​ а полупробелами. У​ имели ввиду под​
​ Ваша длинная и​ не ВПР требуется.​1. перед текстом​ в начале?..​
​ фильтрах и т.д.​ (​Ctrl+H​

​ пробелы (например они​​ он был введен​
​Ещё один способ​ адрес ячейки А2.​Появится окно ввода функции.​ одном случае –​ соответствующей клавише.​: Самым оптимальным будет​ них свой код,​ «Пробелы бывают разные​ сложная формула оставила​ Думаем, однако…​ — т.к. текст​DEAD MAN​Можно, конечно, вручную заменять​Главная – Число –​). Затем нажать кнопку​ стоят как тысячные​ другими пользователями (или​удалить лишние пробелыExcel​

​Нажимаем «ОК». Теперь формулу​​ В нем вам​ если пробелы в​В поле «Заменить на»​ заменить (Ctrl+H или​ который тоже можно​ — чёрные, белые,​ ее корявой. Какой​;)

​avgust​​ не должен начинаться​: Как вариант:​ символы латинцы на​ Текстовый​Заменить все (Replace All)​ разделители внутри больших​ выгружен из какой-нибудь​– это воспользоваться​
​ копируем вниз по​ нужно указать ячейку,​ числах были поставлены​ пропишите один пробел.​ где-то рядом.. )​ заменить на (пусто).​
​ красные.. «​ в этом смысл?Цитатаavgust​: Да, в столбцах​ с пробела.​=ПРАВСИМВ(A1;ДЛСТР(A1)-1)​ соответствующую им кириллицу,​) и для ввода​для удаления.​

​ чисел), то можно​​ корпоративной БД или​ функцией «Найти и​ столбцу всего списка.​ в которой хотите​ путем форматирования. По​Нажмите кнопку «Заменить все».​ начальные пробелы на​ Таблица символов ANSI​;)

​И что делает​​ пишет:​ есть не уникальные​2. два и​Nic70y​ но гораздо быстрее​ длинных последовательностей цифр​Использовать функцию​
​ использовать ту же​ ERP-системы) не совсем​ заменить». О работе​ В столбце В​ убрать пробелы. Для​ сути, это никак​
​В окне с отчетом​:)

​ пустое значение; сработает​​ http://mmb.mediachance.com/mmbhelp/ru/index.html?asciitable.htm​ формула​мне нужно было​
​ данные, в этом​ более пробела заменяет​: Если пробел в​ будет сделать это​

​ (номеров банковских счетов,​​ПЕЧСИМВ (CLEAN)​ замену: нажать​
​ корректно, то он​ с​ получился такой список.​ этого просто кликните​ не повлияет на​ нажмите «ОК».​
​ если начальный пробел​Ким байгильдин​=ПОДСТАВИТЬ(A2;СИМВОЛ(160)​ убрать только первый​ случае я собиралась​ на один.​ начале записи в​ с помощью макроса.​

​ кредитных карт, инвентарных​​. Эта функция работает​Ctrl+H​ легко может содержать:​функцией Excel «Найти и​ Лишние пробелы удалились.​;)

​ по ней левой​​ работу формул и​:)​После этого все двойные​ не один и​: Спасибо. Очень помогло​Почему она а​ пробел, в этом​ вычищать вручную. Но​avgust​ ячейке, перед текстом,​

​ Откройте редактор Visual​​ номеров и т.д.)​ аналогично функции​

​, в первую строку​​лишние пробелы перед, после​ заменить»​Как убрать пробелы в​ кнопкой мыши.​ всего прочего, однако​ пробелы в Excel​ помимо начала строк​У меня есть прайс.​
​ не сжпробел​ случае текст полностью​ раньше мне это​: Спасибо за помощь!​ существует всегда, тогда​ Basic сочетанием клавиш​ он просто незаменим.​СЖПРОБЕЛЫ​ ввести пробел, во​ или между словами​читайте в статье​ числах Excel​Нажмите «ОК».​ некоторым пользователям очень​ будут удалены. Как​ это кол-во пробелов​
​ Там тысячи наимований​Юрий М​ совпадает с текстом​:D​ не мешало.​

​СЖПРОБЕЛЫ меня бы​​ формула​Alt+F11​ Но иногда он​, но удаляет из​ вторую ничего не​ (для красоты!)​ «Поиск в Excel».​.​Сразу после этого лишние​ важно, чтобы все​ можно отметить, способ​ в содержимом ячеек​ и перед каждым​: Я не критикую​ в другой таблице,​До сих пор​ устроило, не будь​DEAD MAN​, вставьте новый модуль​

​ оказывается в ячейках​​ текста не пробелы,​ вводить и нажать​ненужные символы («г.» перед​

​ Сначала копируем пробел​​Если формула не​ пробелы будут убраны.​ числа были записаны​
​ этот довольно простой​

​ не встречается.​​ стоит штук 5​ — просто подметил​ и поле может​ функция впр у​ в некоторых случаях​, иначе примерно так:​

​ (меню​​ против нашей воли​ а непечатаемые знаки.​ кнопку​ названием города)​ (место между цифрами).​ считает и выдает​ Однако исправленный вариант​
​ в ряд без​ в использовании. Все​​Есть, конечно, вариант​;)
​ не нужных пробелов.​ нелепость) А 160​

​ служить признаком, по​​ меня работала без​ набранного от руки​=ЕСЛИ(ЛЕВСИМВ(A1)=» «;ПСТР(A1;2;ДЛСТР(A1)-1);A1)​Insert — Module​ (после выгрузок из​ К сожалению, она​

planetaexcel.ru

Почему Excel не находит пробелы между цифрами в ячейках?

​Заменить все (Replace All)​невидимые непечатаемые символы (неразрывный​ Пробел там есть,​ ошибку, то одной​ будет находиться в​ пробелов. Если вы​ последующие методы не​ написать скрипт, но​ Можно ли как-то​ — это неразрывный​ которому я выберу​ сортировки, или я​ текста (а там​KuklP​) и введите туда​

​ корпоративных баз данных,​​ тоже способна справится​.​ пробел, оставшийся после​ просто он не​
​ из причин может​ той ячейке, где​ из их числа,​
​ будут отличаться особой​
​ это сложнее :)​ все вместе удалить​
​ пробел — тяжёлое​ нужную информацию из​ чего-то сильно не​
​ могут быть и​: Докажите на примере!​
​ его текст:​
​ например) и начинает​ не со всеми​
​Однако, часто возникает ситуация,​ копирования из Word​
​ виден. Получается, мы​ быть лишний пробел​

​ была прописана формула.​​ тогда выполните следующую​ сложностью, и пользователь​Ирина​ или придется каждую​ наследие Word))​ одной таблицы в​ понимаю.​

​ двойные пробелы), мне​​Nic70y​Sub Replace_Latin_to_Russian() Rus​ мешать расчетам. Чтобы​ спецсимволами, но большинство​ когда удалить надо​ или «кривой» выгрузки​ скопировали пустое место,​ в формуле, в​

​ Ничего страшного, просто​​ инструкцию:​

Как удалить пробелы в Excel?

​ легко поймет, как​: а там точно​ строчку редактировать?​Есть много чисел в​ другуюЕсли корректно сжать​Да, думаю, конечно​ нужно было убрать​:​ = «асекорхуАСЕНКМОРТХ» Eng​

​ его удалить, придется​​ из них с​ не все подряд​ из 1С, переносы​ но там есть​ числе, если число​ скопируйте ячейку и​Выделите область таблицы, в​ удалить лишние пробелы​ пробелы? может это​
​Дмитрий к​ ячейках, часть из​ пробелы в ОБЕИХ​jakim​ только первый пробел,​Z​ = «acekopxyACEHKMOPTX» For​ использовать небольшой макрос.​ ее помощью можно​ пробелы, а только​ строк, табуляция)​ пробелы, непечатаемые знаки,​ написано с разрядами,​ вставьте ее в​ ячейках которой вы​ в Excel.​ отступ при форматировании.​: Или можно в​ них, которые больше​ таблицах, вероятность нахождения​: Может быть так​

​ в этом случае​​,​ Each cell In​

​ Откройте редактор Visual​​ убрать.​ лишние – иначе​апострофы (текстовый префикс –​

​ неразрывный пробел, т.д.​​ но не функцией​
​ нужную область.​ хотите избавиться от​Только что мы разобрались,​ тогда все намного​ соседнем столбце воспользоваться​ 1000, с пробелами​ через ВПР многократно​ для одного пробела​

​ текст полностью совпадает​​KuklP​ Selection For i​ Basic сочетанием клавиш​Замену одних символов на​ все слова слипнутся​ спецсимвол, задающий текстовый​Теперь на закладке «Главная»​ «Разряды», а мы​Автор: Вадим Матузок​ пробелов между числовыми​ как удалить пробелы​
​ проще​ формулой СЖПРОБЕЛЫ, которая​ через каждые три​

​ возрастет.​​ слева.​ с текстом в​- вот это​ = 1 To​Alt+F11​

​ другие можно реализовать​

Источник

Всем привет! В сегодняшнем нашем уроке мы посмотрим, как можно удалить лишние пробелы в ячейках Excel. С данной проблемjq сталкиваются почти все, и пробелы действительно сильно мешают в дальнейшей работе. Во-первых, при сортировке или при поиске информации частенько мы не может найти необходимую информацию. Особенно это болезненно при работе с большими документами. Во-вторых, документ при этом смотрится некрасиво и визуально сложно с ним работать. В-третьих, документ таким образом весит больше. Особенно это заметно при копировании большого количества элементов.

Именно поэтому нужно сразу же убрать лишние пробелы в ячейках Excel, как только они начали появляться. Нужно понимать, что пробелы могут быть разного типа – между слов, в начале или в конце. Еще более серьезные пробелы можно увидеть между цифрами или разрядами числа. В таком случае вы можете столкнуться с проблемами при арифметических подсчетах. И ладно, если будет вылезать ошибка, а что, если подсчеты будут неверные. В статье мы рассмотрим несколько способов. Поехали!

Содержание

  1. Способ 1: Замена
  2. Способ 2: Удаление пробела между цифрами
  3. Способ 3: Использование функции
  4. Задать вопрос автору статьи

Способ 1: Замена

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

  1. Перейдите на вкладку «Главная».

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

  1. Теперь в правом верхнем углу окна в разделе «Редактирования» нажмите по значку лупы – далее из выпадающего меню выбираем инструмент «Заменить».

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

  1. В первой строке ставим текстовый курсор, нажав левую кнопку мыши и два раза жмем на «Пробел». Как вы уже догадались в нижней строке нужно поставить только один «Пробел». Теперь жмем по кнопке «Заменить все».

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

  1. Если в документе будут найдены такие элементы, то они будут заменены на обычный пробел. Если же их обнаружено не будет, то вы увидите соответствующее сообщение.

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

Таким же образом можно заменять любые символы, например, звездочку (*) на пробел или тире (-). Очень полезная функция, которая есть во всех программах, работающих с текстом, символами и цифрами. Она также есть и в Word.

Способ 2: Удаление пробела между цифрами

Давайте рассмотрим еще одну очень популярную ситуацию, которая чаще всего возникает при копировании данных из другого места. Представим себе, что у нас есть большое количество чисел, где каждые три разряда разделены пробелом. Для человека подобные цифры воспринимаются удобно, но вот некоторые версии Excel не могут работать с подобными цифрами и считают такие ячейки с наличием символов. Давайте посмотрим, как можно удалить и полностью убрать пробелы в числах в Excel.

ПРИМЕЧАНИЕ! Новые версии Excel спокойно работают с такими цифрами, поэтому перед удалением пробелов проверьте – работают ли формулы вычисления с такими ячейками. Если они работают, то удалять их не нужно.

  1. Выделяем те ячейки, в которых находятся подобные цифры.

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

  1. Открываем тот же самый инструмент.

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

  1. Теперь в первую строку вводим только один пробел, а вот со второй нужно все стереть с помощью кнопки «Backspace».

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

  1. После замены пробелы должны удалиться.

Если вы видите сообщение – «Мы не нашли ничего, что нужно было заменить» – значит данные пропуски не воспринимаются программой как пробелы и просто визуально разграничивают числа для удобства. С ними можно спокойно работать при любом вычислении.

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

Если же они вам не нравятся, то их можно убрать с помощью настроек отображения.

  1. Выделяем эти ячейки.
  2. Жмем правой кнопкой и заходим в «Формат ячейки».

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

  1. В настройках в «Числовом» разделе просто уберите галочку «Разделитель групп разрядов».

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

  1. В конце нажмите «ОК».

Оба предыдущих способа не дают нам возможность, например, удалить один пробел в начале или в конце строки. Конечно, он может мешать не всем, но при добавлении такого пробела в число может возникнуть проблема с подсчетом, а также автоматическом определении формата ячейки. Поэтому лучше всего воспользоваться функцией:

=СЖПРОБЕЛЫ(***)

Дополнительно она удаляет двойные или тройные пробелы из всех ячеек. Вместо звездочек (***) мы будем использовать или просто текст, или адрес ячейки.

  1. Выделите ячейку, параллельную той, которую вы хотите исправить.
  2. Нажмите по кнопке «Функции» рядом со строкой значения.

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

  1. Выберите «Текстовую» категорию и установите нужную нам функцию.
  2. Жмем «ОК».

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

  1. Теперь нам нужно установить адрес – выделите адрес ячейки.

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

  1. Теперь растяните формулу на другие ячейки.

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

  1. Теперь нам нужно скопировать (Ctrl + C) все исправленные значения в старые ячейки (Ctrl + V). При вставке выберите режим «Значения».

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

  1. Эти данные можно удалить – кликаем правой кнопкой по выделению и выбираем команду «Очистить содержимое».

Убрать пробелы в ячейке Excel: двойные пробелы, в числах, в начале и конце

Способ не такой удобный, но зато помогает избавиться от лишних пропусков в начале и конце строки. На этом все, дорогие друзья портала WiFiGiD.RU. Надеюсь, урок вам понравился и был для вас полезным. Пишите свои дополнения и вопросы в комментариях. Всем добра!

Источник

Весьма часто в нашем распоряжении оказываются данные, которые хоть и содержат полезную информацию, но не пригодны для немедленного анализа. Одной из весьма распространенных проблем является наличие лишних пробелов — в начале, в конце или внутри между словами.

Лечится эта проблема очень легко — специальной функцией СЖПРОБЕЛЫ (TRIM). Она убирает все лишние пробелы, но оставляет по одному пробелу между словами:

clean-text2.png

Просто и красиво. Но есть пара нюансов.

Неразрывные пробелы не удаляются

Чайной ложкой дегтя тут представляется только невозможность удалять таким способом неразрывные пробелы. Это особый вариант пробела (внешне неотличимый от обычного), на котором не бывает переноса строки. Обычно его используют в случаях типа «г. Москва» или «Иванов И.И.», чтобы эти фразы не разбивались между строчками. В Microsoft Word такой спецсимвол вводится сочетанием клавиш Ctrl+Shift+Пробел и отображается в виде кружка, а не точки:

Неразрывный пробел

К сожалению, функция СЖПРОБЕЛЫ (TRIM) удаляет только обычные пробелы. Для удаления неразрывных нужно использовать другие функции или макросы.

Формулы для удаления начальных и концевых пробелов

Если необходимо удалить только начальные пробелы (т.е. не трогать концевые и пробелы между словами), то придется делать это хитрыми формулами, т.к. готовой функции (по аналогии с функцией LTrim в VBA) в Microsoft Excel, к сожалению, нет. 

Формула для удаления лишних пробелов только слева будет выглядеть так:

Удаление лишних пробелов слева формулой

В английской версии =MID(A1;FIND(LEFT(TRIM(A1));A1);LEN(A1))

Формула для удаления лишних пробелов только справа будет чуть посложнее и должна вводиться уже как формула массива (с Ctrl+Shift+Enter):

Удаление лишних пробелов справа

В английском варианте это будет =LEFT(A1;MAX((MID(A1&REPT(» «;99);ROW(A1:A99),1);» «)*ROW(A1:A99)))

Ссылки по теме

  • Подсветка ячеек с лишними пробелами условным форматированием
  • Зачистка текста от лишних пробелов, непечатаемых символов, английских букв и т.д.
  • Как проверить текст на соответствие заданному шаблону (маске)
Источник

Понравилась статья? Поделить с друзьями:
  • Удалить пробелы в ячейках excel в тексте
  • Удалить несколько листов excel в один
  • Удалить пробелы в конце ячейках excel
  • Удалить несколько знаков в ячейке excel
  • Удалить пробел слева в ячейке excel