Как посчитать количество различных значений в столбце excel

Подсчет количества уникальных значений

Постановка задачи

Есть диапазон с данными, в котором некоторые значения повторяются больше одного раза:

Задача — подсчитать количество уникальных (неповторяющихся) значений в диапазоне. В приведенном выше примере, как легко заметить, на самом деле упоминаются всего четыре варианта.

Рассмотрим несколько способов ее решения.

Способ 1. Если нет пустых ячеек

Если вы уверены, что в исходном диапазоне данных нет пустых ячеек, то можно использовать короткую и элегантную формулу массива:

Не забудьте ввести ее как формулу массива, т.е. нажать после ввода формулы не Enter, а сочетание Ctrl+Shift+Enter.

Технически, эта формула пробегает по всем ячейкам массива и вычисляет для каждого элемента количество его вхождений в диапазон с помощью функции СЧЕТЕСЛИ (COUNTIF). Если представить это в виде дополнительного столбца, то выглядело бы оно так:

Потом вычисляются дроби 1/Число вхождений для каждого элемента и все они суммируются, что и даст нам количество уникальных элементов:

Способ 2. Если есть пустые ячейки

Если в диапазоне встречаются пустые ячейки, то придется немного усовершенствовать формулу, добавив проверку на пустые ячейки (иначе получим ошибку деления на 0 в дроби):

Вот и все дела.

Ссылки по теме

• Как извлечь из диапазона уникальные элементы и удалить дубликаты
• Как подсветить дубликаты в списке цветом
• Как сравнить два диапазона на наличие в них дубликатов
• Извлечение уникальных записей из таблицы по заданному столбцу с помощью надстройки PLEX

В этом руководстве вы узнаете, как подсчитывать уникальные значения в Excel с помощью формул и как получить автоматическое подсчет различных значений в сводной таблице. Мы также обсудим ряд примеров формул для подсчета уникальных имен, текстов, чисел, чувствительных к регистру уникальных значений и многое другое.

При работе с большим набором данных в Excel часто может потребоваться знать, сколько существует повторяющихся и уникальных значений. И иногда, вы можете считать только различные (разные) значения.

Если вы посещали этот блог на регулярной основе, вы уже знаете формулу Excel для подсчета дубликатов. И сегодня мы собираемся исследовать различные способы подсчета уникальных значений в Excel. Но для большей ясности давайте сначала определимся с терминами.

1. Уникальные значения-это значения, которые появляются в списке только один раз.

1. Различные значения-это все разные значения в списке, т. е. уникальные значения плюс 1 st вхождений повторяющихся значений.

На следующем снимке экрана показана разница:

А теперь давайте посмотрим, как вы можете рассчитывать уникальные и отличные значения в Excel, используя формулы и функции сводной таблицы. В этой статье мы затронем следующие темы:

Как подсчитать уникальные значения в Excel;
Подсчет уникальных значений в столбце;
Подсчет уникальных текстовых значений;
Считайте уникальные числа;
Подсчет уникальных значений с учетом регистра;
Как подсчитать различные значения в Excel;
Подсчитывайте различные значения, игнорируя пустые ячейки;
Формула для подсчета различных текстовых значений;
Формула для подсчета различных чисел;
Подсчет различных значений с учетом регистра;
Как подсчитать уникальные и различные строки в Excel;
Автоматическое подсчет различных значений в сводной таблице;
Как подсчитать уникальные значения в Excel;

Вот общая задача, которую все пользователи Excel должны выполнять один раз в то время. У вас есть список данных, и вам нужно узнать количество уникальных значений в этом списке. Как ты это делаешь? Проще, чем вы можете подумать ниже вы найдете несколько формул для подсчета уникальных значений различных типов.

Подсчет уникальных значений в столбце

Предположим, у вас есть столбец имен в вашем листе Excel, и вам нужно подсчитать уникальные имена в этом столбце. Решение заключается в использовании функции SUM в сочетании с IF и COUNTIF:

=SUM(IF(COUNTIF(range, range)=1,1,0))

Примечание. Это формула массива, поэтому не забудьте нажать Ctrl + Shift + Enter, чтобы завершить его. Как только вы сделаете это, Excel автоматически заключит формулу в {фигурные скобки}, как на скриншоте ниже. Ни в коем случае не следует вводить фигурные скобки вручную, это не будет работать.

