Макрос для скрытия строк по условию в excel - Word и Excel

макрос удалит на листе все строки, в которых содержится искомый текст:

(пример — во вложении ConditionalRowsDeleting.xls)

Sub УдалениеСтрокПоУсловию()
    Dim ra As Range, delra As Range, ТекстДляПоиска As String
    Application.ScreenUpdating = False    ' отключаем обновление экрана

    ТекстДляПоиска = "Наименование ценности"    ' удаляем строки с таким текстом

    ' перебираем все строки в используемом диапазоне листа
    For Each ra In ActiveSheet.UsedRange.Rows
        ' если в строке найден искомый текст
        If Not ra.Find(ТекстДляПоиска, , xlValues, xlPart) Is Nothing Then
            ' добавляем строку в диапазон для удаления
            If delra Is Nothing Then Set delra = ra Else Set delra = Union(delra, ra)
        End If
    Next
    ' если подходящие строки найдены - удаляем их
    If Not delra Is Nothing Then delra.EntireRow.Delete
End Sub

Чтобы вместо удаления просто скрыть такие строки, замените строку

If Not delra Is Nothing Then delra.EntireRow.Delete

на

If Not delra Is Nothing Then delra.EntireRow.Hidden=TRUE

Расширенная версия этого макроса — с использованием UserForm для ввода искомого значения

Function ПоискСтрокПоУсловию(ByVal ТекстДляПоиска As String, Optional HideOnly As Boolean) As Long
    ' функция получает в качестве параметра ТекстДляПоиска (можно использовать символы * и ?)
    ' Если HideOnly = TRUE, то строки, содержащие в ячейках ТекстДляПоиска, скрываются,
    ' иначе (HideOnly = FALSE - по умолчанию) - удаляются
    ' Функция возвращает количество удалённых строк
    Dim ra As Range, delra As Range
    Application.ScreenUpdating = False    ' отключаем обновление экрана

    ' перебираем все строки в используемом диапазоне листа
    For Each ra In ActiveSheet.UsedRange.Rows
        ' если в строке найден искомый текст
        If Not ra.Find(ТекстДляПоиска, , xlValues, xlPart) Is Nothing Then
            ' добавляем строку в диапазон для удаления
            If delra Is Nothing Then Set delra = ra Else Set delra = Union(delra, ra)
        End If
    Next
    On Error Resume Next: ПоискСтрокПоУсловию = delra.Areas.Count ' количество найденных строк
    
    If Not delra Is Nothing Then    ' если подходящие строки найдены - скрываем или удаляем их
        If HideOnly Then delra.EntireRow.Hidden = True Else delra.EntireRow.Delete
    End If
End Function

Ещё один вариант кода, позволяющего выполнять поиск (с последующим удалением или скрытием строк) сразу по нескольким условиям:

Sub УдалениеСтрокПоНесколькимУсловиям()
    Dim ra As Range, delra As Range
    Application.ScreenUpdating = False    ' отключаем обновление экрана

    ' ищем и удаляем строки, содержащие заданный текст
    ' (можно указать сколько угодно значений, и использовать подстановочные знаки)
    УдалятьСтрокиСТекстом = Array("Наименование *", "Количество", _
                                  "текст?", "цен*сти", "*78*")
 
    ' перебираем все строки в используемом диапазоне листа
    For Each ra In ActiveSheet.UsedRange.Rows
        ' перебираем все фразы в массиве
        For Each word In УдалятьСтрокиСТекстом
            ' если в очередной строке листа найден искомый текст
            If Not ra.Find(word, , xlValues, xlPart) Is Nothing Then
                ' добавляем строку в диапазон для удаления
                If delra Is Nothing Then Set delra = ra Else Set delra = Union(delra, ra)
            End If
        Next word
    Next
 
    ' если подходящие строки найдены, то: (оставьте одну из 2 следующих строк)
    If Not delra Is Nothing Then delra.EntireRow.Hidden = True    ' скрываем их
    If Not delra Is Nothing Then delra.EntireRow.Delete    ' удаляем их
