Совпад в excel примеры

В этой статье описаны синтаксис формулы и использование функции СОВПАД в Microsoft Excel.

Описание

Сравнивает две строки текста и возвращает значение ИСТИНА, если они в точности совпадают, и ЛОЖЬ — в противном случае. Функция СОВПАД учитывает регистр, но игнорирует различия в форматировании. Функция СОВПАД позволяет проверить текст, вводимый в документ.

Синтаксис

СОВПАД(текст1;текст2)

Аргументы функции СОВПАД описаны ниже.

• Текст1    — обязательный аргумент. Первая текстовая строка.

• Текст2    — обязательный аргумент. Вторая текстовая строка.

Пример

Скопируйте образец данных из следующей таблицы и вставьте их в ячейку A1 нового листа Excel. Чтобы отобразить результаты формул, выделите их и нажмите клавишу F2, а затем — клавишу ВВОД. При необходимости измените ширину столбцов, чтобы видеть все данные.

Первая строка	Вторая строка
слово	слово
Слово	слово
сл ово	слово
Формула	Описание	Результат
=СОВПАД(A2;B2)	Проверяет, совпадают ли значения в первой строке таблицы	ИСТИНА
=СОВПАД(A3;B3)	Проверяет, совпадают ли значения во второй строке таблицы («С» в ячейке A3 введена верхним регистром)	ЛОЖЬ
=СОВПАД(A4;B4)	Проверяет, совпадают ли значения в третьей строке таблицы (в A4 содержится пробел между «сл» и «ово»)	ЛОЖЬ

Функция СОВПАД в Excel предназначена для проверки двух текстовых срок на их полное соответствие друг другу и возвращает одно из двух возможных логических значений: ИСТИНА – если строки полностью совпадают, ЛОЖЬ – если обнаружено хотя бы одно несоответствие в сравниваемых данных. При работе данной функции учитывается регистр букв. Это значит, что результат сравнения двух строк «текст» и «ТеКсТ» будет равен значению ЛОЖЬ. Распространенный вариант применения рассматриваемой функции – определение вхождения некоторого текста в документ.

Сравнение двух таблиц по функции СОВПАД в Excel

Пример 1. Есть две одинаковые (на первый взгляд) таблицы данных, которые содержат наименования продукции. Одну из них предположительно редактировал уволенный работник. Необходимо быстро сравнить имеющиеся данные и выявить несоответствия.

Вид таблицы данных:

Для сравнения двух строк используем следующую формулу массива (CTRL+SHIFT+Enter):

Описание параметров функции СОВПАД:

• D3 – текущая ячейка с текстом из второй таблицы;
• $B$3:$B$13 – соответствующая ячейка с текстом из второй таблицы для проверки на совпадение со значением D3.

Функция ИЛИ возвращает логическое значение ИСТИНА из массива если хотя бы одно из них совпадает с исходным значением.

Протянем данную формулу вниз до конца таблицы, чтобы Excel автоматически рассчитал значения для остальных строк:

Как видно, в сравниваемых строках были найдены несоответствия.



Выборка значений из таблицы по условию в Excel без ВПР

Пример 2. В таблице содержатся данные о продажах мобильных телефонов (наименование и стоимость). Определить самый продаваемый вид товара за день, рассчитать количество проданных единиц и общую выручку от их продажи.

Вид таблицы данных:

Поскольку товар имеет фиксированную стоимость, для определения самого продаваемого смартфона можно использовать встроенную функцию МОДА. Чтобы найти наименование наиболее продаваемого товара используем следующую запись:

Пояснения:

Функция мода определяет наиболее часто повторяющиеся числовые данные в диапазоне цен. Функция ПОИСКПОЗ находит позицию первой ячейки из диапазона, в которой содержится цена самого популярного товара. Полученное значение выступает в качестве первого аргумента функции адрес, возвращающей ссылку на искомую ячейку (к значению прибавлено число 2, поскольку отсчет начинается с третьей строки сверху). Функция ДВССЫЛ возвращает значение, хранящееся в ячейке по ее адресу.

В результате расчетов получим:

Для определения общей прибыли от продаж iPhone 5s используем следующую запись:

Функция СУММПРИЗВ используется для расчета произведений каждого из элементов массивов, переданных в качестве первого и второго аргументов соответственно. Каждый раз, когда функция СОВПАД находит точное совпадение, значение ИСТИНА будет прямо преобразовано в число 1 (благодаря двойному отрицанию «—») с последующим умножением на значение из смежного столбца (стоимость).

Результат расчетов формулы:

Всего было куплено 4 модели iPhone 5s по цене 239 у.е., что в целом составило 956 у.е.

Правила синтаксиса и параметры функции СОВПАД в Excel

Функция СОВПАД имеет следующий вариант синтаксической записи:

=СОВПАД(текст1;текст2)

