Преобразовать цифру в месяц в excel - Word и Excel - помощь в работе с программами

Как вывести месяц из даты

На примерах мы покажем, как получить месяц из даты в таблицах Excel, преобразовать число в его название и наоборот, а также многое другое.

Думаю, вы уже знаете, что дата в Excel хранится в виде порядковых чисел. Поэтому в явном виде в ней нельзя увидеть ни день, ни месяц, ни год. Тем не менее, очень часто работать с ними по отдельности крайне необходимо. Сейчас мы рассмотрим, как выделить месяц из даты в виде числа или текста.

В этом руководстве вы узнаете:

Функция МЕСЯЦ
Номер месяца — по дате
Извлекаем название месяца из даты
Получаем месяц прописью при помощи форматирования
Как гибко настроить имя месяца при помощи формул
Как название месяца превратить в число
Использование Power Query

Функция МЕСЯЦ в Excel – синтаксис и использование

Microsoft Excel предоставляет специальную функцию МЕСЯЦ() для извлечения месяца из даты. Она возвращает его порядковый номер в диапазоне от 1 (январь) до 12 (декабрь).

Функцию МЕСЯЦ() можно использовать во всех версиях Excel, и ее синтаксис настолько прост, насколько это возможно:

МЕСЯЦ(дата)

Для корректной работы этой функции аргумент следует вводить с помощью функции ДАТА(год; месяц; день). Либо ссылаться на ячейку, в которой она корректно записана.

Например, формула =МЕСЯЦ(ДАТА(2021;2;5)) возвращает 2, поскольку ДАТА представляет 5 февраля 2021 года.

Формула =МЕСЯЦ(«1-Мар-2020») также работает нормально. Дело в том, что если вы введете такой текст в ячейку, то Excel сразу же распознает его как дату. То же самое происходит и в формуле.

На практике гораздо удобнее ссылаться на ячейку с датой или возвращать ее какой-либо другой функцией, чем прописывать прямо в формуле. Например:

=МЕСЯЦ(A1) — возвращает месяц из ячейки A1.

=МЕСЯЦ(СЕГОДНЯ()) — возвращает номер текущего месяца.

На первый взгляд функция МЕСЯЦ() в Excel может показаться простой. Но просмотрите приведенные ниже примеры, и вы удивитесь, узнав, сколько полезных вещей она может делать.

Как определить номер месяца по дате в Excel

Есть несколько способов перевести дату в месяц. Какой из них выбрать, зависит от того, какого именно результата вы пытаетесь достичь.

Функция МЕСЯЦ() – определить номер месяца из даты.

Это наиболее очевидный и простой способ. Например:

=МЕСЯЦ(A2) – возвращает месяц из даты в ячейке A2.
=МЕСЯЦ(ДАТА(2020,7,15)) – возвращает число 7, соответствующее июлю.
=МЕСЯЦ(«15-Апр-2020») – очевидно, возвращает число.

2. Функция ТЕКСТ() – вывести месяц в виде текстовой строки.

Альтернативный способ получить номер месяца из даты Excel — использовать функцию ТЕКСТ:

=ТЕКСТ(A2; «м») — возвращает номер без нуля в начале, от 1 до12.
=ТЕКСТ(A2;»мм») — возвращает номер всегда из двух цифр, от 01 до 12.

Будьте очень внимательны при использовании текстовых функций, потому что они всегда возвращают порядковые номера месяцев в виде текстовых значений. И если вы планируете выполнить какие-то дальнейшие вычисления или использовать полученные числа в других формулах, вам лучше придерживаться функции МЕСЯЦ().

Или же при помощи несложного математического действия преобразуйте текст в число:

=—ТЕКСТ(A2; «м»)

На следующем скриншоте показаны результаты всех приведенных выше формул. Обратите внимание на выравнивание по правому краю чисел, возвращаемых функцией МЕСЯЦ() (ячейки C2 и C3), в отличие от выравнивания по левому краю текстовых значений, возвращаемых функциями ТЕКСТ (ячейки C5 и C6).

Как получить название месяца из даты

Если вы хотите видеть название месяца, а не число, вы снова используете функцию ТЕКСТ, но с другим шаблоном формата:

