Формула массива в excel суммесли в excel

Выборочные вычисления по одному или нескольким критериям

Постановка задачи

Имеем таблицу по продажам, например, следующего вида:

Задача: просуммировать все заказы, которые менеджер Григорьев реализовал для магазина «Копейка».

Способ 1. Функция СУММЕСЛИ, когда одно условие

Если бы в нашей задаче было только одно условие (все заказы Петрова или все заказы в «Копейку», например), то задача решалась бы достаточно легко при помощи встроенной функции Excel СУММЕСЛИ (SUMIF) из категории Математические (Math&Trig). Выделяем пустую ячейку для результата, жмем кнопку fx в строке формул, находим функцию СУММЕСЛИ в списке:

Жмем ОК и вводим ее аргументы:

• Диапазон — это те ячейки, которые мы проверяем на выполнение Критерия. В нашем случае — это диапазон с фамилиями менеджеров продаж.
• Критерий — это то, что мы ищем в предыдущем указанном диапазоне. Разрешается использовать символы * (звездочка) и  ? (вопросительный знак) как маски или символы подстановки. Звездочка подменяет собой любое количество любых символов, вопросительный знак — один любой символ. Так, например, чтобы найти все продажи у менеджеров с фамилией из пяти букв, можно использовать критерий ?????. А чтобы найти все продажи менеджеров, у которых фамилия начинается на букву «П», а заканчивается на «В» — критерий П*В. Строчные и прописные буквы не различаются.
• Диапазон_суммирования — это те ячейки, значения которых мы хотим сложить, т.е. нашем случае — стоимости заказов.

Способ 2. Функция СУММЕСЛИМН, когда условий много

Если условий больше одного (например, нужно найти сумму всех заказов Григорьева для «Копейки»), то функция СУММЕСЛИ (SUMIF) не поможет, т.к. не умеет проверять больше одного критерия. Поэтому начиная с версии Excel 2007 в набор функций была добавлена функция СУММЕСЛИМН (SUMIFS) — в ней количество условий проверки увеличено аж до 127! Функция находится в той же категории Математические и работает похожим образом, но имеет больше аргументов:

При помощи полосы прокрутки в правой части окна можно задать и третью пару (Диапазон_условия3—Условие3), и четвертую, и т.д. — при необходимости.

Если же у вас пока еще старая версия Excel 2003, но задачу с несколькими условиями решить нужно, то придется извращаться — см. следующие способы.

Способ 3. Столбец-индикатор

Добавим к нашей таблице еще один столбец, который будет служить своеобразным индикатором: если заказ был в «Копейку» и от Григорьева, то в ячейке этого столбца будет значение 1, иначе — 0. Формула, которую надо ввести в этот столбец очень простая:

=(A2=»Копейка»)*(B2=»Григорьев»)

Логические равенства в скобках дают значения ИСТИНА или ЛОЖЬ, что для Excel равносильно 1 и 0. Таким образом, поскольку мы перемножаем эти выражения, единица в конечном счете получится только если оба условия выполняются. Теперь стоимости продаж осталось умножить на значения получившегося столбца и просуммировать отобранное в зеленой ячейке:

Способ 4. Волшебная формула массива

Если вы раньше не сталкивались с такой замечательной возможностью Excel как формулы массива, то советую почитать предварительно про них много хорошего здесь. Ну, а в нашем случае задача решается одной формулой:

=СУММ((A2:A26=»Копейка»)*(B2:B26=»Григорьев»)*D2:D26)

После ввода этой формулы необходимо нажать не Enter, как обычно, а Ctrl + Shift + Enter — тогда Excel воспримет ее как формулу массива и сам добавит фигурные скобки. Вводить скобки с клавиатуры не надо. Легко сообразить, что этот способ (как и предыдущий) легко масштабируется на три, четыре и т.д. условий без каких-либо ограничений.

Способ 4. Функция баз данных БДСУММ

В категории Базы данных (Database) можно найти функцию БДСУММ (DSUM), которая тоже способна решить нашу задачу. Нюанс состоит в том, что для работы этой функции необходимо создать на листе специальный диапазон критериев — ячейки, содержащие условия отбора — и указать затем этот диапазон функции как аргумент:

=БДСУММ(A1:D26;D1;F1:G2)

Материалы

Работа с ненормализированными данными

