Libreoffice поддержка макросов excel

Sub HelloMacro
  Print "Hello, World"
End Sub

REM  *****  BASIC  *****

Sub HelloMacro
  Print "Привет"
End Sub

Sub Main

End Sub

REM  *****  BASIC  *****
Sub Main

End Sub

sub EnterMyName
rem -------------------------------------------------------------
rem define variables (определение переменных)
dim document   as object
dim dispatcher as object
rem -------------------------------------------------------------
rem get access to the document (получение доступа к документу)
document   = ThisComponent.CurrentController.Frame
dispatcher = createUnoService("com.sun.star.frame.DispatchHelper")

rem -------------------------------------------------------------
dim args1(0) as new com.sun.star.beans.PropertyValue
args1(0).Name = "Text"
args1(0).Value = "Иван Сидорович Петров"

dispatcher.executeDispatch(document, ".uno:InsertText", "", 0, args1())
end sub

document = ThisComponent.CurrentController.Frame

dispatcher = createUnoService("com.sun.star.frame.DispatchHelper")

dim args1(0) as new com.sun.star.beans.PropertyValue

args1(0).Name = "Text"
args1(0).Value = "Иван Сидорович Петров"

dispatcher.executeDispatch(document, ".uno:InsertText", "", 0, args1())

Расширения¶

Самостоятельное программирование¶

Option VBASupport 
Sub DeleteToLeft()
    Selection.SpecialCells(xlBlanks).Delete shift:=xlToLeft
End Sub
Function SinceLastWash()
    Application.Volatile
    WashCount = 0
    WearCount = 0
    CurrentRow = Application.ThisCell.Row
    For i = 3 To 35
        If Range(Cells(CurrentRow, i), Cells(CurrentRow, i)).Value = "a" Then
            WearCount = WearCount + 1
        End If
        If Range(Cells(CurrentRow, i), Cells(CurrentRow, i)).Value = "q" Then
            WashCount = WashCount + 1
            WearCount = 0
        End If
    Next i
    SinceLastWash = WearCount
End Function
Function testhis()
testhis = Application.ThisCell.Row
End Function

5 ответов

Лучший ответ

Range(Cells(CurrentRow, i), Cells(CurrentRow, i)).Value = "a"

Sub RetrieveTheActiveCell()
  Dim oOldSelection 'The original selection of cell ranges
  Dim oRanges       'A blank range created by the document
  Dim oActiveCell   'The current active cell
  Dim oConv         'The cell address conversion service
  Dim oDoc
  oDoc = ThisComponent

  REM store the current selection
  oOldSelection = oDoc.CurrentSelection

  REM Create an empty SheetCellRanges service and then select it.
  REM This leaves ONLY the active cell selected.
  oRanges = oDoc.createInstance("com.sun.star.sheet.SheetCellRanges")
  oDoc.CurrentController.Select(oRanges)

  REM Get the active cell!
  oActiveCell = oDoc.CurrentSelection

  oConv = oDoc.createInstance("com.sun.star.table.CellAddressConversion")
  oConv.Address = oActiveCell.getCellAddress
  Print oConv.UserInterfaceRepresentation
  print oConv.PersistentRepresentation

  REM Restore the old selection, but lose the previously active cell
  oDoc.CurrentController.Select(oOldSelection)
End Sub

Selection.SpecialCells(xlBlanks).Delete shift:=xlToLeft

Option VBASupport 

Option VBASupport 1
Option Compatible

Макросы — отличный способ автоматизировать задачи в приложениях для работы с электронными таблицами, будь то старый добрый Microsoft Excel или столь же эффективная альтернатива FOSS, LibreOffice Calc. Самое лучшее в макросах то, что они написаны на очень простом языке под названием Basic.

Как следует из самого названия, Basic — это мягкий язык программирования, на самом деле разработанный с учетом простоты использования. Например, верхний/нижний регистр не имеет значения для имен переменных или ключевых слов (if/IF, sub/Sub, function/Function эквивалентны), фигурные скобки функций необязательны, как в Ruby, а преобразование типов происходит автоматически. Это делает Basic одинаково полезным как для опытных пользователей, так и для программистов. Макрос LibreOffice Basic — это просто функция или подпроцедура, которая выполняет определенную полезную задачу. В этом уроке мы увидим десять таких полезных макросов, которые могут помочь вам с различными задачами автоматизации.

