Гидравлического расчета газопровода в excel скачать

Сейчас Вы — Гость на форумах «Проектант». Гости не могут писать сообщения и создавать новые темы.
Преодолейте несложную формальность — зарегистрируйтесь! И у Вас появится много больше возможностей на форумах «Проектант».

Гидравлический расчет трубопроводов

Опубликовано 08 Апр 2014
Рубрика: Теплотехника | 66 комментариев

Системы отопления зданий, теплотрассы, водопроводы, системы водоотведения, гидравлические схемы станков, машин – все это примеры систем, состоящих из трубопроводов. Гидравлический расчет трубопроводов — особенно сложных, разветвленных…

… — является очень непростой и громоздкой задачей. Сегодня в век компьютеров решать ее стало существенно легче при использовании специального программного обеспечения. Но хорошие специальные программы дорого стоят и есть они, как правило, только у специалистов-гидравликов.

В этой статье мы рассмотрим гидравлический расчет трубопроводов на примере расчета в Excel горизонтального участка трубопровода постоянного диаметра по двум методикам и сравним полученные результаты. Для «неспециалистов» применение представленной ниже программы позволит решить несложные «житейские» и производственные задачи. Для специалистов применение этих расчетов возможно в качестве проверочных или для выполнения быстрых простых оценок.

Как правило, гидравлический расчет трубопроводов включает в себя решение двух задач:

1. При проектировочном расчете требуется по известному расходу жидкости найти потери давления на рассматриваемом участке трубопровода. (Потери давления – это разность давлений между точкой входа и точкой выхода.)

2. При проверочном расчете (при аудите действующих систем) требуется по известному перепаду давления (разность показаний манометров на входе в трубопровод и на выходе) рассчитать расход жидкости, проходящей через трубопровод.

Приступаем к решению первой задачи. Решить вторую задачу вы сможете легко сами, используя сервис программы MS Excel «Подбор параметра». О том, как использовать этот сервис, подробно описано во второй половине статьи «Трансцендентные уравнения? «Подбор параметра» в Excel!».

Предложенные далее расчеты в Excel, можно выполнить также в программе OOo Calc из свободно распространяемого пакета Open Office.

Правила цветового форматирования ячеек листа Excel, которые применены в статьях этого блога, детально описаны на странице «О блоге».

Рассмотрим порядок и формулы расчета в Excel на примере прямого горизонтального трубопровода длиной 100 метров из трубы ø108 мм с толщиной стенки 4 мм.

Исходные данные:

1. Расход воды через трубопровод G в т/час вводим

в ячейку D4: 45,000

2. Температуру воды на входе в расчетный участок трубопровода  t_вх в °C заносим

в ячейку D5: 95,0

3. Температуру воды на выходе из расчетного участка трубопровода  t_вых в °C записываем

в ячейку D6: 70,0

4. Внутренний диаметр трубопровода  d в мм вписываем

в ячейку D7: 100,0

5. Длину трубопровода  L в м записываем

в ячейку D8: 100,000

6. Эквивалентную шероховатость внутренних поверхностей труб  ∆ в мм вносим

в ячейку D9:  1,000

Выбранное значение эквивалентной шероховатости соответствует стальным старым заржавевшим трубам, находящимся в эксплуатации много лет.

Эквивалентные шероховатости для других типов и состояний труб приведены на листе «Справка» расчетного файла Excel «gidravlicheskiy-raschet-truboprovodov.xls», ссылка на скачивание которого дана в конце статьи.

7. Сумму коэффициентов местных сопротивлений  Σ(ξ) вписываем

в ячейку D10:  1,89

Мы рассматриваем пример, в котором местные сопротивления присутствуют в виде стыковых сварных швов (9 труб, 8 стыков).

Для ряда основных типов местных сопротивлений данные и формулы расчета представлены на листах «Расчет коэффициентов» и «Справка» файла Excel «gidravlicheskiy-raschet-truboprovodov.xls».

