Excel vba this worksheet activate

Home / VBA / How to Activate a Sheet using VBA

Worksheets("Sheet1").Activate

Worksheets("1").Activate

Sub ActivateSheet1()
Worksheets("Sheet1").Activate
End Sub

Sub auto_open()
Worksheets("Sheet1").Activate
End Su

Sub HideWorksheet()
Dim ws As Worksheet
For Each ws In ThisWorkbook.Worksheets
If ws.Name <> "Sheet1" Then
ws.Visible = xlSheetHidden
End If
Next ws
End Sub

In this Excel VBA Tutorial, you learn how to activate workbooks with macros.

This Excel VBA Activate Workbook Tutorial is currently under development. Subscribe to the Power Spreadsheets Newsletter to get future updates to this Excel VBA Tutorial.

Use the following Table of Contents to navigate to the Section you’re interested in.

VBA Code to Activate This Workbook

To activate this workbook, use the following statement in the applicable procedure.

Process to Activate This Workbook with VBA

1. Refer to this workbook (the workbook where the macro is stored).
2. Activate the workbook.

Main VBA Constructs Used to Activate This Workbook

(1) Application.ThisWorkbook property.

Returns a Workbook object representing the workbook where the macro is stored (the workbook where the macro is running).

(2) Workbook object.

Represents an Excel workbook.

(3) Workbook.Activate method.

Activates the (first) window associated with a workbook.

Macro Example to Activate This Workbook

The macro below does the following:

1. Activate this workbook (the workbook where the macro is stored).
2. Maximize the active window.

Sub ActivateThisWorkbook()
    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/excel-vba-activate-workbook/
    
    'This procedure:
        '(1) Activates this workbook (the workbook where the macro is stored)
        '(2) Maximizes the active window
    
    'Activate this workbook
    ThisWorkbook.Activate
    
    'Maximize the active window
    ActiveWindow.WindowState = xlMaximized

End Sub

Effects of Executing Macro Example to Activate This Workbook

The image below illustrates the effects of using the macro example. In this example:

• 2 workbooks (“Excel VBA Activate Workbook” and “Book1”) are open.
• The “Book1” workbook is the active workbook.
• The macro example is stored in the “Excel VBA Activate Workbook” workbook.

When the macro is executed, Excel:

• Activates this workbook (“Excel VBA Activate Workbook”; the workbook where the macro example is stored); and
• Maximizes the active window.

Excel VBA Activate Workbook by Filename

VBA Code to Activate Workbook by Filename

To activate a workbook by filename, use the following structure/template in the applicable statement.

Workbooks("Filename").Activate

Process to Activate Workbook by Filename with VBA

1. Refer to the workbook to activate by filename.
2. Activate the applicable workbook.

Main VBA Constructs Used to Activate Workbook by Filename

(1) Application.Workbooks property.

Returns a Workbooks collection representing all open workbooks.

(2) Workbooks object.

Represents all open workbooks.

(3) Workbooks.Item property.

Returns a specific Workbook object from the applicable Workbooks collection.

(4) Workbook object.

Represents an Excel workbook.

(5) Workbook.Activate method.

Activates the (first) window associated with a workbook.

Cues to Activate Workbook by Filename with VBA

• Consider whether you must wrap the workbook filename in double quotes and parentheses ((“Filename”)).
• As a general rule: Include the complete filename, including file extension (for ex., “Filename.xlsm”), of a previously saved workbook.

Macro Example to Activate Workbook by Filename

The macro below does the following:

1. Activate the workbook with filename “Excel VBA Activate Workbook.xlsm”.
2. Maximize the active window.

Sub ActivateWorkbookByFilename()
    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/excel-vba-activate-workbook/
    
    'This procedure:
        '(1) Activates the workbook with filename "Excel VBA Activate Workbook.xlsm"
        '(2) Maximizes the active window
    
    'Activate the workbook with filename "Excel VBA Activate Workbook.xlsm"
    Workbooks("Excel VBA Activate Workbook.xlsm").Activate
    
    'Maximize the active window
    ActiveWindow.WindowState = xlMaximized

End Sub

Effects of Executing Macro Example to Activate Workbook by Filename

The image below illustrates the effects of using the macro example. In this example:

• 2 workbooks (“Excel VBA Activate Workbook.xlsm” and “Book1”) are open.
• The “Book1” workbook is the active workbook.

When the macro is executed, Excel:

• Activates the workbook with filename “Excel VBA Activate Workbook.xlsm”; and
• Maximizes the active window.

Excel VBA Activate Workbook with Partial Filename (with Left, Mid, or Right Functions)

VBA Code to Activate Workbook with Partial Filename (with Left, Mid, or Right Functions)