В приложении к статье файл с простой задачей суммирования диапазона по различным условиям.

Как ни странно, подобные задачи вызывают серьезные трудности даже у опытных пользователей Excel, работающих с большими объемами данных. Попробуйте решить самостоятельно (лист ЗАДАЧА) – вычислите значения в желтых ячейках, формулы должны копироваться. Подразумевается также, что даты в исходной таблице и в условиях могут быть любыми.

Если сходу не получилось, то давайте разбираться. Некоторые пользователи указывают на «неправильность» расположения данных в таблице. Действительно, в примере данные не нормализированы – т.е. не в приведены единую таблицу со списками полей, где даты также бы располагались в столбцах, а не в заголовках, как в примере. Но на самом деле это типичный вид рабочей таблицы Excel. Обсуждать неправильность структуры данных в данной статье не будем, хотя, это, пожалуй, главная причина проблем с анализом информации. Но и говорить о том, что задача не имеет решения в Excel нельзя.

СУММЕСЛИ, СУММЕСЛИМН

Итак, рассмотрим первый вариант решения задачи, тот, на котором спотыкается большинство пользователей – лист ОШИБКИ.

Первое, что приходит в голову подавляющему большинству – это использовать формулу SUMIF для первой задачи и SUMIFS для остальных:

=SUMIF($B$3:$B$9;$A12;$C$3:$I$9)
=SUMIFS($C$3:$I$9;$B$3:$B$9;$A18;$C$2:$I$2;$B$17)
=SUMIFS($C$3:$I$9;$B$3:$B$9;$A25;$C$2:$I$2;">="&$B$23;$C$2:$I$2;"<="&$B$24) 

Диапазоны и типы ссылок указаны верно. Специальные выражения с амперсандом («&») используется для неточных сравнений. При этом первая формула выдает неправильный результат, остальные возвращают ошибку #VALUE. Предлагаю, разобраться для начала, почему так происходит.

Что делать с неверным результатом SUMIF? Некоторые пользователи готовы сходу обвинить функцию в неверной работе (и взять в руки калькулятор). Но функция работает именно так как и должна – просматривает массив (диапазон) условий и при выполнении условия суммирует соответствующее число из массива значений. Если количество значений (ячеек) в массиве условий меньше, чем в массиве значений, то функция не проверяет и не суммирует оставшиеся числа. Так и происходит в примере: в диапазоне условий 7 значений, в диапазоне чисел -7*7 = 49. Т.е. функция работает корректно и выдает в качестве результата сумму только по первой дате, остальные даты просто не просматриваются. Кстати, в качестве последнего параметра SUMIF можно указать не диапазон, а ссылку на одну ячейку (верхний левый угол) – результат будет тот же.

SUMIF($B$3:$B$9;$A12;$C$3)

Функция СУММЕСЛИМН не работает, так как она более требовательна к размерам диапазонов – просто выдает ошибку, если количество ячеек в массивах значений и условий не совпадает. Причем важно не только количество ячеек, но и их расположение – по строкам или столбцам.

Можно сделать вывод, что простое использование SUMIFи SUMIFSв данном случае не подходит.

Дополнительные вычисления

В условиях задачи нет запрета на использование дополнительных диапазонов для служебных вычислений. Главное, чтобы результат попал в желтые ячейки и формулы были бы копируемыми. Воспользовавшись этой подсказкой большинство опытных пользователей без труда решают задачу с использованием дополнительных столбцов – лист ДОП.ВЫЧ.

Предварительно вычисляются суммы по периодическим условиям, затем этот результат еще раз обрабатывается через суммирование по округам. Т.е. применяется последовательно 2 функции суммирования с разными условиями, но с одинаковыми размерами диапазонов.

Это очевидный и, в принципе, верный подход к решению подобных задач. Использование дополнительных вычислений – это один из главных методов обработки сложных информационных структур.

СУММПРОИЗВ

Но можно ли обойтись без служебных столбцов? Во-первых, просто ради интереса. Во-вторых, бывают случаи, особенно в сложных экономических моделях, когда наличие дополнительных вычислений не приветствуется. Это может быть связано с алгоритмами вставки новых строк, столбцов и т.п.

Самым простым способом является не совсем стандартное использование функции SUMPRODUCT. Функция, предназначенная для суммы произведений чисел, может использоваться также для работы с условиями (см. лист СУММПРОИЗВ):