Описание аргументов:

• текст1 – обязательный для заполнения, принимает ссылку на ячейку с текстом или текстовую строку для сравнения с данными, принимаемые вторым аргументом.
• текст2 – обязательный для заполнения, принимает ссылку на ячейку или текст, с которым сравниваются данные, переданные в виде первого аргумента.

Примечания:

1. Результат выполнения функции СОВПАД, принимающей на вход два имени, является код ошибки #ИМЯ? (например, СОВПАД(имя;имя)). Для корректной работы функции указываемые текстовые данные необходимо помещать в кавычки (например, («имя»;«имя»)).
2. Функция выполняет промежуточное преобразование числовых данных в текст. Например, результат выполнения =СОВПАД(111;111) будет логическое значение ИСТИНА. Однако, преобразование логических данных в числа текстового формата не выполняется. Например, результат выполнения =СОВПАД(ИСТИНА;1) будет логическое ЛОЖЬ.
3. Результат сравнения двух пустых ячеек или пустых текстовых строк с использованием функции СОВПАД — логическое ИСТИНА.

Раздел функций	Текстовые
Название на английском	EXACT
Волатильность	Не волатильная

Что делает эта функция?

Эта функция сравнивает два элемента текста и определяет, являются ли они абсолютно одинаковыми.

Учитывается регистр символов, только слова, написанные одинаково и имеющие символы верхнего и нижнего регистра в одной и той же позиции, будут считаться равными.

Синтаксис

=СОВПАД(Текст1,Текст2)

Можно сравнить только два аргумента.

Форматирование

Как и все текстовые функции, функция преобразует числовой формат в натуральное число перед сравнением. Поэтому функция считает 200% и 2 (изначально в числовом формате) совпадающими текстовыми значениями.

Это касается форматирования как даты, даты-времени, времени, процентного и финансового формата.

СОВПАД – примеры использования

Функция может быть удобна, когда нужно найти в ячейке буквы в определенном регистре – например, заглавные или строчные.

Найти любые заглавные буквы

Для поиска заглавных букв нам поможет логика и функция СТРОЧН.

Логика такова:

1. переведем значение ячейки в нижний регистр
2. сравним результат с изначальным значением ячейки
3. если вернется ЛОЖЬ, – хотя бы одна заглавная буква была.
4. Вуаля!

А вот и формула:

=НЕ(СОВПАД(СТРОЧН(A1);A1))

Найти любые строчные буквы

Здесь аналогичная формула, но с функцией ПРОПИСН:

=НЕ(СОВПАД(ПРОПИСН(A1);A1))

Найти, есть ли буквы в ячейке

Если проверить, совпадают ли значения ячейки в верхнем и нижнем регистре, можно выявить, есть ли в ней буквы. Если буква была в нижнем, станет верхним, а если в верхнем – в нижнем, и только если букв в ячейке нет, она останется такой же, как была. Иероглифы не в счет.

Логично ведь, правда?

Соответствующая формула:

=НЕ(СОВПАД(ПРОПИСН(A1);СТРОЧН(A1)))

Понравилась статья? Поддержите ее автора!
Набор инструментов !SEMTools поможет решить множество задач без ввода сложных формул и сэкономит ваше время. И вам полезно, и автору приятно!

Функция

СОВПАД(

)

, английский вариант EXACT(),

сравнивает две текстовые строки и возвращает значение ИСТИНА, если они в точности совпадают, и ЛОЖЬ — в противном случае. Функция

СОВПАД()

учитывает РЕгиСТр.

Синтаксис функции

СОВПАД

(

текст1

;

текст2

)

Текст1

— первая текстовая строка.

Текст2

— вторая текстовая строка.

Примеры

Формула

=СОВПАД(«ПЕРВЫЙ»;»Первый»)

вернет ЛОЖЬ, т.е. 2 текстовых значения не совпадают с

учетом РЕгиСТРа

. Формула

=СОВПАД(«ПЕРВЫЙ»;»ПЕРВЫЙ»)

вернет ИСТИНА.

Пусть в ячейке

А2

введена строка

Первый канал — лучший

, а в ячейке

A3

введена строка

ПЕРВЫЙ канал — лучший

. Для сравнения строк с

учетом РЕгиСТРа

используйте формулу

=СОВПАД(A2;A3)

, для сравнения значений без учета РЕгиСТРа используйте формулу

=A2=A3

.

Добро пожаловать на подборку занятий 30 функций Excel за 30 дней (30XL30D). Спасибо, что приняли участие в опросе на тему самых интересных функций. В данной подборке мы сделаем обзор 30 лидирующих функций Excel (по результатам проведённого опроса), из следующих категорий:

• Текст
• Информация
• Поиск и ссылки