В этом примере мы подсчитываем уникальные имена в диапазоне A2:A10, поэтому наша формула принимает следующую форму:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Подсчет уникальных значений в Excel

Далее в этом уроке мы обсудим несколько других формул для подсчета уникальных значений различных типов. И поскольку все эти формулы являются вариациями базовой формулы уникальных значений Excel, имеет смысл разбить приведенную выше формулу, чтобы вы могли полностью понять, как она работает, и настроить ее для ваших данных. Если кто-то не заинтересован в технических деталях, вы можете сразу перейти к следующему примеру формулы.

Как работает формула уникальных значений Excel count

Как вы видите, в нашей уникальной формуле значений используются 3 различных функции-SUM, IF и COUNTIF. Глядя изнутри наружу, вот что делает каждая функция:

1. Функция COUNTIF подсчитывает, сколько раз каждое отдельное значение появляется в указанном диапазоне. В этом примере COUNTIF(A2:A10,A2:A10) возвращает массив {1;2;2;1;2;2;2;1;2}.
2. Функция IF оценивает каждое значение в массиве, возвращаемом COUNTIF, сохраняет все 1 (уникальные значения) и заменяет все другие значения нулями. Таким образом, функция IF(COUNTIF(A2:A10,A2:A10)=1,1,0)становится IF(1;2;2;1;2;2;2;1;2) = 1,1,0,тем, что превращается в массив {1;0;0;1;0;0;0;1;0}, где 1-уникальное значение, а 0-повторяющееся значение.
3. Наконец, функция SUM суммирует значения в массиве, возвращаемом IF, и выводит общее количество уникальных значений, что именно то, что мы хотели.

Совет. Чтобы узнать, к чему относится определенная часть формулы уникальных значений Excel, выберите эту часть в строке формул и нажмите клавишу F9.

Подсчет уникальных текстовых значений в Excel

Если ваш список Excel содержит как числовые, так и текстовые значения, и вы хотите считать только уникальные текстовые значения, добавьте функцию ISTEXT в Формулу массива, описанную выше:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Как известно, функция Excel ISTEXT возвращает TRUE, если вычисленное значение является текстом, в противном случае-FALSE. Поскольку звездочка (*) работает как оператор AND в формулах массива , функция IF возвращает 1 только в том случае, если значение является одновременно текстовым и уникальным, 0 в противном случае. А после того, как функция SUM сложит все единицы, вы получите количество уникальных текстовых значений в указанном диапазоне.

Не забудьте нажать Ctrl + Shift + Enter, чтобы правильно ввести формулу массива, и вы получите результат, аналогичный этому:

Подсчет уникальных текстовых значений в Excel

Как вы можете видеть на скриншоте выше, формула возвращает общее количество уникальных текстовых значений, исключая пустые ячейки, числа, логические значения TRUE и FALSE, а также ошибки.

Подсчет уникальных числовых значений в Excel

Чтобы подсчитать уникальные числа в списке данных, используйте формулу массива, как мы только что использовали для подсчета уникальных текстовых значений, с единственной разницей, что вы вставляете ISNUMBER вместо ISTEXT в свою формулу уникальных значений:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Подсчет уникальных числовых значений в Excel

Примечание. Поскольку Microsoft Excel хранит даты и время в виде серийных номеров, они также учитываются.

Подсчет уникальных значений с учетом регистра в Excel

Если таблица содержит данные с учетом регистра, самый простой способ подсчета уникальных значений — это создание вспомогательного столбца со следующей формулой массива для идентификации повторяющихся и уникальных элементов:

=IF(SUM((—EXACT($A$2:$A$10,A2)))=1,»Unique»,»Dupe»)

А затем используйте простую функцию COUNTIF для подсчета уникальных значений:

=COUNTIF(B2:B10, «unique»)

Подсчет уникальных значений с учетом регистра в Excel

Подсчитайте различные значения в Excel (уникальные и 1-й повторяющиеся вхождения)

Чтобы получить количество различных значений в списке, используйте следующую формулу:

=SUM(1/COUNTIF(range, range))

Помните, что это формула массива, и поэтому вы должны нажать сочетание клавиш Ctrl + Shift + Enter вместо обычного нажатия клавиши Enter.