Формулы выдают правильный результат:

=SUMPRODUCT(($B$3:$B$9=$A12)*$C$3:$I$9)
=SUMPRODUCT(($B$3:$B$9=$A18)*($C$2:$I$2=$B$17)*$C$3:$I$9)
=SUMPRODUCT(($B$3:$B$9=$A25)*($C$2:$I$2>=$B$23)*($C$2:$I$2<=$B$24)*$C$3:$I$9)

В качестве аргумента функции используется произведение векторов на массив, при этом в векторах записаны логически выражения, при выполнении возвращающие 1 (ИСТИНА) или 0 (ЛОЖЬ). Т.е. каждый элемент результирующего массива умножается на 0 или на 1 в зависимости от соответствующего условия вектора. Функция SUMPRODUCT в данном случае работает с массивами данных (см.далее), но в отличие от простых функций агрегирования (SUM, MIN, MAX) не требует ввода через Ctrl+Shift+Enter.

Можно сказать, что как раз этот метод работы функции SUMPRODUCT, гораздо полезнее на практике, чем вычисление суммы произведений.

Формулы обработки массивов

Если вам удалось понять принцип работы СУММПРОИЗВ, то альтернативный метод решения задачи с применением функций обработки массивов не должен вызвать больших проблем, даже, если вы никогда не сталкивались с подобной записью (см. лист МАССИВЫ).

Формулы также выдают правильный результат, но в записи видны фигурные скобки – такие формулы вводятся через нажатие Ctrl+Shift+Enter:

{=SUM(IF($B$3:$B$9=$A12;$C$3:$I$9))}
{=SUM(IF($B$3:$B$9=$A18;ЕСЛИ($C$2:$I$2=$B$17;$C$3:$I$9)))}
{=SUM(IF($B$3:$B$9=$A25;ЕСЛИ($C$2:$I$2>=$B$23;ЕСЛИ($C$2:$I$2<=$B$24;$C$3:$I$9))))}

Принцип работы функций обработки массивов кратко можно изложить следующим образом

• Последовательно просматриваются ячейки в диапазоне строк и столбцов, при этом выбираются соответствующие им значения в прямоугольных диапазонах.
• Каждый шаг образует формулу, которая вычисляется отдельно.
• В конце результат каждого вычисления агрегируется в одно значение (чаще всего используется функция SUM).

По-моему, запись формулы с обработкой массивов, в которой явно заданы условия (функция ЕСЛИ), более наглядна, чем использование скрытых условий в SUMPRODUCT. Хотя принцип работы тот же. Сказать однозначно, что будет работать быстрее на больших объемах данных нельзя – все зависит от расположения значений в массиве данных. Главное для массивов – не забывать про Ctrl+Shift+Enter, просто вписанные вручную фигурные скобки, как пытаются делать некоторые, просто сделают из формулы текстовую строку.

Вычисляемая адресация

Использование функций вычисляемой адресации диапазонов – это одно из мощнейших средств оптимизации работы с ненормализированными структурами данных. Вычисляемая адресация позволяет создать копируемую формулу при обработке многострочных блоков информации, сборе данные из столбцов в строки и наоборот, поиске информацию в диапазонах с заранее неизвестной размерностью. Принцип копируемости формулы в свою очередь существенно сокращает время на обработку информации, снижая при этом риск ошибки.

Пример использования формул с функциями вычисляемой адресацией представлен на листе ВЫЧ.АДРЕС.

В чистом виде использование вычисляемой адресации позволило решить только вторую часть задачи – собрать данные на определенную дату:

=SUMIF($B$3:$B$9;$A18;OFFSET($B$2;1;MATCH($B$17;$C$2:$I$2;0);ROWS($B$3:$B$9);1))

Смысл формулы в том, что столбец для суммирования вычисляется через поиск соответствующего заголовка.

Аналогичная логика заложена и в третьей части задачи:

{=SUM(SUMIF($B$3:$B$9;$A25;OFFSET($B$2;1;IF($C$2:$I$2>=$B$23;IF($C$2:$I$2<=$B$24;COLUMN($C$2:$I$2)-COLUMN($B$2)));ROWS($B$3:$B$9);1)))}

