Макросы excel ввод данных в ячейку

В приложении Excel все данные как правило находятся в ячейках на листах, с которыми макросы работают как с базой данных. Поэтому, начинающему программисту VBA важно понимать как читать значения из ячейки Excel в переменные или массивы и, наоборот, записывать какие-либо значения на лист в ячейки.

Обращение к конкретной ячейке

Прежде чем читать или записывать значение в ячейке, нужно определиться с тем, как можно указать какая именно ячейка нам необходима.

Полный путь к ячейке A1 в Книге1 на Листе1 можно записать двумя вариантами:

• С помощью Range
• С помощью Cells

Пример 1: Обратиться к ячейке A3 находящейся в Книге1 на Листе1

Workbooks("Книга1.xls").Sheets("Лист1").Range("A3") ' Обратиться к ячейке A3
Workbooks("Книга1.xls").Sheets("Лист1").Cells(3, 1) ' Обратиться к ячейке в 3-й строке и 1-й колонке (A3)

Однако, как правило, полный путь редко используется, т.к. макрос работает с Книгой, в которой он записан и часто на активном листе. Поэтому путь к ячейке можно сократить и написать просто:

Пример 2: Обратиться к ячейке A1 в текущей книге на активном листе

Range("A1")
Cells(1, 1)

Если всё же путь к книге или листу необходим, но не хочется его писать при каждом обращении к ячейкам, можно использовать конструкцию With End With. При этом, обращаясь к ячейкам, необходимо использовать в начале «.» (точку).

Пример 3: Обратиться к ячейке A1 и B1 в Книге1 на Листе2.

With Workbooks("Книга1").Sheets("Лист2")
  ' Вывести значение ячейки A1, которая находится на Листе2
  MsgBox .Range("A1")
  ' Вывести значение ячейки B1, которая находится на Листе2
  MsgBox .Range("B1")
End With

Так же, можно обратиться и к активной (выбранной в данный момент времени) ячейке.

Пример 4: Обратиться к активной ячейке на Листе3 текущей книги.

Application.ActiveCell ' полная запись
ActiveCell ' краткая запись

Чтение значения из ячейки

Есть 3 способа получения значения ячейки, каждый из которых имеет свои особенности:

• Value2 — базовое значение ячейки, т.е. как оно хранится в самом Excel-е. В связи с чем, например, дата будет прочтена как число от 1 до 2958466, а время будет прочитано как дробное число. Value2 — самый быстрый способ чтения значения, т.к. не происходит никаких преобразований.
• Value — значение ячейки, приведенное к типу ячейки. Если ячейка хранит дату, будет приведено к типу Date. Если ячейка отформатирована как валюта, будет преобразована к типу Currency (в связи с чем, знаки с 5-го и далее будут усечены).
• Text — визуальное отображение значения ячейки. Например, если ячейка, содержит дату в виде «число месяц прописью год», то Text (в отличие от Value и Value2) именно в таком виде и вернет значение. Использовать Text нужно осторожно, т.к., если, например, значение не входит в ячейку и отображается в виде «#####» то Text вернет вам не само значение, а эти самые «решетки».

По-умолчанию, если при обращении к ячейке не указывать способ чтения значения, то используется способ Value.

Пример 5: В ячейке A1 активного листа находится дата 01.03.2018. Для ячейки выбран формат «14 марта 2001 г.». Необходимо прочитать значение ячейки всеми перечисленными выше способами и отобразить в диалоговом окне.

MsgBox Cells(1, 1)        ' выведет 01.03.2018
MsgBox Cells(1, 1).Value  ' выведет 01.03.2018
MsgBox Cells(1, 1).Value2 ' выведет 43160
MsgBox Cells(1, 1).Text   ' выведет 01 марта 2018 г.

Dim d As Date
d = Cells(1, 1).Value2    ' числовое представление даты преобразуется в тип Date
MsgBox d                  ' выведет 01.03.2018

Пример 6: В ячейке С1 активного листа находится значение 123,456789. Для ячейки выбран формат «Денежный» с 3 десятичными знаками. Необходимо прочитать значение ячейки всеми перечисленными выше способами и отобразить в диалоговом окне.

MsgBox Range("C1")        ' выведет 123,4568
MsgBox Range("C1").Value  ' выведет 123,4568
MsgBox Range("C1").Value2 ' выведет 123,456789
MsgBox Range("C1").Text   ' выведет 123,457р.

Dim c As Currency
c = Range("C1").Value2    ' значение преобразуется в тип Currency
MsgBox c                  ' выведет 123,4568

Dim d As Double
d = Range("C1").Value2    ' значение преобразуется в тип Double
MsgBox d                  ' выведет 123,456789

При присвоении значения переменной или элементу массива, необходимо учитывать тип переменной. Например, если оператором Dim задан тип Integer, а в ячейке находится текст, при выполнении произойдет ошибка «Type mismatch». Как определить тип значения в ячейке, рассказано в следующей статье.

Пример 7: В ячейке B1 активного листа находится текст. Прочитать значение ячейки в переменную.

Dim s As String
Dim i As Integer
s = Range("B1").Value2 ' успех
i = Range("B1").Value2 ' ошибка

Таким образом, разница между Text, Value и Value2 в способе получения значения. Очевидно, что Value2 наиболее предпочтителен, но при преобразовании даты в текст (например, чтобы показать значение пользователю), нужно использовать функцию Format.

Запись значения в ячейку

Осуществить запись значения в ячейку можно 2 способами: с помощью Value и Value2. Использование Text для записи значения не возможно, т.к. это свойство только для чтения.

Пример 8: Записать в ячейку A1 активного листа значение 123,45