To activate a workbook with partial filename (with the Left, Mid, or Right functions), use the following structure/template in the applicable procedure.

VariableDeclarationStatement iWorkbook As Workbook
For Each iWorkbook In Application.Workbooks
    If VbaBuiltInTextFunction(TextFunctionArgumentsIncludingWorkbookName) = "PartialWorkbookFilename" Then
        iWorkbook.Activate
    End If
Next iWorkbook

Process to Activate Workbook with Partial Filename (with Left, Mid, or Right Functions)

1. Declare iteration object variable (usually of the Workbook object data type).
2. Loop through all open workbooks.
3. Test whether the applicable part (for example, the beginning or end) of the name of the workbook (the loop is currently iterating through) matches the (known) partial filename (of the workbook to activate).
4. If the condition is met (the applicable part of the name of the applicable workbook matches the partial filename of the workbook to activate), activate the workbook (the loop is currently iterating through).

Main VBA Constructs Used to Activate Workbook with Partial Filename (with Left, Mid, or Right Functions)

(1) Variable declaration statement.

One of the following 4 statements:

• Dim: Declares variables and allocates storage space.
• Private:
  • Used at the module level.
  • Declares module-level variables and allocates storage space.
• Public:
  • Used at the module level.
  • Declares global variables and allocates storage space.
• Static: Declares static variables and allocates storage space.

(2) Workbook object.

Represents an Excel workbook.

(3) For Each… Next statement.

Repeats a set of statements for each element in an array or collection.

(4) Application.Workbooks property.

Returns a Workbooks collection representing all open workbooks.

(5) Workbooks object.

Represents all open workbooks.

(6) Object variable.

A named storage location containing data (a reference to an object) that can be modified during procedure execution.

(7) If… Then… Else statement.

Conditionally executes a set of statements, depending on the value returned by a logical expression.

(8) VBA built-in text function.

One (or more) of the following VBA built-in text functions:

• Left: Returns a string containing a specific number of characters from the start (left side) of a string.
• Mid: Returns a string containing a specific number of characters from the middle (starting at a specific position) of a string.
• Right: Returns a string containing a specific number of characters from the end (right side) of a string.
• InStr: Returns the position of the first occurrence of one string inside another string.

(9) String.

A sequence of contiguous characters.

(10) Workbook.Activate method.

Activates the (first) window associated with a workbook.

Cues to Activate Workbook with Partial Filename (with Left, Mid, or Right Functions) with VBA

• Consider explicitly declaring:
  • The iteration object variable.
  • The data type (usually Workbook object) of the iteration object variable.
• As a general rule, declare the iteration object variable:
  • Using the Dim statement; and
  • As of the Workbook object data type.
• If the scope of the iteration object variable is module-level or global, follow the applicable rules for (module-level or global) variable declaration.
• Depending on the case you deal with, you may need to work with different versions of the If… Then… Else statement. Consider the following 4 basic versions of the If… Then… Else statement:
  • If… Then. This is the version I use in the structure/template above.
  • If… Then… Else.
  • If… Then… ElseIf.
  • If… Then… ElseIf… Else.
• The appropriate VBA built-in text function you work with depends on the case you deal with (for example, the structure and position of the known partial filename).
• As a general rule:
  • The (main) string you use as one of the arguments of the VBA built-in text function (the string from which you extract characters) is the name of the applicable workbook (the For Each… Next statement is currently iterating through).
  • Work with the Workbook.Name property to obtain the name of the applicable workbook. The Workbook.Name property returns a workbook’s name.
• When specifying the (known) partial filename, consider whether you must wrap this partial filename in double quotes (“PartialWorkbookFilename”).

Macro Example to Activate Workbook with Partial Filename (with Left, Mid, or Right Functions)

The macro below does the following:

1. Declare an object variable (iWorkbook) of the Workbook object data type.
2. Loop through all open workbooks.
3. Test whether the first/leftmost 9 letters of the name of the workbook (the loop is currently iterating through) spell “Excel VBA”.
4. If the condition is met (the first/leftmost 9 letters of the name of the applicable workbook spell “Excel VBA”), activate the workbook (the loop is currently iterating through).

Sub ActivateWorkbookPartialFilenameLeftMidRight()
    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/excel-vba-activate-workbook/
    
    'Declare iteration object variable
    Dim iWorkbook As Workbook
    
    'Loop through all open workbooks
    For Each iWorkbook In Application.Workbooks
        
        'Do the following:
            '(1) Test whether the first/leftmost 9 letters of the name of the workbook (the loop is currently iterating through) spell "Excel VBA"
            '(2) If the condition is met, activate the workbook (the loop is currently iterating through)
        If Left(iWorkbook.Name, 9) = "Excel VBA" Then iWorkbook.Activate
    
    Next iWorkbook
    