Функция СУММЕСЛИ собирает данные по строкам, а номера столбцов вычисляются сложным образом через вложенные условия IF. Выбранные данные суммируются. Формула требует ввод через Ctrl+Shift+Enter, так как в ней использован метод агрегации (SUM) нескольких найденных значений.

Вариант решения первой части задачи – простого итога по округам – совсем не стандартный:

=SUM(SUMIF($B$3:$B$9;$A12;OFFSET($B$2;1;{1:2:3:4:5:6:7};ROWS($B$3:$B$9);1)))

В формуле использован массив констант {1:2:3:4:5:6:7}, обеспечивающий просмотр семи столбцов. По большому счету это та же обработка массива без сложного поиска, как во второй части задачи – последовательно обрабатываются столбцы, затем происходит общее суммирование. Так как массив состоит из констант, то формула не требует обязательного ввода через Ctrl+Shift+Enter.

Не стоит злоупотреблять вычисляемой адресацией диапазонов там, где это не требуется. На больших объемах данных этот метод будет работать медленнее всех, описанных выше.

Помогла ли Вам статья?

СУММЕСЛИ – это математическая функция, которая суммирует числовые значения в указанном диапазоне данных, сопоставляя их с заданным условием.

Практическая работа функции СУММЕСЛИ в Excel

Как работает математическая и в то же время логическая функция СУММЕСЛИ? Ее синтаксис выглядит следующим образом:

Третий аргумент «Диапазон_суммирования» является необязательным. Если он не будет указан, формула сосчитает ячейки, указанные в первом аргументе. Теперь на примере рассмотрим принцип работы СУММЕСЛИ. У нас есть таблица с типами продукции разных компаний и их выручка. Первой задачей будет посчитать выручку компании Sanofi. Для этого нам нужно в качестве первого аргумента указать диапазон А3:А11, вторым аргументом указать условие – компанию «Sanofi». Можно прописать текстовое значение в формуле, а можно указать ссылку на ячейку с прописанным условием. Затем применить третий аргумент, поскольку числовые значения находятся в столбце «Выручка» — диапазон «С3:С11»:

В результате формула суммировала те числовые значения, которые соответствуют компании Sanofi. Следующим заданием будет узнать сумму выручки всех компаний, кроме Sanofi. В этом нам поможет оператор «не равно». Для реализации такого запроса нужно к аргументу 2 применить оператор «<>», амперсанд “&”, (для объединения) и ссылку на ячейку с условием для исключения:

Если использовать текстовое значение, амперсанд не нужен, тогда необходимо и оператор, и текст взять в кавычки:

Использование подстановочных знаков в формуле СУММЕСЛИ

СУММЕСЛИ так же можно использовать с подстановочными знаками, такими как звездочка и знак вопроса. Например, компании у нас разделены по направлению продаж – «Europe» и «Asia». Нам нужно просуммировать выручку из продаж в Европе (Europe). Для этого в аргументе «Условие» указываем нужный нам текст, с обеих сторон расставляем звездочки (подстановочный знак), затем оборачиваем в кавычки, иначе формула не сработает:

СУММЕСЛИ просуммировала только ту выручку, которую получили компании в Европе, при этом в расчет брались все компании. То есть мы указали, что нам неважно, какой текст находится еще в ячейке (в начале, середине или конце), главное, чтобы было совпадение по слову «Europe». Если необходимо ссылаться на ячейку, а не использовать текстовое значение, тогда формула будет выглядеть следующим образом:

С обеих сторон прописываем амперсанды, соединяя ячейку с подстановочными знаками. Если нужно сосчитать выручку тех компаний, в которых слово «Europe», находится в конце, или в начале, нужно изменить положение подстановочного знака на соответствующее:

Первая формула будет работать с теми компаниями, названия которых начинаются на слово «Europe» (желтый цвет). Вторая формула будет работать с теми компаниями, названия которых кончаются на слово «Europe» (синий цвет). Можно также, используя подстановочный знак «?» указать условие «слово из 6 букв». В формуле количество знаков вопроса равно количеству символов в слове:

СУММЕСЛИ прошлась по столбцу А, нашла те компании, которые соответствуют условию «??????», то есть 6 букв в тексте.

Функция СУММЕСЛИ с несколькими условиями