End Sub

Источник

Скрытие/отображение ненужных строк и столбцов

Постановка задачи

Предположим, что у нас имеется вот такая таблица, с которой приходится «танцевать» каждый день:

Кому таблица покажется маленькой — мысленно умножьте ее по площади в двадцать раз, добавив еще пару кварталов и два десятка крупных российских городов.

Задача — временно убирать с экрана ненужные в данный момент для работы строки и столбцы, т.е.,

скрывать подробности по месяцам, оставляя только кварталы
скрывать итоги по месяцам и по кварталам, оставляя только итог за полугодие
скрывать ненужные в данный момент города (я работаю в Москве — зачем мне видеть Питер?) и т.д.

В реальной жизни примеров таких таблиц — море.

Способ 1. Скрытие строк и столбцов

Способ, прямо скажем, примитивный и не очень удобный, но два слова про него сказать можно. Любые выделенные предварительно строки или столбцы на листе можно скрыть, щелкнув по заголовку столбца или строки правой кнопкой мыши и выбрав в контекстном меню команду Скрыть (Hide):

Для обратного отображения нужно выделить соседние строки/столбцы и, щелкнув правой кнопкой мыши, выбрать в меню, соответственно, Отобразить (Unhide).

Проблема в том, что с каждым столбцом и строкой придется возиться персонально, что неудобно.

Способ 2. Группировка

Если выделить несколько строк или столбцов, а затем выбрать в меню Данные — Группа и структура — Группировать (Data — Group and Outline — Group), то они будут охвачены прямоугольной скобкой (сгруппированы). Причем группы можно делать вложенными одна в другую (разрешается до 8 уровней вложенности):

Более удобный и быстрый способ — использовать для группировки выделенных предварительно строк или столбцов сочетание клавиш Alt+Shift+стрелка вправо, а для разгруппировки Alt+Shift+стрелка влево, соответственно.

Такой способ скрытия ненужных данных гораздо удобнее — можно нажимать либо на кнопку со знаком «+» или «—«, либо на кнопки с цифровым обозначением уровня группировки в левом верхнем углу листа — тогда все группы нужного уровня будут сворачиваться или разворачиваться сразу.

Кроме того, если в вашей таблице присутствуют итоговые строки или столбцы с функцией суммирования соседних ячеек, то есть шанс (не 100%-ый правда), что Excel сам создаст все нужные группировки в таблице одним движением — через меню Данные — Группа и структура — Создать структуру (Data — Group and Outline — Create Outline). К сожалению, подобная функция работает весьма непредсказуемо и на сложных таблицах порой делает совершенную ерунду. Но попробовать можно.

В Excel 2007 и новее все эти радости находятся на вкладке Данные (Data) в группе Структура (Outline):

Способ 3. Скрытие помеченных строк/столбцов макросом

Этот способ, пожалуй, можно назвать самым универсальным. Добавим пустую строку и пустой столбец в начало нашего листа и отметим любым значком те строки и столбцы, которые мы хотим скрывать:

Теперь откроем редактор Visual Basic (ALT+F11), вставим в нашу книгу новый пустой модуль (меню Insert — Module) и скопируем туда текст двух простых макросов:

Sub Hide()
    Dim cell As Range
    Application.ScreenUpdating = False                              'отключаем обновление экрана для ускорения
    For Each cell In ActiveSheet.UsedRange.Rows(1).Cells            'проходим по всем ячейкам первой строки
        If cell.Value = "x" Then cell.EntireColumn.Hidden = True    'если в ячейке x - скрываем столбец
    Next
    For Each cell In ActiveSheet.UsedRange.Columns(1).Cells         'проходим по всем ячейкам первого столбца
        If cell.Value = "x" Then cell.EntireRow.Hidden = True       'если в ячейке x - скрываем строку
    Next
    Application.ScreenUpdating = True