End Sub

Effects of Executing Macro Example to Activate Workbook with Partial Filename (with Left, Mid, or Right Functions)

The image below illustrates the effects of using the macro example. In this example:

• 10 workbooks (“Excel VBA Activate Workbook.xlsm”, and “Book1” through “Book9”) are open.
• The “Book1” workbook is the active workbook.

When the macro is executed, Excel activates the workbook whose filename (Excel VBA Activate Workbook.xlsm) contains the (known) partial filename (Excel VBA).

Excel VBA Activate Workbook with Partial Filename (with InStr Function)

VBA Code to Activate Workbook with Partial Filename (with InStr Function)

To activate a workbook with partial filename (with the InStr function), use the following structure/template in the applicable procedure.

VariableDeclarationStatement iWorkbook As Workbook
For Each iWorkbook In Application.Workbooks
    If InStr(1, iWorkbook.Name, "PartialWorkbookFilename", StringCompareMethodConstant) > 0 Then
        iWorkbook.Activate
    End If
Next iWorkbook

Process to Activate Workbook with Partial Filename (with InStr Function)

1. Declare iteration object variable (usually of the Workbook object data type).
2. Loop through all open workbooks.
3. Test whether the name of the workbook (the loop is currently iterating through) contains the (known) partial filename (of the workbook to activate).
4. If the condition is met (the name of the applicable workbook contains the partial filename of the workbook to activate), activate the workbook (the loop is currently iterating through).

Main VBA Constructs Used to Activate Workbook with Partial Filename (with InStr Function)

(1) Variable declaration statement.

One of the following 4 statements:

• Dim: Declares variables and allocates storage space.
• Private:
  • Used at the module level.
  • Declares module-level variables and allocates storage space.
• Public:
  • Used at the module level.
  • Declares global variables and allocates storage space.
• Static: Declares static variables and allocates storage space.
  

(2) Workbook object.

Represents an Excel workbook.

(3) For Each… Next statement.

Repeats a set of statements for each element in an array or collection.

(4) Application.Workbooks property.

Returns a Workbooks collection representing all open workbooks.

(5) Workbooks object.

Represents all open workbooks.

(6) Object variable.

A named storage location containing data (a reference to an object) that can be modified during procedure execution.

(7) If… Then… Else statement.

Conditionally executes a set of statements, depending on the value returned by a logical expression.

(8) InStr function.

Returns the position of the first occurrence of one string inside another string.

Accepts the following 4 arguments:

• start:
  • Optional argument.
  • The starting position for the search.
  • If omitted, the search begins at the first character.
• string1:
  • Required argument.
  • The string you search in.
• string2:
  • Required argument.
  • The string you search for.
• compare:
  • Optional argument.
  • The string comparison method.
  • If omitted, the module’s Option Compare setting applies.

(9) Workbook.Name property.

Returns a workbook’s name.

(10) String.

A sequence of contiguous characters.

(11) Greater than operator (>).

Compares 2 expressions and returns True, False, or Null as follows:

• True: If Expression1 > Expression2.
• False: If Expression1 <= Expression2.
• Null: If (either) Expression1 or Expression2 are Null.

(12) Workbook.Activate method.

Activates the (first) window associated with a workbook.

Cues to Activate Workbook with Partial Filename (with InStr Function) with VBA

• Consider explicitly declaring:
  • The iteration object variable.
  • The data type (usually Workbook object) of the iteration object variable.
• As a general rule, declare the iteration object variable:
  • Using the Dim statement; and
  • As of the Workbook object data type.
• If the scope of the iteration object variable is module-level or global, follow the applicable rules for (module-level or global) variable declaration.
• Depending on the case you deal with, you may need to work with different versions of the If… Then… Else statement. Consider the following 4 basic versions of the If… Then… Else statement:
  • If… Then. This is the version I use in the structure/template above.
  • If… Then… Else.
  • If… Then… ElseIf.
  • If… Then… ElseIf… Else.
• As a general rule, set the arguments of the InStr function as follows:
  • start: 1.
  • string1: The name of the workbook the loop is currently iterating through, as returned by the Workbook.Name property.
  • string2: The (known) partial filename.
  • compare: vbBinaryCompare. vbBinaryCompare (usually) results in a case sensitive comparison.
• When specifying the (known) partial filename (as string2 argument of the InStr function), consider whether you must wrap this partial filename in double quotes (“PartialWorkbookFilename”).

Macro Example to Activate Workbook with Partial Filename (with InStr Function)

The macro below does the following:

1. Declare an object variable (iWorkbook) of the Workbook object data type.
2. Loop through all open workbooks.
3. Test whether the name of the workbook (the loop is currently iterating through) contains “Excel VBA”.
4. If the condition is met (the name of the applicable workbook contains “Excel VBA”), activate the workbook (the loop is currently iterating through).

Sub ActivateWorkbookPartialFilenameInStr()
    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/excel-vba-activate-workbook/
    
    'Declare iteration object variable
    Dim iWorkbook As Workbook
    
    'Loop through all open workbooks
    For Each iWorkbook In Application.Workbooks
        
        'Do the following:
            '(1) Test whether the name of the workbook (the loop is currently iterating through) contains "Excel VBA"
            '(2) If the condition is met, activate the workbook (the loop is currently iterating through)
        If InStr(1, iWorkbook.Name, "Excel VBA", vbBinaryCompare) > 0 Then iWorkbook.Activate
    
    Next iWorkbook

End Sub

Effects of Executing Macro Example to Activate Workbook with Partial Filename (with InStr Function)

The image below illustrates the effects of using the macro example. In this example:

• 10 workbooks (“Excel VBA Activate Workbook.xlsm”, and “Book1” through “Book9”) are open.
• The “Book1” workbook is the active workbook.

When the macro is executed, Excel activates the workbook whose filename (Excel VBA Activate Workbook.xlsm) contains the (known) partial filename (Excel VBA).

Excel VBA Activate Workbook Using Wildcard

VBA Code to Activate Workbook Using Wildcard

To activate a workbook using a wildcard, use the following structure/template in the applicable procedure.

VariableDeclarationStatement Dim iWorkbook As Workbook
For Each iWorkbook In Application.Workbooks
    If iWorkbook.Name Like "WorkbookNameUsingWildcard" Then
        iWorkbook.Activate
    End If
Next iWorkbook

Process to Activate Workbook Using Wildcard

1. Declare iteration object variable (usually of the Workbook object data type).
2. Loop through all open workbooks.
3. Test whether the name of the workbook (the loop is currently iterating through) is like the (known) filename (of the workbook to activate). Use wildcards (as necessary) to specify the filename of the workbook to activate.
4. If the condition is met (the name of the applicable workbook is like the filename -including any wildcards- of the workbook to activate), activate the workbook (the loop is currently iterating through).

Main VBA Constructs Used to Activate Workbook Using Wildcard

(1) Variable declaration statement.

One of the following 4 statements:

• Dim: Declares variables and allocates storage space.
• Private:
  • Used at the module level.
  • Declares module-level variables and allocates storage space.
• Public:
  • Used at the module level.
  • Declares global variables and allocates storage space.
• Static: Declares static variables and allocates storage space.
  

(2) Workbook object.

Represents an Excel workbook.

(3) For Each… Next statement.

Repeats a set of statements for each element in an array or collection.

(4) Application.Workbooks property.

Returns a Workbooks collection representing all open workbooks.

(5) Workbooks object.

Represents all open workbooks.

(6) Object variable.

A named storage location containing data (a reference to an object) that can be modified during procedure execution.

(7) If… Then… Else statement.

Conditionally executes a set of statements, depending on the value returned by a logical expression.

(8) Workbook.Name property.

Returns a workbook’s name.

(9) Like operator.

Compares a string against a pattern and returns True, False, or Null as follows:

• True: If the string matches the pattern.
• False: If the string doesn’t match the pattern.
• Null: If (either) the string or the pattern are Null.

You can combine the following elements when specifying the pattern:

• Wildcard characters.
• Character lists.
• Character ranges.

(10) String.

A sequence of contiguous characters.

(11) Workbook.Activate method.

Activates the (first) window associated with a workbook.

Cues to Activate Workbook Using Wildcard with VBA

• Consider explicitly declaring:
  • The iteration object variable.
  • The data type (usually Workbook object) of the iteration object variable.
• As a general rule, declare the iteration object variable:
  • Using the Dim statement; and
  • As of the Workbook object data type.
• If the scope of the iteration object variable is module-level or global, follow the applicable rules for (module-level or global) variable declaration.
• Depending on the case you deal with, you may need to work with different versions of the If… Then… Else statement. Consider the following 4 basic versions of the If… Then… Else statement:
  • If… Then. This is the version I use in the structure/template above.
  • If… Then… Else.
  • If… Then… ElseIf.
  • If… Then… ElseIf… Else.
• Use the Like operator to compare the string returned by the Workbook.Name property (the name of the workbook the loop is currently iterating through) against a string with the filename (including any wildcards) of the workbook to activate.
• Use the following wildcards when specifying the pattern the Like operator works with:
  • ?: Represents any single character.
  • *: Represents any sequence of 0 or more characters.
