Excel vba for pivot table

Before I hand over this guide to you and you start using VBA to create a pivot table let me confess something.

I have learned using VBA just SIX years back. And the first time when I wrote a macro code to create a pivot table, it was a failure.

Since then, I have learned more from my bad coding rather than from the codes which actually work.

Today, I will show you a simple way to automate your pivot tables using a macro code.

Normally when you insert a pivot table in a worksheet it happens through a simple process, but that entire process is so quick that you never notice what happened.

In VBA, that entire process is same, just executes using a code. In this guide, I’ll show you each step and explain how to write a code for it.

Just look at the below example, where you can run this macro code with a button, and it returns a new pivot table in a new worksheet in a flash.

Without any further ado, let’s get started to write our macro code to create a pivot table.

The Simple 8 Steps to Write a Macro Code in VBA to Create a Pivot Table in Excel

For your convenience, I have split the entire process into 8 simple steps. After following these steps you will able to automate your all the pivot tables.

Make sure to download this file from here to follow along.

1. Declare Variables

The first step is to declare the variables which we need to use in our code to define different things.

'Declare Variables
Dim PSheet As Worksheet
Dim DSheet As Worksheet
Dim PCache As PivotCache
Dim PTable As PivotTable
Dim PRange As Range
Dim LastRow As Long
Dim LastCol As Long

In the above code, we have declared:

1. PSheet: To create a sheet for a new pivot table.
2. DSheet: To use as a data sheet.
3. PChache: To use as a name for pivot table cache.
4. PTable: To use as a name for our pivot table.
5. PRange: to define source data range.
6. LastRow and LastCol: To get the last row and column of our data range.

2. Insert a New Worksheet

Before creating a pivot table, Excel inserts a blank sheet and then create a new pivot table there.

And, below code will do the same for you.

It will insert a new worksheet with the name “Pivot Table” before the active worksheet and if there is worksheet with the same name already, it will delete it first.

After inserting a new worksheet, this code will set the value of PSheet variable to pivot table worksheet and DSheet to source data worksheet.

'Declare Variables
On Error Resume Next
Application.DisplayAlerts = False
Worksheets("PivotTable").Delete
Sheets.Add Before:=ActiveSheet
ActiveSheet.Name = "PivotTable"
Application.DisplayAlerts = True
Set PSheet = Worksheets("PivotTable")
Set DSheet = Worksheets("Data")

Customization Tip: If the name of the worksheets which you want to refer in the code is different then make sure to change it from the code where I have highlighted.

3. Define Data Range

Now, next thing is to define data range from the source worksheet. Here you need to take care of one thing that you can’t specify a fixed source range.

You need a code which can identify the entire data from source sheet. And below is the code:

'Define Data Range
LastRow = DSheet.Cells(Rows.Count, 1).End(xlUp).Row
LastCol = DSheet.Cells(1, Columns.Count).End(xlToLeft).Column
Set PRange = DSheet.Cells(1, 1).Resize(LastRow, LastCol)

This code will start from the first cell of the data table and select up to the last row and then up to the last column.

And finally, define that selected range as a source. The best part is, you don’t need to change data source every time while creating the pivot table.

4. Create Pivot Cache

In Excel 2000 and above, before creating a pivot table you need to create a pivot cache to define the data source.

Normally when you create a pivot table, Excel automatically creates a pivot cache without asking you, but when you need to use VBA, you need to write a code for this.

'Define Pivot Cache
Set PCache = ActiveWorkbook.PivotCaches.Create _
(SourceType:=xlDatabase, SourceData:=PRange). _
CreatePivotTable(TableDestination:=PSheet.Cells(2, 2), _
TableName:="SalesPivotTable")

This code works in two ways, first define a pivot cache by using data source and second define the cell address in the newly inserted worksheet to insert the pivot table.

You can change the position the pivot table by editing this code.

5. Insert a Blank Pivot Table

After pivot cache, next step is to insert a blank pivot table. Just remember when you create a pivot table what happens, you always get a blank pivot first and then you define all the values, columns, and row.

This code will do the same:

'Insert Blank Pivot Table
Set PTable = PCache.CreatePivotTable _
(TableDestination:=PSheet.Cells(1, 1), TableName:="SalesPivotTable")

This code creates a blank pivot table and names it “SalesPivotTable”. You can change this name from the code itself.

6. Insert Row and Column Fields

After creating a blank pivot table, next thing is to insert row and column fields, just like you do normally.

For each row and column field, you need to write a code. Here we want to add years and month in row field and zones in the column field.

Here is the code:

'Insert Row Fields
With ActiveSheet.PivotTables("SalesPivotTable").PivotFields("Year")
.Orientation = xlRowField
.Position = 1
End With

With ActiveSheet.PivotTables("SalesPivotTable").PivotFields("Month")
.Orientation = xlRowField
.Position = 2
End With

'Insert Column Fields
With ActiveSheet.PivotTables("SalesPivotTable").PivotFields("Zone")
.Orientation = xlColumnField
.Position = 1
End With

In this code, you have mentioned year and month as two fields. Now, if you look at the code, you’ll find that a position number is also there. This position number defines the sequence of fields.

Whenever you need to add more than one field (Row or Column), specify their position. And you can change fields by editing their name from the code.

7. Insert Data Field

The main thing is to define the value field in your pivot table.

The code for defining values differs from defining rows and columns because we must define the formatting of numbers, positions, and functions here.

'Insert Data Field
With ActiveSheet.PivotTables("SalesPivotTable").PivotFields("Amount")
.Orientation = xlDataField
.Function = xlSum
.NumberFormat = "#,##0"
.Name = "Revenue "
End With

You can add the amount as the value field with the above code. And this code will format values as a number with a (,) separator.

We use xlsum to sum values, but you can also use xlcount and other functions.

8. Format Pivot Table

Ultimately, you need to use a code to format your pivot table. Typically there is a default formatting in a pivot table, but you can change that formatting.

With VBA, you can define formatting style within the code.

Code is:

'Format Pivot
TableActiveSheet.PivotTables("SalesPivotTable").ShowTableStyleRowStripes = True
ActiveSheet.PivotTables("SalesPivotTable").TableStyle2 = "PivotStyleMedium9"

The above code will apply row strips and the “Pivot Style Medium 9” style, but you can also use another style from this link.

Finally, your code is ready to use.

[FULL CODE] Use VBA to Create a Pivot Table in Excel – Macro to Copy-Paste