=ТЕКСТ(A2;»МММ») — возвращает сокращенное трёхбуквенное название, с «янв» по «дек».
=ТЕКСТ(A2;»ММММ») — выводит полное название, с января по декабрь.

Если вы на просто хотите вывести название месяца вместо полной даты, тогда вам не нужны никакие формулы.

Выберите ячейку с датой, нажмите Ctrl + 1, чтобы открыть диалоговое окно «Формат ячеек». На вкладке «Число» выберите «Все форматы» и введите «МММ» или «ММММ» в поле «Тип», чтобы отобразить сокращенное или полное название соответственно. В этом случае ваши данные останутся полностью функциональными датами Excel, которые вы можете использовать в расчетах и других формулах. Дополнительные сведения об изменении формата см. в статье Создание пользовательского формата даты в Excel.

Автоматическое заполнение.

После того как вы отформатировали столбец значений даты в длинном формате, показанном выше, вы сможете вывести месяц в виде текстового значения, используя автоматическое заполнение.

Начните вводить несколько названий месяца в столбце рядом с отформатированными датами.

Excel угадает закономерность и выведет предлагаемое заполнение в светло-сером цвете. Вы можете нажать Enter, чтобы принять эти значения.

Таким образом, названия месяцев будут существовать как текстовые значения, а не только отформатированные даты.

Как преобразовать номер месяца в его название.

Использование форматирования

Предположим, у вас есть список чисел (от 1 до 12) на листе Excel, который вы хотите конвертировать в названия месяцев. Для этого можно использовать любую из следующих формул:

Чтобы вернуть сокращенное название (янв – дек):

=ТЕКСТ(A2*28;»МММ»)

=ТЕКСТ(ДАТА(2020;A4;1);»МММ»)

Чтобы вернуть полное имя (январь – декабрь):

=ТЕКСТ(A2*28;»ММММ»)

=ТЕКСТ(ДАТА(2020;A4;1);»ММММ»)

Во всех приведенных выше формулах A2 – это ячейка с номером. И единственная реальная разница между формулами – это код формата:

«МММ» — трехбуквенное сокращение, например янв – дек,
«ММММ» — название полностью.

3. Чтобы вернуть только первую букву:

=ТЕКСТ(ДАТА(2020;A4;1);»МММММ»)

«МММММ» — только первая буква названия.

Как работают эти формулы?

Excel считает число 1 днем 1 января 1900 года. Умножая 1, 2, 3 и т. д. на 28, вы получаете дни 28, 56, 84, и т. д. 1900 года, то есть какое-то число в январе, феврале, марте и т. д. Код формата «МММ» или «ММММ» выводит название месяца. А год для нас здесь совсем не важен.

Вторая же формула просто создает дату первого числа соответствующего месяца 2020 года.

Более гибкий способ – функции ВЫБОР, ИНДЕКС или ПЕРЕКЛЮЧ.

Для максимальной гибкости вы можете создавать свои собственные наименования с помощью функции ВЫБОР следующим образом:

=ВЫБОР(МЕСЯЦ(A3);»янв»;»фев»;»мар»;»апр»;»май»;»июн»;»июл»;»авг»;»сен»;»окт»;»ноя»;»дек»)

Введите названия месяцев, которые вы хотите вернуть (настроенные по желанию) как значения в функции ВЫБОР, после первого аргумента, который вводится как МЕСЯЦ([дата]). Функция МЕСЯЦ() извлечет номер (число от 1 до 12), и ВЫБОР будет использовать его для возврата n-го значения в списке.

Использование ВЫБОР – это более громоздкая формула. Но это более гибкое решение, поскольку позволяет вывести как результат любые значения, которые вы пожелаете (т.е. вы можете использовать значения, которые являются настраиваемыми, сокращенными, не сокращенными, в другом падеже, на другом языке).

Вот, например:

=ВЫБОР(МЕСЯЦ(A4);»январь»;»февраль»;»Март»;»апрель»;»май»;»июнь»;»июль»;»август»;»сентябрь»;»октябрь»;»ноябрь»;»декабрь»)

Еще один интересный вариант – использование функции ИНДЕКС. Вновь у нас в качестве аргумента используется массив названий, которых мы можем настраивать так, как будет необходимо.