Кроме того, вы можете использовать функцию SUMPRODUCT и завершить формулу обычным способом, нажав клавишу Enter:

=SUMPRODUCT(1/COUNTIF(range, range))

Например, чтобы подсчитать различные значения в диапазоне A2:A10, вы можете пойти с любым из них:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Или

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Подсчет различных значений в Excel

Как работает формула Excel distinct

Как вы уже знаете, мы используем функцию COUNTIF, чтобы узнать, сколько раз каждое отдельное значение появляется в указанном диапазоне. В приведенном выше примере результатом функции COUNTIF является следующий массив: {2;2;3;1;2;2;3;1;3}.

После этого выполняется ряд операций деления, где каждое значение массива используется в качестве делителя с 1 в качестве дивиденда. Это превращает все повторяющиеся значения в дробные числа, соответствующие числу повторяющихся вхождений. Например, если значение отображается в списке 2 раза, оно генерирует 2 элемента в массиве со значением 0,5 (1/2=0,5). И если значение появляется 3 раза, он производит 3 элемента в массиве со значением 0.3(3). В нашем примере результатом 1/COUNTIF(A2:A10,A2:A10)) является массив {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)}.

Пока что это не имеет особого смысла? Это потому, что мы еще не применили функцию SUM / SUMPRODUCT. Когда одна из этих функций суммирует значения в массиве, сумма всех дробных чисел для каждого отдельного элемента всегда дает 1, независимо от того, сколько вхождений этого элемента существует в списке. И поскольку все уникальные значения отображаются в массиве как 1 (1/1=1), конечный результат, возвращаемый формулой, является общим числом всех различных значений в списке.

Формулы для подсчета различных значений различных типов

Как и в случае с подсчетом уникальных значений в Excel, можно использовать варианты базовой формулы Excel count distinct для обработки конкретных типов значений, таких как числа, текст и регистрозависимые значения.

Пожалуйста, помните, что все приведенные ниже формулы являются формулами массива и требуют нажатия клавиш Ctrl + Shift + Enter.

Подсчитывайте различные значения, игнорируя пустые ячейки

Если столбец, в котором требуется подсчитать различные значения, может содержать пустые ячейки, следует добавить функцию IF, которая будет проверять указанный диапазон на наличие пробелов (в этом случае базовая формула Excel distinct, описанная выше, возвращает ошибку #DIV/0):

=SUM(IF(range<>»»,1/COUNTIF(range, range), 0))

Например, для подсчета различных значений в диапазоне A2:A10 используйте следующую формулу массива:

=SUM(IF(A2:A10<>»»,1/COUNTIF(A2:A10, A2:A10), 0))

Формула для подсчета различных значений игнорирует пустые ячейки

Формула для подсчета различных текстовых значений

Для подсчета различных текстовых значений в столбце мы будем использовать тот же подход, который мы только что использовали для исключения пустых ячеек.

Как вы можете легко догадаться, мы просто встроим функцию ISTEXT в нашу формулу Excel count distinct:

=SUM(IF(ISTEXT(range),1/COUNTIF(range, range),»»))

И вот вам реальный пример формулы:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),»»))

Формула для подсчета различных чисел

Для подсчета различных числовых значений (чисел, дат и времени) используйте функцию ISNUMBER:

=SUM(IF(ISNUMBER(range),1/COUNTIF(range, range),»»))

Например, чтобы посчитать все различные числа в диапазоне A2:A10, используйте следующую формулу:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),»»))

Подсчет различных значений с учетом регистра в Excel

Подобно подсчету уникальных значений с учетом регистра, самый простой способ подсчета различных значений с учетом регистра-это добавление вспомогательного столбца с формулой массива, которая идентифицирует уникальные значения, включая первые повторяющиеся вхождения. Формула в основном такая же , как та, которую мы использовали для подсчета уникальных значений с учетом регистра, с одним небольшим изменением в ссылке на ячейку, что делает большую разницу:

=IF(SUM((—EXACT($A$2:$A2,$A2)))=1,»Distinct»,»»)

Как вы помните, все формулы массива в Excel требуют нажатия клавиш Ctrl + Shift + Enter.

После того, как приведенная выше формула будет завершена, вы можете рассчитывать» отличные » значения с помощью обычной формулы COUNTIF, такой как эта:

=COUNTIF(B2:B10, «distinct»)

Подсчет различных значений с учетом регистра в Excel

Если нет способа добавить вспомогательный столбец на рабочий лист, можно использовать следующую сложную формулу массива для подсчета различных значений с учетом регистра без создания дополнительного столбца:

=SUM(IFERROR(1/IF($A$2:$A$10<>»», FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), «»), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10))), 0), 0))

Подсчет уникальных и отличных строк в Excel

Подсчет уникальных / различных строк в Excel аналогичен подсчету уникальных и различных значений, с той лишь разницей, что вы используете функцию COUNTIFS вместо COUNTIF, которая позволяет указать несколько столбцов для проверки уникальных значений.

Например, для подсчета уникальных или различных имен на основе значений в Столбцах A( имя) и B (фамилия) используйте одну из следующих формул:

Формула для подсчета уникальных строк:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Формула для подсчета различных строк:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Подсчет уникальных и отчетливых строк в Excel

Естественно, вы не ограничены подсчетом уникальных строк, основанных только на двух столбцах, функция COUNTIFS Excel может обрабатывать до 127 пар диапазонов/критериев.

Подсчет различных значений в Excel с помощью сводной таблицы

Последние версии Excel 2013 и Excel 2016 имеют специальную функцию, которая позволяет автоматически подсчитывать различные значения в сводной таблице. Следующий снимок экрана дает представление о том, как выглядит Excel Distinct Count:

Число различных объектов в сводной таблице

Чтобы создать сводную таблицу с определенным числом различных столбцов, выполните следующие действия.

1. Выберите данные для включения в сводную таблицу, перейдите на вкладку Вставка, группа таблицы и нажмите кнопку Сводная таблица.

2. В диалоговом окне создать сводную таблицу выберите, следует ли разместить сводную таблицу на новом или существующем листе, и обязательно установите флажок добавить эти данные в модель данных.

Установите флажок «добавить эти данные в модель данных».

3. Когда ваша сводная таблица откроется, расположите строки, столбцы и области значений так, как вы хотите. Если у вас нет большого опыта работы с сводными таблицами Excel, могут оказаться полезными следующие подробные рекомендации: создание сводной таблицы в Excel.

4. Переместите поле, для которого требуется вычислить число различных объектов (поле элемента в данном примере) , в область значений, щелкните его и в раскрывающемся меню выберите параметры значения поля… :

Переместите поле, число различных значений которого вы хотите вычислить, в область значения и выберите параметры значения поля…
Откроется диалоговое окно настройки поля значений, вы прокрутите вниз до объекта подсчет различных значений, который является самым последним параметром в списке, выберите его и нажмите кнопку ОК.

Вы также можете задать собственное имя для вашего отдельного счетчика, если хотите.

Прокрутите вниз до самого последнего варианта и выберите Distinct Count.

— Готово! Вновь созданная сводная таблица будет отображать отдельный счетчик, как показано на самом первом скриншоте в этом разделе.

Совет. После обновления исходных данных не забудьте обновить сводную таблицу, чтобы обновить число различных объектов. Чтобы обновить сводную таблицу, просто нажмите кнопку Обновить на вкладке анализ в группе данных.

Именно так вы считаете различные и уникальные значения в Excel.

Я благодарю вас за чтение и надеюсь увидеть вас снова на следующей неделе. В следующей статье мы обсудим различные способы поиска, фильтрации, извлечения и выделения уникальных значений в Excel . Пожалуйста, оставайтесь с нами!

Источник перевода: https://www.ablebits.com/office-addins-blog/2016/04/07/how-to-count-distinct-and-unique-values-in-excel/

Сводные таблицы Excel удивительны (я знаю, что упоминаю об этом каждый раз, когда пишу о сводных таблицах, но это правда).

Обладая базовым пониманием, вы можете выполнить свою работу за несколько секунд.

Большинство задач можно сделать с помощью нескольких щелчков в сводных таблицах, но некоторые потребуют дополнительных шагов или подготовительной работы.

Одной из таких задач является подсчет разных значений в сводной таблице.

В этой статье я покажу вам, как подсчитывать разные значения, а также уникальные значения в сводной таблице Excel.