Sub InsertPivotTable()
'Macro By ExcelChamps.com

'Declare Variables
Dim PSheet As Worksheet
Dim DSheet As Worksheet
Dim PCache As PivotCache
Dim PTable As PivotTable
Dim PRange As Range
Dim LastRow As Long
Dim LastCol As Long

'Insert a New Blank Worksheet
On Error Resume Next
Application.DisplayAlerts = False
Worksheets("PivotTable").Delete
Sheets.Add Before:=ActiveSheet
ActiveSheet.Name = "PivotTable"
Application.DisplayAlerts = True
Set PSheet = Worksheets("PivotTable")
Set DSheet = Worksheets("Data")

'Define Data Range
LastRow = DSheet.Cells(Rows.Count, 1).End(xlUp).Row
LastCol = DSheet.Cells(1, Columns.Count).End(xlToLeft).Column
Set PRange = DSheet.Cells(1, 1).Resize(LastRow, LastCol)

'Define Pivot Cache
Set PCache = ActiveWorkbook.PivotCaches.Create _
(SourceType:=xlDatabase, SourceData:=PRange). _
CreatePivotTable(TableDestination:=PSheet.Cells(2, 2), _
TableName:="SalesPivotTable")

'Insert Blank Pivot Table
Set PTable = PCache.CreatePivotTable _
(TableDestination:=PSheet.Cells(1, 1), TableName:="SalesPivotTable")

'Insert Row Fields
With ActiveSheet.PivotTables("SalesPivotTable").PivotFields("Year")
.Orientation = xlRowField
.Position = 1
End With
With ActiveSheet.PivotTables("SalesPivotTable").PivotFields("Month")
.Orientation = xlRowField
.Position = 2
End With

'Insert Column Fields
With ActiveSheet.PivotTables("SalesPivotTable").PivotFields("Zone")
.Orientation = xlColumnField
.Position = 1
End With

'Insert Data Field
With ActiveSheet.PivotTables("SalesPivotTable").PivotFields ("Amount")
.Orientation = xlDataField
.Function = xlSum
.NumberFormat = "#,##0"
.Name = "Revenue "
End With

'Format Pivot Table
ActiveSheet.PivotTables("SalesPivotTable").ShowTableStyleRowStripes = True
ActiveSheet.PivotTables("SalesPivotTable").TableStyle2 = "PivotStyleMedium9"

End Sub

Pivot Table on the Existing Worksheet

The code we have used above creates a pivot table on a new worksheet, but sometimes you need to insert a pivot table in a worksheet already in the workbook.

In the above code (Pivot Table in New Worksheet), in the part where you have written the code to insert a new worksheet and then name it. Please make some tweaks to the code.

Don’t worry; I’ll show you.

You first need to specify the worksheet (already in the workbook) where you want to insert your pivot table.

And for this, you need to use the below code:

Instead of inserting a new worksheet, you must specify the worksheet name to the PSheet variable.

Set PSheet = Worksheets("PivotTable")
Set DSheet = Worksheets(“Data”)

There is a bit more to do. The first code you used deletes the worksheet with the same name (if it exists) before inserting the pivot.

When you insert a pivot table in the existing worksheet, there’s a chance that you already have a pivot there with the same name.

What I’m saying is you need to delete that pivot first.

For this, you need to add the code which should delete the pivot with the same name from the worksheet (if it’s there) before inserting a new one.

Here’s the code which you need to add:

Set PSheet = Worksheets("PivotTable")
Set DSheet = Worksheets(“Data”)
Worksheets("PivotTable").Activate
On Error Resume Next
ActiveSheet.PivotTables("SalesPivotTable").TableRange2.Clear

Let me tell you what this code does.

First, it simply sets PSheet as the worksheet where you want to insert the pivot table already in your workbook and sets data worksheets as DSheet.

After that, it activates the worksheet and deletes the pivot table “Sales Pivot Table” from it.

Important: If the worksheets’ names in your workbook differ, you can change them from the code. I have highlighted the code where you need to do it.

In the End,

By using this code, we can automate your pivot tables. And the best part is this is a one-time setup; after that, we just need a click to create a pivot table and you can save a ton of time. Now tell me one thing.

Have you ever used a VBA code to create a pivot table?

Please share your views with me in the comment box; I’d love to share them with you and share this tip with your friends.

VBA is one of the Advanced Excel Skills, and if you are getting started with VBA, make sure to check out there and Useful Macro Examples and VBA Codes.

• Add or Remove Grand Total in a Pivot Table in Excel
• Add Running Total in a Pivot Table in Excel
• Automatically Update a Pivot Table in Excel
• Add Calculated Field and Item
• Delete a Pivot Table in Excel
• Filter a Pivot Table in Excel
• Add Ranks in Pivot Table in Excel
• Apply Conditional Formatting to a Pivot Table in Excel
• Create Pivot Table using Multiple Files in Excel

• Change Data Source for Pivot Table in Excel
• Count Unique Values in a Pivot Table in Excel
• Pivot Chart in Excel
• Create a Pivot Table from Multiple Worksheets
• Sort a Pivot Table in Excel
• Refresh All Pivot Tables at Once in Excel
• Refresh a Pivot Table
• Pivot Table Timeline in Excel
• Pivot Table Keyboard Shortcuts
• Pivot Table Formatting
• Move a Pivot Table
• Link a Slicer with Multiple Pivot Tables in Excel
• Group Dates in a Pivot Table in Excel

In this VBA Tutorial, you learn how to create a Pivot Table with different destinations (both worksheet or workbook) and from both static and dynamic data ranges.

This Excel VBA Create Pivot Table Tutorial is accompanied by Excel workbooks containing the data and macros I use in the examples below. You can get immediate free access to these example workbooks by clicking the button below.

Use the following Table of Contents to navigate to the section you’re interested in.

Related VBA and Macro Tutorials

The following VBA and Macro Tutorials may help you better understand and implement the contents below:

• General VBA constructs and structures:
  • Learn about commonly-used VBA terms here.
  • Learn about the Excel VBA Object Model here.
  • Learn how to work with variables here.
  • Learn about data types here.
  • Learn about the R1C1 reference-style here.
• Practical VBA applications and macro examples:
  • Learn how to create a new workbook here.
  • Learn how to find the last column with data here.
  • Learn about working with worksheets here.

You can find additional VBA and Macro Tutorials in the Archives.

#1: Create Pivot Table in Existing Sheet

VBA Code to Create Pivot Table in Existing Sheet

