Формула sumifs в excel на русском

На чтение 2 мин

Функция СУММЕСЛИМН (SUMIFS) в Excel используется для суммирования значений по нескольким критериям. Если вы хотите суммировать значения по одному критерию, то лучше использовать функцию SUMIF (СУММЕСЛИ).

Содержание

  1. Что возвращает функция
  2. Синтаксис
  3. Аргументы функции
  4. Дополнительная информация
  5. Примеры использования функции СУММЕСЛИМН в Excel

Что возвращает функция

Возвращает сумму чисел по нескольким критериям.

Telegram Logo Больше лайфхаков в нашем Telegram Подписаться

Синтаксис

=SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, critertia2],…) — английская версия

=СУММЕСЛИМН(диапазон_суммирования; диапазон_условия1; условие1; [диапазон_условия2; условие2]; …) — русская версия

Аргументы функции

  • sum_range (диапазон_суммирования)  — это диапазон данных, по которым будут вычисляться условия указанных вами критериев для суммирования данных;
  • criteria_range1 (диапазон_условия1), сriteria1 (условие1) — диапазон, в котором проверяется первое условие функции. Criteria_range1 (диапазон_условия1) и criteria1(условие1) составляют пару, определяющую, к какому диапазону применяется определенное условие при поиске. Соответствующие значения найденных в этом диапазоне ячеек суммируются в пределах аргумента sum_range (диапазон_суммирования).
  • [criteria_range2], criteria2 ([диапазон_условия2], условие 2) — (опционально) — второй диапазон критериев, по которым будут вычисляться данные;

Дополнительная информация

  • Суммирование значений в функции производится на основе нескольких критериев;
  • Пустые и текстовые ячейки игнорируются в аргументе sum_range (диапазон_суммирования);
  • Критерием могут служить числа, выражения, ссылка на ячейку, текст или формула;
  • Критерий, указанный в текстовом или логическом/математическом формате (=,+,-,/,*) должны быть указаны в двойных кавычках;
  • В качестве критерия могут использоваться подстановочные знаки (*);
  • Критерий не может быть больше чем 255 символов по длине;
  • Ячейки в аргументе sum_range (диапазон_суммирования) суммируются только при выполнении всех условий, заданных в формуле;
  • Если среди значений аргумента sum_range (диапазон_суммирования) указано логическое значение TRUE или FALSE, то они подразумевают значения «1» и «0» соответственно;
  • Диапазон аргументов sum_range (диапазон_суммирования) и всех критериев должны совпадать.

Примеры использования функции СУММЕСЛИМН в Excel

Функция SUMIFS (СУММЕСЛИМН) в Excel

Источник

What to Know

  • Enter input data > use «= SUMIFS (Sum_range,Criteria_range1,Criteria1, …)» syntax.
  • Starting function: Select desired cell > select Formulas tab > Math & Trig > SUMIFS.
  • Or: Select desired cell > select Insert Function > Math & Trig > SUMIFS to start function.

This article explains how to use the SUMIFS function in Excel 2019, 2016, 2013, 2010, Excel for Microsoft 365, Excel 2019 for Mac, Excel 2016 for Mac, Excel for Mac 2011, and Excel Online.

Entering the Tutorial Data

The first step to using the SUMIFS function in Excel is to input the data.

Enter the data into cells D1 to F11 of an Excel worksheet, as seen in the image above.

The SUMIFS function and the search criteria (less than 275 orders and sales agents from the East sales region) goes in row 12 below the data.

The tutorial instructions do not include formatting steps for the worksheet. While formatting will not interfere with completing the tutorial, your worksheet will look different than the example shown. The SUMIFS function will give you the same results.

The SUMIFS Function’s Syntax

In Excel, a function’s syntax refers to the layout of the function and includes the function’s name, brackets, and arguments.

The syntax for the SUMIFS function is: 

= SUMIFS (Sum_range,Criteria_range1,Criteria1,Criteria_range2,Criteria2, ...)

Up to 127 Criteria_range / Criteria pairs can be specified in the function.

Starting the SUMIFS Function

Although it is possible to just the SUMIFS function directly into a cell in a worksheet, many people find it easier to use the function’s dialog box to enter the function.

  1. Click cell F12 to make it the active cell; F12 is where you will enter the SUMIFS function.
  2. Click the Formulas tab.
  3. Click Math & Trig in the Function Library group.
  4. Click SUMIFS in the list to bring up the SUMIFS function’s dialog box.

Excel Online does not have the Formulas tab. To use SUMIFS in Excel Online, go to Insert > Function.

  1. Click cell F12 to make it the active cell so you can enter the SUMIFS function.
  2. Click the Insert Function button. The Insert Function dialog box opens.
  3. Click Math & Trig in the Categories list.
  4. Click SUMIFS in the list to start the function.