Результаты расчетов:

8. Среднюю температуру воды t_ср в °C вычисляем

в ячейке D12: =(D5+D6)/2 =82,5

t_ср=(t_вх+t_вых)/2

9. Кинематический коэффициент вязкости воды n в cм²/с при температуре t_ср рассчитываем

в ячейке D13: =0,0178/(1+0,0337*D12+0,000221*D12^2) =0,003368

n=0,0178/(1+0,0337*t_ср+0,000221*t_ср²)

10. Среднюю плотность воды ρ в т/м³ при температуре t_ср вычисляем

в ячейке D14: =(-0,003*D12^2-0,1511*D12+1003,1)/1000 =0,970

ρ=(-0,003*t_ср²-0,1511*t_ср+1003, 1)/1000

11. Расход воды через трубопровод G’ в л/мин пересчитываем

в ячейке D15: =D4/D14/60*1000 =773,024

G’=G*1000/(ρ*60)

Этот параметр пересчитан нами в других единицах измерения для облегчения восприятия величины расхода.

12. Скорость воды в трубопроводе v в м/с вычисляем

в ячейке D16: =4*D4/D14/ПИ()/(D7/1000)^2/3600 =1,640

v=4*G/(ρ*π*(d/1000)²*3600)

К ячейке D16 применено условное форматирование. Если значение скорости не попадает в диапазон 0,25…1,5 м/с, то фон ячейки становится красным, а шрифт белым.

Предельные скорости движения воды приведены на листе «Справка» расчетного файла Excel «gidravlicheskiy-raschet-truboprovodov.xls».

13. Число Рейнольдса Re определяем

в ячейке D17: =D16*D7/D13*10 =487001,4

Re=v*d*10/n

14. Коэффициент гидравлического трения λ рассчитываем

в ячейке D18: =ЕСЛИ(D17<=2320;64/D17;ЕСЛИ(D17<=4000; 0,0000147*D17;0,11* (68/D17+D9/D7)^0,25)) =0,035

λ=64/Re                              при Re≤2320

λ=0,0000147*Re                при 2320≤Re≤4000

λ=0,11*(68/Re+∆/d)^0,25  при Re≥4000

15. Удельные потери давления на трение R в кг/(см²*м) вычисляем

в ячейке D19: =D18*D16^2*D14/2/9,81/D7*100 =0,004645

R=λ*v²*ρ*100/(2*9,81*d)

16. Потери давления на трение dP_тр в кг/см² и Па находим соответственно

в ячейке D20: =D19*D8 =0,464485

dP_тр=R*L

и в ячейке D21: =D20*9,81*10000 =45565,9

dP_тр=dP_тр*9,81*10000

17. Потери давления в местных сопротивлениях dP_мс в кг/см² и Па находим соответственно

в ячейке D22: =D10*D16^2*D14*1000/2/9,81/10000 =0,025150

dP_мс=Σ(ξ)*v²*ρ/(2*9,81*10)

и в ячейке D23: =D22*9,81*10000 =2467,2

dP_тр=dP_мс*9,81*10000

18. Расчетные потери давления в трубопроводе dP в кг/см² и Па находим соответственно

в ячейке D24: =D20+D22 =0,489634

dP=dP_тр+dP_мс

и в ячейке D25: =D24*9,81*10000 =48033,1

dP=dP*9,81*10000

19. Характеристику гидравлического сопротивления трубопровода S в Па/(т/ч)² вычисляем

в ячейке D26: =D25/D4^2 =23,720

S=dP/G²

Гидравлический расчет в Excel трубопровода по формулам теоретической гидравлики выполнен!

Гидравлический расчет трубопроводов в Excel по формулам СНиП 2.04.02-84.

Этот расчет определяет потери на трение в трубопроводах по эмпирическим формулам без учета коэффициентов местных сопротивлений, но с учетом сопротивлений, вносимых стыками.