End Sub

Sub Show()
    Columns.Hidden = False   'отменяем все скрытия строк и столбцов
    Rows.Hidden = False
End Sub

Как легко догадаться, макрос Hide скрывает, а макрос Show — отображает обратно помеченные строки и столбцы. При желании, макросам можно назначить горячие клавиши (Alt+F8 и кнопка Параметры), либо создать прямо на листе кнопки для их запуска с вкладки Разработчик — Вставить — Кнопка (Developer — Insert — Button).

Способ 4. Скрытие строк/столбцов с заданным цветом

Допустим, что в приведенном выше примере мы, наоборот, хотим скрыть итоги, т.е. фиолетовые и черные строки и желтые и зеленые столбцы. Тогда наш предыдущий макрос придется немного видоизменить, добавив вместо проверки на наличие «х» проверку на совпадение цвета заливки с произвольно выбранными ячейками-образцами:

Sub HideByColor()
    Dim cell As Range
    Application.ScreenUpdating = False
    For Each cell In ActiveSheet.UsedRange.Rows(2).Cells
        If cell.Interior.Color = Range("F2").Interior.Color Then cell.EntireColumn.Hidden = True
        If cell.Interior.Color = Range("K2").Interior.Color Then cell.EntireColumn.Hidden = True
    Next
    For Each cell In ActiveSheet.UsedRange.Columns(2).Cells
        If cell.Interior.Color = Range("D6").Interior.Color Then cell.EntireRow.Hidden = True
        If cell.Interior.Color = Range("B11").Interior.Color Then cell.EntireRow.Hidden = True
    Next
    Application.ScreenUpdating = True
End Sub

Однако надо не забывать про один нюанс: этот макрос работает только в том случае, если ячейки исходной таблицы заливались цветом вручную, а не с помощью условного форматирования (это ограничение свойства Interior.Color). Так, например, если вы с помощью условного форматирования автоматически подсветили в своей таблице все сделки, где количество меньше 10:

…и хотите их скрывать одним движением, то предыдущий макрос придется «допилить». Если у вас Excel 2010-2013, то можно выкрутиться, используя вместо свойства Interior свойство DisplayFormat.Interior, которое выдает цвет ячейки вне зависимости от способа, которым он был задан. Макрос для скрытия синих строк тогда может выглядеть так:

Sub HideByConditionalFormattingColor()
    Dim cell As Range
    Application.ScreenUpdating = False
    For Each cell In ActiveSheet.UsedRange.Columns(1).Cells
        If cell.DisplayFormat.Interior.Color = Range("G2").DisplayFormat.Interior.Color Then cell.EntireRow.Hidden = True
    Next
    Application.ScreenUpdating = True
End Sub

Ячейка G2 берется в качестве образца для сравнения цвета. К сожалению, свойство DisplayFormat появилось в Excel только начиная с 2010 версии, поэтому если у вас Excel 2007 или старше, то придется придумывать другие способы.

Ссылки по теме

Что такое макрос, куда вставлять код макроса, как их использовать
Автоматическая группировка в многоуровневых списках

Источник

Макрос на скрытие строк по условию

Irokezx

Дата: Воскресенье, 30.07.2017, 15:40 |
Сообщение № 1

Группа: Пользователи

Ранг: Прохожий

Сообщений: 4

Репутация:
0
±

Замечаний:
0% ±

Excel 2013

Добрый день, уважаемые форумчане!

Выкладываю пример макроса для решения следующей задачи (см. файл-пример): автоматически скрывать/показывать строки при проверке условия в ячейках B8:B19 (List1).

[vba]

Код