Прежде чем приступить к работе, важно понять разницу между «Подсчетом разных значений» и «подсчетом уникальным значений»

Разные значения против уникальных значений

Кажется, что это одно и то же, но это не так.

Ниже приведен пример со списком имен, в столбцах отдельно выделены уникальные и разные имена.

Уникальные значения / имена — это те, которые встречаются только один раз. Это означает, что все имена, которые повторяются и имеют дубликаты, не являются уникальными. Уникальные имена перечислены в столбце D вышеупомянутого набора данных.

Разными значениями / именами являются те, которые встречаются хотя бы один раз в наборе данных. Поэтому, если имя появляется три раза, оно все равно считается разным значением. Такой список можно получить путем удаления повторяющихся значений / имен и сохранения всех разных значений. Разные имена перечислены в столбце C приведенного выше набора данных.

В большинстве случаев, когда люди говорят, что хотят получить уникальные значения в сводной таблице, когда на самом деле имеют в виду разные.

Подсчет разных значений в сводной таблице Excel

Предположим, у вас есть данные о продажах:

Нажмите здесь, чтобы загрузить файл примера и делать все вместе со мной:

С этим набором данных вам нужно найти ответ на следующие вопросы:

• Сколько сотрудников в каждом регионе (а это не что иное, как количество разных сотрудников в каждом регионе)?
• Сколько сотрудников продали принтер в 2019 году?

Находить сумму сводные таблицы могут мгновенно, чтобы получить количество разных значений, вам нужно будет сделать еще несколько шагов.

Если вы используете Excel 2013 или более поздние версии, в сводной таблице есть встроенная функция, которая быстро подсчитывает количество.

А если вы используете Excel 2010 или ранние версии, вам придется изменить исходные данные, добавив вспомогательный столбец.

В этой статье рассматриваются следующие методы:

• Добавление вспомогательного столбца в исходный набор данных для подсчета разных значений (работает во всех версиях).
• Добавление данных в модель данных и использование параметра «Число различных элементов» (доступно в Excel 2013 и последующих версиях).

Существует третий метод, он называет метод сводной таблицы в сводной таблице.

Давайте начнем!

Добавление вспомогательного столбца в набор данных

Примечание. Если вы используете Excel 2013 и более поздние версии, пропустите этот метод и перейдите к следующему (вам доступна встроенная функция).

Это простой способ подсчета разных значений в сводной таблице, поскольку вам нужно только добавить вспомогательный столбец к исходным данным. После добавления вспомогательного столбца вы легко ответите на вопросы задачи.

Хотя это простой обходной путь, у него есть некоторые недостатки (которые будут рассмотрены далее).

Позвольте мне сначала показать вам, как добавить вспомогательный столбец и посчитать разные значения.

Предположим, у меня есть набор данных, как показано ниже:

Добавьте следующую формулу в столбец F и примените ее ко всем ячейкам, в которых есть данные в соседних столбцах.

= ЕСЛИ (СЧЁТЕСЛИМН ($C$2:C2; C2; $B$2:B2; B2) > 1;0;1)

Приведенная выше формула использует функцию СЧЁТЕСЛИМН для подсчета количества раз, когда имя появляется в данном регионе. Также обратите внимание на диапазоны критериев: $C$2:C2 и $B$2:B2. Это означает, что они продолжают расширяться, когда вы идете вниз по столбцу.

Например, в ячейке F2 диапазон критериев составляет $C$2:C2 и $B$2:B2, а в ячейке F3 эти диапазоны расширяются до $C$3:C3 и $B$3:B3.

Это гарантирует, что функция СЧЁТЕСЛИМН считает первый экземпляр имени как 1, второй экземпляр имени как 2 и так далее.

Поскольку мы хотим получить только разные имена, используется функция ЕСЛИ, которая возвращает 1, когда имя появляется для региона в первый раз, и возвращает 0, когда оно появляется снова. Это гарантирует, что учитываются только разные имена, а не повторы.

Ниже показано, как будет выглядеть таблица, когда вы добавите вспомогательный столбец.

Теперь, когда мы изменили исходные данные, мы можем использовать их для создания сводной таблицы. Подключив вспомогательный столбец, получим количество различных сотрудников в каждом регионе.

Ниже приведены шаги, как сделать это:

• Выберите любую ячейку в таблице.
• Нажмите вкладку «Вставка».

• Нажмите на кнопку Сводная таблица.

• В диалоговом окне «Создание сводной таблицы» убедитесь, что таблица / диапазон указаны правильно (и включает вспомогательный столбец), и выбран «На новый лист» в качестве места размещения.

• Нажмите ОК.

Вышеуказанные шаги вставят новый лист со сводной таблицей.

Перетащите поле «Регион» в область «Строки» и поле «Помощник» в область «Значения».

Вы получите вот такую сводную таблицу:

Теперь вы можете изменить заголовок столбца с «Сумма по полю Помощник» на «Количество сотрудников».

Недостатки использования вспомогательного столбца

Хотя этот метод довольно прост, я должен выделить несколько недостатков, связанных с изменением исходных данных в сводной таблице:

• Источник данных со вспомогательным столбцом не такой динамичный, как сводная таблица. Если изменится поставленная задача, вам придется вернуться к исходным данным и изменить формулу вспомогательного столбца (или добавить новый вспомогательный столбец).
• Поскольку вы добавляете больше данных в источник сводной таблицы (который также добавляется в сводный кэш), это может привести к увеличению размера файла Excel.
• Так как мы используем формулу Excel, это может замедлить работу вашей книги Excel, если в данных тысячи строк.

Добавить данные в модель данных и суммировать, используя «Число различных элементов»

В сводную таблицу добавлены новые функции в Excel 2013, которые позволяют получать количество различных значений.

В случае, если вы используете предыдущую версию, вы не сможете использовать этот метод (используйте метод, описанный выше).

Напомню, что у нас есть таблица данных, и мы хотим получить количество разных сотрудников в каждом регионе.

Ниже приведены шаги для получения количества разных сотрудников в сводной таблице:

• Выберите любую ячейку в таблице.
• Нажмите вкладку «Вставка».

• Нажмите на кнопку Сводная таблица.

• В диалоговом окне «Создание сводной таблицы» убедитесь, что таблица / диапазон указаны правильно и выбран новый рабочий лист.
• Установите флажок «Добавить эти данные в модель данных».

• Нажмите ОК.

Приведенные выше шаги вставят новый лист с новой сводной таблицей.

Перетащите регион в область «Строки» и «Сотрудник» в область «Значения». Вы получите такую сводную таблицу:

В этой сводной таблице приводится общее количество сотрудников в каждом регионе (а не количество разных).

Чтобы получить подсчет разных значений в сводной таблице, выполните следующие действия:

• Щелкните правой кнопкой мыши по любой ячейке в «Число элементов в столбце Сотрудник»
• Нажмите на «Параметры полей значений».

• В диалоговом окне «Параметры поля значений» выберите «Число различных элементов» в качестве операции (вам может потребоваться прокрутить список вниз, чтобы найти его).

• Нажмите ОК.

Обратите внимание, что название столбца изменится с «Число элементов в столбце Сотрудник» на «Число разных элементов в столбце Сотрудник». Вы можете изменить его.

Некоторые вещи, которые нужно знать, добавляя свои данные в модель данных:

• Если вы сохраните свои данные в модели данных, а затем откроете в более старой версии Excel, появится предупреждение: «Некоторые функции сводной таблицы не будут сохранены».
• Когда вы добавляете свои данные в модель данных и создаете сводную таблицу, в ней не отображаются параметры добавления вычисляемых полей и вычисляемых столбцов.

Что если вы хотите посчитать уникальные значения (а не разные значения)?

Если вы хотите посчитать уникальные значения, то встроенные функции вам не помогут, придется полагаться только на вспомогательные столбцы.

Помните — уникальные значения и разные значения не одно и то же. Нажмите здесь, чтобы узнать разницу.

Рассмотрим пример, когда нам нужно определить количество уникальных сотрудников для каждого региона. Это означает, что они работают только в одном конкретном регионе, а не в других.

В таких случаях вам нужно создать один или несколько вспомогательных столбцов.

Вот формула для этого случая:

= ЕСЛИ (ЕСЛИ (СЧЁТЕСЛИМН ($C$2:$C$1001; С2; $B$2:$B$1001; В2) / СЧЁТЕСЛИ ($C$2:$C$1001; С2) <1;0;1); ЕСЛИ (СЧЁТЕСЛИ ($С2:С$22; С2) > 1;0;1);0)