The data that we enter into the blank lines in the dialog box will form the arguments of the SUMIFS function.

These arguments tell the function what conditions we are testing for and what range of data to sum when it meets those conditions.

Entering the Sum_range Argument

The Sum_range argument contains the cell references to the data we want to add up.

In this tutorial, the data for the Sum_range argument goes in the Total Sales column.

Tutorial Steps

  1. Click the Sum_range line in the dialog box.
  2. Highlight cells F3 to F9 in the worksheet to add these cell references to the Sum_range line.

Entering the Criteria_range1 Argument

In this tutorial we are trying to match two criteria in each data record:

  1. Sales agents from the East sales region
  2. Sales agents who have made fewer than 275 sales this year

The Criteria_range1 argument indicates the range of cells the SUMIFS is to search when trying to match the first criteria: the East sales region.

Tutorial Steps

  1. Click the Criteria_range1 line in the dialog box.
  2. Highlight cells D3 to D9 in the worksheet to enter these cell references as the range to be searched by the function.

Entering the Criteria1 Argument

The first criteria we are looking to match is if data in the range D3:D9 equals East.

Although actual data, such as the word East, can be entered into the dialog box for this argument it is usually best to add the data to a cell in the worksheet and then input that cell reference into the dialog box.

Tutorial Steps

  1. Click the Criteria1 line in the dialog box.
  2. Click cell D12 to enter that cell reference. The function will search the range selected in the previous step for data that matches these criteria.

How Cell References Increase SUMIFS Versatility

If a cell reference, such as D12, is entered as the Criteria Argument, the SUMIFS function will look for matches to whatever data is in that cell in the worksheet.

So after finding the sales amount for the East region, it will be easy to locate the same data for another sales region simply by changing East to North or West in cell D12. The function will automatically update and display the new result.

Entering the Criteria_range2 Argument

The Criteria_range2 argument indicates the range of cells the SUMIFS is to search when trying to match the second criteria: sales agents who have sold fewer than 275 orders this year.

  1. Click the Criteria_range2 line in the dialog box.
  2. Highlight cells E3 to E9 in the worksheet to enter these cell references as the second range to be searched by the function.

Entering the Criteria2 Argument

The second standard we are looking to match is if data in the range E3:E9 is less than 275 sales orders.

As with the Criteria1 argument, we will enter the cell reference to Criteria2’s location into the dialog box rather than the data itself.

  1. Click the Criteria2 line in the dialog box.
  2. Click cell E12 to enter that cell reference. The function will search the range selected in the previous step for data that matches the criteria.
  3. Click OK to complete the SUMIFS function and close the dialog box.

An answer of zero (0) will appear in cell F12 (the cell where we entered the function) because we have not yet added the data to the Criteria1 and Criteria2 fields (C12 and D12). Until we do, there is nothing for the function to add up, and so the total stays at zero.

Adding the Search Criteria and Completing the Tutorial

The last step in the tutorial is to add data to the cells in the worksheet identified as containing the Criteria arguments.

For help with this example see the image above.

  1. In cell D12 type East and press the Enter key on the keyboard.
  2. In cell E12 type <275 and press the Enter key on the keyboard (the » < » is the symbol for less than in Excel).

The answer $119,719.00 should appear in cell F12.

Only two records, those in rows 3 and 4 match both criteria and, therefore, only the sales totals for those two records are summed by the function.

The sum of $49,017 and $70,702 is $119,719.

When you click on cell F12, the complete function =SUMIFS(F3:F9,D3:D9,D12,E3:E9,E12) appears in the formula bar above the worksheet.

How the SUMIFS Function Works

Usually, SUMIFS works with rows of data called records. In a record, all of the data in each cell or field in the row is related, such as a company’s name, address and phone number.

The SUMIFS argument looks for specific criteria in two or more fields in the record and only if it finds a match for each field specified is the data for that record summed up.

In the SUMIF step by step tutorial, we matched the single criterion of sales agents who had sold more than 250 orders in a year.

In this tutorial, we will set two conditions using SUMIFS: that of sales agents in the East sales region who had fewer than 275 sales in the past year.

Setting more than two conditions can be done by specifying additional Criteria_range and Criteria arguments for SUMIFS.

The SUMIFS Function’s Arguments

The function’s arguments tell it which conditions to test for and what range of data to sum when it meets those conditions.

All arguments in this function are required.

Sum_range — the data in this range of cells is summed when a match is found between all specified Criteria and their corresponding Criteria_range arguments.