Следующим заданием у нас будет найти выручку от реализации мазей и порошковых препаратов. Теперь у нас сразу несколько условий. Усвоив предыдущие уроки, мы можем выполнить это задание, используя отдельно две формулы, затем сложить их между собой:

Для того чтобы формула подтянула не только мази, но и мази в тюбиках, мы использовали подстановочный символ. То же самое сделали и с порошками. Затем сложили две формулы и получили желаемый результат. Однако, этот самый простой способ работает, когда критериев немного. Ведь если критерии будут добавляться, постоянно строить новые формулы – очень долго. В этом случае нам поможет массив критериев. В качестве второго аргумента мы сразу укажем «мази*» и «порошок*» с использованием фигурных скобок. Затем построенную формулу нам нужно вложить в функцию СУММ, чтобы она посчитала содержимое нашего массива данных:

Практическое использование формулы СУММЕСЛИ и СУММПРОИЗВ

В следующем примере отведем для критериев отдельную таблицу. Например, мы хотим производить поиск по типу «Таблетки» и «Порошок»:

Здесь мы можем воспользоваться дополнительно функцией СУММПРОИЗВ, которая умножит элементы в указанных массивах и возвратит сумму этих произведений. В качестве второго аргумента для функции СУММЕСЛИ указываем диапазон критериев Е121:Е122. Затем вкладываем всю формулу в функцию СУММПРОИЗВ:

Благодаря дополнительной таблице наша формула динамическая, можем, например, изменить второй критерий на «Мази в тюбиках» и формула пересчитает наш результат:

Пример формулы СУММЕСЛИ и ВПР

В следующем примере используем функцию СУММЕСЛИ в комбинации с функцией ВПР. Допустим, у нас есть две таблицы: первая содержит информацию о названии товара и соответствующего кода, вторая содержит информацию о выручке по коду товара:

Нам необходимо найти объем выручки по конкретному товару. В этом примере у нас сложность в том, что вторая таблица содержит сразу несколько позиций выручки по одному коду и добавить столбец с именами ко второй табличке не является возможным. Пусть результатом нашей работы будет объем выручки по товару «Порошок». Определим первый аргумент для функции СУММЕСЛИ. Поскольку мы ищем по коду товара, указываем диапазон из второй таблицы «D130:D142». Вторым аргументом у нас будет функция ВПР, которая задаст условие. И третьим аргументом будет диапазон, по котором происходит суммирование – Е130:Е142:

Теперь разберем формулу ВПР. Ее синтаксис выглядит следующим образом: (искомое значение; диапазон поиска; номер столбца в диапазоне с возвращаемым значением; возврат приблизительного или точного совпадения). Первым аргументом будет ячейка Е147, в которой содержится значение продукта. Вторым аргументом будет первая таблица А130:В137. Третьим аргументом будет номер столбца, по которому будет возвращаться значение. Также укажем четвертый аргумент «ЛОЖЬ» для точного совпадения:

Теперь складываем наши формулы в одну и получаем сумму выручки по продукту «Порошок»:

Скачать практические примеры функции СУММЕСЛИ в Excel

Функция ВПР извлекла из таблицы значение d-02, которое соответствовало искомому «Порошку». Затем СУММЕСЛИ суммировала все значения из столбца «Выручка», которые соответствовали коду «d-02», поскольку это значение было условием для суммирования.

Допустим нам необходимо суммировать числовые значения в границах дат от 23-го и до 29-го июня включительно. Начальные и конечные даты введены в соответствующих ячейках дополнительной таблицы для составления запросов выборки из исходной таблицы. Ниже на рисунке изображены исходные значения и условия отбора значений для суммирования:

Описанная данная техника суммирования по нескольким условиям с помощью функции СУММЕСЛИ основана на вычитании. В данной формуле первая функция СУММЕСЛИ возвращает сумму значений, соответствующих датам раньше конечной даты в ячейке E3 или равной этой дате (в данном случаи =29-е Июня). Оператор «меньше» объединен символом амперсант (&) со ссылкой на ячейку E2 (начальной даты).

Когда формула содержала бы только первую функцию =СУММЕСЛИ(A2:A12;”<=”&E3;B2:B12), тогда итоговый результат составил = 5721.

Но нам необходимо получить сумму чисел в границах между 25-ым и 29-ым числом Июня месяца включительно, а не между 20-ым и 29-ым. Для этого необходимо вычесть из первого итогового результата 5721,00 сумму чисел раньше даты 25-го Июня – 3 726,50.

