Protect one sheet in excel

When it comes time to send your Excel spreadsheet, it’s important to protect the data that you’re sharing. You might want to share your data, but that doesn’t mean it should be changed by someone else.

Spreadsheets often contain essential data that shouldn’t be modified or removed by the recipient. Luckily, Excel has built-in features to protect your spreadsheets.

In this tutorial, I’ll help you make sure that your Excel workbooks maintain data integrity. Here are three key techniques you’ll learn in this tutorial:

• Password protect entire workbooks to prevent them from being opened by unauthorized users.
• Protect individual sheets and the workbook structure, to prevent the insertion or deletion of sheets in the workbook.
• Protect cells, to specifically allow or disallow changes to key cells or formulas in your Excel spreadsheets.

Even users with the best intentions may accidentally break an important or complex formula. The best thing to do is remove the option to change your spreadsheets altogether.

How to Protect Excel: Cells, Sheets, & Workbooks (Watch & Learn)

In the screencast below, you’ll see me work through several important types of protection in Excel. We’ll protect an entire workbook, a single spreadsheet, and more.

Want a step-by-step walkthrough? Check out my steps below to find out how to use these techniques. You’ll learn how to protect your workbook in Excel, as well as protecting individual worksheets, cells, and how to work with advanced settings. 

We start with broader worksheet protections, then work down to narrower targeted protections you can apply in Excel. Let’s get started learning how to protect your spreadsheet data:

1. Password Protect an Excel Workbook File

Let’s start off by protecting an entire Excel file (or workbook) with a password to prevent others from opening it.

This is a breeze to do. While working in Excel, navigate to the File tab choose the Info tab. Click on the Protect Workbook dropdown option and choose Encrypt with Password.

As is the case with any password, choose a strong and secure combination of letters, numbers, and characters, bearing in mind that passwords are case-sensitive.

It’s important to note that Microsoft has really beefed up the seriousness of their password protection in Excel. In prior versions, there were easy workarounds to bypass password protection of Excel workbooks, but not in newer versions.

In Excel 2013 and beyond, the password implementation will prevent these traditional methods to bypass it. Make sure that you store your passwords carefully and safely or you risk permanently losing access to your crucial workbooks.

Excel Workbook — Mark as Final

If you want to be a bit less forceful with your spreadsheets, consider using the Mark as Final feature. When you mark an Excel file as the final version, it switches the file to read-only mode, and the user will have to re-enable editing.

To change a file to read-only mode, return to the File > Info button, and click on Protect Workbook again. Click on Mark as Final and confirm that you want to mark the document as a final version.

Marking a file as the final version will add a soft warning to the top of the file. Anyone who opens the file after it has been marked as final will see a notice, warning them that the file is finalized. 

Marking a file as the final version is a less formal way of signaling that a file shouldn’t be changed further. The recipient still has the ability to click Edit Anyway and modify the spreadsheet. Marking a file as the final edition is more like a suggestion, but it’s a great approach if you trust the other file users.

2. Password Protect Your Excel Sheet Structure

Next up, let’s learn how to protect the structure of an Excel workbook. This option will ensure that no sheets are deleted, added, or re-arranged inside of the workbook.

If you want everyone to be able to access the workbook, but limit the changes they can make to a file, this is a great start. This protects the structure of the workbook, and limits how the user can change the sheets inside of it.

To turn on this protection, go to the Review tab on Excel’s ribbon and click on Protect Workbook.

Once this option is turned on, the following will go into effect:

• No new sheets can be added to the workbook.
• No sheets can be deleted from the workbook.
• Sheets can no longer be hidden or unhidden from the user’s view.
• The user can no longer drag and drop the sheet tabs to reorder them in the workbook.

Of course, trusted users can be given the password to unprotect the workbook and modify it. To unprotect a workbook, simply click on the Protect Workbook button again and input the password to unprotect the Excel workbook.

3. How to Protect Cells in Excel

Now, let’s get down to really detailed methods for protecting a spreadsheet. So far, we’ve been password protecting an entire workbook or the structure of an Excel file. In this section, we dig into how to protect your cells in Excel with specific settings you can apply. We cover how to allow or block certain types of changes to be made to parts of your spreadsheet.

To get started, find Excel’s Review tab, and click on Protect Sheet. On the pop-up window, you’ll see a huge set of options. This window allows you to fine-tune how you want to protect the cells in your Excel spreadsheet. For now, let’s leave the settings at their default.

This option allows for very specific protections of your spreadsheet. By default, the options will almost totally lock down the spreadsheet. Let’s add a password so that the sheet is protected. If you press OK at this point, let’s see what happens when you attempt to change a cell.

Excel throws off an error that the cell is protected, which is exactly what we wanted.