Criteria_range — the group of cells the function is to search for a match to the corresponding Criteria argument.

Criteria — this value is compared with the data in the corresponding.

Criteria_range — actual data or the cell reference to the data for the argument.

Thanks for letting us know!

Get the Latest Tech News Delivered Every Day

Subscribe

Источник

Skip to content

Функция СУММЕСЛИМН — как суммировать ячейки в Excel, когда много условий?

В этом руководстве объясняется различие между функциями СУММЕСЛИ (SUMIF) и СУММЕСЛИМН (SUMIFS) с точки зрения их синтаксиса и использования, а также приводятся примеры формул для суммирования значений с несколькими критериями в Excel 2016, 2013, 2010, 2007, 2003 и ниже.

Как известно, Microsoft Excel предоставляет множество функций для выполнения различных расчетов с данными. Мы уже рассмотрели СУММЕСЛИ, которая суммирует числа, соответствующие указанным критериям. Теперь пришло время перейти к расширенной версии этой функции СУММЕСЛИМН, которая позволяет найти сумму по нескольким условиям.

Те, кто знаком с функцией СУММЕСЛИ, могут подумать, что преобразование ее в СУММЕСЛИМН потребует лишь букв «МН» и некоторого количества дополнительных критериев. Это может показаться вполне логичным… но «логично» — это не всегда имеет место при работе с Microsoft:)

Как работает СУММЕСЛИМН?

При помощи СУММЕСЛИМН можно найти сумму величин, для которых есть много условий. Она появилась впервые в MS Excel 2007, поэтому вы можете использовать ее во всех современных версиях программы.

По сравнению с СУММЕСЛИ, синтаксис СУММЕСЛИМН немного сложнее:

СУММЕСЛИМН(диапазон_суммирования, диапазон_условия1, условие1, [диапазон_условия2, условие2],…)

Первые 3 аргумента являются обязательными, а вот дополнительные диапазоны и связанные с ними условия являются необязательными.

диапазон_суммирования — требуется одна или более ячеек для суммирования. Это может быть отдельная клеточка, область или именованный диапазон. Суммируются только ячейки с чисами; пустые и текстовые значения игнорируются.

диапазон_условия1 — обязательный первый диапазон, который должен быть оценен по соответствующим критериям.

условие1— обязательное первое условие, которое должно быть выполнено. Вы можете предоставить его в виде числа, логического выражения, ссылки, текста или другой функции Excel. Например, вы можете использовать такие критерии, как 10, «> = 10», A1, «яблоко» или СЕГОДНЯ().

Все, что следует далее — это дополнительные диапазоны и связанные с ними критерии. Они не являются обязательными, но если у вас только одно ограничение, то зачем вам эта функция? Просто используйте СУММЕСЛИ. Тем не менее, вы можете использовать до 127 пар диапазон/условие.

Важно! Функция СУММЕСЛИМН работает с логикой «И». Это означает, что число в диапазоне суммирования учитывается, только если оно удовлетворяет всем указанным критериям (все требования соблюдаются для этой ячейки).

Использование СУММЕСЛИМН и СУММЕСЛИ в Excel — что нужно запомнить?

Поскольку целью этого руководства является охват всех возможных способов суммирования значений по большому количеству ограничений, мы обсудим примеры выражений с обеими функциями — СУММЕСЛИМН и СУММЕСЛИ с несколькими критериями. Чтобы использовать их правильно, вам необходимо четко понимать, что общего между этими двумя функциями и чем они отличаются.

Хотя общая часть ясна — схожий пункт назначения и параметры – но различия не так очевидны, хотя и достаточно существенны.

1. Порядок аргументов

Аргументы применяются по-разному. В частности, диапазон_сумирования является 1-м параметром в СУММЕСЛИ, но является третьим в СУММЕСЛИМН.

На первый взгляд может показаться, что Microsoft намеренно усложняет процесс обучения для своих пользователей. Однако при ближайшем рассмотрении вы увидите причины этого. Дело в том, что этот диапазон является необязательным в СУММЕСЛИ. Если вы его опустите, то нет никаких проблем, ваша формула будет складывать в диапазоне поиска (первый параметр).

В СУММЕСЛИМН он, напротив, очень важен и обязателен, и поэтому и стоит первым. Вероятно, ребята из Microsoft подумали, что после добавления 10- й или 100- й пары диапазон/критерий кто-то может забыть указать диапазон для суммирования:)

2. Диапазон суммирования и область критериев должны быть одинакового размера

В функции СУММЕСЛИ эти аргументы не обязательно должны иметь одинаковую размерность. Достаточно указать начальную точку. В СУММЕСЛИМН они должны содержать одинаковое количество строк и столбцов.