=ИНДЕКС({«январь»;»февраль»;»Март»;»апрель»;»май»;»июнь»;»июль»;»август»;»сентябрь»;»октябрь»;»ноябрь»;»декабрь»};МЕСЯЦ(A7))

А второй аргумент – это порядковый номер месяца. Его можно указать явным образом либо получить функцией МЕСЯЦ(). Из массива будет извлечено значение, порядковый номер которого мы указали.

И, наконец, третий вариант – функция ПЕРЕКЛЮЧ. Вновь извлекаем порядковый номер как числовое значение от 1 до 12.

А затем пишем вот такую формулу:

=ПЕРЕКЛЮЧ(МЕСЯЦ(A3);1;»янв»;2;»фев»;3;»мар»;4;»апр»;5;»май»;6;»июн»;7;»июл»;8;»авг»;9;»сен»;10;»окт»;11;»ноя»;12;»дек»)

Как видите, здесь тоже каждому числу соответствует определённое значение. Его мы и выводим в столбце B.

Как преобразовать название месяца в число

Теперь рассмотрим противоположную по логике задачу. Существуют две функции Excel, которые могут помочь вам преобразовать названия месяцев в числа – ДАТАЗНАЧ() и МЕСЯЦ(). Функция Excel ДАТАЗНАЧ() преобразует дату, сохраненную в виде текста, в порядковый номер, который Microsoft Excel распознает как дату. Затем функция МЕСЯЦ() извлекает из неё номер месяца.

Полная формула выглядит следующим образом:

=МЕСЯЦ(ДАТАЗНАЧ(«1-«&A2))

Где A2 – это ячейка, содержащая название месяца, которое вы хотите превратить в число.

Конструкция

«1-«&

добавляется к значению ячейки, чтобы дать понять Экселю, что это дата. Иначе говоря, если вы в ячейку руками введёте, к примеру,

1-февраль

или

1-фев

то программа определит вашу информацию как 1 февраля текущего года, дополнит недостающее содержимое в ячейке и применит формат даты для её отображения.

То же самое происходит и в формуле ДАТАЗНАЧ, когда мы к единице дописываем имя месяца с дефисом. Единственное важное условие здесь – нужно использовать именительный падеж, как это принято по умолчанию в Windows.

Однако, достаточно даже первых трёх букв месяца, чтобы не заморачиваться с падежами 😊.

Так тоже работает.

Использование Power Query.

Надстройка Excel Power Query может помочь вам перевести дату в месяц и извлекать его номер или название.

Итак, у нас есть список дат и нужно вытащить из них месяц.

Прежде всего, преобразуйте ваши данные в таблицу.
После этого выберите любую из ячеек в таблице и перейдите на вкладку «Данные».
Нажмите кнопку «Из таблицы».

Ваша таблица будет загружена в Power Query.

Здесь у вас есть два варианта действий: либо добавить новый столбец, в который будет записан нужный результат, либо сразу преобразовать ваши даты. Пропустите следующие два шага, если вы просто хотите преобразовать дату в месяц без добавления нового столбца.

Кликните правой кнопкой мыши заголовок столбца.
Нажмите «Создать дубликат».

Кликните по заголовку нужного столбца правой кнопкой мыши.
Перейдите Преобразование ➜ Месяц ➜ Название месяца.

Ваши даты тут же будут преобразованы, как на скриншоте ниже.

Еще одна вещь, которую имеет смысл сделать: щелкните правой кнопкой мыши заголовок столбца и переименуйте его в «Месяц».
Теперь нажмите «Закрыть и загрузить», и ваши данные будут перенесены в рабочий лист.

Плюсы —

Ваши исходные данные ни при каком раскладе не пострадают.

Минусы —

У вас должен быть установлен Power Query в вашей версии Excel. Название месяца будет полным, в именительном падеже.

Вот основные способы, как можно в Excel вывести месяц из даты. Надеюсь, эти советы были вам полезны.

Как перевести время в число — В статье рассмотрены различные способы преобразования времени в десятичное число в Excel. Вы найдете множество формул для преобразования времени в часы, минуты или секунды. Поскольку Microsoft Excel использует числовую систему для работы с временем, вы можете…