Basically, this option is crucial if you want to ensure that your spreadsheet isn’t changed by others who have access to the file. Using the protect sheet feature is a way that you can selectively protect the spreadsheet.

To unprotect the sheet, simply click on the Protect Sheet button and re-enter the password to remove the protections added to the sheet.

Specific Protections in Excel

Let’s take a second look at the options that show when you start to protect a sheet in Excel workbooks.

The Protect Sheet menu lets you refine the options for sheet protection. Each of the boxes on this menu lets the user change slightly more inside of a protected worksheet.

To remove a protection, check the respective box in the list. For example, you could allow the spreadsheet user to Format cells by checking the corresponding box.

Here are two ideas on how you could selectively allow the user to change the spreadsheet:

• Check the Format cells, columns, and rows boxes to let the user change the visual appearance of cells without modifying the original data.
• Insert columns and rows could be checked so that the user can add more data, while protecting the original cells.

The important box to leave checked is the Protect worksheet and contents of locked cells box. This protects the data inside of cells. 

When you’re working with crucial financial data or formulas that will be used in making decisions, you have to maintain control of the data and ensure that it doesn’t change. Using these types of targeted protections is an important Excel skill to master.

Recap and Keep Learning More About Excel

Locking up a spreadsheet before you send it is crucial to protecting your valuable data and making sure that it’s not misused. The tips I shared in this tutorial help you maintain control of that data even after your Excel spreadsheet is forwarded and shared.

All of these tips are additional tools and steps to becoming an advanced Excel user. Protecting your workbooks is a specific skill, but there are lots of ways to improve your performance. As always, there’s room to grow your Excel skills further. Here are some helpful Excel tutorials with important skills to master next:

• PivotTables are a great tool for working with spreadsheet data. Here’s 5 Advanced Excel Pivot Table Techniques to learn now.
• ExcelZoo has a listing of additional tutorials for protecting your workbooks, sheets, and cells.
• Condition formatting changes how a cell looks based on what’s inside of it. Here’s a comprehensive Excel tutorial on How to Use Conditional Formatting.

How do you protect your important business data when sharing it? Let me know in the comments section if you use these protection tools or others I may not know about.

Did you find this post useful?

I believe that life is too short to do just one thing. In college, I studied Accounting and Finance but continue to scratch my creative itch with my work for Envato Tuts+ and other clients. By day, I enjoy my career in corporate finance, using data and analysis to make decisions.

I cover a variety of topics for Tuts+, including photo editing software like Adobe Lightroom, PowerPoint, Keynote, and more. What I enjoy most is teaching people to use software to solve everyday problems, excel in their career, and complete work efficiently. Feel free to reach out to me on my website.

Protecting and unprotecting sheets is a common action for an Excel user. There is nothing worse than when somebody, who doesn’t know what they’re doing, overtypes essential formulas and cell values. It’s even worse when that person happens to be us; all it takes is one accidental keypress, and suddenly the entire worksheet is filled with errors. In this post, we explore using VBA to protect and unprotect sheets.

Protection is not foolproof but prevents accidental alteration by an unknowing user.

Sheet protection is particularly frustrating as it has to be applied one sheet at a time. If we only need to protect a single sheet, that’s fine. But if we have more than 5 sheets, it is going to take a while. This is why so many people turn to a VBA solution.

The VBA Code Snippets below show how to do most activities related to protecting and unprotecting sheets.

Download the example file: Click the link below to download the example file used for this post:

Adapting the code for your purposes

Unless stated otherwise, every example below is based on one specific worksheet. Each code includes Sheets(“Sheet1”)., this means the action will be applied to that specific sheet. For example, the following protects Sheet1.

Sheets("Sheet1").Protect

But there are lots of ways to reference sheets for protecting or unprotecting. Therefore we can change the syntax to use one of the methods shown below.

Using the active sheet

The active sheet is whichever sheet is currently being used within the Excel window.

ActiveSheet.Protect

Applying a sheet to a variable

If we want to apply protection to a sheet stored as a variable, we could use the following.

Dim ws As Worksheet

Set ws = Sheets("Sheet1")

ws.Protect

Later in the post, we look at code examples to loop through each sheet and apply protection quickly.

Let’s begin with some simple examples to protect and unprotect sheets in Excel.

Protect a sheet without a password

Sub ProtectSheet()

'Protect a worksheet
Sheets("Sheet1").Protect

End Sub

Unprotect a sheet (no password)

Sub UnProtectSheet()

'Unprotect a worksheet
Sheets("Sheet1").Unprotect

End Sub

Protecting and unprotecting with a password

Adding a password to give an extra layer of protection is easy enough with VBA. The password in these examples is hardcoded into the macro; this may not be the best for your scenario. It may be better to apply using a string variable, or capturing user passwords with an InputBox.

VBA Protect sheet with password