Выражение =СУММЕСЛИМН(E2:E21;C2:C21;I2;F2:F22;I3) вернет сообщение об ошибке #ЗНАЧ!, так как второй параметр поиска (F2:F22) не совпадает по размеру с остальными (E2:E21) и (C2:C21).

Хорошо, хватит стратегии (т.е. теории), давайте перейдем к тактике (к примерам).

Суммирование с множеством условий.

Имеются данные о заказах и продаже шоколада. Подсчитаем итог совершённых продаж по молочному шоколаду. То есть, у нас два требования: должно совпадать наименование товара и в колонке «Выполнен» должно быть указано «Да».

Первым аргументом мы указываем диапазон суммирования E2:E21, а затем попарно – диапазон условия и само условие для него.

=СУММЕСЛИМН(E2:E21;C2:C21;I2;F2:F21;I3)

В C2:C21 будем искать слово «молочный» с любым его вхождением. То есть, до и после него могут быть еще любые другие символы.

В F2:F21 ищем «Да», то есть отметку о том, что заказ выполнен.

Если ОБА эти требования выполняются, то такой заказ нам подходит, и его стоимость мы учтём.

Как видите, у нас найдено 2 совпадения, в которых был продан молочный шоколад.

Использование операторов сравнения.

Рассчитаем по покупателю «Красный» стоимость заказов, в которых было более 100 единиц товара. Как видим, здесь нужно использовать и текстовый, и числовой критерий.

суммирование много условий

Критерии можно записать в саму формулу, и выглядеть это будет так:

=СУММЕСЛИМН(E2:E21;B2:B21;”Красный”;D2:D21;”>100”)

Но более рационально использовать ссылки, как это и сделано на рисунке:

=СУММЕСЛИМН(E2:E21;B2:B21;I2;D2:D21;I4)

Примечание. Обратите внимание, что в формулах логические выражения с операторами сравнения всегда должны быть заключены в двойные кавычки («»).

Синтаксис, а также работа с числами, текстом и датами у этой функции точно такие же, как и СУММЕСЛИ. Поэтому рекомендую обратиться к нашему предыдущему материалу о условном суммировании.

А как еще можно решить нашу задачу?

Способ 2. Используем функцию СУММПРОИЗВ.

Разберем подробнее, как работает СУММПРОИЗВ():

=СУММПРОИЗВ(—(B2:B21=$I$12);—(D2:D21>I13);E2:E21)

Результатом вычисления B2:B21=$I$12 является массив

{ЛОЖЬ:ИСТИНА:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ИСТИНА:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ИСТИНА:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ}.

ИСТИНА означает соответствие кода покупателя условию, т.е. слову Красный. Массив этот можно увидеть, выделив в строке формул B2:B21=$I$12, а затем нажав F9.

А что за странные знаки «минус» перед этими выражениями? Дело в том, что нам необходимы не эти логические выражения, а числа, чтобы их затем можно было перемножать и складывать. Если Эксель производит математическую операцию с логическим выражением, то он автоматически преобразует его в число. А знак минус означает умножение на -1. А если дважды умножить на -1, то число в результате не изменится. Это мы помним еще из школьной математики 😊

И в результате логический массив превратится в массив чисел {0:1:0:0:0:0:0:0:0:0:0:0:1:0:0:0:1:0:0:0}.

Результатом вычисления D2:D21>I13 является массив

{ИСТИНА:ИСТИНА:ИСТИНА:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ИСТИНА:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ИСТИНА:ЛОЖЬ:ИСТИНА:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ}.

ИСТИНА соответствует ограничению «количество больше 100». Здесь мы также применяем двойное отрицание, чтобы преобразовать логические переменные в числа.

И, наконец, результатом вычисления В2:В13 является массив {11250:23210:12960:3150:5280:9750:3690:18300:5720:6150: 8400:2160:7200:1890:17050:3450:15840:2250:7200:8250}, т.е. просто числа из столбца E.

Результатом поэлементного умножения этих трех массивов является {0:23210:0:0:0:0:0:0:0:0:0:0:0:0:0:0:15840:0:0:0}. Суммируем эти произведения и получаем 39050.

Способ 3. Формула массива.

И еще один вариант расчета – применим формулу массива. В I14 запишем:

=СУММ((B2:B21=I12)*(D2:D21>I13)*(E2:E21))

Не забудьте в конце нажать комбинацию клавиш CTRL+SHIFT+ENTER, чтобы обозначить это выражение как формулу массива. Фигурные скобки в начале и в конце программа добавит автоматически. Вновь получим результат 39050.

Способ 4. Автофильтр.