Приведенная выше формула проверяет, встречается ли имя сотрудника только в одном регионе или в нескольких регионах. Это делается путем подсчета количества появлений имени в регионе и деления его на общее количество появлений имени. Если значение меньше 1, это означает, что имя встречается в двух или более двух регионах.

Если имя встречается в нескольких регионах, формула возвращает 0, в противном случае возвращает единицу.

Формула также проверяет, повторяется ли имя в том же регионе или нет. Если имя повторяется, только первый экземпляр имени возвращает значение 1, а все остальные экземпляры возвращают 0.

Это может показаться немного сложным, но это опять-таки зависит от того, чего вы пытаетесь достичь.

Таким образом, если вы хотите подсчитать уникальные значения в сводной таблице, используйте вспомогательные столбцы, а если вы хотите подсчитать различные значения, вы можете использовать встроенную функцию (в Excel 2013 и более поздних версиях) или использовать вспомогательный столбец.

Произведем подсчет уникальных текстовых значений в диапазоне ячеек.

Сначала поясним, что значит подсчет

уникальных

значений. Пусть имеется массив текстовых значений {«а»,»b»,

«а»,»а»,»а»

}. При подсчете уникальных игнорируются все повторы, т.е. значения выделенные

жирным

. Соответственно, подсчитываются остальные значения, т.е. «а» и «b». Ответ очевиден: количество уникальных значений равно 2.

Задача

Произведем подсчет числа

уникальных

текстовых значений в диапазоне

A7:A15

(см.

файл примера

). Диапазон может содержать

пустые

ячейки.

Решение

Запишем формулу

=СУММПРОИЗВ((

A7:A15<>»»

)/СЧЁТЕСЛИ(A7:A15;A7:A15))

Если в диапазоне кроме текстовых значений содержатся также и числа, то формула подсчитает и их. Чтобы игнорировать числовые значения нужно записать формулу

=СУММПРОИЗВ(ЕТЕКСТ(

A7:A15

)/СЧЁТЕСЛИ(A7:A15;A7:A15))

Если в список постоянно добавляются значения, то можно создать

Динамический именованный диапазон

Исходный_список

.

=СУММПРОИЗВ((Исходный_список<>»»)/СЧЁТЕСЛИ(Исходный_список;Исходный_список))

Теперь при добавлении новых значений они будут учитываться формулой.

Примечание

: Уникальные значения в

файле примера

выделены с помощью

Условного форматирования

(см. статью

Выделение уникальных значений в MS EXCEL

).

Часто вместо формулы

=СУММПРОИЗВ((

A7:A15<>»»

)/СЧЁТЕСЛИ(A7:A15;A7:A15))

используют более простую формулу

=СУММПРОИЗВ(1

/СЧЁТЕСЛИ(A7:A15;A7:A15))

. Разница между формулами состоит в том, что вторая формула учитыват значения

Пустой текст («»)

, а первая их игнорирует.

Приведем пример, когда это бывает важно.

Пусть дана таблица продаж товаров (см. рисунок ниже, столбцы А и В). С помощью формулы

=ЕСЛИ(МЕСЯЦ(B26)=1;A26;»»)

определяются товары, которые были проданы в январе. Если товар продан не в январе, то формула возвращает значение

Пустой текст.

Пользователь решает подсчитать количество уникальных товаров в январе (их всего 3: Товар1, Товар2 и Товар3).

Формула

=СУММПРОИЗВ((

A7:A15<>»»

)/СЧЁТЕСЛИ(A7:A15;A7:A15))

вернет правильный результат 3, а формула

=СУММПРОИЗВ(1

/СЧЁТЕСЛИ(A7:A15;A7:A15))

вернет 4, т.к. в «пустых» ячейках

С31:С34

на самом деле содержатся 4 значения «», которые воспринимаются ей как некое текстовое значение, хотя и нулевой длины.

СОВЕТ

: Как подсчитать уникальные числовые значения показано в одноименной статье

Подсчет уникальных числовых значений

.

СОВЕТ

: Как подсчитать уникальные числовые значения с дополнительными условиями (критериями) показано в статье

Подсчет Уникальных ЧИСЛОвых значений в MS EXCEL

.