Рецепт 0: Как создать макрос LibreOffice

Хотя макросы также можно создавать в Writer и Draw, в этом конкретном руководстве мы ограничимся электронными таблицами (Calc). Чтобы создать макрос, просто откройте электронную таблицу в LibreOffice и перейдите в меню Tools->Macros->Organize Macros->LibreOffice Basic. После этого, если вы хотите создать макрос, специфичный для вашей электронной таблицы (как это обычно бывает), разверните файл электронной таблицы слева, выберите Standard и нажмите New. Это откроет Редактор макросов LibreOffice в виде отдельного окна.

Рецепт 1: Чтение содержимого ячейки

Одной из самых основных вещей, необходимых для автоматизации, является чтение содержимого ячейки. Следующий фрагмент кода делает именно это:

Sub read_cell
	dim document as object
	document = ThisComponent
	sheet = document.Sheets(0)
	MsgBox(sheet.getCellByPosition(0, 0).String)
End Sub

dim — это ключевое слово, используемое для объявления переменной, но объявление является необязательным, если только Option Explicit не указано в начале модуля. ThisComponent — это объект LibreOffice, который ссылается на текущую электронную таблицу (или письменный документ в случае Writer). Здесь важно выражение sheet.getCellByPosition(0, 0).String, которое получает содержимое первой ячейки в первой строке. На ячейки можно ссылаться, используя систему координат, где (0,0) относится к ячейке в строке-0 и столбце-0. Таким образом, с помощью этого простого метода можно получить любое значение во всей электронной таблице.

Чтобы запустить макрос из редактора, просто поместите курсор внутрь sub или function тела любого макроса и нажмите F5 (или щелкните значок Run BASIC на панели инструментов).

Рецепт 2: Изменить содержимое ячейки

Еще одна часто необходимая вещь — возможность изменить содержимое ячейки. Следующий код устанавливает для первой ячейки в первой строке значение «Hola! Mundo», испанское выражение «Привет! Мир»:

Sub change_cell
	dim document as object
	document = ThisComponent
	sheet = document.Sheets(0)
	sheet.getCellByPosition(0, 0).String = "Hola Mundo!"
	MsgBox("Done")
End Sub

Рецепт 3: Поиск и замена

Поиск и замена определенных строк может быть важной частью вашей процедуры автоматизации. Ниже приведен забавный макрос, который ищет имена некоторых экспертов по Linux (таких как Линус, Ричард, Питер и т. д.) и заменяет их фамилиями (Торвальдс, Столлман, Энвин):

Sub replace_text
  Dim names() As String
  Dim surnames() As String
  Dim n As Long
  Dim document As Object
  Dim sheets as Object
  Dim sheet as Object
  Dim replace As Object

  names() = Array("Linus", "Richard", "Peter", "Greg", "Bill")
  surnames() = Array("Torvalds", "Stallman", "Anvin", "Kroah", "Gates")
  document = ThisComponent rem .CurrentController.Frame
  rem sheet = doc.CurrentSelection.Spreadsheet
  sheets = document.getSheets()
  sheet = sheets.getByIndex(0)
  replace = sheet.createReplaceDescriptor rem document.createReplaceDescriptor in case of Writer
  rem replace.SearchRegularExpression = True
  For n = lbound(names()) To ubound(names())
    replace.SearchString = names(n)
    replace.ReplaceString = surnames(n)
    sheet.replaceAll(replace)
  Next n
  MsgBox("Done")
End Sub

names() и surnames() на самом деле являются массивами. В отличие от C и Java, массивы в Basic объявляются и доступны с помощью круглых, а не квадратных скобок. Кроме того, в объявлении массива объявляется верхняя граница, а не общий размер. Таким образом, foo(2) на самом деле представляет собой массив размера 3 с индексами от 0 до 2.