To create a Pivot Table in an existing sheet with VBA, use a statement with the following structure:

Workbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=SourceWorksheetName & "!" & SourceDataAddress).createPivotTable TableDestination:=DestinationWorksheetName & "!" & DestinationRangeAddress, TableName:="NewPivotTable"

Process Followed by VBA Code

VBA Statement Explanation

1. Item: Workbook.
   • VBA Construct: Workbook object.
   • Description: Represents the Excel workbook containing the source (SourceWorksheet) and destination worksheets (DestinationWorksheet) you work with. For purposes of this structure, both the source and destination worksheet are in the same workbook.

     Use properties such Application.Workbooks, Application.ThisWorkbook and Application.ActiveWorkbook to return this Workbook object.

2. Item: PivotCaches
   • VBA Construct: Workbook.PivotCaches method.
   • Description: Returns the PivotCaches collection representing all the Pivot Table caches within Workbook.
3. Item: Create.
   • VBA Construct: PivotCaches.Create method.
   • Description: Creates a new PivotCache object representing the memory cache for the Pivot Table you create.
4. Item: SourceType:=xlDatabase
   • VBA Construct: SourceType parameter of the PivotCaches.Create method.
   • Description: Sets the data source of the Pivot Table you create to an Excel list or database (xlDatabase).

     Use the constants within the xlPivotTableSourceType enumeration for purposes of specifying a different data source. Nonetheless, setting SourceType to xlPivotTable (representing the same data source as another Pivot Table) or xlScenario (representing scenarios created using the Scenario Manager) generally results in a run-time error.

5. Item: SourceData:=SourceWorksheetName & “!” & SourceDataAddress.
   • VBA Construct: SourceData parameter of the PivotCaches.Create method.
   • Description: Specifies the data source for the Pivot Table cache.

     If you use the statement structure specified within this VBA Tutorial and explicitly declare variables to represent SourceWorksheetName and SourceDataAddress, use the String data type. Within this structure, SourceData is specified as follows:

     • SourceWorksheetName: Name of the worksheet containing the source data.

       If necessary, use the Worksheet.Name property to return a string representing the worksheet’s name.
     • &: Concatenation operator.
     • SourceDataAddress: Address of the cell range containing the source data.

       If necessary, use the Range.Address property to return a string representing the cell range reference.

     SourceData is of the Variant data type. However, Microsoft’s documentation recommends the following:

     • Either (i) using a string to specify the worksheet and cell range (as above), or (ii) setting up a named range and passing the name as a string.
     • Avoid passing a Range object, as this may result in unexpected “type mismatch” errors.
6. Item: createPivotTable
   • VBA Construct: PivotCache.CreatePivotTable method.
   • Description: Creates a Pivot Table based on the PivotCache created by the PivotCaches.Create method.
7. Item: TableDestination:=DestinationWorksheetName & “!” & DestinationRangeAddress
   • VBA Construct: TableDestination parameter of PivotCache.CreatePivotTable method.
   • Description: Specifies the cell in the upper-left corner of the cell range where the Pivot Table you create is located.

     If you use the statement structure specified within this VBA Tutorial and explicitly declare variables to represent DestinationWorksheetName and DestinationRangeAddress, use the String data type. Within this structure, TableDestination is specified as follows:

     • DestinationWorksheetName: Name of the destination worksheet where the Pivot Table you create is located.

       If necessary, use the Worksheet.Name property to return a string representing the worksheet’s name.

     • &: Concatenation operator.
     • DestinationRangeAddress: Address of the cell in the upper-left corner of the cell range where the Pivot Table you create is located.

       If necessary, use the Range.Address property to return a string representing the cell range reference.

8. Item: TableName:=”NewPivotTable”
   • VBA Construct: TableName parameter of the PivotCache.CreatePivotTable method.
   • Description: Specifies the name of the Pivot Table you create as “NewPivotTable”.

     If you explicitly declare a variable to represent NewPivotTable, use the String data type and omit the quotes included above (” “).

Macro Example

The following macro creates a new Pivot Table in an existing worksheet (PivotTable).

Sub createPivotTableExistingSheet()

    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/vba-create-pivot-table/

    'declare variables to hold row and column numbers that define source data cell range
    Dim myFirstRow As Long
    Dim myLastRow As Long
    Dim myFirstColumn As Long
    Dim myLastColumn As Long

    'declare variables to hold source and destination cell range address
    Dim mySourceData As String
    Dim myDestinationRange As String

    'declare object variables to hold references to source and destination worksheets, and new Pivot Table
    Dim mySourceWorksheet As Worksheet
    Dim myDestinationWorksheet As Worksheet
    Dim myPivotTable As PivotTable

    'identify source and destination worksheets
    With ThisWorkbook
        Set mySourceWorksheet = .Worksheets("Data")
        Set myDestinationWorksheet = .Worksheets("PivotTable")
    End With

    'obtain address of destination cell range
    myDestinationRange = myDestinationWorksheet.Range("A5").Address(ReferenceStyle:=xlR1C1)

    'identify row and column numbers that define source data cell range
    myFirstRow = 5
    myLastRow = 20005
    myFirstColumn = 1
    myLastColumn = 6

    'obtain address of source data cell range
    With mySourceWorksheet.Cells
        mySourceData = .Range(.Cells(myFirstRow, myFirstColumn), .Cells(myLastRow, myLastColumn)).Address(ReferenceStyle:=xlR1C1)
    End With

    'create Pivot Table cache and create Pivot Table report based on that cache
    Set myPivotTable = ThisWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=mySourceWorksheet.Name & "!" & mySourceData).CreatePivotTable(TableDestination:=myDestinationWorksheet.Name & "!" & myDestinationRange, TableName:="PivotTableExistingSheet")

    'add, organize and format Pivot Table fields
    With myPivotTable
        .PivotFields("Item").Orientation = xlRowField
        With .PivotFields("Units Sold")
            .Orientation = xlDataField
            .Position = 1
            .Function = xlSum
            .NumberFormat = "#,##0.00"
        End With
        With .PivotFields("Sales Amount")
            .Orientation = xlDataField
            .Position = 2
            .Function = xlSum
            .NumberFormat = "#,##0.00"
        End With
    End With

End Sub

Effects of Executing Macro Example

The following GIF illustrates the results of executing this macro example. As expected, the macro creates a Pivot Table in the “PivotTable” worksheet.

#2: Create Pivot Table in New Sheet

VBA Code to Create Pivot Table in New Sheet