Private Sub Worksheet_Change(ByVal Target As Range) ‘Задаём событие, при котором запускается макрос
Application.ScreenUpdating = False ‘Отключаем обновление экрана во время выполнения макроса
Dim i& ‘Объявляем переменную
For i = 8 To 19 ‘Указываем диапазон цикла, в данном случае по номерам строк
If Range(«B» & i).Value = «» Then ‘Проверяем, пустые ли ячейки, соответствующие указанному выше диапазону, в интересующем столбце («B»)
Rows(i).EntireRow.Hidden = True ‘Скрываем строки, если эти ячейки пустые
Else: Rows(i).EntireRow.Hidden = False ‘Отображаем строки, если ячейки заполнены
End If ‘Закрываем конструкцию проверки указанных условий
Next ‘Запускаем описанную выше процедуру для каждого значения переменной из указанного диапазона цикла
End Sub

[/vba]

Собственно макрос работает, но у меня возник ряд вопросов, связанный с теоретической частью VBA (уровень моих знаний около нулевой отметки):

1) Соответствует ли содержимое моих комментариев после знака апострофа (см. тело макроса) правильному описанию выполняемой процедуры?
2) Было бы интересно посмотреть более рациональные (Ваши) варианты решения для этой задачки с использованием VBA-кода, если они существуют.
3) Чем отличаются между собой макросы типов Sub/Private Sub/Public Sub? Если я правильно понял, процедуру Private Sub можно запустить только из модуля, в котором он прописан (т.е. в моём случае это List1), тогда как процедуру Sub возможно выполнить из любой части рабочей книги. Разницу между Sub и Public Sub понять не могу.
4) Есть ли возможность написания аналогичного макроса, при условии проверки несмежных диапазонов листа? Полагаю, это можно осуществить в одном коде путём обозначения нескольких переменных и перечисления для каждой условия проверки. На этот вопрос участников форума прошу на текущий момент не выкладывать готовое решение. Хочется увидеть ответ в формате Есть/Нет и Правильный/Неправильный ход мысли.

Ответить

_Boroda_

Дата: Воскресенье, 30.07.2017, 16:16 |
Сообщение № 2

Группа: Модераторы

Ранг: Местный житель

Сообщений: 16618

Репутация:
6465
±

Замечаний:
0% ±

2003; 2007; 2010; 2013 RUS

1. Если не сильно придираться к определениям, то да

2. Для небольших объемов все нормально. Для больших — Вы независимо от того, скрыта ячейка или нет, все равно с ней что-то делаете. Зачем, если Вам нужно скрыть, а она уже скрыта? Или наоборот — открыть, а она уже открыта (кстати, как у Вас может быть заполнена ячейка, если перед этим она скрыта была? Её ж для этого открыть нужно). По возможности к листу нужно как можно меньше обращаться — сильно влияет на скорость. Поэтому я бы написал что-то типа:
Сначала всё открываем[vba]

Код

Rows(«8:19»).EntireRow.Hidden = False

[/vba]потом пробегаемся по ячейкам и собираем их адреса в одну кучу. А потом что-то типа
[vba]

Код

Range(«B6:B7,B9,B11,B14,B16,B18:B20,B22»).RowHeight = 0

[/vba]
Можно и не пробегаться циклом. Если ячеек не очень много (могу ошибаться, вроде до 2^13 = 8192) и там действительно реально пусто, а не результат формулы «», то прокатит вот так
[vba]

Код

Range(«B8:B19»).SpecialCells(xlCellTypeBlanks).RowHeight = 0

[/vba]
И Application.ScreenUpdating нужно возвращать в True. Теоретически он возвращается сам, но здесь на форуме с год назад была тема про тормоза макроса (сейчас искать не буду — долго), где лечение заключалось как раз в этом.

3. В общих чертах, не придираясь к конкретным словам, да, все верно. Sub по умолчанию означает Public Sub. В этом отличие от переменных, которые по умолчанию Private

4. См. п.2

Файл не смотрел

Скажи мне, кудесник, любимец ба’гов…
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995

Ответить

Irokezx