• When specifying the pattern the Like operator works with (the filename -including any wildcards- of the workbook to activate), consider whether you must wrap this partial filename in double quotes (“WorkbookNameUsingWildcard”).

Macro Example to Activate Workbook Using Wildcard

The macro below does the following:

1. Declare an object variable (iWorkbook) of the Workbook object data type.
2. Loop through all open workbooks.
3. Test whether the name of the workbook (the loop is currently iterating through) has the following structure:
   1. Starts with “Excel VBA”;
   2. Followed by any sequence of characters; and
   3. Ends with the “.xlsm” file extension.
4. If the condition is met (the name of the applicable workbook is like the specified filename, including the * wildcard), activate the workbook (the loop is currently iterating through).

Sub ActivateWorkbookUsingWildcard()
    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/excel-vba-activate-workbook/
    
    'Declare iteration object variable
    Dim iWorkbook As Workbook
    
    'Loop through all open workbooks
    For Each iWorkbook In Application.Workbooks
        
        'Do the following:
            '(1) Test whether the name of the workbook (the loop is currently iterating through) has the following structure:
                '(1) Starts with "Excel VBA"
                '(2) Followed by any sequence of characters
                '(3) Ends with the ".xlsm" file extension
            '(2) If the condition is met, activate the workbook (the loop is currently iterating through)
        If iWorkbook.Name Like "Excel VBA*.xlsm" Then iWorkbook.Activate
    
    Next iWorkbook
    
End Sub

Effects of Executing Macro Example to Activate Workbook Using Wildcard

The image below illustrates the effects of using the macro example. In this example:

• 10 workbooks (“Excel VBA Activate Workbook.xlsm”, and “Book1” through “Book9”) are open.
• The “Book1” workbook is the active workbook.

When the macro is executed, Excel activates the workbook whose filename (Excel VBA Activate Workbook.xlsm) has the following structure:

1. Starts with “Excel VBA”;
2. Followed by any sequence of characters; and
3. Ends with the “.xlsm” file extension.

Excel VBA Activate Workbook and Worksheet

VBA Code to Activate Workbook and Worksheet

To activate a workbook and a worksheet, use the following structure/template in the applicable statement.

WorkbookObjectReference.WorksheetObjectReference.Activate

Process to Activate Workbook and Worksheet with VBA

1. Refer to the workbook and worksheet to activate.
2. Activate the applicable worksheet.

Main VBA Constructs Used to Activate Workbook and Worksheet

(1) Workbook object.

Represents an Excel workbook.

(2) Workbook.Worksheets property.

Returns a Sheets collection representing all worksheets in the applicable workbook.

(3) Worksheets object.

Represents all worksheets in the applicable workbook.

(4) Worksheets.Item property.

Returns a specific Worksheet object from the applicable Worksheets collection.

(5) Worksheet object.

Represents a worksheet.

(6) Worksheet.Activate method.

Activates the applicable worksheet.

Cues to Activate Workbook and Worksheet with VBA

• Work with (among others) one of the following VBA constructs (or groups of constructs) to return a Workbook object:
  • Application.Workbooks property, Workbooks object, and Workbooks.Item property.
  • Application.ThisWorkbook property.
• As a general rule, identify the applicable Worksheet object (inside the Worksheets collection) using one of the following:
  • An index number. The index number:
    • Represents the position of the Worksheet object in the Worksheets collection.
    • Is:
      • Wrapped in parentheses ((IndexNumber)).
      • Included after the reference to the Worksheets collection (Worksheets(IndexNumber)).
  • The Worksheet object’s name (Worksheet.Name property). The name is:
    • Wrapped in:
      • Double quotes (“WorksheetName”); and
      • Parentheses ((“WorksheetName”)).
    • Included after the reference to the Worksheets collection (Worksheets(“WorksheetName”)).
• You can (also) use a Worksheet object’s CodeName property (Worksheet.CodeName property) to refer to the applicable worksheet.

Macro Example to Activate Workbook and Worksheet

The macro below does the following:

1. Activate:
   1. The “Excel VBA Activate Workbook.xlsm” workbook; and
   2. The “Activate Workbook and Worksheet” worksheet.
2. Maximize the active window.

Sub ActivateWorkbookAndWorksheet()
    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/excel-vba-activate-workbook/
    
    'This procedure:
        '(1) Activates the "Activate Workbook and Worksheet" worksheet in the "Excel VBA Activate Workbook.xlsm" workbook
        '(2) Maximizes the active window
    
    'Activate the "Activate Workbook and Worksheet" worksheet in the "Excel VBA Activate Workbook.xlsm" workbook
    Workbooks("Excel VBA Activate Workbook.xlsm").Worksheets("Activate Workbook and Worksheet").Activate
    
    'Maximize the active window
    ActiveWindow.WindowState = xlMaximized