Еще один альтернативный вариант – применение автофильтра. Для этого преобразуйте диапазон данных A1:F21 в «умную» таблицу. Напомню, что для этого в меню «Главная» выберите «Форматировать как таблицу». После этого добавьте в нее строку итогов (вкладка «Конструктор») и установите необходимые фильтры.

автофильтр и сумма в умной таблице

Без всяких формул итог по отфильтрованным строкам будет определён.

Как СУММЕСЛИМН работает с датами?

Если вы хотите отобрать и сложить какие-то показатели в определенном временном интервале на основе текущей даты, используйте функцию СЕГОДНЯ() в ваших ограничениях, как это показано ниже.

Следующая формула суммирует числа в столбце D, если соответствующая дата в столбце А попадает в последние 7 дней, включая сегодняшний день (предполагается, что сегодня 7 февраля):

=СУММЕСЛИМН(D2:D21;A2:A21;»<=»&СЕГОДНЯ();A2:A21;»>=»&СЕГОДНЯ()-6)

Замечание. Когда вы при составлении ограничения используете другую функцию Excel вместе с логическим оператором, нужно использовать амперсанд (&) для объединения всего выражения в виде текста, например «<=»&СЕГОДНЯ().

Аналогичным образом вы можете использовать функцию Excel СУММЕСЛИ для суммирования каких-то показателей в заданном диапазоне дат. Например, следующая формула также решит нашу задачу:

=СУММЕСЛИ(A2:A21;»>=»&СЕГОДНЯ()-6;D2:D21) — СУММЕСЛИ(A2:A21;»<=»&СЕГОДНЯ();D2:D21)

Однако СУММЕСЛИМН сложение делает гораздо проще и понятнее, не так ли?

Суммирование по пустым и непустым ячейкам.

При анализе отчетов и других данных вам часто может потребоваться суммировать данные, соответствующие пустым или непустым клеткам таблицы.

Критерии Описание Содержание
Пустые ячейки «=» Суммируйте числа, соответствующие пустым, которые не содержат абсолютно ничего — ни формулы, ни строки нулевой длины. =СУММЕСЛИМН(C2:C10;A2:A10;»=»;B2:B10,»=»)
Суммируйте в C2:C10, если соответствующие ячейки в столбцах A и B абсолютно пусты.
«» Суммируйте числа, соответствующие «визуально» пустым, включая те, которые содержат пустые строки, возвращаемые какой-либо другой функцией Excel (например, ячейки с формулой вроде = «»). =СУММЕСЛИМН(C2:C10;A2:A10;»»;B2:B10,»»)  
Суммируйте в C2:C10 с теми же параметрами, что и в приведенной выше формуле, но с пустыми строками.
Непустые ячейки «<>» Суммируйте числа, соответствующие непустым, включая строки нулевой длины. =СУММЕСЛИМН(C2:C10;A2:A10;»<>»;B2:B10,»<>») Суммируйте в C2: C10, если соответствующие ячейки в столбцах A и B не пусты, включая ячейки с пустыми строками.
Суммируйте числа, соответствующие непустым, не включая строки нулевой длины. =СУММ(C2:C10) — СУММЕСЛИМН(C2:C10;A2:A10;»»;B2:B10,»»)
или
{=СУММ((C2:C10)*(ДЛСТР(A2:A10)>0)*(ДЛСТР(B2: B10)>0))}
Если в столбцах A и B содержится текст ненулевой длины, тогда соответствующее число из C складывается. Внимание! Это формула массива! Фигурные скобки вводить не нужно!

А теперь давайте посмотрим, как вы можете использовать формулу СУММЕСЛИМН с «пустыми» и «непустыми» ячейками для реальных данных.

По покупателю «Красный» рассчитаем количество товара в невыполненных заказах. Для этого в столбце B ищем соответствующее название клиента, а в F – пустую ячейку. Если оба требования совпадают, складываем количество товара из столбца D.

=СУММЕСЛИМН(D2:D21;F2:F21;»»;B2:B21;»Красный»)

или

=СУММЕСЛИМН(D2:D21;F2:F21;»=»;B2:B21;»Красный»)

Каждое из этих выражений дает верный результат – 144 единицы в заказе от 4 февраля.

Сумма нескольких условий.

А теперь давайте рассчитаем общую стоимость выполненных заказов по двум товарам.

Если мы просто добавим второй критерий в I3, и вместо I2 используем область I2:I3, то расчет будет неверным, поскольку в C2:C21 будем искать товар, в названии которого есть И «черный», И «молочный» одновременно. Ведь таких просто нет.

Поэтому первый вариант расчета таков:

=СУММЕСЛИМН(E2:E21;C2:C21;I2;F2:F21;I4)+СУММЕСЛИМН(E2:E21;C2:C21;I3;F2:F21;I4)

Просто складываем выполненные заказы сначала по первому, а затем по второму наименованию.

Второй вариант: используем элемент массива критериев и функцию СУММ.

=СУММ(СУММЕСЛИМН(E2:E21;C2:C21;{«*молочный*»;»*черный*»};F2:F21;I4))

Как видите, результаты получены одинаковые. Выбирайте способ, который будет для вас проще и понятнее.

Ещё примеры расчета суммы:

Источник

Функция СУММЕСЛИМН была добавлена в 2007-й версии Excel в дополнение к функции СУММЕСЛИ и она суммирует ячейки в диапазоне, удовлетворяющие нескольким условиям.

Описание функции СУММЕСЛИМН

Суммирует ячейки в диапазоне, удовлетворяющие нескольким условиям. Например, если необходимо суммировать числа в диапазоне
A1:A20, которым соответствуют значения в диапазоне B1:B20 больше нуля (0) и значения в диапазоне C1:C20 меньше 10, можно использовать следующую формулу:

=СУММЕСЛИМН(A1:A20; B1:B20; ">0"; C1:C20; "<10")

Важно! Порядок аргументов в функциях СУММЕСЛИМН и СУММЕСЛИ различается. В СУММЕСЛИМН аргумент диапазон_суммирования является первым аргументом, а в СУММЕСЛИ — третьим. При копировании и изменении этих похожих функций необходимо следить за тем, чтобы аргументы были указаны в правильном порядке.

Синтаксис

=СУММЕСЛИМН(диапазон_суммирования; диапазон_условий1; условия1; [диапазон_условий2; условия2]; ...)

Аргументы

диапазон_суммированиядиапазон_условий1условия1диапазон_условий2; условия2 …

Обязательный аргумент. Одна или несколько ячеек для суммирования, включая числа или имена, диапазоны или ссылки на ячейки. Пустые ячейки и ячейки, содержащие текстовые значения, пропускаются.

Обязательный аргумент. Первый диапазон, в котором проверяется соответствующее условие.

Обязательный аргумент. Условия в виде числа, выражения, ссылки на ячейку или в виде текста, определяющие, какие ячейки в аргументе диапазон_критериев1 будут просуммированы. Например, условия могут быть представлены в следующем виде: 32, «>32», B4, «яблоки» или «32».

Необязательный аргумент. Дополнительные диапазоны и условия для них. Разрешается использовать до 127 пар диапазонов и условий.

Замечания

  • Каждая ячейка в аргументе диапазон_суммирования суммируется только в том случае, если выполнены все указанные условия, соответствующие этой ячейке. Например, формула содержит два аргумента диапазон_условий. Если первая ячейка аргумента диапазон_условий1 соответствует аргументу условия1, а первая ячейка аргумента диапазон_условий2 — аргументу условия2, первая ячейка аргумента диапазон_суммирования добавляется к сумме (и т. д. для всех остальных ячеек в указанных диапазонах).
  • Ячейки в аргументе диапазон_суммирования, которым присвоено значение ИСТИНА, оцениваются как 1; ячейки в аргументе диапазон_суммирования, которым присвоено значение ЛОЖЬ, оцениваются как 0 (нуль).
  • В отличие от аргументов диапазона и условий в функции СУММЕСЛИ, в функции СУММЕСЛИМН каждый аргумент диапазон_условий обязательно должен иметь то же количество строк и столбцов, что и аргумент диапазон_суммирования.
  • В условии можно использовать подстановочные знаки: вопросительный знак (?) и звездочку (*) . Вопросительный знак соответствует одному любому символу, а звездочка — любой последовательности знаков. Если требуется найти непосредственно вопросительный знак (или звездочку), необходимо поставить перед ним знак «тильда» (~).

Пример

Источник

На своём сайте я много внимания уделял Excel функциям извлечения данных (ИНДЕКС, ВПР, ПОИСКПОЗ, ГПР). Они, безусловно, очень важны, но есть ещё один краеугольный класс формул, без которых просто никуда. Это, конечно же, формулы подсчёта и суммирования.

Эта статья будет посвящена формулам СУММЕСЛИМН (SUMIFS), СЧЁТЕСЛИМН (COUNTIFS) и СРЗНАЧЕСЛИМН (AVERAGEIFS). Если вы раньше использовали формулы СУММЕСЛИ (SUMIF), СЧЁТЕСЛИ (COUNTIF) или СРЗНАЧЕСЛИ (AVERAGEIF), то, ознакомившись со статьёй, можете благополучно забыть об их существовании, так как функционально *ЕСЛИМН формулы кроют *ЕСЛИ формулы, как бык овцу.