Формат времени в Excel — Вы узнаете об особенностях формата времени Excel, как записать его в часах, минутах или секундах, как перевести в число или текст, а также о том, как добавить время с помощью…

Как быстро вставить сегодняшнюю дату в Excel? — Это руководство показывает различные способы ввода дат в Excel. Узнайте, как вставить сегодняшнюю дату и время в виде статической метки времени или динамических значений, как автоматически заполнять столбец или строку…

Количество рабочих дней между двумя датами в Excel — Довольно распространенная задача: определить количество рабочих дней в период между двумя датами – это частный случай расчета числа дней, который мы уже рассматривали ранее. Тем не менее, в Excel для…

Источник

How to convert a month’s name, such as January, into a number using a formula in Excel; also, how to do the reverse, convert a number into the name of the month.

Sections:

Convert Month Name to Number

Convert Month Number to Name

Notes

Convert Month Name to Number

=MONTH(DATEVALUE(A2&1))

(Alternate formula — not as robust)

=MONTH(A2&1)

Result:

Copy the formula down for the entire list and it will work without issue.

How the Formula Works

DATEVALUE converts the date from a text format to a readable Excel format; however, we have to attach a 1 to the name of the month in order for this to work, which is why there is &1 in the formula. This tells the DATEVALUE function to get the date for, for instance, January 1st.

MONTH function takes the date returned by the DATEVALUE function and strips out everything except for the month. This is what returns the actual number for the month.

3 Letter Month Names

If you have 3 letter month abbreviations, this formula will work the same:

Convert Month Number to Name

=TEXT(DATE(2018,B2,1),"mmmm")

Result:

How the Formula Works

DATE(2018,B2,1) gets an actual date from the single number that represents the month.

2018 is a placeholder for the year; it doesn’t matter what year you use.

1 is a placeholder for the day of the month.

B2 is the cell that contains the number of the month.

DATE is the function that combines the previous values to create a working date in Excel.

TEXT is the function that takes the working date and pulls out the text name for the month.

mmmm is what tells the TEXT function to return the full name of the month. If you replace this with only 3 m’s like this mmm then the abbreviated version of the month will be returned.

3 Letter Month Names

=TEXT(DATE(2018,B3,1),"mmm")

The difference here is that there are three m letters instead of four in the TEXT function.

Notice mmm instead of mmmm

Get Month Name from Full Date

If you are starting with a complete date instead of just the number of the month, you can easily get the name of the month like this:

=TEXT(E2,"mmmm")

Result:

Notes

Once you get a list of month names or numbers, you will often want to «freeze» that data. In this case, you can copy/paste-special values to quickly remove all formulas and keep only the visible values. To do this, select the desired cells and hit Ctrl+C and then Alt+E+S+V Enter.

Make sure to download the attached workbook to view these examples in Excel.

Subscribe for Weekly Tutorials

BONUS: subscribe now to download our Top Tutorials Ebook!

Источник

17 авг. 2022 г.
читать 2 мин

Вы можете использовать одну из следующих формул для преобразования даты в месяц и год в Excel:

Формула 1: преобразование даты в месяц и полный год (например, 01/2022)

=TEXT( A1 , "mm/yyyy")

Формула 2: преобразование даты в месяц и две последние цифры года (например, 01/22)

=TEXT( A1 , "mm/yy")

Формула 3: преобразование даты в сокращенный месяц и полный год (например, январь 2022 г.)

=TEXT( A1 , "mmm. yyyy")

Формула 4: преобразование даты в полный месяц и полный год (например, январь 2022 г.)

=TEXT( A1 , "mmmm yyyy")

Обратите внимание, что каждая формула предполагает, что дата находится в ячейке A1 .

В следующих примерах показано, как использовать каждую формулу на практике.

Пример 1: преобразование даты в месяц и полный год

Мы можем использовать следующую формулу для преобразования даты в месяц и полный год:

=TEXT( A2 , "mm/yyyy")

Мы можем ввести эту формулу в ячейку B2 и перетащить ее в каждую оставшуюся ячейку в столбце B:

Столбец B отображает месяц и полный год для каждой даты в столбце A.