End Sub

Effects of Executing Macro Example to Activate Workbook and Worksheet

The image below illustrates the effects of using the macro example. In this example:

• 2 workbooks (“Excel VBA Activate Workbook.xlsm” and “Book1”) are open.
• The “Book1” workbook is the active workbook.
• The “Sheet1” worksheet is the active worksheet in both (“Excel VBA Activate Workbook.xlsm” and “Book1”) workbooks.

When the macro is executed, Excel:

• Activates:
  • The “Excel VBA Activate Workbook.xlsm” workbook; and
  • The “Activate Workbook and Worksheet” worksheet.
• Maximizes the active window.

Excel VBA Activate Workbook and Chart Sheet

VBA Code to Activate Workbook and Chart Sheet

To activate a workbook and a chart sheet, use the following structure/template in the applicable statement.

WorkbookObjectReference.ChartObjectReference.Activate

Process to Activate Workbook and Chart Sheet with VBA

1. Refer to the workbook and chart sheet to activate.
2. Activate the applicable chart sheet.

Main VBA Constructs Used to Activate Workbook and Chart Sheet

(1) Workbook object.

Represents an Excel workbook.

(2) Workbook.Charts property.

Returns a Sheets collection representing all chart sheets in the applicable workbook.

(3) Charts object.

Represents all chart sheets in the applicable workbook.

(4) Charts.Item property.

Returns a specific Chart object from the applicable Charts collection.

(5) Chart object.

Represents a chart in a workbook. The chart can be either of the following:

• A chart sheet.
• An embedded chart (not the subject of this Section).

(6) Chart.Activate method.

Activates the applicable chart.

Cues to Activate Workbook and Chart Sheet with VBA

• Work with (among others) one of the following VBA constructs (or groups of constructs) to return a Workbook object:
  • Application.Workbooks property, Workbooks object, and Workbooks.Item property.
  • Application.ThisWorkbook property.
• As a general rule, identify the applicable Chart object (inside the Charts collection) using one of the following:
  • An index number. The index number:
    • Represents the position of the Chart object in the Charts collection.
    • Is:
      • Wrapped in parentheses ((IndexNumber)).
      • Included after the reference to the Charts collection (Charts(IndexNumber)).
  • The Chart object’s name (Chart.Name property). The name is:
    • Wrapped in:
      • Double quotes (“ChartSheetName”); and
      • Parentheses ((“ChartSheetName”)).
    • Included after the reference to the Charts collection (Charts(“ChartSheetName”)).
• You can (also) use a Chart object’s CodeName property (Chart.CodeName property) to refer to the applicable chart sheet.

Macro Example to Activate Workbook and Chart Sheet

The macro below does the following:

1. Activate:
   1. The “Excel VBA Activate Workbook.xlsm” workbook; and
   2. The “Activate Workbook Chart Sheet” chart sheet.
2. Maximize the active window.

Sub ActivateWorkbookAndChartSheet()
    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/excel-vba-activate-workbook/
    
    'This procedure:
        '(1) Activates the "Activate Workbook Chart Sheet" chart sheet in the "Excel VBA Activate Workbook.xlsm" workbook
        '(2) Maximizes the active window
    
    'Activate the "Activate Workbook Chart Sheet" chart sheet in the "Excel VBA Activate Workbook.xlsm" workbook
    Workbooks("Excel VBA Activate Workbook.xlsm").Charts("Activate Workbook Chart Sheet").Activate
    
    'Maximize the active window
    ActiveWindow.WindowState = xlMaximized
    
End Sub

Effects of Executing Macro Example to Activate Workbook and Chart Sheet

The image below illustrates the effects of using the macro example. In this example:

• 2 workbooks (“Excel VBA Activate Workbook.xlsm” and “Book1”) are open.
• The “Book1” workbook is the active workbook.
• The “Sheet1” worksheet is the active sheet in both (“Excel VBA Activate Workbook.xlsm” and “Book1”) workbooks.

When the macro is executed, Excel:

• Activates:
  • The “Excel VBA Activate Workbook.xlsm” workbook; and
  • The “Activate Workbook Chart Sheet” chart sheet.
• Maximizes the active window.

Excel VBA Activate Workbook with Variable Name

VBA Code to Activate Workbook with Variable Name

To activate a workbook with variable name (where the workbook filename is held by a variable), use the following structure/template in the applicable procedure.

VariableDeclarationStatement WorkbookFilenameVariable As String
WorkbookFilenameVariable = WorkbookFilenameString
Workbooks(WorkbookFilenameVariable).Activate