Идея формулы

Прежде, чем погружаться в детали функционирования формулы, полезно понимать, что же она делает по самой своей сути. Смотрим на рисунок.

Мы располагаем таблицей, в которой необходимо просуммировать значения из столбца Количество, но с учётом двух критериев или фильтров, если угодно. Первый критерий — столбец Магазин должен содержать значение Центр, второй критерий — столбец Товар должен содержать значение Компьютер. Оба критерия действуют одновременно или, как говорят, по «И» (а не по «ИЛИ«). То есть нас интересует, сколько компьютеров продал центральный магазин.

Для этого в ячейку G7 мы помещаем формулу СУММЕСЛИМН, в которую передаём 5 параметров:

  • D3:D15 — диапазон, содержащий числа, которые мы собираемся суммировать

  • B3:B15 — диапазон, содержащий значения для сравнения с критерием 1

  • G3 — ячейка, содержащая, собственно, критерий 1 — значение, которое нас интересует — «Центр«

  • C3:C15 — диапазон, содержащий значения для сравнения с критерием 2

  • G5 — ячейка, содержащая критерий 2 — «Компьютер«

Формула вернёт нам значение 14, так как только 2 строки таблицы удовлетворяют обоим нашим критериям, и обе они содержат число 7. А теперь давайте дадим более формальное описание данной функции.

Синтаксис

Вот синтаксис формулы суммирования:

    =СУММЕСЛИМН( sum_range; criteria_range_1; criteria_1 [; criteria_range_2; criteria_2 [ … ] ] )

  • sum_range — первый параметр — всегда диапазон суммирования.

  • criteria_range_1 — диапазон для тестирования на соответствие критерию 1

  • criteria_1 — значение критерия 1. Значение может быть в виде:

    • ссылки на ячейку, например E3
    • выражения в виде текстовой строки, например «>10«
    • значения в виде числа или текста, например 45 или «Москва«

  • criteria_range_n и criteria_n — таких критериев, которые описываются всегда двумя параметрами, может быть до 127 штук. Принцип их организации остаётся неизменным.

Некоторые важные замечания

  • Количество параметров будет всегда нечётным, так как есть диапазон суммирования, а критерии идут парами. Это будет выглядеть как 3, 5, 7, 9 и т.д. параметров. Что будет соответствовать 1, 2, 3, 4 и т.д. критериев отбора строк для суммирования.

  • Диапазоны суммирования и диапазоны критериев должны всегда иметь одинаковый размер и одинаковую ориентацию (вертикальную или горизонтальную)

  • Диапазоны суммирования и диапазоны критериев могут не быть векторами (то есть располагаться более чем в одной строке или одном столбце), но опять же они должны соответствовать друг другу. То есть если диапазон суммирования имеет размер 10 на 3, то и все критериальные диапазоны должны быть строго 10 на 3. В целом, я не рекомендую подобную архитектуру ваших таблиц. Вы сэкономите себе массу сил, если критерии будут располагаться в отдельных столбцах. 1 столбец — 1 критерий.

СРЗНАЧЕСЛИМН и СЧЁТЕСЛИМН

Не откладывая в долгий ящик, сразу посмотрим на синтаксис формул СРЗНАЧЕСЛИМН и СЧЁТЕСЛИМН. У СРЗНАЧЕСЛИМН отличие только в том, что она не суммирует числа, а вычисляет по ним среднюю величину.

    =СРЗНАЧЕСЛИМН( avg_range; criteria_range_1; criteria_1 [; criteria_range_2; criteria_2 [ … ] ] )

А СЧЁТЕСЛИМН считает строки, а не числа, поэтому она не имеет аналога параметров sum_range или avg_range. Таким образом её параметры описывают только критерии и количество параметров всегда должно быть чётным, в отличие от её коллег.

    =СЧЁТЕСЛИМН( criteria_range_1; criteria_1 [; criteria_range_2; criteria_2 [ … ] ] )

Файл примера

Скачать

Критерии

Теперь, когда мы получили некоторое представление по механизму работы СУММЕСЛИМН, мы можем погрузиться в более сложные примеры, раскрывающие мощь и полезность этой формулы. В качестве полигона будем использовать вот такую умную таблицу с именем Sales:

СУММЕСЛИМН и умные таблицы

Посмотрите на пример 1 нашего учебного файла, формула в L6. Обратите внимание, как удобно использовать структурные ссылки умных таблиц в формулах вообще и в СУММЕСЛИМН в частности.


L4 и L5 содержат значения критериев.