Range("A1") = 123.45
Range("A1").Value = 123.45
Range("A1").Value2 = 123.45

Все три строки запишут в A1 одно и то же значение.

Пример 9: Записать в ячейку A2 активного листа дату 1 марта 2018 года

Cells(2, 1) = #3/1/2018#
Cells(2, 1).Value = #3/1/2018#
Cells(2, 1).Value2 = #3/1/2018#

В данном примере тоже запишется одно и то же значение в ячейку A2 активного листа.

Визуальное отображение значения на экране будет зависеть от того, какой формат ячейки выбран на листе.

Последовательный ввод данных в Excel

Добрый день, уважаемые читатели блога и зрители канала! 

Отгремели новогодние праздники — пора браться за работу. Сегодня отвечу на очередной вопрос о вводе данных. Оговорюсь — речь пойдёт о последовательном вводе, когда мы вносим данные в таблицу ячейка за ячейкой. 

Если не отклоняться от стандартного способа ввода, то наши действия укладываются в следующий алгоритм:

Ввод данных -> Tab -> ввод данных -> Tab -> ввод данных -> Enter

Такой алгоритм позволит нам сначала вводить данные в строку (горизонтально), нажатие Enter позволит спуститься вниз на одну строку и вернуться в начало диапазона ввода.

Если сбиться и по привычке нажать Enter вместо Tab, то придётся устанавливать курсор в начало диапазона данных и снова повторять всю процедуру. Не удобно. Особенно если у нас идёт первоначальный ввод данных и их много.

Отталкиваясь от примера, давайте создадим небольшой макрос, который будет контролировать ввод данных и сам будет переходить на новые строки.

Построим работу на диалоговых окнах. В них будем вводить соответственно три переменных — «Название магазина», «Дата», «Выручка».

Переходим на вкладку «Разработчик» и добавляем новый модуль в книгу. О том как это сделать — ЗДЕСЬ.

1. Вкладка «Разработчик», блок кнопок «Код», кнопка «Visual Basic»;
2. Далее «Insert» — > «Module».

Теперь внесём туда следующий код. Его вы можете модифицировать по своему желанию.

Sub SerialInput()
Dim strDate As String
Dim strSum As String
Dim strMag As String
Dim lngRow As Long

Do
lngRow = Range(«A65536»).End(xlUp).Row + 1

‘ Вводим название магазина
strMag = InputBox(«Введите название магазина»)
If strMag = «» Then Exit Sub

‘ Вводим дату
strDate = InputBox(«Введите дату»)
If strDate = «» Then Exit Sub

‘ Вводим выручку
strSum = InputBox(«Введите выручку»)
If strSum = «» Then Exit Sub

‘ Записываем данные в ячейки таблицы
Cells(lngRow, 1) = strMag
Cells(lngRow, 2) = strDate
Cells(lngRow, 3) = strSum

Loop

End Sub

Пояснения

Как вы уже поняли, первым делом мы объявляем три переменных как и договаривались — strMag, strDate, strSum. Даём им значение — СТРОКА (String).

Также необходимо объявить переменную lngRow, она будет определять конец нашего диапазона. В примере у нас три столбца и 65536 строк. Также эта переменная будет цикличной (в конце макроса стоит команда Loop, петля).

Далее мы выводим три диалоговых окна (InputBox) с условием If str*** = «» Then Exit Sub, то есть если любое из полей будет пустым, макрос закончит свою работу.

Оставшиеся значения (Cells) записывают в соответствующие ячейки то, что введено в диалоговые окна.

Проверим правильность работы макроса. На вкладке «Разработчик» жмём кнопку макросы (альтернатива Alt+F8) и нажимаем кнопку «Выполнить».

Всё работает! Если же нам нужно продолжить ввод данных, просто устанавливаем курсор в первую ячейку (А10, А20, А30 и т.д.) и снова запускаем макрос.

Что-то было непонятно? Смотрим обучающее видео!

Автоматическая вставка текущей даты в ячейку при вводе данных

Предположим, у нас имеется таблица заказов, куда пользователь вводит номер заказа, имя клиента, сумму и т.д. Необходимо сделать так, чтобы при внесении номера заказа в столбец А — в столбце B напротив введенного заказа автоматически появлялись дата и время его занесения:

Чтобы реализовать такой ввод даты, нам потребуется простой макрос, который надо добавить в модуль рабочего листа. Для этого щелкните правой кнопкой мыши по ярлычку листа с таблицей и выберите в контекстном меню команду Исходный текст (View code).

В открывшееся окно редактора Visual Basic скопируйте этот текст этого макроса:

Private Sub Worksheet_Change(ByVal Target As Range)
    
    For Each cell In Target   'проходим по всем измененным ячейкам
       If Not Intersect(cell, Range("A2:A100")) Is Nothing Then  'если изменененная ячейка попадает в диапазон A2:A100
            With cell.Offset(0, 1)         'вводим в соседнюю справа ячейку дату
               .Value = Now
               .EntireColumn.AutoFit  'выполняем автоподбор ширины для столбца B, чтобы дата умещалась в ячейке
            End With
       End If
    Next cell
End Sub

При необходимости измените «чувствительный» диапазон «А2:А100» на свой собственный. Если необходимо вставлять дату не в соседний столбец, а правее — подставьте в оператор Offset(0,1) вместо 1 число побольше.

Закройте редактор Visual Basic и попробуйте ввести что-нибудь в диапазон А2:А100. В соседней ячейке тут же появится текущая дата-время!

Ссылки по теме

• Как сделать выпадающий календарь для быстрого ввода любой даты мышью в любую ячейку.
• Как Excel работает с датами
• Что такое макрос, как он работает, куда копировать текст макроса, как запустить макрос?