Пример 2. Преобразование даты в месяц и две последние цифры года

Мы можем использовать следующую формулу для преобразования даты в месяц и две последние цифры года:

=TEXT( A2 , "mm/yy")

Мы можем ввести эту формулу в ячейку B2 и перетащить ее в каждую оставшуюся ячейку в столбце B:

Столбец B отображает месяц и две последние цифры года для каждой даты в столбце A.

Пример 3: преобразование даты в сокращенный месяц и полный год

Мы можем использовать следующую формулу для преобразования даты в сокращенное название месяца и полный год:

=TEXT( A2 , "mmm. yyyy")

Мы можем ввести эту формулу в ячейку B2 и перетащить ее в каждую оставшуюся ячейку в столбце B:

Столбец B отображает сокращенный месяц и полный год для каждой даты в столбце A.

Пример 4: преобразование даты в полный месяц и полный год

Мы можем использовать следующую формулу для преобразования даты в полное название месяца и полный год:

=TEXT( A2 , "mmmm yyyy")

Мы можем ввести эту формулу в ячейку B2 и перетащить ее в каждую оставшуюся ячейку в столбце B:

Столбец B отображает полный месяц и полный год для каждой даты в столбце A.

Дополнительные ресурсы

В следующих руководствах объясняется, как выполнять другие распространенные задачи в Excel:

Как преобразовать дату в квартал и год в Excel
Как сравнить даты без времени в Excel
Как фильтровать даты по месяцам в Excel

Источник

Функции и формулы для преобразования номера в название месяца

Время от времени возникает необходимость изменить порядковый номер месяца на название и наоборот (например, 3 на «Март» или «Октябрь» на 10).

Сначала рассмотрим, каким способом изменить номер месяца его название. А после речь пойдет о том, как выполнить обратный процесс, то есть изменить название на соответствующий ему порядковый номер.

Изменение порядкового номера месяца на его название в Excel

Первый способ, который пришел мне на ум, это просто составить список ячеек с последовательными названиями месяцев, а затем использовать функцию:

=ИНДЕКС($A$2:$A$13;B2)

где $A$2:$A$13 – это, конечно, диапазон с названиями месяцев, а B2 — ячейка с порядковым номером в году, для которого мы ищем его название.

По схожему принципу с функцией ИНДЕКС работает другая функция, которую вы можете использовать — ВЫБОР. Разница состоит в том, что она не использует ячейки листа, в которых хранятся названия месяцев. Названия месяцев просто даем в качестве аргумента функции.

Функция ВЫБОР принимает в качестве аргументов номер индекса (который определяет какой из элементов в списке значений вернуть в качестве результата) и список значений. Интересующиеся подробностями, конечно же, могут скачать файл с примерами.

Если в качестве списка значений указать названия месяцев (по очередности), а в качестве индекса — ячейку с номером месяца, то функция вернет соответствующее ему название для каждого заданного числа.

Вариант2 автономный и более удобный для использования формулы на разных листах или рабочих книга без применения внешних ссылок.

Примеры как получить название месяца из даты в Excel

Подобно тому как показано выше, в случае, когда необходимо «вытянуть» название месяца из даты, необходимо воспользоваться помощью функции МЕСЯЦ.

Если у вас есть список с датами и нужно «вытянуть» из них название месяцев, то функция ИНДЕКС в приведенном выше виде выдаст ошибку. Если вы хотите, чтобы формула работала правильно, необходимо при помощи функции МЕСЯЦ «вытянуть» номер месяца из ячейки с датой. Формула будет выглядеть следующим образом:

=ИНДЕКС($A$2:$A$13;МЕСЯЦ(E2))

Еще один способ (возможно, самый удобный) — использовать функцию ТЕКСТ (все, что делает функция ТЕКСТ, это преобразует числовое значение в текст с соответствующим форматированием).

Если у вас есть список с датами и нужно «вытянуть» из них название месяцев, просто введите:

=ТЕКСТ(E2;»mmmm»)

где E2 – это, конечно, ячейка с датой.

Если вы работаете только с числами (1-12), функция в приведенной выше форме будет работать неправильно. Вы должны помнить, что число 1 для Excelя это 1 января 1900 года, число 2 — 2 января 1900 года и так далее. Это все тот же месяц — январь. Поэтому ТЕКСТ(E2;»ММММ») возвращает «Январь» для каждого номера месяца.