Дата: Вторник, 01.08.2017, 02:05 |
Сообщение № 3

Группа: Пользователи

Ранг: Прохожий

Сообщений: 4

Репутация:
0
±

Замечаний:
0% ±

Excel 2013

_Boroda_, доброго времени суток и спасибо за ответ. Сейчас завал на работе, к сожалению, и нет времени попробовать Ваш метод, поэтому прошу пока данную тему не закрывать, так как есть вопросы, которые я напишу, когда отчётливо пойму, что осталось для меня непонятным. Если у Вас будет возможность ответить на них, буду крайне признательным.

Ответить

Источник

Burk, Hugo121, Добрый день.

Я искала решение своей проблемы, увидела, что вы в макросах вроде разбираетесь, хотела бы спросить, если можно.

Я вообще в макросах не разбираюсь, но появилась необходимость использовать. Нужно было в очень большой таблице скрывать нужные месяцы. Вручную это занимает очень много времени так как повторение месяцев идет больше 100 раз.

Нашла в интернете макрос, что скрывал бы отмеченные столбцы :

Visual Basic

Sub Hide()
    Dim cell As Range
    Application.ScreenUpdating = False                              'отключаем обновление экрана для ускорения
    For Each cell In ActiveSheet.UsedRange.Rows(1).Cells            'проходим по всем ячейкам первой строки
        If cell.Value = "x" Then cell.EntireColumn.Hidden = True    'если в ячейке x - скрываем столбец
    Next
    For Each cell In ActiveSheet.UsedRange.Columns(1).Cells         'проходим по всем ячейкам первого столбца
        If cell.Value = "x" Then cell.EntireRow.Hidden = True       'если в ячейке x - скрываем строку
    Next
    Application.ScreenUpdating = True
End Sub
 
Sub Show()
    Columns.Hidden = False   'отменяем все скрытия строк и столбцов
    Rows.Hidden = False
End Sub

Но так как у меня условие это название месяца, я немного исправила, руководствуясь просто логикой:

Visual Basic

Sub Hide()
    Dim cell As Range
    Application.ScreenUpdating = False
    For Each cell In ActiveSheet.UsedRange.Rows(1).Cells
        If cell.Value = "Январь" Then cell.EntireColumn.Hidden = True
        If cell.Value = "Февраль" Then cell.EntireColumn.Hidden = True
    Next
    Application.ScreenUpdating = True
End Sub
 
Sub Show()
    Columns.Hidden = False
    Rows.Hidden = False
End Sub

Теперь отображать месяца все он отображает, но нужное не скрывает.
Подскажите, пожалуйста, что я сделала не так?
Заранее спасибо!

Источник

Как скрыть строки при условии без применения фильтра

Автор Serj Kalsin, 29.01.2010, 13:52

« назад — далее »

Здравствуйте!

Имеется таблица, в которой по итогу расчитываются две надбавки к основным ценам, надбавка эта меняется в зависимости применения определенного коэффициента.
Но когда коэффициент равен нулю, я хочу чтобы эти строки с надбавками автоматом скрывались.
Возможно ли такое?

Приложил файл где все описано что я хочу получить на выходе.
Надеюсь на вашу помощь!!!

Скажи мне, кудесник, любимец ба’гов…

Яндекс-деньги: 41001632713405
Webmoney: R289877159277; Z102172301748; E177867141995

Хороший метод!
Только я никогда не работал с макросами.
Вы этот макрос как создали?
Чтобы мне такой макрос применять в других моих настоящих документах, что мне надо сделать?

Жмем ПКМ на название листа — «Исходный текст», попадаем в модуль листа. Туда вставляем такой код