Sub ProtectSheetWithPassword()

'Protect worksheet with a password
Sheets("Sheet1").Protect Password:="myPassword"

End Sub

VBA Unprotect sheet with a password

Sub UnProtectSheetWithPassword()

'Unprotect a worksheet with a password
Sheets("Sheet1").Unprotect Password:="myPassword"

End Sub

NOTE – It is not necessary to unprotect, then re-protect a sheet to change the settings. Instead, just protect again with the new settings.

Using a password based on user input

Using a password that is included in the code may partly defeat the benefit of having a password. Therefore, the codes in this section provide examples of using VBA to protect and unprotect based on user input. In both scenarios, clicking Cancel is equivalent to entering no password.

Protect with a user-input password

Sub ProtectSheetWithPasswordFromUser()

'Protect worksheet with a password
Sheets("Sheet1").Protect Password:=InputBox("Enter a protection password:")

End Sub

Unprotect with a user-input password

Sub UnProtectSheetWithPasswordFromUser()

'Protect worksheet with a password
Sheets("Sheet1").Unprotect _
    Password:=InputBox("Enter a protection password:")

End Sub

Catching errors when incorrect password entered

If an incorrect password is provided, the following error message displays.

The code below catches the error and provides a custom message.

Sub CatchErrorForWrongPassword()

'Keep going even if error found
On Error Resume Next

'Apply the wrong password
Sheets("Sheet1").Unprotect Password:="incorrectPassword"

'Check if an error has occured
If Err.Number <> 0 Then
    MsgBox "The Password Provided is incorrect"
    Exit Sub
End If

'Reset to show normal error messages
On Error GoTo 0

End Sub

If you forget a password, don’t worry, the protection is easy to remove.

Applying protection to different parts of the worksheet

VBA provides the ability to protect 3 aspects of the worksheet:

• Contents – what you see on the grid
• Objects – the shapes and charts which are on the face of the grid
• Scenarios – the scenarios contained in the What If Analysis section of the Ribbon

By default, the standard protect feature will apply all three types of protection at the same time. However, we can be specific about which elements of the worksheet are protected.

Protect contents

Sub ProtectSheetContents()

'Apply worksheet contents protection only
Sheets("Sheet1").Protect Password:="myPassword", _
    DrawingObjects:=False, _
    Contents:=True, _
    Scenarios:=False

End Sub

Protect objects

Sub ProtectSheetObjects()

'Apply worksheet objects protection only
Sheets("Sheet1").Protect Password:="myPassword", _
    DrawingObjects:=True, _
    Contents:=False, _
    Scenarios:=False

End Sub

Protect scenarios

Sub ProtectSheetScenarios()

'Apply worksheet scenario protection only
Sheets("Sheet1").Protect Password:="myPassword", _
    DrawingObjects:=False, _
    Contents:=False, _
    Scenarios:=True

End Sub

Protect contents, objects and scenarios

Sub ProtectSheetAll()

'Apply worksheet protection to contents, objects and scenarios
Sheets("Sheet1").Protect Password:="myPassword", _
    DrawingObjects:=True, _
    Contents:=True, _
    Scenarios:=True

End Sub

Applying protection to multiple sheets

As we have seen, protection is applied one sheet at a time. Therefore, looping is an excellent way to apply settings to a lot of sheets quickly. The examples in this section don’t just apply to Sheet1, as the previous examples have, but include all worksheets or all selected worksheets.

Protect all worksheets in the active workbook

Sub ProtectAllWorksheets()

'Create a variable to hold worksheets
Dim ws As Worksheet

'Loop through each worksheet in the active workbook
For Each ws In ActiveWorkbook.Worksheets

    'Protect each worksheet
    ws.Protect Password:="myPassword"

Next ws

End Sub

Protect the selected sheets in the active workbook

Sub ProtectSelectedWorksheets()

Dim ws As Worksheet
Dim sheetArray As Variant

'Capture the selected sheets
Set sheetArray = ActiveWindow.SelectedSheets

'Loop through each worksheet in the active workbook
For Each ws In sheetArray

    On Error Resume Next

    'Select the worksheet
    ws.Select

    'Protect each worksheet
    ws.Protect Password:="myPassword"

    On Error GoTo 0

Next ws

sheetArray.Select

End Sub

Unprotect all sheets in active workbook

Sub UnprotectAllWorksheets()

'Create a variable to hold worksheets
Dim ws As Worksheet

'Loop through each worksheet in the active workbook
For Each ws In ActiveWorkbook.Worksheets

'Unprotect each worksheet
ws.Unprotect Password:="myPassword"

Next ws

End Sub

Checking if a worksheet is protected

The codes in this section check if each type of protection has been applied.

Check if Sheet contents is protected

Sub CheckIfSheetContentsProtected()

