Как вставить excel таблицу в тело письма

Хитрости »

13 Апрель 2017              37188 просмотров

Про создание писем в Outlook через Visual Basic for Applications(VBA) Excel я уже писал пару статей, в том числе и о том, как вставить одну из стандартных подписей в письмо — Вставить в письмо подпись из Outlook через VBA(по умолчанию при создании писем из VBA подпись не вставляется, даже если это настроено параметрами почты). Но т.к. отправка происходит из Excel, то часто возникает и другой вопрос — как в письмо вставить не просто текст, а целую таблицу? Да еще со всем форматированием ячеек? Если речь о ручной вставке, то тут все просто: скопировали диапазон, перешли в письмо — вставили. Но если попробовать тоже самое кодом (через копировать-вставить) — ничего не получится(у Outlook просто нет метода Paste или что-то вроде того). Можно использовать метод SendKeys, но он весьма нестабилен и я стараюсь его вообще нигде не применять, только в случаях, когда по-другому ну вообще никак:

Sub Send_Mail()
    Dim objOutlookApp As Object, objMail As Object
 
    Application.ScreenUpdating = False
    'копируем выделенную таблицу
    Selection.Copy
    On Error Resume Next
    Set objOutlookApp = CreateObject("Outlook.Application")
    objOutlookApp.Session.Logon
    Set objMail = objOutlookApp.CreateItem(0)   'создаем новое сообщение
    If Err.Number <> 0 Then Set objOutlookApp = Nothing: Set objMail = Nothing: Exit Sub
    On Error GoTo 0
    'создаем сообщение
    With objMail
        .To = "адрес получателя"
        .Subject = "Тема: тест вставки таблицы"
        .BodyFormat = 2  'olFormatHTML - формат HTML
        .Display 'отображаем сообщение
        'передаем управление ОС, чтобы завершились все лишние процессы
        DoEvents
        'посылаем команду нажатия клавиш Ctrl+V для вставки таблицы из буфера обмена
        Application.SendKeys "^v"
    End With
 
    Set objOutlookApp = Nothing: Set objMail = Nothing
    Application.ScreenUpdating = True
End Sub

Чем мне не нравится этот метод? Как уже писал — он не очень стабилен и может получиться так, что вставите скопированное не туда или вставка вообще не произойдет.
Если же переносить таблицу кодом вроде такого:
.Body = Range(«A1»).Value & Range(«A2»).Value
то это будут только значения ячеек, но не их форматирование и уж никак не таблица.
Все дело в том, что таблица в теле письма это отдельный объект формата HTML. И при вставке через копировать-вставить руками Excel и Outlook делают за нас всю грязную работу по перекодировке скопированного в нужный формат HTML. А значит и нам надо каким-то образом конвертировать нужные ячейки в этот формат, да еще учесть всё форматирование. К примеру, есть такая таблица:

Теперь эту таблицу надо вставить в письмо вместе с остальным текстом, чтобы было что-то вроде:

Чтобы конвертировать нужные ячейки в самостоятельную таблицу в формате HTML я использую такую функцию:

Function ConvertRngToHTM(rng As Range)
    Dim fso As Object, ts As Object
    Dim sF As String, resHTM As String
    Dim wbTmp As Workbook
 
    sF = Environ("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
    'переносим указанный диапазон в новую книгу
    rng.Copy
    Set wbTmp = Workbooks.Add(1)
    With wbTmp.Sheets(1)
        'вставляем только ширину столбцов, значения и форматы
        .Cells(1).PasteSpecial xlPasteColumnWidths
        .Cells(1).PasteSpecial xlPasteValues
        .Cells(1).PasteSpecial xlPasteFormats
        .Cells(1).Select
        Application.CutCopyMode = False
        'удаляем все объекты(фигуры, рисунки и пр.)
        '------------------------------------------
        'если рисунки и объекты нужны - удалить этот блок
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
        '------------------------------------------
    End With
    'сохраняем книгу как Веб-страницу(чтобы содержимое конвертировать в HTML-код)
    With wbTmp.PublishObjects.Add( _
         SourceType:=xlSourceRange, Filename:=sF, _
         Sheet:=wbTmp.Sheets(1).Name, Source:=wbTmp.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With
    'открываем созданный файл как текстовый и считываем содержимое
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(sF).OpenAsTextStream(1, -2)
    resHTM = ts.ReadAll
    ts.Close
    'выравниваем таблицу по левому краю(если надо оставить по центру - удалить эту строку)
    ConvertRngToHTM = Replace(resHTM, "align=center x:publishsource=", "align=left x:publishsource=")
    'закрываем временную книгу и удаляем
    wbTmp.Close False
    Kill sF
    'очищаем объектные переменные
    Set ts = Nothing: Set fso = Nothing
    Set wbTmp = Nothing
End Function

Все, что остается — это в нужный момент вызвать эту функцию и вставить в нужное место письма.
Например, для конвертации в текст HTML выделенного на листе диапазона необходимо выполнить код:

Dim sTblBody As String
sTblBody = ConvertRngToHTM(Selection)

Чтобы создать письмо в Outlook и вставить туда эту таблицу можно использовать такой код:

Sub Send_Mail()
    Dim objOutlookApp As Object, objMail As Object
 
    Application.ScreenUpdating = False
    On Error Resume Next
    Set objOutlookApp = CreateObject("Outlook.Application")
    objOutlookApp.Session.Logon
    Set objMail = objOutlookApp.CreateItem(0)   'создаем новое сообщение
    If Err.Number <> 0 Then Set objOutlookApp = Nothing: Set objMail = Nothing: Exit Sub
    On Error GoTo 0
    'создаем сообщение
    With objMail
        .To = "адрес получателя"
        .Subject = "Тема: тест вставки таблицы"
        .BodyFormat = 2  'olFormatHTML - формат HTML
        .HTMLBody = ConvertRngToHTM(Selection)
        .Display 'отображаем сообщение
    End With
 
    Set objOutlookApp = Nothing: Set objMail = Nothing
    Application.ScreenUpdating = True
End Sub

Более подробно про создание и отправку писем из Excel я писал в этой статье: Как отправить письмо из Excel?
По сути основная задача выполнена, теперь вы сможете вкладывать в сообщение таблицу без потери форматирования.
Если задача поставлена так, что необходимо вставить таблицу не на основании выделенного диапазона(Selection), а на основании конкретного диапазона ячеек на листе(скажем диапазона A20:F27 на листе с именем Лист1), то это должно выглядеть так:

Dim sTblBody As String
sTblBody = ConvertRngToHTM(Worksheets("Лист1").Range("A20:F27"))

Скачать файл:

  Пример вставки таблицы в письмо Outlook.xls (67,5 KiB, 3 451 скачиваний)

В файле-примере, приложенном к статье, более расширенный вариант кода, который оформлен более удобно, там можно задать в ячейках адрес получателя, тему письма и текст письма. Плюс помимо описанного выше добавляет форматирование к письму, проставляет корректные переносы и непосредственно вставляет таблицу в любое место письма.
За форматирование(назначает шрифт Arial, размер 14) отвечает строка:

sBody = "<span style=""font-size: 14px; font-family: Arial"">" & sBody & "</span>"

Полагаю, несложно догадаться где изменить размер шрифта и его имя. Так же можно и иное форматирование применять, если Вам знакомы основы работы с HTML.
Корректные для HTML переносы строк текста

'Переносы строк и шрифт
sBody = Replace(sBody, Chr(10), "<br />")
sBody = Replace(sBody, vbNewLine, "<br />")

Про вставку таблицы следует расписать чуть подробнее. В примере в ячейку B13 записан следующий текст:
Уважаемый клиент!
Только для Вас мы подготовили специальное предложение по товарам, которыми Вы интересовались в нашем Интернет-магазине:
{TABLE}
Будем рады видеть Вас среди наших постоянных клиентов!
(а для постоянных клиентов у нас действуют еще более выгодные условия)
С уважением, Дмитрий
менеджер по работе с постоянными клиентами

красным специально выделен тег {TABLE}. Именно на место этого тега будет вставлена таблица, созданная из указанного диапазона и результат будет как на рис.2(см.выше). Эту метку можно вставлять в любое место и именно туда будет помещена таблица.
В коде диапазон вставляемой таблицы указывается в строке:

Set rDataR = .Range("A15:D18") 'Selection - если надо отправить только выделенные диапазона

Его можно изменить на любой необходимый.
Что важно помнить: если помимо вставки таблицы Вы планируете форматировать письмо другими тегами HTML, то лучше сначала сделать все форматирование и только в самом конце, самым последним шагом, добавлять таблицу в письмо. Иначе разметка таблицы может «поплыть».

Надеюсь теперь Вам не составит труда сделать свои сообщения более красивыми и аккуратными.

Понимаю, что многие захотят сделать из этого массовую рассылку. Для этого придется совместить код из этой статьи с кодом из статьи Как отправить письмо из Excel?. Там есть пример отправки писем через Outlook списку получателей.

Подумал, что неплохо было бы дополнить статью простенькой функцией, которая не сохраняет никаких файлов, форматированных таблиц и практически не делает лишних движений. Она просто в письмо вкладывает значения всех ячеек указанного диапазона простым текстом, без форматирования(разве что добавил переносы строки и табуляцию, чтобы соблюдался хоть какой-то табличный вид и текст не был одной единой строкой):

'---------------------------------------------------------------------------------------
' Author : The_Prist(Щербаков Дмитрий)
'          Профессиональная разработка приложений для MS Office любой сложности
'          Проведение тренингов по MS Excel
'          http://www.excel-vba.ru
' Purpose: функция объединяет значения указанного диапазона ячеек в строку
'          разрывы между столбцами заменяются табуляцией
'          разрывы между строками заменяются переносами на строки
'---------------------------------------------------------------------------------------
Function RangeToTextTable(rng As Range)
    Dim lr As Long, lc As Long, arr
    Dim res As String
 
    arr = rng.Value
    If Not IsArray(arr) Then
        ReDim arr(1 To 1, 1 To 1)
        arr(1, 1) = rng.Value
    End If
    For lr = 1 To UBound(arr, 1)
        For lc = 1 To UBound(arr, 2)
            If lc = 1 Then
                res = res & arr(lr, lc)
            Else
                res = res & vbTab & arr(lr, lc)
            End If
        Next
        res = res & vbNewLine
    Next
    RangeToTextTable = res
End Function

Вставляем значения ячеек при помощи этой функции в письмо:

    'создаем сообщение
    With objMail
        .To = "адрес получателя"
        .Subject = "Тема: тест вставки таблицы"
        '.BodyFormat = 2  'уже не надо, т.к. форматирования нет
        .Body = RangeToTextTable(Selection)
        .Display 'отображаем сообщение
    End With

Здесь следует помнить, что «таблица» после такой вставки будет выглядеть не очень красиво. И речь не о цвете заголовков — при различной длине текста внутри ячеек текст в письме будет сдвигаться:

чтобы этого как-то избежать, можно чуть модифицировать функцию:

'---------------------------------------------------------------------------------------
' Author : The_Prist(Щербаков Дмитрий)
'          Профессиональная разработка приложений для MS Office любой сложности
'          Проведение тренингов по MS Excel
'          http://www.excel-vba.ru
'          WebMoney - R298726502453; Яндекс.Деньги - 41001332272872
' Purpose: функция объединяет значения указанного диапазона ячеек в строку
'          разрывы между столбцами заменяются табуляцией
'          разрывы между строками заменяются переносами на строки
'---------------------------------------------------------------------------------------
Function RangeToTextTable(rng As Range)
    Dim lr As Long, lc As Long, arr
    Dim res As String, rh()
    Dim lSpaces As Long, s As String
 
    arr = rng.Value
    If Not IsArray(arr) Then
        ReDim arr(1 To 1, 1 To 1)
        arr(1, 1) = rng.Value
    End If
    ReDim rh(1 To UBound(arr, 2))
    For lr = 1 To UBound(arr, 1)
        For lc = 1 To UBound(arr, 2)
            If Len(arr(lr, lc)) > rh(lc) Then
                rh(lc) = Len(arr(lr, lc))
            End If
        Next
    Next
    For lr = 1 To UBound(arr, 1)
        For lc = 1 To UBound(arr, 2)
            s = arr(lr, lc)
            lSpaces = rh(lc) - Len(s)
            If lSpaces > 0 Then
                s = s & Space(lSpaces)
            End If
            If lc = 1 Then
                res = res & s
            Else
                res = res & vbTab & s
            End If
        Next
        res = res & vbNewLine
    Next
    RangeToTextTable = res
End Function

и назначить шрифт для писем по умолчанию Courier New или любой другой мноноширный шрифт. Тогда можно получить примерно такой результат:

Если использовать не моноширный шрифт, то визуально таблица все равно будет неравной и смысла в модификации функции нет.

Так же см.:
Как отправить письмо из Excel?
Вставить в письмо подпись из Outlook через VBA
Сохранить вложения из Outlook в указанную папку
Как отправить письмо от другой учетной записи Outlook

Статья помогла? Поделись ссылкой с друзьями!

    Видеоуроки

Поиск по меткам



Access
apple watch
Multex
Power Query и Power BI
VBA управление кодами
Бесплатные надстройки
Дата и время
Записки
ИП
Надстройки
Печать
Политика Конфиденциальности
Почта
Программы
Работа с приложениями
Разработка приложений
Росстат
Тренинги и вебинары
Финансовые
Форматирование
Функции Excel
акции MulTEx
ссылки
статистика

If you want to insert or add a Table in Gmail and Outlook messages, here is how you can do that. It is quite straightforward since you can use Google Sheets or Excel Online to fetch the table from. Here is everything you need to know about inserting tables in Gmail and Outlook messages on the web and Mail for Windows 11/10.

Let’s assume that you want to send a list containing some product names and their prices. Adding a table is probably the most efficient way to get the job done. The problem begins when you try to add the table since Gmail doesn’t allow you to do that. On the other hand, Outlook for the web lets you insert the table, but it doesn’t have any option to customize it. That is why you need to check out this article to learn more about various methods to insert a table in your emails.

How to add a Table in Gmail and Outlook using Copy-Paste

Follow these steps to add a Table in Gmail and Outlook using Copy-Paste:

1. Open Google Sheets on your browser.
2. Create the table you want to insert in the email.
3. Copy the entire table to your clipboard.
4. Open Gmail or Outlook and compose a message.
5. Press Ctrl+V to paste the table

To learn more about these steps, continue reading.

It is the most common method when you are using Gmail. You can create a table in any spreadsheet maker, such as Excel Online, Google Sheets, or Excel for desktop. For this example, we are about to show you the screenshots of Google Sheets and Gmail. However, you can do the same with any other spreadsheet maker and Outlook also.

To get started, open the official website of Google Sheets, docs.google.com, and create a black spreadsheet. Following that, create a table as per your requirements and copy the entire table to your clipboard.

Next, open Gmail and start composing an email. Select a position where you want to display the table and press Ctrl+V to paste the copied table.

Now you can see the table in your email.

There is a more efficient way to insert a table when you are using Outlook.com. The web version of Outlook allows you to insert a table using the in-built option it includes.

Disadvantage: Outlook lets you edit the table, change the column width, insert or remove rows/columns, etc. However, Gmail doesn’t have any such option.

To insert table in Outlook for web, follow these steps:

1. Log in to your account on outlook.com.
2. Click on the New message button to start composing an email.
3. Click on the Insert table icon in the toolbar.
4. Select the number of rows and columns.

Let’s check out these steps in detail.

To get started, log in to your user account on the Outlook.com website and click the New message button to start composing a new email.

Following that, find out the Insert table icon in the toolbar and click on it.

Now, you need to select the number of rows and columns of your table.

Following that, you can start entering the values in each cell as per your wish.

Disadvantage: You cannot edit the first row or heading of a table if you insert it using the in-built option in Outlook.

How to add or insert a Table in Mail on Windows 11/10

To add or insert table in Mail on Windows 11/10, follow these steps:

1. Open the Mail app on your computer.
2. Start composing a message.
3. Switch to the Insert tab.
4. Click on the Table option.

You need to open the Mail app on your computer and start composing a message to get started. When you open the panel to start writing an email, it shows a toolbar on the top. You need to switch to the Insert tab and click on the Table option.

By default, it adds a 3×3 table automatically. If you want to insert more columns or rows, click on the Insert button and choose the option accordingly.

The best thing about this option is that you can customize the table in the way you want. There is almost no limitation in editing the table in the Mail app if you use the in-built option. The second advantage is that you get the same options for Gmail accounts as well.

How do I insert a Table into the body of an email?

To insert a table into the body of an email, you have three options – use the Copy-Paste method, use the in-built Insert table option, and use the Mail app on Windows 11/10. The Copy-Paste method works when you have a dedicated spreadsheet maker.

How do I add Rows to a Table in Gmail?

You cannot add rows to a table in Gmail once it is inserted already. You need to change the table before pasting it in the email body.

How do I edit a Table in Gmail?

It is not possible to edit the header color, insert more rows/columns, etc. However, you can change the value of cells in a table in Gmail. For that, click on the text you want to edit, remove it, and add the new one.

This is how you can add or insert a table in Gmail and Outlook.

Read: How to insert a checkbox in Outlook email and Mail app.

Вставить таблицу Excel в Outlook — это шаг, который нужно выполнить, если мы хотим обмениваться информацией через эту платформу, есть другие способы поделиться таблицей Excel для электронной почты в Outlook, мы вскоре объясним их, а также вставим в сообщение.

Если вы хотите добавить, вставить или вставить таблицу Excel прямо в сообщение электронной почты Outlook, здесь мы предоставим вам шаги. может сделать это без осложнений . Мы также научим вас другим способам совместного использования таблицы Excel через Outlook.

Когда мы работаем в электронной таблице Excel, мы обычно используем таблицы, информация, собранная в Таблицы Excel понимать простые в выполнении расчеты. Если мы хотим поделиться этой информацией, есть несколько способов сделать это.

Один из способов поделиться информацией в таблице — это добавить в электронную почту Outlook, и это оказывается самым простым способом поделиться ими. Однако, когда мы не знаем, как применить процесс добавления или вставки массива, все усложняется.

Что мы собираемся сделать, чтобы вставить таблицу Excel в Outlook, очень просто: первое, что нужно сделать, это ввести наш рабочий лист Excel; щелкнув левой кнопкой мыши вниз, мы выберут все квадраты, соответствующие таблице.

Затем мы щелкнем правой кнопкой мыши по этому выбору и выберем возможность скопировать ; на этом этапе вы должны перейти к электронной почте и открыть новое сообщение для создания. 

Следующее, что нужно сделать, это щелкнуть правой кнопкой мыши сообщение Outlook, сначала указав адрес электронной почты получателя и тему, а затем нажмите на вставку . Таблица будет автоматически вставлена, и вы можете отправить ее, чтобы другой пользователь получил ее как сообщение.

Какие еще способы поделиться файлом Excel в Outlook?

Способ, который мы объясняли ранее, относится к простейшему механизму обмена информацией в Outlook, но есть и другие. способы отправить документ или таблицу Excel через эту платформу без необходимости вставлять таблицу Excel в Outlook.

Помня, что Outlook имеет связи с различными типами программного обеспечения Microsoft Office, мы можем сказать, что процесс совместное использование файла Excel через Outlook довольно просто.

Один из способов — отправить документ или таблицу Excel как вложение в Outlook , для чего требуется только файл заранее зарегистрирован на отправляющем устройстве. Существует также возможность отправки в формате PDF, когда он отправляется в виде файла, который нельзя редактировать из Outlook или другого почтового носителя.

А с другой стороны, есть возможность отправить как XPS по электронной почте – почта , способ, позволяющий сохранить дизайн, формат и изображения при отправке. Могут быть и другие способы отправки документа Excel через Outlook, но это метод по умолчанию, установленный Microsoft Office.

Что делать, если я не могу вставить таблицу Excel по электронной почте из Outlook?

Возможно, вы пытались вставить таблицу Excel в Outlook отправить его как обычное сообщение, и у вас это не сработало; и, возможно, позже вы попытались отправить его другими способами, которые мы здесь упомянули, и это тоже не сильно помогло. 

Процесс вставка или добавление таблицы Excel в сообщении Outlook не работает в некоторых случаях, и содержащаяся в нем информация может не «перевариваться» форматом сообщения. Это также происходит с некоторыми изображениями, когда они вставлен в тело письма в Outlook.

Однако это не значит, что вы не можете этого сделать. Другой вариант вставки таблицы Excel в Outlook можно сделать с помощью ссылок между программами Microsoft Office.

Вы можете попробовать связать таблицу Excel с Word , или вы также можете сделать это с помощью другой носитель, такой как Power Point. Один или оба из этих пунктов могут помочь .

Последнее делается для того, чтобы скопировать рассматриваемую таблицу. в этих форматах и вставьте их в сообщение электронной почты Outlook.

Отправка книги или листа по электронной почте

Если вам часто приходится рассылать определенные книги или листы по электронной почте, то вы должны были заметить, что процедуру эту быстрой не назовешь. Если делать ее «классически», то надо:

• открыть почтовую программу (например Outlook)
• создать новое сообщение
• вбить туда адрес, тему и текст
• прикрепить к сообщению файл (не забыть!)
• нажать кнопку Отправить

На самом деле почту можно легко отправлять прямо из Excel кучей разных способов. Поехали…

Способ 1. Встроенная отправка

Если у вас еще старый добрый Excel 2003, то все просто. Открываете нужную книгу/лист и выбираете в меню Файл — Отправить — Сообщение (File — Send To — Mail Recipient). Откроется окошко, в котором можно выбрать один из двух вариантов отправки:

В первом случае текущая книга будет добавлена в сообщение как вложение, во втором — содержимое текущего листа попадет прямо в текст сообщения как текстовая таблица (без формул).

Кроме этого в меню Файл — Отправить (File — Send To) есть еще несколько более экзотических вариантов отправки:

• Сообщение (для ознакомления) (Mail Recipient for Review) — отправляется вся книга целиком и при этом для нее включается отслеживание изменений, т.е. начинает явно фиксироваться — кто, когда и в каких ячейках какие изменения производил. Отобразить внесенные изменения потом можно в меню Сервис — Исправления — Выделить исправления (Tools — Track changes — Highlight changes) или на вкладке Рецензирование — Исправления (Reveiw — Track Changes) Выглядеть это будет примерно так:
  
  

  Цветные рамочки помечают изменения, внесенные в документ (для каждого пользователя — свой цвет). При наведении мыши всплывает похожее на примечание окошко с подробным описанием кто, что и когда изменил в этой ячейке. Весьма удобно для рецензирования документов, когда, например, вы правите отчет своих подчиненных или шеф правит ваш.

• По маршруту (Routing Recipient) — сообщение, куда будет вложена ваша книга, отправится по цепочке получателей, каждый из которых автоматически будет пересылать его дальше, как эстафетную палочку. При желании можно задать, чтобы в конце цепочки сообщение вернулось к вам обратно. Можно включить режим отслеживания изменений, чтобы видеть правки, внесенный каждым человеком в цепочке.

В новых Excel 2007/2010 ситуация немного другая. В этих версиях для отправки книги по почте нужно выбрать кнопку Офис (Office Button) или вкладку Файл (File) и команду Отправить (Send). Далее, пользователю предлагается набор вариантов отправки:

Обратите внимание на то, что в новых версиях исчезла возможность отправки отдельного листа книги, вставленного в тело письма — как это было в Excel 2003 и старше. Осталась только возможность отправить весь файл целиком. Зато появилась полезная возможность отправлять в известном формате PDF и менее известном XPS (аналог PDF, но не требует Acrobat Reader для чтения — открывается прямо в Internet Explorer). Команду отправки книги для ознакомления можно вытащить как дополнительную кнопку на панель быстрого доступа через Файл — Параметры — Панель быстрого доступа — Все команды — Отправить на проверку (File — Options — Quick Access Toolbar — All Comands — Send for Review).

Способ 2. Простые макросы для отправки

Отправка макросом гораздо проще. Открываем редактор Visual Basic через меню Сервис — Макрос — Редактор Visual Basic (Tools — Macro — Visual Basic Editor), вставляем новый модуль в меню Insert — Module и копируем туда текст этих двух макросов:

Sub SendWorkbook()
    ActiveWorkbook.SendMail Recipients:="vasya@pupkin.com", Subject:="Лови файлик"
End Sub

Sub SendSheet()
    ThisWorkbook.Sheets("Лист1").Copy
    With ActiveWorkbook
        .SendMail Recipients:="vasya@pupkin.com", Subject:="Лови файлик"
        .Close SaveChanges:=False
    End With
End Sub

После этого скопированные макросы можно запустить в меню Сервис — Макрос — Макросы (Tools — Macro — Macros). SendWorkbook отправляет на заданный адрес всю текущую книгу, а SendSheet — Лист1 как вложение.

При запуске макроса Excel будет обращаться к Outlook, что вызовет появление вот такого сообщения безопасности на экране:

Дождитесь, пока кнопка Разрешить станет активной и нажмите ее, чтобы подтвердить свою отправку. После этого созданные автоматически сообщения будут помещены в папку Исходящие и отправятся получателям при первом запуске Outlook или, если он у вас запущен, непосредственно сразу же.

Способ 3. Универсальный макрос

А если хочется отправлять не текущую книгу, а любой другой файл? И текст сообщения тоже неплохо было бы задать! Предыдущие макросы здесь не помогут, поскольку ограничены возможностями самого Excel, но можно создать макрос, который будет из Excel’я управлять Outlook’ом — создавать и заполнять окно нового сообщения и отправлять его. Макрос выглядит так:

Sub SendMail()
    Dim OutApp As Object
    Dim OutMail As Object
    Dim cell As Range
    
    Application.ScreenUpdating = False
    Set OutApp = CreateObject("Outlook.Application")   'запускаем Outlook в скрытом режиме
    OutApp.Session.Logon      
    On Error GoTo cleanup  'если не запустился - выходим 
    Set OutMail = OutApp.CreateItem(0)   'создаем новое сообщение
    On Error Resume Next
    'заполняем поля сообщения
    With OutMail
        .To = Range("A1").Value
        .Subject = Range("A2").Value
        .Body = Range("A3").Value
        .Attachments.Add Range("A4").Value
        'команду Send можно заменить на Display, чтобы посмотреть сообщение перед отправкой 
        .Send
    End With

    On Error GoTo 0
    Set OutMail = Nothing

cleanup:
    Set OutApp = Nothing
    Application.ScreenUpdating = True
End Sub

Адрес, тема, текст сообщения и путь к вложенному файлу должны быть в ячейках A1:A4 текущего листа.

Ссылки по теме

• Групповая рассылка почтовых сообщений из Excel с помощью надстройки PLEX
• Макросы для отправки почты из Excel через Lotus Notes от Dennis Wallentin
• Что такое макросы, куда вставлять код макроса на Visual Basic
• Создание писем с помощью функции ГИПЕРССЫЛКА