Рецепт 4: Регулярные выражения

Регулярные выражения очень полезны при поиске и замене текста на основе определенных шаблонов. Следующий макрос выполняет поиск всех адресов электронной почты в электронной таблице и заменяет каждый из них на [email protected]:

Sub replace_with_regex
  Dim names() As String
  Dim surnames() As String
  Dim n As Long
  Dim document As Object
  Dim sheets as Object
  Dim sheet as Object
  Dim replace As Object

  pattern = "b[A-Z0-9._%+-][email protected][A-Z0-9.-]+.[A-Z]{2,}b" rem regex pattern to match any email address
  document = ThisComponent rem .CurrentController.Frame
  sheets = document.getSheets()
  sheet = sheets.getByIndex(0)
  replace = sheet.createReplaceDescriptor rem document.createReplaceDescriptor in case of Writer
  replace.SearchRegularExpression = True
  replace.SearchString = pattern
  replace.ReplaceString = "[email protected]"
  sheet.replaceAll(replace)

  MsgBox("Done")
End Sub

Рецепт 5: Показать диалоговое окно открытия файла

Отображение диалогового окна открытия файла является очень распространенным требованием, особенно когда вы хотите открыть внешний файл для обработки. В приведенном ниже коде объект FilePicker используется для отображения диалогового окна открытия файла и возврата выбранного имени файла:

function show_open_dialog
	dim aurl as object
	dim s as string
	dim oDlg as object
	
	oDlg = createUnoService("com.sun.star.ui.dialogs.FilePicker")
	oDlg.setMultiSelectionMode(false)
	oDlg.appendFilter("CSV Files (.csv)", "*.csv" )	
	oDlg.execute
	aUrl = oDlg.getFiles()
	
	s = aUrl(0)
	if len(s) > 0 then
		MsgBox("File Selected: " & s & chr(13))
	end if
	show_open_dialog = s
end function

createUnoService — это особый метод LibreOffice для создания вспомогательных объектов, таких как FilePicker в этом примере. Метод appendFilter используется для фильтрации только CSV файлов в диалоговом окне.

Рецепт 6: Показать диалоговое окно сохранения файла

Для отображения диалогового окна сохранения файла используется тот же объект FilePicker, который инициализируется аргументом FILESAVE_AUTOEXTENSION:

function show_save_dialog
	dim aurl as object
	dim s as string
	dim oDlg as object
	
	sFilePickerArgs = Array(_
	com.sun.star.ui.dialogs.TemplateDescription.FILESAVE_AUTOEXTENSION )	
	oDlg = createUnoService("com.sun.star.ui.dialogs.FilePicker")
	oDlg.initialize(sFilePickerArgs())
	oDlg.setMultiSelectionMode(false)
	oDlg.appendFilter("CSV Files (.csv)", "*.csv" )	
	oDlg.setTitle("Save As....")
	
	if oDlg.execute() then
		aUrl = oDlg.getFiles()
		s = aUrl(0)
		if len(s) > 0 then
			MsgBox("File Selected: " & s & chr(13))
		end if
	else
		s = ""
	end if
	show_save_dialog = s
end function

Рецепт 7. Файловый ввод-вывод: чтение из файлов

Ввод-вывод необработанных файлов — это функция, предоставляемая почти каждым языком, а макросы Basic делают ее почти слишком простой. Код ниже используется для чтения CSV-файла с тремя столбцами. Имя файла задается в переменной filename. Переменная num представляет собой числовой тег, используемый для ссылки на обработчик файлов, а FreeFile() возвращает свободный доступный номер, который можно использовать для тегирования. Оператор open говорит сам за себя. В Basic файлы можно открывать в режимах Input, Output и Binary. Наконец, оператор input используется для фактического чтения файла в переменные строка за строкой.

sub file_io_read
	dim v1, v2, v3
	filename = "/home/prahlad/data/test.csv"
	num = FreeFile()
	open filename for input as #num 
	do while not eof(num)
		input #num, v1, v2, v3
		print v1 & "::" & v2 & "::" & v3
	loop
	close #num
	msgbox "Done"