Private Sub Worksheet_Change(ByVal Target As Range) If Target.Address = "$C$3" Or Target.Address = "$C$4" Then Rows("29:31").EntireRow.Hidden = [c3] + [c4] = 0 Rows(28 - ([c3] = 0) - ([c4] = 0) * 2).EntireRow.Hidden = ([c3] = 0) + ([c4] = 0) End If End Sub
где
1. $C$3 и $C$4 — адреса ячеек, при изменении значений в которых будет отрабатывать наш макрос,
2. Rows(«29:31») — строки, которые нужно скрывать — отображать,
3. [с3] и [с4] — значения ячек С3 и С4,
4. Rows(«29:31»).EntireRow.Hidden — скрытие строк 29:31 (если не равно 0, то скрыты, если 0 — отображены),
5. 28 — строка, на единицу выше первой строки из п. 2,
6. [c3] = 0 — принимает значение 1, если С3=0, иначе — 0,
7. 28 — ([c3] = 0) — ([c4] = 0) * 2 — принимает значение от 28 до 31 в зависимости от того, равны ли нолю С3 и С4,
8. ([c3] = 0) + ([c4] = 0) — принимает значение от 0 до 2 в зависимости от того, равны ли нолю С3 и С4 (если не равно 0, то строки из п. 7 скрыты, если 0 — отображены),
9. Target — именяемая ячейка.

Уокенбах «Профессиональное програмирование на VBA в Excel » для 2007, для 2003
Джелен «VBA и макросы в майкрософт оффис excel 2007»
Гарнаев «Excel 2002 Разработка приложений»

Скажи мне, кудесник, любимец ба’гов…

Яндекс-деньги: 41001632713405
Webmoney: R289877159277; Z102172301748; E177867141995

Спасибо!
Буду изучать этот код и пытаться его понять.
Огромное спасибо!

А может посоветуете какую-нибудь книгу по макросам, как их программировать и т.п. Или может какой-нибудь ресурс.

У меня похожая задача и ваш пример идеально подходит для ее решения.
Но к сожалению не получается составить аналогичный пример.
Помогите плз.

Суть в следующем: Есть ячейка D11 с выпадающим списком от 2х до 8. Нужно что бы при выборе значения скрывались определенные диапазоны строк от 69 до 200 при 2, от 91 до 200 при 3х и т.д.

И есть ячейка D12 в которой тоже выбор значения из списка но уже текстового.

Private Sub Worksheet_Change(ByVal Target As Range) Dim R% Application.ScreenUpdating = False Rows("46:200").EntireRow.Hidden = False If Target.Address = "$D$11" Then If Target.Value <> 8 Then R = Choose(Target.Value, 47, 69, 91, 113, 157, 179) Rows(R & ":200").EntireRow.Hidden = True End If End If Application.ScreenUpdating = True End Sub в модуль листа

Спасибо огромное!
Есть только проблема когда удаляешь значение из ячейки D11 макрос выдает ошибку.
А нужно что бы он делал строки видимыми.

И как мне учесть выбор из ячейки d12? Попробовал по аналогии с вашим макросом не получилось.

зачем удалять? ставите 8 и все кассы видны.

Private Sub Worksheet_Change(ByVal Target As Range) Dim R% Application.ScreenUpdating = False Rows("46:200").EntireRow.Hidden = False If Target.Address = "$D$11" Then If Target.Value <> "" Then If Target.Value <> 8 Then R = Choose(Target.Value, 47, 69, 91, 113, 157, 179) Rows(R & ":200").EntireRow.Hidden = True End If End If End If Application.ScreenUpdating = True End Sub
про d12 опишите что вам там нужно.

Данной формой будет пользоваться не один человек.
Можно ли сделать так что бы при удалении значения выводилось сообщение или просто показывались все строки.

В ячейке d12 есть выбор между 2 значениями. «Система видеонаблюдения».

Соответственно если выбрана одна из систем 2я скрывается.
Скрываются строки 224:232 если выбран ITV и 233:247 если RVI.