Данного результата мы добиваемся с помощью повторного использования такой же функции СУММЕСЛИ, но с немного измененным вторым аргументом СУММЕСЛИ(A2:A12;”<“&E2;B2:B12).

Теперь проверим разницу вычислений двух частей формулы с помощью вычитания:

Суммирование числовых значений, соответствующих датам раньше конечной даты (29-го Июня и равной ей) с последующим вычитанием от данного результата суммы всех числовых значений, относящихся к датам раньше от начальной (25-го Июня) позволяет получить сумму всех чисел в границах соответствующим датам заданного периода в таблице составления запроса выборки.

Функция СУММЕСЛИ в Excel с примерами – Пример функции СУММЕСЛИ, суммирование исключая значение в ячейке F1

Примечание. Когда вы используете логическое выражение с ссылкой на ячейку, вы должны использовать двойные кавычки (“”), чтобы начать текстовую строку и амперсанд (&), чтобы объединить и завершить строку, например «<>» и F1.

Оператор «равенства» (=) можно не использовать до ссылки на ячейку, поэтому обе приведенные ниже формулы эквивалентны и правильны:

Формула 1: =СУММЕСЛИ(A2:A8; “=” & F1; C2:C8)

Формула 2: =СУММЕСЛИ(A2:A8; F1; C2:C8)

СУММЕСЛИ примеры формул с подстановочными знаками

Если вы намерены условно суммировать ячейки на основе «текстовых» критериев и хотите суммировать путем частичного совпадения, вам нужно использовать подстановочные знаки в формуле СУММЕСЛИ.

Доступны следующие подстановочные знаки:

Звездочка (*) – представляет любое количество символов

Знак вопроса (?) – представляет один символ в определенном месте

Пример 1. Суммирование значений, основанные на частичном совпадении

Предположим, вы хотите суммировать количество, относящиеся ко всем видам бананов. Следующие формулы СУММЕСЛИ будут очень эффективны в таких случаях:

=СУММЕСЛИ(A2:A8; “*бананы*”;C2:C8) – критерий включает текст, заключенный в звездочки (*).

=СУММЕСЛИ(A2:A8; “*”&F1&”*”; C2:C8) – критерий включает ссылку на ячейку, заключенную в звездочки, обратите внимание на использование амперсанда (&) до и после ссылки на ячейку для конкатенации строки.

Функция СУММЕСЛИ в Excel с примерами – Пример функции СУММЕСЛИ с подстановочными знаками для суммирования по частичному совпадению

Если вы хотите считать только те ячейки, которые начинаются или заканчиваются определенным текстом, добавьте только один * до или после текста:

=СУММЕСЛИ(A2:A8; “бананы*”; C2:C8) – значения суммы в C2:C8, если соответствующая ячейка в столбце A начинается со слова «бананы».

=СУММЕСЛИ(A2:A8; “*бананы”; C2:C8) – значения суммы в C2:C8, если соответствующая ячейка в столбце A заканчивается словом «бананы».

Функция СУММЕСЛИ в Excel с примерами – Пример использования функции СУММЕСЛИ с текстовым условием

Пример 2. Суммирование по заданному количеству символов

Если вы хотите суммировать некоторые значения длиной в шесть букв, вы должны использовать следующую формулу:

=СУММЕСЛИ(A2:A8; “??????”; C2:C8)

Функция СУММЕСЛИ в Excel с примерами – Пример функции СУММЕСЛИ с условием суммирования, если длина текстовой строки в шесть букв

Пример 3. Сумма ячеек, соответствующих текстовым значениям

Если ваш рабочий лист содержит разные типы данных, и вы хотите только суммировать ячейки, соответствующие текстовым значениям, пригодится следующая формула СУММЕСЛИ:

=СУММЕСЛИ(A2:A8; “?*”; C2:C8) – суммирует значения из ячеек C2:C8, если соответствующая ячейка в столбце A содержит не менее 1 символа.

=СУММЕСЛИ(A2:A8; “*”; C2:C8) – учитывает пустые ячейки, содержащие строки нулевой длины, возвращаемые некоторыми другими формулами, например =””.