end sub

Рецепт 8. Файловый ввод-вывод: запись в файлы

Для записи в файлы обработчик открывается в режиме output вместо input, а оператор write используется для фактической записи переменных в файл.

sub file_io_write
	filename = "/home/prahlad/data/dummy.csv"
	num = FreeFile()
	open filename for output as #num 
	write #num, "col1", "col2", "col3"
	write #num, "1", "2", "3"
	write #num, "4", "5", "6"
	close #num
	msgbox "Done"
end sub

Рецепт 9: Загрузить данные из CSV-файла

Помимо работы в режиме необработанного ввода-вывода, иногда требуется загрузить полный CSV-файл в виде листа в текущем документе. Используя функцию show_open_dialog, которую мы изучали ранее, следующий макрос сначала запрашивает у пользователя диалоговое окно открытия файла, а затем загружает указанный CSV-файл как новый лист:

sub load_from_csv
	fname = show_open_dialog
	if len(fname)>0 then
		dim fileProps(1) as new com.sun.star.beans.PropertyValue
		fileProps(0).Name = "FilterName"
		fileProps(0).Value = "Text - txt - csv (StarCalc)"
		fileProps(1).Name = "FilterOptions"
		fileProps(1).Value = "44,34,76,1,,0,false,true,true,false"
		document = StarDesktop.loadComponentFromURL(fname, "_blank", 0, fileProps())		
	end if
	msgbox "Done"
end sub

fileProps(0) — это переменная свойства, используемая для указания формата файла CSV, а fileProps(1) указывает параметры форматирования по умолчанию для CSV (например, разделитель, набор символов и т. д.).

Рецепт 10: Скопируйте текст в буфер обмена

Ваша пользовательская обработка может включать в себя помещение определенного текста в буфер обмена из LibreOffice Calc. Следующий код показывает, как поместить строку «Hola!» в системный буфер обмена:

sub copy_to_clipboard
	oClip = CreateUnoService("com.sun.star.datatransfer.clipboard.SystemClipboard")
	oTR = createUnoListener("TR_", "com.sun.star.datatransfer.XTransferable")
	oClip.setContents(oTR, null)
	msgbox "Done"
end sub

Function TR_getTransferData( aFlavor As com.sun.star.datatransfer.DataFlavor ) As Any
	If (aFlavor.MimeType = "text/plain;charset=utf-16") Then
		TR_getTransferData = "Hola!"
	EndIf
End Function

Function TR_getTransferDataFlavors() As Any
	Dim aF As new com.sun.star.datatransfer.DataFlavor
	aF.MimeType = "text/plain;charset=utf-16"
	aF.HumanPresentableName = "Unicode-Text"
	TR_getTransferDataFlavors = Array(aF)
End Function

Function TR_isDataFlavorSupported( aFlavor As com.sun.star.datatransfer.DataFlavor ) As Boolean
	TR_isDataFlavorSupported = (aFlavor.MimeType = "text/plain;charset=utf-16")
End Function

Вторая функция является обратным вызовом и используется для сохранения строки в буфер обмена. Последние две являются вспомогательными функциями, которые используются вспомогательными объектами SystemClipboard и XTransferable и являются обязательными.

Демо

Наконец, рабочую электронную таблицу LibreOffice Calc, реализующую все эти примеры, можно найти здесь.

использованная литература

• http://api.libreoffice.org/examples/examples.html#Basic_examples
• https://forum.openoffice.org/en/forum/viewtopic.php?f=25&t=36441
• https://ask.libreoffice.org/en/question/39940/calc-open-and-save-csv-file-with-given-filter-options/
• https://wiki.openoffice.org/wiki/Documentation/DevGuide/OpenOffice.org_Developers_Guide
• https://wiki.openoffice.org/wiki/Documentation/BASIC_Guide/Ячейки_и_диапазоны
• http://www.excel-spreadsheet.com/vba/inputoutput.htm
• https://forum.openoffice.org/en/forum/viewtopic.php?f=45&t=13783

Первоначально опубликовано на www.prahladyeri.com 26 февраля 2016 г.