Private Sub Worksheet_Change(ByVal Target As Range) Dim R% Application.ScreenUpdating = False If Target.Address = "$D$11" Then If Target.Value <> "" And Target.Value <> 8 Then Rows("46:200").EntireRow.Hidden = False R = Choose(Target.Value, 47, 69, 91, 113, 157, 179) Rows(R & ":200").EntireRow.Hidden = True Else Rows("46:200").EntireRow.Hidden = False End If: Exit Sub ElseIf Target.Address = "$D$12" Then If Target.Value <> "" Then Rows("224:247").EntireRow.Hidden = False If Target.Value = "RVI" Then Rows("233:247").EntireRow.Hidden = True Else Rows("224:232").EntireRow.Hidden = True End If Else Rows("224:247").EntireRow.Hidden = False End If End If Application.ScreenUpdating = True End Sub

Как то странно получилось. Изменил некоторые настройки в профиле и началась абра-кадабра. Когда выхожу все ок..

Пришлось перерегистрироваться. Может у кого было подскажите как все вернуть обратно.

при выборе кассы должна отображаться только выбранная касса или с первой по выбранную?

cheshiki1 Все получилось. Спасибо большое.

Добрый день. Здесь обсуждается вопрос, над которым я как раз ломаю голову, авось поможете.
На первом листе есть выпадающий список от 1 до 10, на втором листе должен работать макрос, который в зависимости от числа, которое в списке первого листа, будет скрывать строки в таблицах. То есть, если в списке число 1- значит в таблицах должно остаться по 1 строке, если в списке число 4, то соответственно должно остаться по 4 строки. Помогите пожалуйста, совсем сил нет уже.

Private Sub Worksheet_Change(ByVal Target As Range) Dim R% Application.ScreenUpdating = False If Target.Address <> "$A$1" Then Exit Sub With Sheets("Лист2") If Target = "" Then .Rows("1:100").EntireRow.Hidden = False Else .Rows("1:100").EntireRow.Hidden = False For i = .Cells(Rows.Count, 1).End(xlUp).Row To 1 Step -1 If .Cells(i, 1) > Target And .Cells(i, 1) <> "" Then .Cells(i, 1).EntireRow.Hidden = True Next End If End With Application.ScreenUpdating = True End Sub

Огромное вам спасибо.

Доброго времени суток. Снова вынужден просить о помощи(.
Использую код для скрытия строк относительно числа в ячейке. Если число в ячейке просто прописано(в моём случае это список от1 до 10), то код работает. Если же число выводится посредством формулы(необходимо считать количество заполненных строк в таблице и относительно результата скрывать лишние строки), код работать отказывается. Можно ли заставить VBA работать относительно ячейки, с обновляемым значением?
Собсно код:

Возможно есть не очень сложное решение этого вопроса? Заранее благодарен.
С ув. athe.

Прошу меня извинить за глупые вопросы. «Ларчик просто открывался»:

If Target.Value = "" Then...

13:31
Нет, я ошибся. Не работает. Вопрос актуален.

пробуйте

Private Sub Worksheet_Change(ByVal Target As Range) Dim R% Application.DisplayAlerts = False Application.ScreenUpdating = False If Not (Intersect(Target, Union(Me.Range("A1"), Me.Range("A1").Precedents)) Is Nothing) Then With Sheets("Лист2") If Target = "" Then .Rows("1:100").EntireRow.Hidden = False Else .Rows("1:100").EntireRow.Hidden = False For i = .Cells(Rows.Count, 1).End(xlUp).Row To 1 Step -1 If .Cells(i, 1) > Target And .Cells(i, 1) <> "" Then .Cells(i, 1).EntireRow.Hidden = True Next End If End With End If Application.DisplayAlerts = True Application.ScreenUpdating = True End Sub
файл не смотрел.

cheshiki1
Спасибо за отклик. Код работает, но к сожалению не так, как нужно. У меня значение [A1] высчитывается формулой:

=10-счётесли(Лист2!B3:B12;0)
Увы, строки при этом не скрываются. Я также пробовал добывать [A1] из таблицы, которая не участвует в макросе, но эффект был такой же.
Интересным образом программа работает если значение [A1] считается суммой двух ячеек. Учитывается не сумма, а значения слагаемых.
При попытке изменить ячейку в листе 1 программа ругается на эту строку:

If Not (Intersect(Target, Union(Me.Range("A1"), Me.Range("A1").Precedents)) Is Nothing) Then

Спасибо.
С ув. athe.

Вот что значит файл не посмотрел. Та строка не работает если в формуле ссылка на другой лист.
пробуйте это

Private Sub Worksheet_Calculate() Static v As Variant Application.Calculation = xlManual Application.ScreenUpdating = False If Me.Range("A1").Value <> v Then With Sheets("Ëèñò2") If Cells(1, 1) = "" Then .Rows("1:100").EntireRow.Hidden = False Else .Rows("1:100").EntireRow.Hidden = False For i = .Cells(Rows.Count, 1).End(xlUp).Row To 1 Step -1 If .Cells(i, 1) > Cells(1, 1) And .Cells(i, 1) <> "" Then .Cells(i, 1).EntireRow.Hidden = True Next End If End With v = Me.Range("A1").Value End If Application.ScreenUpdating = True Application.Calculation = xlAutomatic End Sub

cheshiki1, спасибо вам большое. Всё отлично работает. Теперь отчёты потекут рекой).