Обе приведенные выше формулы игнорируют нетекстовые значения, такие как ошибки, логические значения, числа и даты.

Пример 4. Использование * или ? как обычные символы

Если вы хотите использовать либо *, либо ? для обработки в функции СУММЕСЛИ как литерала, а не подстановочного знака, то используйте перед этим знаком тильду (~). Например, следующая формула СУММЕСЛИ просуммирует значения в ячейках C2:C8, если ячейка в столбце A в той же строке содержит знак вопроса:

=СУММЕСЛИ(A2: A8; “~?”; C2: C8)

СУММЕСЛИ в заданном диапазоне дат

Если вам необходимо суммировать значения между двумя датами, то необходимо использовать комбинацию, а точнее разницу двух функций СУММЕСЛИ. В версиях старше Excel 2007 вы можете использовать функцию СУММЕСЛИМН, которая позволяет использовать несколько условий. Эту функцию мы рассмотрим в следующей статье. А так как данная статья посвящена функции СУММЕСЛИ, то приведем пример использования СУММЕСЛИ в диапазоне дат:

=СУММЕСЛИ(B2:B9; “>=01.11.2017”; C2:C9) – СУММЕСЛИ(B2:B9; “>=01.12.2017”; C2:C9)

Эта формула суммирует значения в ячейках C2:C9, если дата в столбце B находится между 1 ноября 2017 года и 30 ноября 2017, включительно.

Задача1 (1 текстовый критерий и 1 числовой)

Найдем количество ящиков товара с определенным Фруктом И , у которых Остаток ящиков на складе не менее минимального. Например, количество ящиков с товаром персики ( ячейка D 2 ), у которых остаток ящиков на складе >=6 ( ячейка E 2 ) . Мы должны получить результат 64. Подсчет можно реализовать множеством формул, приведем несколько (см. файл примера Лист Текст и Число ):

1. = СУММЕСЛИМН(B2:B13;A2:A13;D2;B2:B13;”>=”&E2)

Синтаксис функции: СУММЕСЛИМН(интервал_суммирования;интервал_условия1;условие1;интервал_условия2; условие2…)

• B2:B13 Интервал_суммирования — ячейки для суммирования, включающих имена, массивы или ссылки, содержащие числа. Пустые значения и текст игнорируются.
• A2:A13 и B2:B13 Интервал_условия1; интервал_условия2; … представляют собой от 1 до 127 диапазонов, в которых проверяется соответствующее условие.
• D2 и “>=”&E2 Условие1; условие2; … представляют собой от 1 до 127 условий в виде числа, выражения, ссылки на ячейку или текста, определяющих, какие ячейки будут просуммированы.

Порядок аргументов различен в функциях СУММЕСЛИМН() и СУММЕСЛИ() . В СУММЕСЛИМН() аргумент интервал_суммирования является первым аргументом, а в СУММЕСЛИ() – третьим. При копировании и редактировании этих похожих функций необходимо следить за тем, чтобы аргументы были указаны в правильном порядке.

2. другой вариант = СУММПРОИЗВ((A2:A13=D2)*(B2:B13);–(B2:B13>=E2)) Разберем подробнее использование функции СУММПРОИЗВ() :

• Результатом вычисления A2:A13=D2 является массив {ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ИСТИНА:ИСТИНА:ИСТИНА:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ} Значение ИСТИНА соответствует совпадению значения из столбца А критерию, т.е. слову персики . Массив можно увидеть, выделив в Строке формул A2:A13=D2 , а затем нажав F9
  
• Результатом вычисления B2:B13 является массив {3:5:11:98:4:8:56:2:4:6:10:11}, т.е. просто значения из столбца B
  
• Результатом поэлементного умножения массивов (A2:A13=D2)*(B2:B13) является {0:0:0:0:4:8:56:0:0:0:0:0}. При умножении числа на значение ЛОЖЬ получается 0; а на значение ИСТИНА (=1) получается само число;
• Разберем второе условие: Результатом вычисления –( B2:B13>=E2) является массив {0:0:1:1:0:1:1:0:0:1:1:1}. Значения в столбце « Количество ящиков на складе », которые удовлетворяют критерию >=E2 (т.е. >=6) соответствуют 1;
• Далее, функция СУММПРОИЗВ() попарно перемножает элементы массивов и суммирует полученные произведения. Получаем – 64.