На длинных трубопроводах, каковыми являются водопроводы и теплотрассы, влияние местных сопротивлений мало по сравнению с шероховатостью стенок труб и перепадами высот, и часто коэффициентами местных сопротивлений можно пренебречь при оценочных расчетах.

Исходные данные:

Этот расчет использует ранее введенные в предыдущем расчете значения внутреннего диаметра трубопровода d и длины трубопровода L, а также рассчитанное значение скорости движения воды v.

1. Выбираем из выпадающего списка, расположенного над ячейками A30…E30 вид трубы:

Неновые стальные и неновые чугунные без внутр. защитного покр. или с битумным защитным покр., v > 1,2м/c

Результаты расчетов:

По выбранному виду трубы Excel автоматически извлекает из таблицы базы данных значения эмпирических коэффициентов. Таблица базы данных, взятая из СНиП 2.04.02–84, расположена на этом же рабочем листе «РАСЧЕТ».

2. Коэффициент m извлекается

в ячейку D32: =ИНДЕКС(H31:H42;H29) =0,300

3. Коэффициент A₀ извлекается

в ячейку D33: =ИНДЕКС(I31:I42;I29) =1,000

4. Коэффициент 1000A₁ извлекается

в ячейку D34: =ИНДЕКС(J31:J42;J29) =21,000

5. Коэффициент 1000A₁/(2g) извлекается

в ячейку D35: =ИНДЕКС(K31:K42;K29) =1,070

6. Коэффициент С извлекается

в ячейку D36: =ИНДЕКС(L31:L42;L29) =0,000

7. Коэффициент  гидравлического сопротивления i  в м.вод.ст./м рассчитываем

в ячейке D37: =D35/1000*((D33+D36/D16)^D32)/((D7/1000)^(D32+1))*D16^2 =0,057

i=((1000A1/(2g))/1000)*(((A0+C/v)^m)/((d/1000)^(m+1)))*v²

8. Расчетные потери давления в трубопроводе dP в кг/см² и Па находим соответственно

в ячейке D38: =D39/9,81/10000 =0,574497

dP=dP/9,81/10000

и в ячейке D39: =D37*9,81*1000*D8 =56358,1

dP=i*9,81*1000*L

Гидравлический расчет трубопровода по формулам Приложения 10 СНиП 2.04.02–84 в Excel завершен!

Итоги.

Полученные значения потерь давления в трубопроводе, рассчитанные по двум методикам отличаются в нашем примере на 15…17%! Рассмотрев другие примеры, вы можете увидеть, что отличие иногда достигает и 50%! При этом значения, полученные по формулам теоретической гидравлики всегда меньше, чем результаты по СНиП 2.04.02–84. Я склонен считать, что точнее первый расчет, а СНиП 2.04.02–84 «подстраховывается». Возможно, я ошибаюсь в выводах. Следует отметить, что гидравлические расчеты трубопроводов тяжело поддаются точному математическому моделированию и базируются в основном на зависимостях, полученных из опытов.

В любом случае, имея два результата, легче принять нужное правильное решение.

При гидравлическом расчете трубопроводов с перепадом высот входа и выхода не забывайте добавлять (или отнимать) к результатам статическое давление. Для воды – перепад высот в 10 метров ≈ 1 кг/см².

Уважаемые читатели, Ваши мысли, замечания и предложения всегда интересны коллегам и автору. Пишите их внизу, в комментариях к статье!

Ссылка на скачивание файла: gidravlicheskiy-raschet-truboprovodov (xls 57,5KB).

Важное и, думаю, интересное продолжение темы читайте здесь.

Другие статьи автора блога

На главную

Статьи с близкой тематикой

Отзывы

Друзья сайта

	Суббота, 15.04.2023, 09:44
Вы вошли как Гость | Группа «Гости«Приветствую Вас Гость | RSS
Проектирование систем газоснабжения           Персональный сайт Гусаренко Виктора Степановича
ГЛАВНАЯ | Ваш профиль| Регистрация | Выход | ВХОД