Process to Activate Workbook with Variable Name

1. Declare variable (usually of the String data type) to represent workbook filename.
2. Assign workbook filename to variable.
3. Refer to the workbook to activate by using the applicable variable name (representing the workbook filename).
4. Activate the applicable workbook.

Main VBA Constructs Used to Activate Workbook with Variable Name

(1) Variable declaration statement.

One of the following 4 statements:

• Dim: Declares variables and allocates storage space.
• Private:
  • Used at the module level.
  • Declares module-level variables and allocates storage space.
• Public:
  • Used at the module level.
  • Declares global variables and allocates storage space.
• Static: Declares static variables and allocates storage space.

(2) String data type.

Holds textual data (a sequence of characters representing the characters themselves).

(3) Assignment operator (=).

Assigns a value to a variable or property.

(4) Application.Workbooks property.

Returns a Workbooks collection representing all open workbooks.

(5) Workbooks object.

Represents all open workbooks.

(6) Workbooks.Item property.

Returns a specific Workbook object from the applicable Workbooks collection.

(7) Workbook object.

Represents an Excel workbook.

(8) Variable.

A named storage location containing data that can be modified during procedure execution.

(9) Workbook.Activate method.

Activates the (first) window associated with a workbook.

Cues to Activate Workbook with Variable Name with VBA

• Consider explicitly declaring:
  • The variable representing the workbook filename.
  • The data type (usually String) of the variable representing the workbook filename.
• As a general rule, declare the variable representing the workbook filename:
  • Using the Dim statement; and
  • As of the String data type.
• If the scope of the variable representing the workbook filename is module-level or global, follow the applicable rules for (module-level or global) variable declaration.
• When assigning the workbook filename to the variable representing the workbook filename:
  • Consider whether you must wrap the workbook filename in double quotes and parentheses ((“Filename”)).
  • As a general rule:
    • Include the complete filename, including file extension (for ex., “Filename.xlsm”), of a previously saved workbook.
    • Do not include the file path.

Macro Example to Activate Workbook with Variable Name

The macro below does the following:

1. Declare a variable (WorkbookFilename) of the String data type.
2. Assign a string (Excel VBA Activate Workbook.xlsm) to the WorkbookFilename variable.
3. Activate the workbook whose filename is represented by the WorkbookFilename variable.
4. Maximize the active window.

Sub ActivateWorkbookWithVariableName()
    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/excel-vba-activate-workbook/
    
    'This procedure:
        '(1) Declares a variable (WorkbookFilename) of the String data type
        '(2) Assigns a string (Excel VBA Activate Workbook.xlsm) to the WorkbookFilename variable
        '(3) Activates the workbook whose filename is represented by the WorkbookFilename variable
        '(4) Maximizes the active window
    
    'Declare variable to represent workbook filename
    Dim WorkbookFilename As String
    
    'Assign workbook filename to variable
    WorkbookFilename = "Excel VBA Activate Workbook.xlsm"
    
    'Activate the workbook whose filename is represented by the WorkbookFilename variable
    Workbooks(WorkbookFilename).Activate
    
    'Maximize the active window
    ActiveWindow.WindowState = xlMaximized

End Sub

Effects of Executing Macro Example to Activate Workbook with Variable Name

The image below illustrates the effects of using the macro example. In this example:

• 2 workbooks (“Excel VBA Activate Workbook.xlsm” and “Book1”) are open.
• The “Book1” workbook is the active workbook.

When the macro is executed, Excel:

• Activates the workbook whose filename (Excel VBA Activate Workbook.xlsm) is held by a variable (WorkbookFilename); and
• Maximizes the active window.

Excel VBA Activate Workbook with Object Variable Name

VBA Code to Activate Workbook with Object Variable Name

To activate a workbook with object variable name (where the Workbook object is represented by an object variable), use the following structure/template in the applicable procedure.

VariableDeclarationStatement WorkbookObjectVariable As Workbook
Set WorkbookObjectVariable = WorkbookObjectReference
WorkbookObjectVariable.Activate

Process to Activate Workbook with Object Variable Name

1. Declare object variable (usually of the Workbook object data type) to represent workbook.
2. Assign Workbook object reference to object variable.
3. Refer to the workbook to activate by using the applicable object variable name (representing the workbook).
4. Activate the applicable workbook.

Main VBA Constructs Used to Activate Workbook with Object Variable Name

(1) Variable declaration statement.

One of the following 4 statements:

• Dim: Declares variables and allocates storage space.
• Private:
  • Used at the module level.
  • Declares module-level variables and allocates storage space.
• Public:
  • Used at the module level.
  • Declares global variables and allocates storage space.
• Static: Declares static variables and allocates storage space.

