Get text in excel cell

Microsoft Excel is a great tool, but sometimes the spreadsheet files we get to work with aren’t ideal. One example is a file with a data column, maybe a street address, that you’d really like to pull apart. In this tutorial, I’ll show how to extract text from a cell in Excel using some powerful, but simple text functions. (Includes practice workbook.)

What’s an Excel Substring?

Before we have Excel extract text from string, we need to define some things. Some programming languages have dedicated substring functions. Excel does something similar using Text functions. They have their own category.

When we speak of a substring, we mean a part or subset of the Excel cell’s content. For example, if the cell contained 1001 Drake Ave., any of these items could be a substring:

• 1001
• Drake Ave.
• 100
• rake

A Common Problem

Many membership databases or mailing lists are set up with defined fields for First Name, Last Name, Street, City, State, and Zip. This format works fine if you’re creating a mailing label as the post office relies on zip code sorting. And sometimes you can luck out and parse first and last names using Excel’s Convert Text to Columns Wizard.

But what if you need to do door-to-door canvassing to check on neighbors or to inform people about an upcoming ballot measure?

If you open this type of list in Excel and sort it on the Street column, you get a numerically sorted list. As you can see in the example below, the Drake Ave records are not together.

Ideally, you want to sort the list so the Drake Ave. entries are together. There are several ways to do this in Excel, but one way is to create two columns from the Street column.

The first column reflects the street number substring, and the second the street name substring. You can then resort the list based on the street name and street number.

Visually Building the Nested Formula

For the first example, we’ll nest some Excel functions such as LEFT and FIND. As we progress, we’ll add several sets of parentheses. By nested, I mean we’ll use one function (FIND) as an argument for another function such as LEFT or RIGHT.

Let’s start with =FIND(" ",C2). In plain text, our function syntax is asking Excel to look in reference cell C2 for a blank space which is represented by the ” “. In the picture below, I added a starting position of “1“, but this is an optional parameter and Excel starts at 1 by default. Excel found the blank space in position 5 which shows in cell D2.

To make the formula easier, I’ll remove the optional starting parameter of 1 since Excel starts there anyway.

Now, let’s add the LEFT function so that our formula reads =LEFT(C2,(FIND(" ",C2))). In this instance, we’re again using cell C2, but the LEFT function is going to grab the cell contents in C2 from position 1 to position 5 where the Excel FIND function found the blank space.

However, there is a minor issue. While you can’t see it, there is a trailing space in D2. Using the LEN function we can see cell D2 has 5 characters. You may remember this handy function from our tutorial on how to check character count in Excel.

The solution is to subtract 1 or use the TRIM function which I referenced in how to separate names in Excel. For simplicity, I’ll use the -1. While the visual results are the same, you can see the character count dropped by 1.

1. Import your data into Microsoft Excel or use the sample spreadsheet in the Resources section.
2. In cell D1, type Nbr.
3. In cell E1, type Street Name
4. In cell D2, type the following Excel formula =LEFT(C2,(FIND(" ",C2)-1))
5. Press Enter. The value 1001 should show in D2.

The next part involves copying this formula to the rest of the entries. However, we need to reference the correct street cell and not use C2 for the remaining rows.

1. Click cell D2 to select the beginning of our range.
2. Move your mouse to the lower right corner.

1. Double-click the + cursor in the lower right. This will copy your formula down the column.

In column D, you should see the extracted street numbers.

We’ll now create a similar nested formula to capture the street address using the RIGHT function. This time, we will grab the contents to the right of the first space from the Street column.

1. In cell E2, type the following formula =RIGHT(C2,LEN(C2)-FIND(" ",C2))
2. Press Enter. E2 should show as Drake Ave.
3. Click cell E2 to select the beginning of our range.
4. Move your mouse to the lower right corner.
5. Double-click the + cursor in the lower right. This will copy your formula down the column.

Columns D and E should contain the parsed contents from your original street address.

Your spreadsheet should look similar to the one below.

Clean Up the Spreadsheet and Change Cell Format

The spreadsheet now has your split fields, but you should clean up the formulas. My suggestion would be to convert the LEFT and RIGHT formulas to their respective values. We did an earlier tutorial on how to copy formula values in Excel to values.

After you convert the Nbr column, you probably want to change the format type to a number.

1. Click column D.
2. Right-click and select Format cells...
3. On the Format Cells dialog box, select Number.
4. Set Decimal places to 0.
5. Click OK.

Although our example extracted text from an Excel cell containing street information, you can use the same process to parse other entries. For example, Step 1 above is really parsing everything but the first word because it is searching for a blank space. You can alter the formula to find different values, such as a comma or an @ sign.

Excel Practice File

Hand-picked Excel Tutorials

.

This tutorial will demonstrate how to extract text from a cell in Excel and Google Sheets.

