Поиск слова vba word

• Remove From My Forums

All replies

• You’re doing a wildcard search for \\*.doc. In VBA, this is done as follows:

  Sub FindIt()
      Selection.HomeKey Unit:=wdStory
      With Selection.Find
          .ClearFormatting
          .Text = "\\*.doc"
          .Forward = True
          .Wrap = wdFindStop
          .Format = False
          .MatchCase = False
          .MatchWholeWord = False
          .MatchAllWordForms = False
          .MatchSoundsLike = False
          .MatchWildcards = True
          .Execute
      End With
  End Sub

  or if you want to find all occurrences:

  Sub FindIt()
      Selection.HomeKey Unit:=wdStory
      With Selection.Find
          .ClearFormatting
          .Text = "\\*.doc"
          .Forward = True
          .Wrap = wdFindStop
          .Format = False
          .MatchCase = False
          .MatchWholeWord = False
          .MatchAllWordForms = False
          .MatchSoundsLike = False
          .MatchWildcards = True
          Do While .Execute
              ' Do something here
          Loop
      End With
  End Sub

  ---

  Regards, Hans Vogelaar (http://www.eileenslounge.com)

• Hi,

  Thanks for the reply.

  I getting the error when i use the code. please find below the changes i made

    doc.ActiveDocument.Application.Selection.HomeKey Unit:=wdStory

   
  With Selection.Find
          .ClearFormatting
          .Text = «\\*.doc»
          .Forward = True
          .Wrap = wdFindStop
          .Format = False
          .MatchCase = False
          .MatchWholeWord = False
          .MatchAllWordForms = False
          .MatchSoundsLike = False
          .MatchWildcards = True
          .Execute
      End With

  Error :

  Wrong number of arguments or invalid property

  Thanks in advance.

• Hi,

  my requirement is from excel VBA i will open the document and will search in that document  so only i have used

    doc.ActiveDocument.Application.Selection.HomeKey Unit:=wdStory

  Thanks

• It might have helped had you said you were woking from Excel — it isn’t clear from the forum

  In this case you could use the following which will list the paths in column A of the activesheet. You can change that in the code where marked in bold

  Sub FindIt()
  Dim wdApp As Object
  Dim wdDoc As Object
  Dim oRng As Object
  Dim bStarted As Boolean
  Dim i As Integer
      On Error Resume Next
      Set wdApp = GetObject(, «Word.Application»)
      If Err Then
          Set wdApp = CreateObject(«Word.Application»)
          bStarted = True
      End If
      On Error GoTo 0
      ActiveWorkbook.Save
      ‘Note that opening the document in Word if it is already open does not cause an error. It just sets the value to that open document.
      Set wdDoc = wdApp.Documents.Open(«C:PathDocumentName.docx«)
      Set oRng = wdDoc.Range
      With oRng.Find
          i = 1
          Do While .Execute(FindText:=.Text = «\\*.doc», MatchWildCards:=True)
              Range(«A» & i) = oRng.Text
              oRng.collapse 0
              i = i + 1
          Loop
      End With
      wdDoc.Close 0
      If bStarted Then wdApp.Quit
      Set oRng = Nothing
      Set wdDoc = Nothing
      Set wdApp = Nothing
  End Sub

  ---

  Graham Mayor — Word MVP
  www.gmayor.com
  

  • Edited by

    Tuesday, December 30, 2014 7:25 AM

• Hi,

  many Thanks for the reply

  oRng.Text is always returning 0.

  but i need the path to be written in the excel.

  Thanks.

• Hi,

  My requirement is

  I have 100 + word documents.

  In that i have some paths hard coded in header,footer and in the content.

  I need to take all those paths and need to write in excel sheet.

  I know only the starting and the end letters of the document. starting is \\ and the end is .doc.

  I need the complete paht between these.

  Many thanks in advance.

  Thanks

• Apologies, the line

  Do While .Execute(FindText:=.Text = «\\*.doc», MatchWildCards:=True)

  should read

  Do While .Execute(FindText:=»\\*.doc», MatchWildCards:=True)

  It will however only work for the document body. If the string is in a different story range you will have to loop through those story ranges e.g.

  Sub FindIt()
  Dim wdApp As Object
  Dim wdDoc As Object
  Dim oRng As Object
  Dim bStarted As Boolean
  Dim i As Integer
      On Error Resume Next
      Set wdApp = GetObject(, «Word.Application»)
      If Err Then
          Set wdApp = CreateObject(«Word.Application»)
          bStarted = True
      End If
      On Error GoTo 0
      ActiveWorkbook.Save
      Set wdDoc = wdApp.Documents.Open(«C:PathDocumentName.docx»)
      i = 1
      For Each oRng In wdDoc.StoryRanges
          With oRng.Find
              .MatchWildcards = True
              Do While .Execute(FindText:=»\\*.doc»)
                  Range(«A» & i) = oRng.Text
                  oRng.Collapse 0
                  i = i + 1
              Loop
          End With
          If oRng.StoryType <> wdMainTextStory Then
              While Not (oRng.NextStoryRange Is Nothing)
                  Set oRng = oRng.NextStoryRange
                  With oRng.Find
                      .MatchWildcards = True
                      Do While .Execute(FindText:=»\\*.doc»)
                          Range(«A» & i) = oRng.Text
                          oRng.Collapse 0
                          i = i + 1
                      Loop
                  End With
              Wend
          End If
      Next oRng
      wdDoc.Close 0
      If bStarted Then wdApp.Quit
      Set oRng = Nothing
      Set wdDoc = Nothing
      Set wdApp = Nothing
  End Sub

  ---

  Graham Mayor — Word MVP
  www.gmayor.com
  

  • Edited by
    Graham MayorMVP
    Tuesday, December 30, 2014 10:51 AM

• Hi,

  Many Thanks for the reply. This helped me a lot. I have an another issue. When i try to convert my .dot files to .dotm the macros are not getting converted.  Any Idea please.

  Thanks

• Hi,

  Thanks for the help.

  I there any way to find/search for the text in notepad through VBA.

  Thanks

• You can open a text file in Word, edit it and then save it.

  ---

  Regards, Hans Vogelaar (http://www.eileenslounge.com)

• Hi,

  I have a footer document which is kept seperately in the some other folder.

  I have thousands of files which refer to that footer document. I am planning to write an ini file to automate the usage.

  IS there any way to read the data from the another file to one file using Ini.

  Thanks.