'Check if worksheets contents is protected
If Sheets("Sheet1").ProtectContents Then MsgBox "Protected Contents"

End Sub

Check if Sheet objects are protected

Sub CheckIfSheetObjectsProtected()

'Check if worksheet objects are protected
If Sheets("Sheet1").ProtectDrawingObjects Then MsgBox "Protected Objects"

End Sub

Check if Sheet scenarios are protected

Sub CheckIfSheetScenariosProtected()

'Check if worksheet scenarios are protected
If Sheets("Sheet1").ProtectScenarios Then MsgBox "Protected Scenarios"

End Sub

Changing the locked or unlocked status of cells, objects and scenarios

When a sheet is protected, unlocked items can still be edited. The following codes demonstrate how to lock and unlock ranges, cells, charts, shapes and scenarios.

When the sheet is unprotected, the lock setting has no impact. Each object becomes locked on protection.

All the examples in this section set each object/item to lock when protected. To set as unlocked, change the value to False.

Lock a cell

Sub LockACell()

'Changing the options to lock or unlock cells
Sheets("Sheet1").Range("A1").Locked = True

End Sub

Lock all cells

Sub LockAllCells()

'Changing the options to lock or unlock cells all cells
Sheets("Sheet1").Cells.Locked = True

End Sub

Lock a chart

Sub LockAChart()

'Changing the options to lock or unlock charts
Sheets("Sheet1").ChartObjects("Chart 1").Locked = True

End Sub

Lock a shape

Sub LockAShape()

'Changing the option to lock or unlock shapes
Sheets("Sheet1").Shapes("Rectangle 1").Locked = True

End Sub

Lock a Scenario

Sub LockAScenario()

'Changing the option to lock or unlock a scenario
Sheets("Sheet1").Scenarios("scenarioName").Locked = True

End Sub

Allowing actions to be performed even when protected

Even when protected, we can allow specific operations, such as inserting rows, formatting cells, sorting, etc. These are the same options as found when manually protecting the sheet.

Allow sheet actions when protected

Sub AllowSheetActionsWhenProtected()

'Allowing certain actions even if the worksheet is protected
Sheets("Sheet1").Protect Password:="myPassword", _
    DrawingObjects:=False, _
    Contents:=True, _
    Scenarios:=False, _
    AllowFormattingCells:=True, _
    AllowFormattingColumns:=True, _
    AllowFormattingRows:=True, _
    AllowInsertingColumns:=False, _
    AllowInsertingRows:=False, _
    AllowInsertingHyperlinks:=False, _
    AllowDeletingColumns:=True, _
    AllowDeletingRows:=True, _
    AllowSorting:=False, _
    AllowFiltering:=False, _
    AllowUsingPivotTables:=False

End Sub

Allow selection of any cells

Sub AllowSelectionAnyCells()

'Allowing selection of locked or unlocked cells
Sheets("Sheet1").EnableSelection = xlNoRestrictions

End Sub

Allow selection of unlocked cells

Sub AllowSelectionUnlockedCells()

'Allowing selection of unlocked cells only
Sheets("Sheet1").EnableSelection = xlUnlockedCells

End Sub

Don’t allow selection of any cells

Sub NoSelectionAllowed()

'Do not allow selection of any cells
Sheets("Sheet1").EnableSelection = xlNoSelection

End Sub

Allowing VBA code to make changes, even when protected

Even when protected, we still want our macros to make changes to the sheet. The following VBA code changes the setting to allow macros to make changes to a protected sheet.

Sub AllowVBAChangesOnProtectedSheet()

'Enable changes to worksheet by VBA code, even if protected
Sheets("Sheet1").Protect Password:="myPassword", _
    UserInterfaceOnly:=True

End Sub

Unfortunately, this setting is not saved within the workbook. It needs to be run every time the workbook opens. Therefore, calling the code in the Workbook_Open event of the Workbook module is probably the best option.

Allowing the use of the Group and Ungroup feature

To enable users to make use of the Group and Ungroup feature of protected sheets, we need to allow changes to the user interface and enable outlining.

Sub AllowGroupingAndUngroupOnProtectedSheet()

'Allow user to group and ungroup whilst protected
Sheets("Sheet1").Protect Password:="myPassword", _
    UserInterfaceOnly:=True

Sheets("Sheets1").EnableOutlining = True

End Sub

As noted above the UserInterfaceOnly setting is not stored in the workbook; therefore, it needs to be run every time the workbook opens.

Conclusion

Wow! That was a lot of code examples; hopefully, this covers everything you would ever need for using VBA to protect and unprotect sheets.

Related posts:

• Office Scripts – Workbook & worksheet protection
• VBA Code to Password Protect an Excel file
• VBA code to Protect and Unprotect Workbooks