Добрый день.
Прошу прощения за поднятие старой темы.
Успешно использую вышеуказанный код, за что благодарен участникам форума.
Я попытался использовать его для несколько иной задачи, но, увы ничего не вышло. Необходимо скрывать тот или иной диапазон строк в зависимости от значения в списке. Для этого в столбце А вместо чисел я прописал формулы: «=ЕСЛИ(Лист_1!I8=draft!A1;1;2)». Себто, если значение в ячейке соответствует таблице №1, то в столбце А, возле таблицы №1 будет значение 1 (таблица видима), а напротив остальных таблиц будет значение 2 (таблица скрыта).
Код к сожалению срабатывает только один раз, после чего не реагирует на изменения значения в списке. Если войти и выйти в режим конструктора, — программа снова может сработать один раз. Подскажите пожалуйста, в чём может быть загвоздка?
Заранее благодарен,
athe

Собсно код:

Private Sub Worksheet_Calculate() Static v As Variant Application.Calculation = xlManual Application.ScreenUpdating = False If Me.Range("A1").Value <> v Then With Sheets("Лист_1") If Cells(1, 1) = "" Then .Rows("1:1000").EntireRow.Hidden = False Else .Rows("1:1000").EntireRow.Hidden = False For i = .Cells(Rows.Count, 1).End(xlUp).Row To 1 Step -1 If .Cells(i, 1) > Cells(1, 1) And .Cells(i, 1) <> "" Then .Cells(i, 1).EntireRow.Hidden = True Next End If End With v = Me.Range("A1").Value End If Application.ScreenUpdating = True Application.Calculation = xlAutomatic End Sub

я так понял вы меняете значение в ячейке I8 и должны скрываться таблицы? как будет меняться значение формулой или список?

Private Sub Worksheet_Change(ByVal Target As Range) If Target.Address <> "$I$8" Then Exit Sub Dim i As Long Application.Calculation = xlManual Application.ScreenUpdating = False


With Sheets("Лист_1")
     .Rows("1:1000").EntireRow.Hidden = False
         For i = .Cells(Rows.Count, 1).End(xlUp).Row To 12 Step -1
            If .Cells(i, 1) <> 1 Then .Cells(i, 1).EntireRow.Hidden = True
         Next
End With
Application.ScreenUpdating = True
Application.Calculation = xlAutomatic
End Sub

Профессиональные приемы работы в Microsoft Excel
►
Обмен опытом
►
Microsoft Excel
►
Как скрыть строки при условии без применения фильтра

Источник