Критерий для периода дат

А вот как задать период дат (с… по …) при суммировании:


Обратите внимание на очень важную конструкцию:

    «>=» & $O$5

Это не что иное, как выражение в виде текстовой строки. Причём это не статическое выражение, которое обычно приводят в справке по СУММЕСЛИМН, типа «>= 200000«. Это выражение динамическое, то есть — гораздо более ценное и интересное. Всё что вам нужно — это вставить между знаком операции «>=» и ссылкой на ячейку с параметром — знак операции сложения строк «&«.

Динамическая операция сравнения

А почему бы не дать на откуп пользователю право определять операцию для критерия? В предыдущем примере пользователь мог выбирать порог N в критерии «>=N«. А в этом примере пользователь определяет и порог и саму операцию! А почему нет?


В L12 у нас находится выпадающий список, ссылающийся на 4 возможные операции: >, >=, <, <=.

Символы подстановки

При формировании критериев можно использовать символы подстановки: «?» — заменяет любой символ, «*» — заменяет любое количество символов (в том числе и его отсутствие). Например критерий «*т*» сработает и на слово «Центр», и на слово «Восток». А, если бы существовала такая альтернатива, то сработал бы и на слово «опт» (это, как раз случай, когда вторая звёздочка в «*т*» заменила ноль символов справа от «т»).


Ответы на сложные вопросы

При помщи *ЕСЛИМН формул можно отвечать на довольно заковыристые вопросы. Например, какая доля холодильников в Центре была продана по ценам, превышающим средние цены холодильников по всем магазинам? А вот формула, которое это расчитывает:


Как видите мы использовали 2 формулы СУММЕСЛИМН и 1 СРЗНАЧЕСЛИМН. СРЗНАЧЕСЛИМН вернула нам средние цены по холодильникам. Первая СУММЕСЛИМН вернула количество проданных телевизоров с ценами выше средних, а вторая формула вернула общее количество холодильников, проданных в Центре. Найдя частное между результатами двух СУММЕСЛИМН, мы получили долю от единицы и просто выразили её в процентах.

Набор магазинов

А что делать, если нам нужны продажи двух магазинов? В рамках одной формулы это решить в общем случае нельзя (метод через символы подстановки не универсален, так как магазины могут иметь полностью уникальные имена). Ответ очевиден — надо использовать 2 формулы и просто сложить их результаты. Хотя понятно, что такой метод подойдёт далеко не во всех ситуациях.


Но есть и ограничения…

Надеюсь вы убедились, что *ЕСЛИМН достаточно гибки, но есть один узкий момент, который надо хорошо понимать. Например, я хочу знать, сколько раз я торговал в Центре, предоставляя покупателям скидку более или равную 5%? Как я могу это узнать? Только вычисляя по каждой строке отношение предоставленной скидки к базовой цене. Понимаете — по каждой строке надо делать вычисление и сравнивать с 5%! Вот такое формулы *ЕСЛИМН сами, без вашей помощи сделать не смогут, так как формула один раз вычисляет критерий, а потом сравнивает его со всеми строками критериального диапазона, а нам надо это делать динамически. Но никто нам не мешает организовать дополнительный столбец, который будет предварительно считать отношение скидки к базовой цене, а после этого можно уже остальную работу поручить формуле СЧЁТЕСЛИМН (см. пример 7).


Пустые ячейки

Если вы хотите, чтобы формула *ЕСЛИМН отреагировала на пустые ячейки, то следует использовать критерии «» (пустая строка) или «=». Например, посмотрите лист Blank нашего учебного файла:

    =СУММЕСЛИМН( E3:E10; B3:B10; «=» )

однако, если пустота ячейки является следствием работы формулы (например, формулы ЕСЛИ), то такая ячейка отреагирует только на критерий «», то есть:

    =СУММЕСЛИМН( E3:E10; B3:B10; «» )

Не пустые ячейки

А вот, если критерием является то, что ячейка хоть что-то содержит, то можно использовать такую форму:

    =СУММЕСЛИМН( E3:E10; B3:B10; «<>» )

Ну что ж, я надеюсь, что вы почувствовали всю силу, сосредоточенную в формулах этого семейства. Удачи!

Читайте также:

  • Умные таблицы

  • Функция ВПР (VLOOKUP) или тайна четвёртого параметра

  • Наиважнейшая формула Excel

  • Список всех формул Excel и классификация их востребованности

Источник

Понравилась статья? Поделить с друзьями:
  • Формула join в excel
  • Формула sumif в excel для чайников
  • Формула excel формула с постоянной ячейкой
  • Формула isnumber в excel на русском
  • Формула subtotal в excel на русском