Однако вы можете легко изменить последовательные числа на номера месяцев. Например, вы можете умножить каждое число на среднее количество дней в месяце (30).

Формула функции:

=ТЕКСТ(B2*30;»mmmm»)

будет работать правильно, и в качестве результата вернет названия месяцев.

Как преобразовать название месяца в порядковый номер

Теперь будем преобразовывать обратно – имя месяца в соответствующий ему порядковый номер в году.

Пример1. Формула первая:

=МЕСЯЦ(ДАТАЗНАЧ(A2&»1″))

Значение Декабрь1 Excel автоматически преобразует в дату дек.01. Далее функция ДАТАЗНАЧ преобразует дату в число после с помощью функции МЕСЯЦ мы получаем порядковый номер в году для текущего названия месяца. По сути формулу можно упростить:

=МЕСЯЦ(A2&»1″)

Пример2. Формула вторая:

=ВПР(A2;$G$1:$H$12;2;0)

Пример3. Формула третья:

ВПР.

Наиболее оптимальным вариантом является лаконичная формула =МЕСЯЦ(A2&»1″). В ней не нужно резервировать названия месяцев и присваивать им соответственные порядковые номера. К тому же в ней используется всего лишь одна функция.

Источник

преобразование числа в месяц

Автор Kn793, 24.06.2008, 19:13

« назад — далее »

Здравствуйте!
Подскажите пожалуйста как можно преобразовать цифру, папример 5 в месяц текстом, тут «май». А лучше как если есть дата записанная типом дата преобразавать её в месяц и год записанные текстом.

Цитата: Kn793 от 24.06.2008, 19:13
А лучше как если есть дата записанная типом дата преобразавать её в месяц и год записанные текстом.

Если дата в A1, тогда:

=ВЫБОР(МЕСЯЦ(A1);»Январь»;»Февраль»;»Март»;»Апрель»;»Май»;…)&» «&ГОД(A1)&» года»

PS: Вместо троеточия продолжи сам.

Знания недостаточно, необходимо применение. Желания недостаточно, необходимо действие. (с) Брюс Ли

О я тоже недавно такое хотел.
Вообще я сделал вот так: =ТЕКСТ(B5;»[$-419]ММММ ГГГГ;@») ,
где B5 — это ячейка с датой (именно с датой),
чтобы превратить дату в текст просто с месяцем, например май, нужно:
выделить ячейку с этой датой, зайти в меню формат ячейки, выбрать формат из группы Дата, который вам больше нравится, ничего не нажимая перейти в группу Все форматы, там скопировать то, как записан этот формат, типа
[$-419]ММММ ГГГГ;@ . И вставить это в верхнюю формулу не забыв про кавычки.
Некоторых форматов нет в группе Дата, но их можно наколхозить самому, используя примеры из группы Все форматы.

Можно попробовать так, с помощью VBA:
Заводим определенный массив с названиями месяцев и сортировкой индексов массива соответственно названию месяца. С помощью функции mid() вырезаем из значения даты число месяца. Далее определяем название месяца в массиве через индекс массива равный числу месяца из даты. Для автоматизации вешаем все это на какое -нибудь событие листа или ячейки, например Worksheet_SelectionChange(). Теперь собственно код:
Dim M(12) As String
M(1) = «Январь»
M(2) = «Февраль»
…
M(11) = «Ноябрь»
M(12) = «Декабрь»
Range(«k13»).Value = M(Mid(Calendar1.Value, 4, 2))
/где-Range(ячейка).Value-Ваша ячейка для вывода текстового значения,
/Calendar1- объект календарь(у меня дата выбирается через календарь, в другом случае можно указать ячейку со значением даты, например: Mid(Range(«k13»).Value, 4, 2) -(даная функция вырезает из значения даты информацию о месяце в числовом виде)

=ТЕКСТ(A1;»ММММ ГГГГ»)&» года»

Профессиональные приемы работы в Microsoft Excel
►
Обмен опытом
►
Microsoft Excel
►
преобразование числа в месяц

Источник