В конце этого 30-дневного марафона, будет опубликован список всех упомянутых функций в порядке, соответствующем количеству набранных в опросе голосов. Тем не менее, 30 самых популярных функций будут рассмотрены в случайном порядке, так что заходите сюда каждый день, чтобы ничего не пропустить.

Дадим старт нашему марафону и в качестве первой функцию возьмём EXACT (СОВПАД). Вы увидите 7 примеров использования этой функции, так что приготовьтесь удивляться её возможностям. Если у Вас есть свои приёмы или примеры использования этой функции, пожалуйста, поделитесь ими в комментариях.

Функция 01: EXACT (СОВПАД)

Функция EXACT (СОВПАД) может проверить две текстовые строки на предмет точного совпадения, причем, с учётом регистра. Форматирование на результат не влияет. Если совпадение строк точное, то функция возвращает значение TRUE (ИСТИНА), если же точного совпадения нет, то FALSE (ЛОЖЬ).

Как можно использовать функцию EXACT (СОВПАД)?

Кроме проверки двух ячеек на предмет точного совпадения, Вы можете выполнять при помощи функции EXACT (СОВПАД) следующие действия:

• Использовать для проверки данных, чтобы блокировать изменения в ячейке.
• Задавать условие на ввод только символов в верхнем регистре.
• Проверять точное совпадение в списке значений.
• Находить точное совпадение при поиске в таблице.
• Подсчитывать количество точных совпадений в списке.
• Выявлять различия между двумя ячейками.

Синтаксис EXACT (СОВПАД)

Функция EXACT (СОВПАД) имеет следующий синтаксис:

EXACT(text1,text2)
СОВПАД(текст1;текст2)

• text1 (текст1) – это первая текстовая строка.
• text2 (текст2) – это вторая текстовая строка.

Аргументы text1 и text2 можно ввести как текстовые строки или как ссылки на другие ячейки. В Excel максимальная длина строки для EXACT (СОВПАД) составляет 32767 символов.

Ловушки EXACT (СОВПАД)

В справке Excel 2007 в разделе Примечания для функции EXACT (СОВПАД) существует такая строка:

Возможно также использовать двойной знак равно (==) вместо функции EXACT (СОВПАД), чтобы произвести точное сравнение. Например, =A1==B1 возвратит такой же результат, как =СОВПАД(A1;B1).

Это не верно. В Excel нет оператора — двойной знак равно (==), и уже в справке к Microsoft Excel 2010 это примечание было убрано.

Пример 1: Проверка пароля

Представьте, что Вы ввели секретный пароль в одну из ячеек своей книги Excel и назвали эту ячейку pwd.

• На рисунке ниже секретный пароль находится в ячейке C2 с именем pwd. Она располагается на листе AdminData, который может быть скрыт от пользователей.

На другом листе пользователи будут вводить пароль, а Вы проверять его, используя функцию EXACT (СОВПАД).

• На листе Ex01 пользователь будет вводить пароль в ячейку C3.
• В ячейке C5 с помощью оператора равенства (=) сравниваем значения в ячейках C3 и pwd:

  =C3=pwd

• В ячейке C6 функция EXACT (СОВПАД) сравнивает ячейки C3 и pwd с учётом регистра:

  =EXACT(C3,pwd)
=СОВПАД(C3;pwd)

Если содержимое двух ячеек совпадает, включая регистр, то результатом в обоих случаях будет TRUE (ИСТИНА). Какие-либо различия в форматировании (например, жирный шрифт) будут проигнорированы.

Если хотя бы одна буква введена в другом регистре, то результатом в ячейке C6 будет FALSE (ЛОЖЬ).

Пример 2: Разрешение на изменение ячейки

После того, как пользователь ввел правильный пароль, Вы можете открыть доступ к изменению некоторых ячеек таблицы. Например, создав формулу для проверки данных в ячейке C5, можно контролировать в ней изменения значений.

Используя такую формулу в диалоговом окне Data Validation (Проверка данных), пользователи могут ввести значение в ячейку C5 только в том случае, если пароль, введённый в ячейку C3, полностью соответствует секретному паролю, сохранённому в ячейке pwd. Кроме того, значение в ячейке C5 должно быть больше 0 и меньше 0,1.

=AND(EXACT(C3,pwd),C5>0,C5<0.1)
=И(СОВПАД(C3;pwd);C5>0;C5<0,1)

Пример 3: Условие на ввод только символов в верхнем регистре

Вы можете использовать функцию EXACT (СОВПАД) для проверки, что в ячейку введены только буквы верхнего регистра. Например, канадский почтовый индекс имеет установленный формат с чередующимися цифрами и буквами верхнего регистра, например, L9L 9L9.

В ячейке C2 проверка данных была установлена с применением формулы:

=EXACT(C2,upper(C2))
=СОВПАД(C2;ПРОПИСН(C2))