To create a Pivot Table in a new sheet with VBA, use a macro with the following statement structure:

Dim DestinationWorksheet As Worksheet
Set DestinationWorksheet = Worksheets.Add
Workbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=SourceWorksheetName & "!" & SourceDataAddress).createPivotTable TableDestination:=DestinationWorksheet.Name & "!" & DestinationRangeAddress, TableName:="NewPivotTable"

Process Followed by VBA Code

VBA Statement Explanation

Line #1: Dim DestinationWorksheet As Worksheet

1. Item: Dim DestinationWorksheet As Worksheet.
   • VBA Construct: Dim statement.
   • Description: Declares the DestinationWorksheet object variable as of the Worksheet object data type.

     DestinationWorksheet represents the new worksheet (line #2 below) where the Pivot Table you create (line #3 below) is located.

Line #2: Set DestinationWorksheet = Worksheets.Add

1. Item: Set.
   • VBA Construct: Set statement.
   • Description: Assigns the reference to the Worksheet object returned by the Worksheets.Add method to the DestinationWorksheet object variable.
2. Item: DestinationWorksheet.
   • VBA Construct: Object variable of the Worksheet object data type.
   • Description: Represents the new worksheet where the Pivot Table you create (line #3 below) is located.
3. Item: =.
   • VBA Construct: Assignment operator.
   • Description: Assigns the reference to the Worksheet object returned by the Worksheets.Add method to the DestinationWorksheet object variable.
4. Item: Worksheets.
   • VBA Construct: Worksheets collection.
   • Description: The collection containing all the Worksheet objects (each representing a worksheet) within the workbook your work with.
5. Item: Add.
   • VBA Construct: Worksheets.Add method.
   • Description: Creates a new worksheet. This is the worksheet where the Pivot Table you create (line #3 below) is located.

Line #3: Workbook.PivotCaches.Create( SourceType:=xlDatabase, SourceData:=SourceWorksheetName & “!” & SourceDataAddress).createPivotTable TableDestination:=DestinationWorksheetName & “!” & DestinationRangeAddress, TableName:=”NewPivotTable”

1. Item: Workbook.
   • VBA Construct: Workbook object.
   • Description: Represents the Excel workbook containing the source (SourceWorksheet) and destination worksheets (DestinationWorksheet) you work with. For purposes of this structure, both the source and destination worksheet are in the same workbook.

     Use properties such Application.Workbooks, Application.ThisWorkbook and Application.ActiveWorkbook to return this Workbook object.

2. Item: PivotCaches
   • VBA Construct: Workbook.PivotCaches method.
   • Description: Returns the PivotCaches collection representing all the Pivot Table caches within Workbook.
3. Item: Create.
   • VBA Construct: PivotCaches.Create method.
   • Description: Creates a new PivotCache object representing the memory cache for the Pivot Table you create.
4. Item: SourceType:=xlDatabase
   • VBA Construct: SourceType parameter of the PivotCaches.Create method.
   • Description: Sets the data source of the Pivot Table you create to an Excel list or database (xlDatabase).

     Use the constants within the xlPivotTableSourceType enumeration for purposes of specifying a different data source. Nonetheless, setting SourceType to xlPivotTable (representing the same data source as another Pivot Table) or xlScenario (representing scenarios created using the Scenario Manager) generally results in a run-time error.

5. Item: SourceData:=SourceWorksheetName & “!” & SourceDataAddress.
   • VBA Construct: SourceData parameter of the PivotCaches.Create method.
   • Description: Specifies the data source for the Pivot Table cache.

     If you use the statement structure specified within this VBA Tutorial and explicitly declare variables to represent SourceWorksheetName and SourceDataAddress, use the String data type. Within this structure, SourceData is specified as follows:

     • SourceWorksheetName: Name of the worksheet containing the source data.

       If necessary, use the Worksheet.Name property to return a string representing the worksheet’s name.

     • &: Concatenation operator.
     • SourceDataAddress: Address of the cell range containing the source data.

       If necessary, use the Range.Address property to return a string representing the cell range reference.

     SourceData is of the Variant data type. However, Microsoft’s documentation recommends the following:

     • Either (i) using a string to specify the worksheet and cell range (as above), or (ii) setting up a named range and passing the name as a string.
     • Avoid passing a Range object, as this may result in unexpected “type mismatch” errors.
6. Item: createPivotTable
   • VBA Construct: PivotCache.CreatePivotTable method.
   • Description: Creates a Pivot Table based on the PivotCache created by the PivotCaches.Create method.
7. Item: TableDestination:=DestinationWorksheet.Name & “!” & DestinationRangeAddress
   • VBA Construct: TableDestination parameter of PivotCache.CreatePivotTable method.
   • Description: Specifies the cell in the upper-left corner of the cell range where the Pivot Table you create is located.

     If you use the statement structure specified within this VBA Tutorial and explicitly declare a variable to represent DestinationRangeAddress, use the String data type. Within this structure, TableDestination is specified as follows:

     • DestinationWorksheet.Name: Worksheet.Name property.

       Returns a string representing the name of DestinationWorksheet. DestinationWorksheet is the new worksheet where the Pivot Table you create is located.

     • &: Concatenation operator.
     • DestinationRangeAddress: Address of the cell in the upper-left corner of the cell range where the Pivot Table you create is located.

       If necessary, use the Range.Address property to return a string representing the cell range reference.

8. Item: TableName:=”NewPivotTable”
   • VBA Construct: TableName parameter of the PivotCache.CreatePivotTable method.
   • Description: Specifies the name of the Pivot Table you create as “NewPivotTable”.

     If you explicitly declare a variable to represent NewPivotTable, use the String data type and omit the quotes included above (” “).

Macro Example

The following macro creates a new Pivot Table in a new worksheet.

Sub createPivotTableNewSheet()

    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/vba-create-pivot-table/

    'declare variables to hold row and column numbers that define source data cell range
    Dim myFirstRow As Long
    Dim myLastRow As Long
    Dim myFirstColumn As Long
    Dim myLastColumn As Long

    'declare variables to hold source and destination cell range address
    Dim mySourceData As String
    Dim myDestinationRange As String

    'declare object variables to hold references to source and destination worksheets, and new Pivot Table
    Dim mySourceWorksheet As Worksheet
    Dim myDestinationWorksheet As Worksheet
    Dim myPivotTable As PivotTable

    'identify source and destination worksheets. Add destination worksheet
    With ThisWorkbook
        Set mySourceWorksheet = .Worksheets("Data")
        Set myDestinationWorksheet = .Worksheets.Add
    End With

    'obtain address of destination cell range
    myDestinationRange = myDestinationWorksheet.Range("A5").Address(ReferenceStyle:=xlR1C1)

    'identify row and column numbers that define source data cell range
    myFirstRow = 5
    myLastRow = 20005
    myFirstColumn = 1
    myLastColumn = 6

    'obtain address of source data cell range
    With mySourceWorksheet.Cells
        mySourceData = .Range(.Cells(myFirstRow, myFirstColumn), .Cells(myLastRow, myLastColumn)).Address(ReferenceStyle:=xlR1C1)
    End With

    'create Pivot Table cache and create Pivot Table report based on that cache
    Set myPivotTable = ThisWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=mySourceWorksheet.Name & "!" & mySourceData).CreatePivotTable(TableDestination:=myDestinationWorksheet.Name & "!" & myDestinationRange, TableName:="PivotTableNewSheet")

    'add, organize and format Pivot Table fields
    With myPivotTable
        .PivotFields("Item").Orientation = xlRowField
        With .PivotFields("Units Sold")
            .Orientation = xlDataField
            .Position = 1
            .Function = xlSum
            .NumberFormat = "#,##0.00"
        End With
        With .PivotFields("Sales Amount")
            .Orientation = xlDataField
            .Position = 2
            .Function = xlSum
            .NumberFormat = "#,##0.00"
        End With
    End With

End Sub

Effects of Executing Macro Example

The following GIF illustrates the results of executing this macro example. As expected, the macro creates a Pivot Table in a new worksheet (Sheet4).

#3: Create Pivot Table in New Workbook

VBA Code to Create Pivot Table in New Workbook

To create a Pivot Table in a new workbook with VBA, use a macro with the following statement structure:

Dim DestinationWorkbook As Workbook
Set DestinationWorkbook = Workbooks.Add
DestinationWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:="[" & SourceWorkbookName & "]" & SourceWorksheetName & "!" & SourceDataAddress).createPivotTable TableDestination:="[" & DestinationWorkbook.Name & "]" & DestinationWorkbook.Worksheets(1).Name & "!" & DestinationRangeAddress, TableName:="NewPivotTable"

Process Followed by VBA Code

VBA Statement Explanation

Line #1: Dim DestinationWorkbook As Workbook

1. Item: Dim DestinationWorkbook As Workbook.
   • VBA Construct: Dim statement.
   • Description: Declares the Destination Workbook object variable as of the Workbook object data type.

     DestinationWorkbook represents the new workbook (line #2 below) where the Pivot Table you create (line #3 below) is located.

Line #2: Set DestinationWorkbook = Workbooks.Add

1. Item: Set.
   • VBA Construct: Set statement.
   • Description: Assigns the reference to the Workbook object returned by the Workbooks.Add method to the DestinationWorkbook object variable.
2. Item: DestinationWorkbook.
   • VBA Construct: Object variable of the Workbook object data type.
   • Description: Represents the new workbook where the Pivot Table you create (line #3 below) is located.
3. Item: =.
   • VBA Construct: Assignment operator.
   • Description: Assigns the reference to the Workbook object returned by the Workbooks.Add method to the DestinationWorkbook object variable.
4. Item: Workbooks.
   • VBA Construct: Workbooks collection.
   • Description: The collection containing all the Workbook objects (each representing a workbook) currently open in Excel.
5. Item: Add.
   • VBA Construct: Workbooks.Add method.
   • Description: Creates a new workbook. This is the workbook where the Pivot Table you create (line #3 below) is located.

Line #3: DestinationWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=”[” & SourceWorkbookName & “]” & SourceWorksheetName & “!” & SourceDataAddress).createPivotTable TableDestination:=”[” & DestinationWorkbook.Name & “]” & DestinationWorkbook.Worksheets(1).Name & “!” & DestinationRangeAddress, TableName:=”NewPivotTable”

1. Item: DestinationWorkbook.
   • VBA Construct: Object variable of the Workbook object data type.
   • Description: Represents the new workbook where the Pivot Table you create is located.
2. Item: PivotCaches
   • VBA Construct: Workbook.PivotCaches method.
   • Description: Returns the PivotCaches collection representing all the Pivot Table caches within DestinationWorkbook.
3. Item: Create.
   • VBA Construct: PivotCaches.Create method.
   • Description: Creates a new PivotCache object representing the memory cache for the Pivot Table you create.
4. Item: SourceType:=xlDatabase
   • VBA Construct: SourceType parameter of the PivotCaches.Create method.
   • Description: Sets the data source of the Pivot Table you create to an Excel list or database (xlDatabase).

     Use the constants within the xlPivotTableSourceType enumeration for purposes of specifying a different data source. Nonetheless, setting SourceType to xlPivotTable (representing the same data source as another Pivot Table) or xlScenario (representing scenarios created using the Scenario Manager) generally results in a run-time error.

5. Item: SourceData:=”[” & SourceWorkbookName & “]” & SourceWorksheetName & “!” & SourceDataAddress.
   • VBA Construct: SourceData parameter of the PivotCaches.Create method.
   • Description: Specifies the data source for the Pivot Table cache.

     If you use the statement structure specified within this VBA Tutorial and explicitly declare variables to represent SourceWorkbookName, SourceWorksheetName and SourceDataAddress, use the String data type. Within this structure, SourceData is specified as follows:

     • SourceWorkbookName: Name of the workbook containing the source data.

       If necessary, use the Workbook.Name property to return a string representing the workbook’s name.

     • SourceWorksheetName: Name of the worksheet containing the source data.

       If necessary, use the Worksheet.Name property to return a string representing the worksheet’s name.

     • SourceDataAddress: Address of the cell range containing the source data.

       If necessary, use the Range.Address property to return a string representing the cell range reference.

     • &: Concatenation operator.

     SourceData is of the Variant data type. However, Microsoft’s documentation recommends the following:

     • Either (i) using a string to specify the worksheet and cell range (as above), or (ii) setting up a named range and passing the name as a string.
     • Avoid passing a Range object, as this may result in unexpected “type mismatch” errors.
6. Item: createPivotTable
   • VBA Construct: PivotCache.CreatePivotTable method.
   • Description: Creates a Pivot Table based on the PivotCache created by the PivotCaches.Create method.
7. Item: TableDestination:=”[” & DestinationWorkbook.Name & “]” & DestinationWorkbook.Worksheets(1).Name & “!” & DestinationRangeAddress.
   • VBA Construct: TableDestination parameter of PivotCache.CreatePivotTable method.
   • Description: Specifies the cell in the upper-left corner of the cell range where the Pivot Table you create is located.

     If you use the statement structure specified within this VBA Tutorial and explicitly declare a variable to represent DestinationRangeAddress, use the String data type. Within this structure, TableDestination is specified as follows:

     • DestinationWorkbook.Name: Workbook.Name property.

       Returns a string representing the name of DestinationWorkbook. DestinationWorkbook is the new workbook where the Pivot Table you create is located.

     • DestinationWorkbook.Worksheets(1).Name: Workbook.Worksheets property and Worksheet.Name property.

       The Workbook.Worksheets property (DestinationWorkbook.Worksheets(1)) returns a Worksheet object representing the first worksheet (Worksheets(1)) of DestinationWorkbook. The Worksheet.Name property returns a string representing the name of that worksheet, which is where the Pivot Table you create is located.

     • DestinationRangeAddress: Address of the cell in the upper-left corner of the cell range where the Pivot Table you create is located.

       If necessary, use the Range.Address property to return a string representing the cell range reference.

     • &: Concatenation operator.
8. Item: TableName:=”NewPivotTable”
   • VBA Construct: TableName parameter of the PivotCache.CreatePivotTable method.
   • Description: Specifies the name of the Pivot Table you create as “NewPivotTable”.

     If you explicitly declare a variable to represent NewPivotTable, use the String data type and omit the quotes included above (” “).

Macro Example

The following macro creates a new Pivot Table in a new workbook.

Sub createPivotTableNewWorkbook()

    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/vba-create-pivot-table/

    'declare variables to hold row and column numbers that define source data cell range
    Dim myFirstRow As Long
    Dim myLastRow As Long
    Dim myFirstColumn As Long
    Dim myLastColumn As Long

    'declare variables to hold source and destination cell range address
    Dim mySourceData As String
    Dim myDestinationRange As String

    'declare object variables to hold references to destination workbook, source and destination worksheets, and new Pivot Table
    Dim myDestinationWorkbook As Workbook
    Dim mySourceWorksheet As Worksheet
    Dim myDestinationWorksheet As Worksheet
    Dim myPivotTable As PivotTable

    'add and identify destination worksheet
    Set myDestinationWorkbook = Workbooks.Add

    'identify source and destination worksheets
    Set mySourceWorksheet = ThisWorkbook.Worksheets("Data")
    Set myDestinationWorksheet = myDestinationWorkbook.Worksheets(1)

    'obtain address of destination cell range
    myDestinationRange = myDestinationWorksheet.Range("A5").Address(ReferenceStyle:=xlR1C1)

    'identify row and column numbers that define source data cell range
    myFirstRow = 5
    myLastRow = 20005
    myFirstColumn = 1
    myLastColumn = 6

    'obtain address of source data cell range
    With mySourceWorksheet.Cells
        mySourceData = .Range(.Cells(myFirstRow, myFirstColumn), .Cells(myLastRow, myLastColumn)).Address(ReferenceStyle:=xlR1C1)
    End With

    'create Pivot Table cache and create Pivot Table report based on that cache
    Set myPivotTable = myDestinationWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:="[" & ThisWorkbook.Name & "]" & mySourceWorksheet.Name & "!" & mySourceData).CreatePivotTable(TableDestination:="[" & myDestinationWorkbook.Name & "]" & myDestinationWorksheet.Name & "!" & myDestinationRange, TableName:="PivotTableNewWorkbook")

    'add, organize and format Pivot Table fields
    With myPivotTable
        .PivotFields("Item").Orientation = xlRowField
        With .PivotFields("Units Sold")
            .Orientation = xlDataField
            .Position = 1
            .Function = xlSum
            .NumberFormat = "#,##0.00"
        End With
        With .PivotFields("Sales Amount")
            .Orientation = xlDataField
            .Position = 2
            .Function = xlSum
            .NumberFormat = "#,##0.00"
        End With
    End With

End Sub

Effects of Executing Macro Example

The following GIF illustrates the results of executing this macro example. As expected, the macro creates a Pivot Table in a new workbook.

#4: Create Pivot Table from Dynamic Range

VBA Code to Create Pivot Table from Dynamic Range

To create a Pivot Table from a dynamic range (where the number of the last row and last column may vary) with VBA, use a macro with the following statement structure:

Dim LastRow As Long
Dim LastColumn As Long
Dim SourceDataAddress As String
With SourceWorksheet.Cells
LastRow = .Find(What:="*", LookIn:=xlFormulas, LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
LastColumn = .Find(What:="*", LookIn:=xlFormulas, LookAt:=xlPart, SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column
SourceDataAddress = .Range(.Cells(1, 1), .Cells(LastRow, LastColumn)).Address(ReferenceStyle:=xlR1C1)
End With
Workbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=SourceWorksheetName & "!" & SourceDataAddress).createPivotTable TableDestination:=DestinationWorksheetName & "!" & DestinationRangeAddress, TableName:="NewPivotTable"

Process Followed by VBA Code

VBA Statement Explanation

Line #1: Dim LastRow As Long

1. Item: Dim LastRow As Long.
   • VBA Construct: Dim statement.
   • Description: Declares the LastRow variable as of the Long data type.

     LastRow holds the number of the last row with data in the worksheet containing the source data (SourceWorksheet).

Line #2: Dim LastColumn As Long

1. Item: Dim LastColumn As Long.
   • VBA Construct: Dim statement.
   • Description: Declares the LastColumn variable as of the Long data type.

     LastColumn holds the number of the last column with data in the worksheet containing the source data (SourceWorksheet).

Line #3: Dim SourceDataAddress As String

1. Item: Dim SourceDataAddress As String.
   • VBA Construct: Dim statement.
   • Description: Declares the SourceDataAddress variable as of the String data type.

     SourceDataAddress holds the address of the cell range containing the source data.

Lines #4 and #8: With SourceWorksheet.Cells | End With

1. Item: With… End With.
   • VBA Construct: With… End With statement.
   • Description: Statements within the With… End With statement (lines #5 through #7 below) are executed on the Range object returned by SourceWorksheet.Cells.
2. Item: SourceWorksheet.
   • VBA Construct: Worksheet object.
   • Description: Represents the worksheet containing the source data. If you explicitly declare an object variable to represent SourceWorksheet, use the Worksheet object data type.
3. Item: Cells.
   • VBA Construct: Worksheets.Cells property.
   • Description: Returns a Range object representing all the cells in SourceWorksheet.

Line #5: LastRow = .Find(What:=”*”, LookIn:=xlFormulas, LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row

1. Item: LastRow.
   • VBA Construct: Variable of the long data type.
   • Description: LastRow holds the number of the last row with data in SourceWorksheet.
2. Item: =.
   • VBA Construct: Assignment operator.
   • Description: Assigns the row number returned by the Range.Row property to the LastRow variable.
3. Item: Find.
   • VBA Construct: Range.Find method.
   • Description: Returns a Range object representing the first cell where the information specified by the parameters of the Range.Find method (What, LookIn, LookAt, SearchOrder and SearchDirection) is found. Within this macro structure, this Range object represents the last cell with data in the last row with data in SourceWorksheet.
4. Item: What:=”*”.
   • VBA Construct: What parameter of the Range.Find method.
   • Description: Specifies the data the Range.Find method searches for. The asterisk (*) is a wildcard and, therefore, the Range.Find method searches for any character sequence.
5. Item: LookIn:=xlFormulas.
   • VBA Construct: LookIn parameter of the Range.Find method.
   • Description: Specifies that the Range.Find method looks in formulas (xlFormulas).
6. Item: LookAt:=xlPart.
   • VBA Construct: LookAt parameter of the Range.Find method.
   • Description: Specifies that the Range.Find method looks at (and matches) a part (xlPart) of the search data.
7. Item: SearchOrder:=xlByRows.
   • VBA Construct: SearchOrder parameter of the Range.Find method.
   • Description: Specifies that the Range.Find method searches by rows (xlByRows).
8. Item: SearchDirection:=xlPrevious.
   • VBA Construct: SearchDirection parameter of the Range.Find method.
   • Description: Specifies that the Range.Find method searches for the previous match (xlPrevious).
9. Item: Row.
   • VBA Construct: Range.Row property.
   • Description: Returns the row number of the Range object returned by the Range.Find method. Within this macro structure, this row number corresponds to the last row with data in SourceWorksheet.

Line #6: LastColumn = .Find(What:=”*”, LookIn:=xlFormulas, LookAt:=xlPart, SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column

1. Item: LastColumn.
   • VBA Construct: Variable of the long data type.
   • Description: Variable of the long data type.

     LastColumn holds the number of the last column with data in SourceWorksheet.

2. Item: =.
   • VBA Construct: Assignment operator.
   • Description: Assigns the column number returned by the Range.Column property to the LastColumn variable.
3. Item: Find.
   • VBA Construct: Range.Find method.
   • Description: Returns a Range object representing the first cell where the information specified by the parameters of the Range.Find method (What, LookIn, LookAt, SearchOrder and SearchDirection) is found. Within this macro structure, this Range object represents the last cell with data in the last column with data in SourceWorksheet.
4. Item: What:=”*”.
   • VBA Construct: What parameter of the Range.Find method.
   • Description: Specifies the data the Range.Find method searches for. The asterisk (*) is a wildcard and, therefore, the Range.Find method searches for any character sequence.
5. Item: LookIn:=xlFormulas.
   • VBA Construct: LookIn parameter of the Range.Find method.
   • Description: Specifies that the Range.Find method looks in formulas (xlFormulas).
6. Item: LookAt:=xlPart.
   • VBA Construct: LookAt parameter of the Range.Find method.
   • Description: Specifies that the Range.Find method looks at (and matches) a part (xlPart) of the search data.
7. Item: SearchOrder:=xlByColumns.
   • VBA Construct: SearchOrder parameter of the Range.Find method.
   • Description: Specifies that the Range.Find method searches by columns (xlByColumns).
8. Item: SearchDirection:=xlPrevious.
   • VBA Construct: SearchDirection parameter of the Range.Find method.
   • Description: Specifies that the Range.Find method searches for the previous match (xlPrevious).
9. Item: Column.
   • VBA Construct: Range.Column property.
   • Description: Returns the column number of the Range object returned by the Range.Find method. Within this macro structure, this column number corresponds to the last column with data in SourceWorksheet.

Line #7: SourceDataAddress = .Range(.Cells(1, 1), .Cells(LastRow, LastColumn)).Address(ReferenceStyle:=xlR1C1)

1. Item: SourceDataAddress.
   • VBA Construct: Variable of the String data type.
   • Description: SourceDataAddress holds the address of the cell range containing the source data.
2. Item: =.
   • VBA Construct: Assignment operator.
   • Description: Assigns the string returned by the Range.Address property to the SourceDataAddress variable.
3. Item: Range.
   • VBA Construct: Range.Range property.
   • Description: Returns a Range object representing the cell range containing the source data. Within this macro structure, the Range property is applied to the Range object returned by the Worksheet.Cells property in the opening statement of the With… End With statement (line #4 above).
4. Item: Cells(1, 1).
   • VBA Construct: Cells1 parameter of the Range.Range property, Range.Cells property and Range.Item property.
   • Description: The Cells1 parameter of the Range.Range property specifies the cell in the upper-left corner of the cell range. Within this macro structure, Cells1 is the Range object returned by the Range.Cells property.

     The Range.Cells property returns all the cells within the cell range represented by the Range object returned by the Worksheet.Cells property in the opening statement of the With… End With statement (line #4 above). The Range.Item property is the default property and returns a Range object representing the cell on the first row and first column (Cells(1, 1)) of the cell range it works with.

     Since the Worksheet.Cells property in line #4 above returns all the cells in SourceWorksheet, this is cell A1 of SourceWorksheet.

5. Item: Cells(LastRow, LastColumn).
   • VBA Construct: Cells2 parameter of the Range.Range property, Range.Cells property and Range.Item property.
   • Description: The Cells2 parameter of the Range.Range property specifies the cells in the lower-right corner of the cell range. Within this macro structure, Cells2 is the Range object returned by the Range.Cells property.

     The Range.Cells property returns all the cells within the cell range represented by the Range object returned by the Worksheet.Cells property in the opening statement of the With… End With statement (line #4 above). The Range.Item property is the default property and returns a Range object representing the cell located at the intersection of LastRow and LastColumn.

     Since the Worksheet.Cells property in line #4 above returns all the cells in SourceWorksheet, this is the cell located at the intersection of the last row and the last column (or the last cell with data) within SourceWorksheet.

6. Item: Address.
   • VBA Construct: Range.Address property.
   • Description: Returns a string representing the cell range reference to the Range object returned by the Range.Range property.
7. Item: ReferenceStyle:=xlR1C1.
   • VBA Construct: ReferenceStyle parameter of the Range.Address property.
   • Description: Specifies that the cell range reference returned by the Range.Address property is in the R1C1 reference style.

Line #9: Workbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=SourceWorksheetName & “!” & SourceDataAddress).createPivotTable TableDestination:=DestinationWorksheetName & “!” & DestinationRangeAddress, TableName:=”NewPivotTable”

1. Item: Workbook.
   • VBA Construct: Workbook object.
   • Description: Represents the Excel workbook containing the source (SourceWorksheet) and destination worksheets (DestinationWorksheet) you work with. For purposes of this structure, both the source and destination worksheet are in the same workbook.

     Use properties such Application.Workbooks, Application.ThisWorkbook and Application.ActiveWorkbook to return this Workbook object.

2. Item: PivotCaches
   • VBA Construct: Workbook.PivotCaches method.
   • Description: Returns the PivotCaches collection representing all the Pivot Table caches within Workbook.
3. Item: Create.
   • VBA Construct: PivotCaches.Create method.
   • Description: Creates a new PivotCache object representing the memory cache for the Pivot Table you create.
4. Item: SourceType:=xlDatabase
   • VBA Construct: SourceType parameter of the PivotCaches.Create method.
   • Description: Sets the data source of the Pivot Table you create to an Excel list or database (xlDatabase).

     Use the constants within the xlPivotTableSourceType enumeration for purposes of specifying a different data source. Nonetheless, setting SourceType to xlPivotTable (representing the same data source as another Pivot Table) or xlScenario (representing scenarios created using the Scenario Manager) generally results in a run-time error.

5. Item: SourceData:=SourceWorksheetName & “!” & SourceDataAddress.
   • VBA Construct: SourceData parameter of the PivotCaches.Create method.
   • Description: Specifies the data source for the Pivot Table cache.

     If you use the statement structure specified within this VBA Tutorial and explicitly declare variables to represent SourceWorksheetName and SourceDataAddress, use the String data type. Within this structure, SourceData is specified as follows:

     • SourceWorksheetName: Name of the worksheet containing the source data.

       If necessary, use the Worksheet.Name property to return a string representing the worksheet’s name.

     • &: Concatenation operator.
     • SourceDataAddress: Variable of the String data type.

       SourceDataAddress holds the address of the cell range containing the source data.

6. Item: createPivotTable
   • VBA Construct: PivotCache.CreatePivotTable method.
   • Description: Creates a Pivot Table based on the PivotCache created by the PivotCaches.Create method.
7. Item: TableDestination:=DestinationWorksheetName & “!” & DestinationRangeAddress
   • VBA Construct: TableDestination parameter of PivotCache.CreatePivotTable method.
   • Description: Specifies the cell in the upper-left corner of the cell range where the Pivot Table you create is located.

     If you use the statement structure specified within this VBA Tutorial and explicitly declare variables to represent DestinationWorksheetName and DestinationRangeAddress, use the String data type. Within this structure, TableDestination is specified as follows:

     • DestinationWorksheetName: Name of the destination worksheet where the Pivot Table you create is located.

       If necessary, use the Worksheet.Name property to return a string representing the worksheet’s name.

     • &: Concatenation operator.
     • DestinationRangeAddress: Address of the cell in the upper-left corner of the cell range where the Pivot Table you create is located.

       If necessary, use the Range.Address property to return a string representing the cell range reference.

8. Item: TableName:=”NewPivotTable”
   • VBA Construct: TableName parameter of the PivotCache.CreatePivotTable method.
   • Description: Specifies the name of the Pivot Table you create as “NewPivotTable”.

     If you explicitly declare a variable to represent NewPivotTable, use the String data type and omit the quotes included above (” “).

Macro Example

The macro below creates a new Pivot Table from a dynamic range, where the last row and column is dynamically identified.

Sub createPivotTableDynamicRange()

    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/vba-create-pivot-table/

    'declare variables to hold row and column numbers that define source data cell range
    Dim myFirstRow As Long
    Dim myLastRow As Long
    Dim myFirstColumn As Long
    Dim myLastColumn As Long

    'declare variables to hold source and destination cell range address
    Dim mySourceData As String
    Dim myDestinationRange As String

    'declare object variables to hold references to source and destination worksheets, and new Pivot Table
    Dim mySourceWorksheet As Worksheet
    Dim myDestinationWorksheet As Worksheet
    Dim myPivotTable As PivotTable

    'identify source and destination worksheets
    With ThisWorkbook
        Set mySourceWorksheet = .Worksheets("Data")
        Set myDestinationWorksheet = .Worksheets("DynamicRange")
    End With

    'obtain address of destination cell range
    myDestinationRange = myDestinationWorksheet.Range("A5").Address(ReferenceStyle:=xlR1C1)

    'identify first row and first column of source data cell range
    myFirstRow = 5
    myFirstColumn = 1

    With mySourceWorksheet.Cells

        'find last row and last column of source data cell range
        myLastRow = .Find(What:="*", LookIn:=xlFormulas, LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
        myLastColumn = .Find(What:="*", LookIn:=xlFormulas, LookAt:=xlPart, SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column

        'obtain address of source data cell range
        mySourceData = .Range(.Cells(myFirstRow, myFirstColumn), .Cells(myLastRow, myLastColumn)).Address(ReferenceStyle:=xlR1C1)

    End With

    'create Pivot Table cache and create Pivot Table report based on that cache
    Set myPivotTable = ThisWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=mySourceWorksheet.Name & "!" & mySourceData).CreatePivotTable(TableDestination:=myDestinationWorksheet.Name & "!" & myDestinationRange, TableName:="PivotTableExistingSheet")

    'add, organize and format Pivot Table fields
    With myPivotTable
        .PivotFields("Item").Orientation = xlRowField
        With .PivotFields("Units Sold")
            .Orientation = xlDataField
            .Position = 1
            .Function = xlSum
            .NumberFormat = "#,##0.00"
        End With
        With .PivotFields("Sales Amount")
            .Orientation = xlDataField
            .Position = 2
            .Function = xlSum
            .NumberFormat = "#,##0.00"
        End With
    End With

End Sub

Effects of Executing Macro Example

The following GIF illustrates the results of executing this macro example. As expected, the macro creates a Pivot Table from a dynamic range.