(2) Workbook object.

Represents an Excel workbook.

(3) Set statement.

Assigns an object reference to a variable or property.

(4) Application.Workbooks property.

Returns a Workbooks collection representing all open workbooks.

(5) Workbooks object.

Represents all open workbooks.

(6) Workbooks.Item property.

Returns a specific Workbook object from the applicable Workbooks collection.

(7) Object Variable.

A named storage location containing data (a reference to an object) that can be modified during procedure execution.

(8) Workbook.Activate method.

Activates the (first) window associated with a workbook.

Cues to Activate Workbook with Object Variable Name with VBA

• Consider explicitly declaring:
  • The object variable representing the workbook.
  • The data type (usually Workbook object) of the object variable representing the workbook.
• As a general rule, declare the object variable representing the workbook:
  • Using the Dim statement; and
  • As of the Workbook object data type.
• If the scope of the object variable representing the workbook is module-level or global, follow the applicable rules for (module-level or global) variable declaration.

Macro Example to Activate Workbook with Object Variable Name

The macro below does the following:

1. Declare an object variable (WorkbookObjectVariable) of the Workbook object data type.
2. Assign a Workbook object reference (Excel VBA Activate Workbook.xlsm) to the WorkbookObjectVariable object variable.
3. Activate the workbook represented by the WorkbookObjectVariable object variable.
4. Maximize the active window.

Sub ActivateWorkbookWithObjectVariableName()
    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/excel-vba-activate-workbook/
    
    'This procedure:
        '(1) Declares an object variable (WorkbookObjectVariable) of the Workbook object data type
        '(2) Assigns a Workbook object reference (to the "Excel VBA Activate Workbook.xlsm" workbook) to the WorkbookObjectVariable object variable
        '(3) Activates the workbook represented by the WorkbookObjectVariable object variable
        '(4) Maximizes the active window
    
    'Declare object variable to represent workbook
    Dim WorkbookObjectVariable As Workbook
    
    'Assign Workbook object reference to object variable
    Set WorkbookObjectVariable = Workbooks("Excel VBA Activate Workbook.xlsm")
    
    'Activate workbook represented by the WorkbookObjectVariable object variable
    WorkbookObjectVariable.Activate
    
    'Maximize the active window
    ActiveWindow.WindowState = xlMaximized

End Sub

Effects of Executing Macro Example to Activate Workbook with Object Variable Name

The image below illustrates the effects of using the macro example. In this example:

• 2 workbooks (“Excel VBA Activate Workbook.xlsm” and “Book1”) are open.
• The “Book1” workbook is the active workbook.

When the macro is executed, Excel:

• Activates the workbook whose reference (Excel VBA Activate Workbook.xlsm) is held by an object variable (WorkbookObjectVariable); and
• Maximizes the active window.

Excel VBA Open and Activate Workbook

VBA Code to Open and Activate Workbook

To open and activate a workbook, use the following structure/template in the applicable statement.

Workbooks.Open Filename:="PathAndFilename"

Process to Open and Activate Workbook with VBA

1. Open the workbook with the Workbooks.Open method.

Main VBA Constructs Used to Open and Activate Workbook

(1) Workbooks.Open method.

Opens a workbook.

(2) Filename parameter.

The:

• First parameter of the Workbooks.Open method.
• Filename of the workbook to open.

Cues to Open and Activate Workbook with VBA

• When you open a workbook with the Workbooks.Open method, the opened workbook becomes the active workbook.
• Consider whether you must wrap the workbook path and filename in double quotes (“PathAndFilename”).
• As a general rule:
  • Include the full path and filename (including file extension).
  • If the workbook is stored in the default file folder (where Excel currently saves files by default), you can exclude the workbook’s path (use only the filename, including file extension).

Macro Example to Open and Activate Workbook

The macro below opens (and activates) the workbook with filename “Excel VBA Open and Activate Workbook.xlsx” stored in the Desktop folder.

Sub OpenAndActivateWorkbook()
    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/excel-vba-activate-workbook/
    
    'Open the workbook with filename "Excel VBA Open and Activate Workbook.xlsx" stored in the Desktop folder. The opened workbook becomes the active workbook
    Workbooks.Open Filename:="C:UsersPowerSpreadsheetsDesktopExcel VBA Open and Activate Workbook.xlsx"
    
End Sub

Effects of Executing Macro Example to Open and Activate Workbook

The image below illustrates the effects of using the macro example.

In this example (only) 1 workbook (“Excel VBA Activate Workbook”) is open. This is (also) the active workbook.

When the macro is executed, Excel opens and activates the workbook with filename “Excel VBA Open and Activate Workbook.xlsx” stored in the Desktop folder.