Как запретить удаление листа в excel vba

Protecting workbook structure will prevent a user from deleting sheets. But how could I (using VBA) prevent a user from deleting a particular sheet I designate? I’ve seen examples where an active sheet is prevented from deletion by

Set mymenubar = CommandBars.ActiveMenuBar
mymenubar.Controls("Edit").Controls("Delete sheet").Visible = False

in its Worksheet_Activate event but that of course only works if the sheet is activated.
Is there a way to prevent a sheet from being deleted whether active or no?
For clarity: I’m fine with the user deleting some sheets, just not a couple of particular sheets.
So protecting workbook structure won’t work.

As far as I can tell, it isn’t possible to natively tag a single sheet as non-deletable; and there isn’t an event that can be used to detect when a sheet is about to be deleted so the workbook can be protected preventively.

However, here is one potential workaround:

1. Protect workbook structure: this will, as you indicate, prevent all sheets from being deleted.
2. Create a «Controls» sheet. On this sheet, maintain a list of all sheet names (except those you don’t want to be deletable).
3. If users want to delete a sheet, they will have to select its name on the Controls sheet (e.g. in a data validation drop-down menu) and press a «Delete» button. This button will call a macro that temporarily unprotects the workbook, deletes the selected sheet, and then reprotects the workbook.

Of course, the users will have to get used to this way of deleting sheets (as opposed to just right-click > Delete on the sheet’s tab). Still, this isn’t crazy complicated.

As for how to achieve #2 i.e. maintaining that list of sheet names, I suppose you could make use of a UDF like this one (must be called as an array formula):

Function DeletableSheetNames() As String()
    Application.Volatile
    Dim i As Long
    Dim sn() As String
    With ThisWorkbook
        ReDim sn(1 To .Sheets.Count)
        For i = 1 To .Sheets.Count
            With .Sheets(i)
                If .Name = "DataEntry1" Or .Name = "DataEntry2" Then
                    'Don't include it in the list.
                Else
                    sn(i) = .Name
                End If
            End With
        Next i
    End With
    DeletableSheetNames = sn
End Function

answered May 14, 2014 at 7:12

You cannot stop users to delete a particular sheet but you could use the Workbook_BeforeSave() event to prevent the workbook from being saved if a particular sheet is missing. The documentation on this event precisely shows how to allow saving a workbook only when certain conditions are met. See http://msdn.microsoft.com/en-us/library/office/ff840057(v=office.14).aspx

I can prevent a sheet from being deleted via the Worksheet_BeforeDelete Event as follows:

Private Sub Worksheet_BeforeDelete()

    Call ThisWorkbook.Protect("password")

    Call MsgBox("This sheet cannot be deleted.", vbExclamation)

End Sub

This protects all sheets from being deleted, however if you add some event code on the ThisWorkbook module like the following :

Private Sub Workbook_SheetActivate(ByVal Sh As Object)

    Call ThisWorkbook.Unprotect("password")

End Sub

I will then be able to delete any other sheet as soon as it is selected.

Bear in mind, you will lose copy and paste functionality between pages due to the page unlocking when it is selected.

«there isn’t an event that can be used to detect when a sheet is about to be deleted»

Since Office 2013, it is possible with the SheetBeforeDelete event.

answered Jun 2, 2018 at 3:54

Answer is by adding the following code to each of the protected sheets:

Private Sub Worksheet_Deactivate()
    ThisWorkbook.Protect , True
    Application.OnTime Now, "UnprotectBook"
End Sub

And the following to a Module:

Sub UnprotectBook()
    ThisWorkbook.Unprotect
End Sub

Check https://www.top-password.com/blog/prevent-excel-sheet-from-being-deleted/ for credits accordingly.

answered Sep 26, 2019 at 6:45

The following disables the menu when you right click on tab. This stops the delete option being available.

Sub tab_rclick_off()
Application.CommandBars("Ply").Enabled = False
End Sub

The following turns the menu back on.

Sub tab_rclick_on()
Application.CommandBars("Ply").Enabled = True
End Sub

This option is simple, concise, prevents any issues with data entry/editing with protected sheets and can be called from anywhere in code, ie in conjunction with log on permissions can be given to some and not others etc. foremost yourself.

answered Oct 2, 2022 at 19:21

Maybe you could try to protect the structure of the workbook in SheetBeforeDelete.
See my example:

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
    ThisWorkbook.Protect Structure:=False
End Sub

Private Sub Workbook_SheetBeforeDelete(ByVal Sh As Object)
    If Sh.Name = "Example" Then
        ThisWorkbook.Protect Structure:=True
    End If
End Sub

answered Dec 25, 2020 at 15:26

Here is another answer from mine base on the idea of @Jean-François Corbett
You can use ‘Protect WB Structure’ and Event ‘Workbook_SheetBeforeDelete’ to achieve this.
The result is that an dialog will pop up said «Workbook is protected and cannot be changed.»

Private Sub zPreventWShDel(WSh As Worksheet, Protection As Boolean)
Dim zPassword As String: zPassword = ""
Dim zWB As Workbook
Set zWB = WSh.Parent
If Protection Then
    zWB.Protect zPassword, Protection
Else
    zWB.Protect zPassword, Protection
End If

'Stop
End Sub

Private Sub Workbook_SheetBeforeDelete(ByVal Sh As Object)
Call zPreventWShDel(Sh, True)
End Sub

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
Call zPreventWShDel(Sh, False)
End Sub

Do not Call the code on Sheet Deactivation like below. Because it will deactivate it. Sequence of running is Event_SheetBeforeDelete -> Event_SheetDeactivate.

Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
Call zPreventWShDel(Sh, False)
End Sub

answered Mar 12, 2022 at 7:52

I created a different approach to this.

On the sheet(s) you want protected, add this code:

Private Sub Worksheet_BeforeDelete()

ThisWorkbook.Worksheets("Unprotect Workbook").Visible = True
ThisWorkbook.Worksheets("Unprotect Workbook").Activate
ThisWorkbook.Protect

End Sub

Create the («Unprotect Workbook») sheet and make the visibility: xlSheetVeryHidden

on the «Unprotect Workbook» sheet add a button or shape that you can assign a macro to.

on the «Unprotect Workbook» sheet, add this code:

Sub unprotectThisWorkbook()

ThisWorkbook.unprotect
ActiveSheet.Visible = xlSheetVeryHidden

End Sub

Assign the sub you added, «Sub unprotectThisWorkbook()», to the button on the «Unprotect Worksheet» sheet

When you delete the sheet you protected, the workbook is protected and it takes you to the unprotect worksheet as a notice to the user and as a way to unprotect the workbook. Once the button is clicked, the workbook is unprotected and the «unprotect sheet» is hidden again.

This will work for any sheet you want to protect.

answered Dec 13, 2022 at 19:35