Если в ячейку введены буквы нижнего регистра, появится предупреждение об ошибке. Конечно же, это не спасёт от всех возможных ошибок при записи почтового индекса, но будьте уверены – все буквы будут в верхнем регистре.

Пример 4: Найти точное совпадение в списке

Вместо простого сравнения ячеек, иногда требуется найти точное совпадение в списке значений. Например, если кто-то напишет код товара в ячейке, как проверить соответствует ли этот код какому-то товару из Вашего списка?

В следующем примере коды товаров записаны в ячейках B2:B5. Клиент может заказать товар, введя его код в ячейке E2.

Формула в ячейке F2 использует функцию EXACT (СОВПАД), чтобы проверить код, введённый в ячейку E2 на точное совпадение с нашим списком.

Формула введена, как формула массива, нажатием Ctrl+Shift+Enter.

{=OR(EXACT($B$2:$B$5,E2))}
{=ИЛИ(СОВПАД($B$2:$B$5;E2))}

Пример 5: Вернуть название по точному совпадению в списке

При поиске в таблице функция EXACT (СОВПАД) может отличить AA1 от Aa1, что позволяет найти правильное название продукта отдельно по каждому коду. Другие функции поиска, такие как VLOOKUP (ВПР), будут рассматривать такие коды как идентичные, и вернут результат, который первым попадётся в списке с таким кодом.

В следующем примере коды продуктов находятся в диапазоне B2:B5, покупатель может заказать продукт, введя его код в ячейку D2.

Формула в ячейке E2 использует 3 функции – INDEX (ИНДЕКС), MATCH (ПОИСКПОЗ) и EXACT (СОВПАД)

• Функция EXACT (СОВПАД) проверяет код, введённый в ячейке D2, и ищет точное совпадение в списке товаров.
• Функция MATCH (ПОИСКПОЗ) возвращает номер строки таблицы, в которой предыдущая функция нашла совпадение. В нашем случае код bG8943TO найден во второй строке диапазона.
• Функция INDEX (ИНДЕКС) возвращает значение из второй строки диапазона A2:A5, т.е. Sam.

Формула введена, как формула массива, нажатием Ctrl+Shift+Enter.

{= INDEX($A$2:$A$5,MATCH(TRUE,EXACT($B$2:$B$5,D2),0))}
{=ИНДЕКС($A$2:$A$5;ПОИСКПОЗ(ИСТИНА;СОВПАД($B$2:$B$5;D2);0))}

Пример 6: Подсчитать точные совпадения в списке

При поиске в таблице функция EXACT (СОВПАД) может отличить Aa1 от AA1, что позволяет подсчитать правильное количество отдельно по каждому коду. Другие функции, такие как COUNTIF (СЧЁТЕСЛИ), будут рассматривать такие коды как идентичные и посчитают их общее количество.

В следующем примере список повторяющихся значений находится в диапазоне A2:A11, а список уникальных значений в столбце C.

Формула в столбце D использует две функции – SUMPRODUCT (СУММПРОИЗВ) и EXACT (СОВПАД)

• Функция EXACT (СОВПАД) смотрит, что введено в столбец C, и проверяет, есть ли точное совпадение в списке элементов A2:A11.
• Функция SUMPRODUCT (СУММПРОИЗВ) возвращает общее количество, которое складывается из результатов TRUE (ИСТИНА)

=SUMPRODUCT(--EXACT($A$2:$A$11,C2))
=СУММПРОИЗВ(--СОВПАД($A$2:$A$11;C2))

Два знака минус (двойное отрицание) перед функцией EXACT (СОВПАД) превращают значения TRUE (ИСТИНА) и FALSE (ЛОЖЬ) соответственно в 1 и 0.

Пример 7: Проверить каждый символ в ячейке

Самое простое, что может сделать для Вас функция EXACT (СОВПАД) – подсказать есть ли точное совпадение между двумя текстовыми строками. Но иногда при несоответствии строк требуется определить, какие именно символы не совпадают. В следующем примере в каждой текстовой строке содержится по 6 символов. Также есть 6 столбцов, заголовки которых пронумерованы от 1 до 6.

Формула в ячейке C2 составлена из трёх функций, среди которых MID (ПСТР) и EXACT (СОВПАД).

• Функция MID (ПСТР) возвращает определённый символ из ячеек A2 и B2. Выбор позиции символа в тексте происходит по номеру столбца, содержащего формулу. Например, формула в ячейке C2, проверяет первые символы каждой текстовой строки, поскольку этот столбец имеет номер 1.
• Функция EXACT (СОВПАД) сравнивает два символа, извлечённых из текста при помощи двух функций MID (ПСТР).

=EXACT(MID($A2,C$1,1),MID($B2,C$1,1))
=СОВПАД(ПСТР($A2;C$1;1);ПСТР($B2;C$1;1))