Extract Text from Left

You can extract text from the left side of a cell in Excel by using the LEFT Function. Simply supply the text, and enter the number of characters to return.

However, this will only extract a fixed number of characters. You can see above some cook temperatures are correct extracted (ex. 300), but some are not (ex. 95F). To create a dynamic formula that will work in all scenarios are we can use the LEN Function, combined with the LEFT Function.

LEN Function – Count Characters in a Cell

Use the LEN Function to count the number of characters in the cell:

=LEN(C3)

LEFT Function – Show Characters from the Left

Then, create a new LEFT Function that extracts a number of characters determined by the LEN Function created above.

=LEFT(C3, E3-1)

Combining these functions looks like this:

=LEFT(C3,LEN(C3)-1)

RIGHT and LEN Functions

Similarly, we can also extract characters from the right of a cell by using the RIGHT Function to return a certain number of characters from the right.

=RIGHT(C3,LEN(C3)-n)

MID and SEARCH Functions

In the next section, we will use the SEARCH and MID functions to extract characters from the middle of a text string.

=MID(B3,SEARCH(" ",B3)+1,999)

SEARCH Function

First, we use the SEARCH Function to find the position of the space (” “) between the first and last names.

=SEARCH(" ", B3)

MID Function

Next, we use the MID Function to return all the characters after the space.

• We need to add 1 to the result of the previous formula so that we return the first character after the space.
• We use the large number 999 to return all characters.

=MID(B3, C3+1, 999)

Combining these 2 functions gives us the original formula for the last name.

=MID(B3, SEARCH(B3, " ")+1, 999)

Extract Text Before or After a Specific Character

You can also use the LEFT, RIGHT, LEN and SEARCH functions to extract the text before or after a specific character. In this case we will separate first and last names.

Extract Text Before Character

First, we can use the SEARCH Function to find the position of the comma in the text string.

=SEARCH(",", B3)

Next, we can use the LEFT function to extract the text before the position of the comma.

• We need to subtract 1 from the position of the comma so not to include the comma in our result.

=LEFT(B3, SEARCH(",",B3)-1)

Combining these 2 functions gives us the original formula for the last name.

Extract Text After Character

=RIGHT(B3,LEN(B3)-SEARCH(",",B3)-1)

In addition to using the SEARCH function once again, we also use the LEN function in conjunction with the RIGHT function to get extract text after a specific character.

The LEN Function is to get the length of the text in B3, while the SEARCH function is once again used to find the position of the comma.  We then use the RIGHT function to extract the characters after the comma in the text string.

Extract Text From Middle of Text String

Next, we will discuss how to extract text from the middle of a text string

To extract text from the middle of a text string, we can use the RIGHT, SEARCH and LEN functions to get the text from the right side of the string, and then use the MID and LEN functions to get the text in the middle. We will also incorporate the TRIM function to trim any spaces on either side of the text string.

=RIGHT(B3,LEN(B3)-SEARCH(" ",B3)-LEN(TRIM(MID(B3,SEARCH(" ",B3,1)+1,
SEARCH(" ",B3,SEARCH(" ",B3,1)+1)-SEARCH(" ",B3,1))))-1)

This formula will only work if there is more than one space in the text string. If there is only one space, an error with #VALUE would be returned.

To solve this problem, for names without middle names or initials, we can use the original formula using the MID and SEARCH Functions.

=MID(B3,SEARCH(" ",B3)+1,999))

We can create a single formula that uses both techniques to handle all situations with the IFERROR Function. (The IFERROR Function performs a calculation. If that calculation results in an error, then another calculation is performed.)

=IFERROR(RIGHT(B3,LEN(B3)-SEARCH(" ",B3)-LEN(TRIM(MID(B3,SEARCH(" ",B3,1)+1,
SEARCH(" ",B3,SEARCH(" ",B3,1)+1)-SEARCH(" ",B3,1))))-1),MID(B3,SEARCH(" ",B3)+1,999))

We can then use the MID and LEN functions to obtain the middle name or initial.

=MID(B3,LEN(C3)+1,LEN(B3)-LEN(C3&D3))

Extract Text From Cell in Google Sheets

All the examples above works the same way in Google Sheets.

Excel has a set of TEXT Functions that can do wonders. You can do all kinds of text slice and dice operations using these functions.

One of the common tasks for people working with text data is to extract a substring in Excel (i.e., get psrt of the text from a cell).

Unfortunately, there is no substring function in Excel that can do this easily. However, this could still be done using text formulas as well as some other in-built Excel features.

Let’s first have a look at some of the text functions we will be using in this tutorial.

Excel TEXT Functions

Excel has a range of text functions that would make it really easy to extract a substring from the original text in Excel. Here are the Excel Text functions that we will use in this tutorial:

• RIGHT function: Extracts the specified numbers of characters from the right of the text string.
• LEFT function: Extracts the specified numbers of characters from the left of the text string.
• MID function: Extracts the specified numbers of characters from the specified starting position in a text string.
• FIND function: Finds the starting position of the specified text in the text string.
• LEN function: Returns the number of characters in the text string.

Extract a Substring in Excel Using Functions

Suppose you have a dataset as shown below:

These are some random (but superhero-ish) email ids (except mine), and in the examples below, I’ll show you how to extract the username and domain name using the Text functions in Excel.

Example 1 – Extracting Usernames from Email Ids

While using Text functions, it is important to identify a pattern (if any). That makes it really easy to construct a formula. In the above case, the pattern is the @ sign between the username and the domain name, and we will use it as a reference to get the usernames.

Here is the formula to get the username:

=LEFT(A2,FIND("@",A2)-1)

The above formula uses the LEFT function to extract the username by identifying the position of the @ sign in the id. This is done using the FIND function, which returns the position of the @.

For example, in the case of brucewayne@batman.com, FIND(“@”,A2) would return 11, which is its position in the text string.

Now we use the LEFT function to extract 10 characters from the left of the string (one less than the value returned by the LEFT function).

Example 2 – Extracting the Domain Name from Email Ids

The same logic used in the above example can be used to get the domain name. A minor difference here is that we need to extract the characters from the right of the text string.

Here is the formula that will do this:

=RIGHT(A2,LEN(A2)-FIND("@",A2))

In the above formula, we use the same logic, but adjust it to make sure we are getting the correct string.

Let’s again take the example of brucewayne@batman.com. The FIND function returns the position of the @ sign, which is 11 in this case. Now, we need to extract all the characters after the @. So we identify the total length of the string and subtract the number of characters till the @. It gives us the number of characters that cover the domain name on the right.

Now we can simply use the RIGHT function to get the domain name.

Example 3 – Extracting the Domain Name from Email Ids (without .com)

To extract a substring from the middle of a text string, you need to identify the position of the marker right before and after the substring.

For example, in the example below, to get the domain name without the .com part, the marker would be @ (which is right before the domain name) and . (which is right after it).

Here is the formula that will extract the domain name only:

=MID(A2,FIND("@",A2)+1,FIND(".",A2)-FIND("@",A2)-1) 

Excel MID function extracts the specified number of characters from the specified starting position. In this example above, FIND(“@”,A2)+1 specifies the starting position (which is right after the @), and FIND(“.”,A2)-FIND(“@”,A2)-1 identifies the number of characters between the ‘@‘ and the ‘.‘

Update: One of the readers William19 mentioned that the above formula wouldn’t work in case there is a dot(.) in the email id (for example, bruce.wayne@batman.com). So here is the formula to deal with such cases:

=MID(A1,FIND("@",A1)+1,FIND(".",A1,FIND("@",A1))-FIND("@",A1)-1)

Using Text to Columns to Extract a Substring in Excel

Using functions to extract a substring in Excel has the advantage of being dynamic. If you change the original text, the formula would automatically update the results.

If this is something you may not need, then using the Text to Columns feature could be a quick and easy way to split the text into substrings based on specified markers.

Here is how to do this:

This will instantly give you two sets of substrings for each email id used in this example.

If you want to further split the text (for example, split batman.com to batman and com), repeat the same process with it.

Using FIND and REPLACE to Extract Text from a Cell in Excel

FIND and REPLACE can be a powerful technique when you are working with text in Excel. In the examples below, you’ll learn how to use FIND and REPLACE with wildcard characters to do amazing things in Excel.

See Also: Learn All about Wildcard Characters in Excel.

Let’s take the same Email ids examples.

Example 1 – Extracting Usernames from Email Ids

Here are the steps to extract usernames from Email Ids using the Find and Replace functionality:

This will instantly remove all the text before the @ in the email ids. You’ll have the result as shown below:

How this works?? – In the above example, we have used a combination of @ and *. An asterisk (*) is a wildcard character that represents any number of characters. Hence, @* would mean, a text string that starts with @ and can have any number of characters after it. For example in brucewayne@batman.com, @* would be @batman.com. When we replace @* with blank, it removes all the characters after @ (including @).

Example 2 – Extracting the Domain Name from Email Ids

Using the same logic, you can modify the ‘Find what’ criteria to get the domain name.

Here are the steps:

This will instantly remove all the text before the @ in the email ids. You’ll have the result as shown below:

You May Also Like the Following Excel Tutorials:

• How to Count Cells that Contain Text Strings.
• Extract Usernames from Email Ids in Excel [2 Methods].
• Excel Functions (Examples + Videos).
• Get More Out of Find and Replace in Excel.
• How to Capitalize First Letter of a Text String in Excel
• How to Extract the First Word from a Text String in Excel
• Separate Text and Numbers in Excel