Excel vba code list

With macros, we can automate Excel and save time; big tasks or small tasks, it doesn’t matter.  All that matters is that we’ve become more efficient.

In this post, I share 30 of the most useful VBA codes for Excel that you can use today.

If you’ve never used VBA before, that’s fine.  Part 1 contains instructions of how to use the codes and part 2 contains the code sample themselves.

Download the eBook

Get our FREE VBA eBook of the 30 most useful Excel VBA macros.

Claim your free eBook

PART ONE: How to use VBA Macros

What is VBA?

Visual Basic for Applications (VBA) is the programming language created by Microsoft to control parts of their applications. Most things which you can do with the mouse or keyboard in the Microsoft Office suite, you can also do using VBA. For example, in Excel, you can create a chart; you can also create a chart using VBA, it is just another method of achieving the same thing.

Advantages of using VBA

Since VBA code can do the same things as we could with the mouse or keyboard, why bother to use VBA at all?

Saves time:

VBA code will operate at the speed your computer will allow, which is still significantly faster than you can operate. For example, if you have to open 10 workbooks, print the documents, then close the workbook, it might take you 2 minutes with a mouse and keyboard, but with VBA it could take seconds.

Reduces errors:

Do you ever click the wrong icons or type the wrong words? Me too, but VBA doesn’t. It will do the same task over and over again, without making any errors. Don’t get me wrong, you still have to program the VBA code correctly. If you tell it to do the wrong things 10 times, then it will. But if we can get it right, then it can remove the errors created by human interaction.

Completes repetitive actions without complaining:

Have you ever had to carry out the same action many times? Maybe creating 100 charts, or printing 100 documents, or changing the heading on 100 spreadsheets. That’s not fun, nobody wants to do that. But VBA is more than happy to do it for you. It can do the same thing in a repetitive way (without complaining). In fact, repetitive tasks is one of the things VBA does best.

Integration with other applications:

You can use VBA in Word, Access, Excel, Outlook and many other programs, including Windows itself. But it doesn’t end there, you can use VBA in Excel to control Word and PowerPoint, without even needing to open those applications.

What is programming?

Programming is simply writing words in a way which a computer can understand. However, computers are not particularly flexible, so we have to be very specific about what we want the computer to do, and how we tell it to do it. The skill of programming is learning how to convey the request to the computer as clearly, as simply and as efficiently as possible.

What is the difference between a Macro and VBA?

This is a common question which can be confusing. Put simply, VBA is the language used to write a macro – just in the same way as a paragraph might be written using the English language.

The terms ‘macro’ and ‘VBA’ are often used interchangeably.

The golden rule of learning VBA

If you are still learning to write VBA, there is one thing which will help you. While it may be common practice, to copy and paste code, it will not help you to learn VBA quickly. Here is the one rule I am going to ask you to stick to… type out the code yourself.

Why am I asking you to do this? Because it will help you learn the VBA language much faster.

Let’s get started

Now you know what VBA is, why you should use it, and the golden rule, so there is only one thing left to do… let’s get started!

Setting up Excel

Before you can get stuck in with using the code in this post, you must first have Excel set up correctly. This involves:

1. Ensuring the correct macro security settings have been applied
2. Enabling the Developer ribbon.

Macro security settings

Macros can be used for malicious purposes, such as installing a virus, recording key-strokes, etc. This can be blocked with the security settings. However, if the settings are set too high, you cannot run any macros, or too low, you will not be protected. Neither of these is a good option.

Let’s apply suitable settings which will give you the power to decide when to allow macros or not.

1. In Excel, click File > Options
2.  In the Excel Options dialog box, click Trust Centre > Trust Centre Settings…
3. In the Trust Centre dialog box, click Macro Settings > Disable all macros with notification.
   
   
4. Click OK to close the Trust Centre, then OK again to close the Excel Options.

Workbooks containing macros will now be automatically disabled until you click the Enable Content button at the top of the screen.

Enable the Developer ribbon

The Developer ribbon is the place where all the VBA tools are kept. It is unlikely that this is already enabled, unless you or your IT department have already done so.

Look at the top of your Excel Window if you see the word ‘Developer’ in the menu options, then you are ready to go. You can skip straight ahead to the next part. However, if the ‘Developer’ ribbon is not there, just follow these instructions.

1. In Excel, click File > Options
2. In the Excel Options dialog box, click Customize Ribbon
3. Ensure the Developer option is checked
   
4. Click OK to close the Excel Options

The Developer ribbon should now be visible at the top of the Excel window.

File format for macro enabled files

To save a workbook containing a macro, the standard .xlsx format will not work.

Generally, the .xlsm (Excel Macro-Enabled Workbook) file format should be used for workbooks containing macros. However .xlam (Excel Add-in), .xlsb (Excel Binary Workbook) and .xltx (Excel Macro-Enabled Template) are scenario specific formats which can also contain macros.

The legacy .xls and .xla file formats can both contain macros. They were superseded in 2007, and should now be avoided.

The basic rule is… if you don’t know, go for .xlsm.

Personal macro workbook

If we want macros to be reusable for many workbooks, often the best place to save them is in the personal macro workbook.

A personal macro workbook is a hidden file which opens whenever the Excel application opens.

How to create a personal macro workbook?

A personal macro workbook does not exist by default; we have to create it. There are many ways to do this, but the easiest is to let Excel do it for us.

1. In the ribbon, click Developer > Record Macro.
   
2. In the Record Macro dialog box, select Personal Macro Workbook from the drop-down list.
   
3. Click OK.
4. Do anything in Excel, such as typing your name into cell A1.
5. Click Developer > Stop Recording
   
   
6. Close all the open workbooks in Excel, this will force the personal macro workbook to be saved. A warning message will appear, click Save.
   

In the next part, we will learn how to use the Visual Basic Editor, which gives us access to the personal macro workbook.

Using the Visual Basic Editor

The Visual Basic Editor (or VBE as it can be known) is the place where we enter or edit VBA code. The Visual Basic Editor is found within the Developer Ribbon

In Excel, click Developer > Visual Basic to open the VBE.

Alternatively, you could use the keyboard; press ALT+F11 (the + indicates that you should hold down the ALT key, press F11, then release the ALT key), which toggles between the Excel window and the VBE.

The Visual Basic Editor Window

The Visual Basic Editor contains four main sections.

Within the top left of the VBE, we will see a list of items which can contain VBA code (known as the project window)

Double-clicking any sheet name, workbook or module, will open the code window associated with that item. VBA code is entered into the code window.

Unless you have specific reasons, the best option is to enter the macro into a module. To create a module, click Insert > Module within the VBE.

Running a macro

There are many ways to run VBA code. This section is not exhaustive, but is intended to provide an overview of the most common methods.

Running a macro from within Visual Basic Editor

When testing VBA code, it is common to execute that code from the VBE.

Click anywhere within the code, between the Sub and End Sub lines, choose one of the following options:

1. Click Run > Run Sub/UserForm from the menu at the top of the VBE
2. Using the keyboard, you can press ALT+F5
3. Click the play button at the top of the VBE
   

The code you entered will be executed.

Running a macro from within Excel

Once the code has been tested and in working order, it is common to execute it directly within Excel. There are lots of options for this too (including events, or user defined functions), however the three most common methods I will show you are:

Run from the Macro window

1. Click View > Macros or Developer > Macros
   
   
2. Select the macro from the list and click Run.
   

Create a custom ribbon

Having macros always available in the ribbon is a great time saver. Therefore, learning how to customize the ribbon is useful.

1. In Excel, click File > Options
2. In the Excel Options dialog box, click Customize Ribbon
3. Click New Tab to create a new ribbon tab, then click New Group to create a section within the new tab.
4. In the Choose commands from drop-down, select Macros. Select your macro and click
   Add >> to move the macro it into your new group.
5. Use the Rename… button to give the tab, group or macro a more useful name.
   
6. Click OK to close the window.
7. The new ribbon menu will appear containing your macro. Click the button to run the macro.
   

Create a button/shape on a worksheet

Macros can be executed using buttons or shapes on the worksheet.

1. To create a button, click Developer > Insert > Form Control > Button
2. Draw a shape on the worksheet to show the location and size of the button
3. The Assign Macro dialog will appear, select the macro and click OK.
   
4. The button will appear. Clicking the button will run the macro
   
5. Right-click on the button to change the description

To assign a different macro, right-click on the button and select Assign Macro… from the menu.

Alternatively, a macro can be assigned to a shape. After creating a shape, right-click on it and select Assign Macro… from the menu, then follow the same process as for a button.

Hide all selected sheets

What does it do?

Hides all the selected sheets.

VBA code

Sub HideAllSelectedSheets()

'Create variable to hold worksheets
Dim ws As Worksheet

'Ignore error if trying to hide the last worksheet
On Error Resume Next

'Loop through each worksheet in the active workbook
For Each ws In ActiveWindow.SelectedSheets

    'Hide each sheet
    ws.Visible = xlSheetHidden

Next ws

'Allow errors to appear
On Error GoTo 0

End Sub

Notes:

Excel requires at least one active worksheet. If all the visible sheets are selected, to avoid an error, the VBA code will not hide the last sheet.

For other examples of hiding worksheets check out these posts:

• Macro to hide all sheets except one
• Hide all sheets except one with Office Scripts

Unhide all sheets

What does it do?

Makes all worksheets visible.

VBA code

Sub UnhideAllWorksheets()

'Create variable to hold worksheets
Dim ws As Worksheet

'Loop through each worksheet in the active workbook
For Each ws In ActiveWorkbook.Worksheets

    'Unhide each sheet
    ws.Visible = xlSheetVisible

Next ws

End Sub

Protect all selected worksheets

What does it do?

Protects all the selected worksheets with a password determined by the user.

VBA code

Sub ProtectSelectedWorksheets()

Dim ws As Worksheet
Dim sheetArray As Variant
Dim myPassword As Variant

'Set the password
myPassword = Application.InputBox(prompt:="Enter password", _
    Title:="Password", Type:=2)

'The User clicked Cancel
If myPassword = False Then Exit Sub

'Capture the selected sheets
Set sheetArray = ActiveWindow.SelectedSheets

'Loop through each worksheet in the active workbook
For Each ws In sheetArray

    On Error Resume Next

    'Select the worksheet
    ws.Select

    'Protect each worksheet
    ws.Protect Password:=myPassword

    On Error GoTo 0

Next ws

sheetArray.Select

End Sub

Unprotect all worksheets

What does it do?

Unprotects all worksheets with a password determined by the user.

VBA code

Sub UnprotectAllWorksheets()

'Create a variable to hold worksheets
Dim ws As Worksheet

'Create a variable to hold the password
Dim myPassword As Variant

'Set the password
myPassword = Application.InputBox(prompt:="Enter password", _
    Title:="Password", Type:=2)

'The User clicked Cancel
If myPassword = False Then Exit Sub

'Loop through each worksheet in the active workbook
For Each ws In ActiveWindow.SelectedSheets

    'Protect each worksheet
    ws.Unprotect Password:=myPassword

Next ws

End Sub

Lock cells containing formulas

What does it do?

Password protects a single worksheet with cells containing formulas locked, all other cells are unlocked.

VBA code

Sub LockOnlyCellsWithFormulas()

'Create a variable to hold the password
Dim myPassword As Variant

'If more than one worksheet selected exit the macro
If ActiveWindow.SelectedSheets.Count > 1 Then

    'Display error message and exit macro
    MsgBox "Select one worksheet and try again"
    Exit Sub

End If

'Set the password
myPassword = Application.InputBox(prompt:="Enter password", _
    Title:="Password", Type:=2)

'The User clicked Cancel
If myPassword = False Then Exit Sub

'All the following to apply to active sheet
With ActiveSheet

    'Ignore errors caused by incorrect passwords
    On Error Resume Next

    'Unprotect the active sheet
    .Unprotect Password:=myPassword

    'If error occured then exit macro
    If Err.Number <> 0 Then

        'Display message then exit
        MsgBox "Incorrect password"
        Exit Sub

    End If

    'Turn error checking back on
    On Error GoTo 0

    'Remove lock setting from all cells
    .Cells.Locked = False

    'Add lock setting to all cells
    .Cells.SpecialCells(xlCellTypeFormulas).Locked = True

    'Protect the active sheet
    .Protect Password:=myPassword

    End With

End Sub

Hide formulas when protected

What does it do?

When the active sheet is protected, formulas will not be visible in the formula bar. Uses a predefined password of mypassword.

VBA code

Sub HideFormulasWhenProtected()

'Create a variable to hold the password
Dim myPassword As String

'Set the password
myPassword = "myPassword"

'All the following to apply to active sheet
With ActiveSheet

    'Unprotect the active sheet
    .Unprotect Password:=myPassword

    'Hide formulas in all cells
    .Cells.FormulaHidden = True

    'Protect the active sheet
    .Protect Password:=myPassword

End With

End Sub

Save time stamped backup file

What does it do?

Save a backup copy of the workbook with a time stamp.

VBA code

Sub SaveTimeStampedBackup()

'Create variable to hold the new file path
Dim saveAsName As String

'Set the file path
saveAsName = ActiveWorkbook.Path & "" & _
Format(Now, "yymmdd-hhmmss") & " " & ActiveWorkbook.Name

'Save the workbook
ActiveWorkbook.SaveCopyAs Filename:=saveAsName

End Sub

Prepare workbook for saving

What does it do?

The macro will, for each worksheet:

• Close all group outlining
• Set the view to the normal view
• Remove gridlines
• Hide all row numbers and column numbers
• Select cell A1

The first sheet is selected.

After running the macro, every worksheet in the workbook will be in a tidy state for the next use.

VBA code

Sub PrepareWorkbookForSaving()

'Declare the worksheet variable
Dim ws As Worksheet

'Loop through each worksheet in the active workbook
For Each ws In ActiveWorkbook.Worksheets

    'Activate each sheet
    ws.Activate

    'Close all of groups
    ws.Outline.ShowLevels RowLevels:=1, ColumnLevels:=1

    'Set the view settings to normal
    ActiveWindow.View = xlNormalView

    'Remove the gridlines
    ActiveWindow.DisplayGridlines = False

    'Remove the headings on each of the worksheets
    ActiveWindow.DisplayHeadings = False

    'Get worksheet to display top left
    ws.Cells(1, 1).Select
Next ws

'Find the first visible worksheet and select it
For Each ws In Worksheets

    If ws.Visible = xlSheetVisible Then

        'Select the first visible worksheet
        ws.Select

        'Once the first visible worksheet is found exit the sub
        Exit For

    End If

Next ws

End Sub

Convert merged cells to center across

What does it do?

Changes all single row merged cells into center across formatting.

VBA code

Sub ConvertMergedCellsToCenterAcross()

Dim c As Range
Dim mergedRange As Range

'Loop through all cells in Used range
For Each c In ActiveSheet.UsedRange

    'If merged and single row
    If c.MergeCells = True And c.MergeArea.Rows.Count = 1 Then

        'Set variable for the merged range
        Set mergedRange = c.MergeArea

        'Unmerge the cell and apply Centre Across Selection
        mergedRange.UnMerge
        mergedRange.HorizontalAlignment = xlCenterAcrossSelection

    End If

Next

End Sub

Fit selection to screen

What does it do?

Zoom the screen on the selected cells.

VBA code

Sub FitSelectionToScreen()

'To zoom to a specific area, then select the cells
Range("A1:I15").Select

'Zoom to selection
ActiveWindow.Zoom = True

'Select first cell on worksheet
Range("A1").Select

End Sub

Flip number signage on selected cells

What does it do?

Flips the number signage of all numeric values in the selected cells

VBA code

Sub FlipNumberSignage()

'Create variable to hold cells in the worksheet
Dim c As Range

'Loop through each cell in selection
For Each c In Selection

    'Test if the cell contents is a number
    If IsNumeric(c) Then

        'Convert signage for each cell
        c.Value = -c.Value

    End If

Next c

End Sub

Clear all data cells

What does it do?

Clears all cells in the selection which are constants (i.e. not formulas).

VBA code

Sub ClearAllDataCellsInSelection()

'Clear all hardcoded values in the selected range
Selection.SpecialCells(xlCellTypeConstants).ClearContents

End Sub

Add prefix to each cell in selection

What does it do?

Adds a prefix to each cell in the selected cells (excludes formulas and blanks).

VBA code

Sub AddPrefix()

Dim c As Range
Dim prefixValue As Variant

'Display inputbox to collect prefix text
prefixValue = Application.InputBox(Prompt:="Enter prefix:", _
    Title:="Prefix", Type:=2)

'The User clicked Cancel
If prefixValue = False Then Exit Sub

For Each c In Selection

    'Add prefix where cell is not a formula or blank
    If Not c.HasFormula And c.Value <> "" Then

        c.Value = prefixValue & c.Value

    End If

Next

End Sub

Add suffix to each cell in selection

What does it do?

Adds a suffix to each value in the selected cells (excludes formulas and blanks).

VBA code

Sub AddSuffix()

Dim c As Range
Dim suffixValue As Variant

'Display inputbox to collect prefix text
suffixValue = Application.InputBox(Prompt:="Enter Suffix:", _
    Title:="Suffix", Type:=2)

'The User clicked Cancel
If suffixValue = False Then Exit Sub

    'Loop through each cellin selection
    For Each c In Selection

        'Add Suffix where cell is not a formula or blank
        If Not c.HasFormula And c.Value <> "" Then

            c.Value = c.Value & suffixValue

        End If

Next

End Sub

Reverse row order

What does it do?

Reverses the order of all rows of data in the selection.

VBA code

Sub ReverseRows()

'Create variables
Dim rng As Range
Dim rngArray As Variant
Dim tempRng As Variant
Dim i As Long
Dim j As Long
Dim k As Long

'Record the selected range and it's contents
Set rng = Selection
rngArray = rng.Formula

'Loop through all cells and create a temporary array
For j = 1 To UBound(rngArray, 2)
    k = UBound(rngArray, 1)
    For i = 1 To UBound(rngArray, 1) / 2
        tempRng = rngArray(i, j)
        rngArray(i, j) = rngArray(k, j)
        rngArray(k, j) = tempRng
        k = k - 1
    Next
Next

'Apply the array
rng.Formula = rngArray

End Sub

Reverse column order

What does it do?

Reverses the order of all column data in the selection.

VBA code

Sub ReverseColumns()

'Create variables
Dim rng As Range
Dim rngArray As Variant
Dim tempRng As Variant
Dim i As Long
Dim j As Long
Dim k As Long

'Record the selected range and it's contents
Set rng = Selection
rngArray = rng.Formula

'Loop through all cells and create a temporary array
For i = 1 To UBound(rngArray, 1)
    k = UBound(rngArray, 2)
    For j = 1 To UBound(rngArray, 2) / 2
        tempRng = rngArray(i, j)
        rngArray(i, j) = rngArray(i, k)
        rngArray(i, k) = tempRng
        k = k - 1
    Next
Next

'Apply the array
rng.Formula = rngArray

End Sub

Transpose selection

What does it do?

Transposes the selected cells with a single click.

VBA code

Sub TransposeSelection()

'Create variables
Dim rng As Range
Dim rngArray As Variant
Dim i As Long
Dim j As Long
Dim overflowRng As Range
Dim msgAns As Long

'Record the selected range and it's contents
Set rng = Selection
rngArray = rng.Formula

'Test the range and identify if any cells will be overwritten
If rng.Rows.Count > rng.Columns.Count Then

    Set overflowRng = rng.Cells(1, 1). _
        Offset(0, rng.Columns.Count). _
        Resize(rng.Columns.Count, _
        rng.Rows.Count - rng.Columns.Count)

ElseIf rng.Rows.Count < rng.Columns.Count Then

    Set overflowRng = rng.Cells(1, 1).Offset(rng.Rows.Count, 0). _
        Resize(rng.Columns.Count - rng.Rows.Count, rng.Rows.Count)

End If

If rng.Rows.Count <> rng.Columns.Count Then

    If Application.WorksheetFunction.CountA(overflowRng) > 0 Then

        msgAns = MsgBox("Worksheet data in " & overflowRng.Address & _
            " will be overwritten." & vbNewLine & _
            "Do you wish to continue?", vbYesNo)

    If msgAns = vbNo Then Exit Sub

    End If

End If

'Clear the rnage
rng.Clear

'Reapply the cells in transposted position
For i = 1 To UBound(rngArray, 1)

    For j = 1 To UBound(rngArray, 2)

        rng.Cells(1, 1).Offset(j - 1, i - 1) = rngArray(i, j)

    Next

Next

End Sub

Create red box around selected areas

What does it do?

Draws a rectangle shape to fit around the selected cells.

VBA code

Sub AddRedBox()

Dim redBox As Shape
Dim selectedAreas As Range
Dim i As Integer
Dim tempShape As Shape

'Loop through each selected area in active sheet
For Each selectedAreas In Selection.Areas

    'Create a rectangle
    Set redBox = ActiveSheet.Shapes.AddShape(msoShapeRectangle, _
        selectedAreas.Left, selectedAreas.Top, _
        selectedAreas.Width, selectedAreas.Height)

    'Change attributes of shape created
    redBox.Line.ForeColor.RGB = RGB(255, 0, 0)
    redBox.Line.Weight = 2
    redBox.Fill.Visible = msoFalse

    'Loop to find a unique shape name
    Do
        i = i + 1
        Set tempShape = Nothing

        On Error Resume Next
        Set tempShape = ActiveSheet.Shapes("RedBox_" & i)
        On Error GoTo 0

    Loop Until tempShape Is Nothing

    'Rename the shape
    redBox.Name = "RedBox_" & i

Next

End Sub

Delete all red boxes on active sheet

What does it do?

Having created the red boxes in the macro above. This code removes all the red boxes on the active sheet with a single click.

VBA code

Sub DeleteRedBox()

Dim shp As Shape

'Loop through each shape on active sheet
For Each shp In ActiveSheet.Shapes

    'Find shapes with a name starting with "RedBox_"
    If Left(shp.Name, 7) = "RedBox_" Then

        'Delete the shape
        shp.Delete

    End If

Next shp

End Sub

Save selected chart as an image

What does it do?

Saves the selected chart as a picture to the file location contained in the macro.

VBA code

Sub ExportSingleChartAsImage()

'Create a variable to hold the path and name of image
Dim imagePath As String
Dim cht As Chart

imagePath = "C:UsersmarksDocumentsmyImage.png"
Set cht = ActiveChart

'Export the chart
cht.Export (imagePath)

End Sub

Resize all charts to same as active chart

What does it do?

Select the chart with the dimensions you wish to use, then run the macro. All the charts will resize to the same dimensions.

VBA code

Sub ResizeAllCharts()

'Create variables to hold chart dimensions
Dim chtHeight As Long
Dim chtWidth As Long

'Create variable to loop through chart objects
Dim chtObj As ChartObject

'Get the size of the first selected chart
chtHeight = ActiveChart.Parent.Height
chtWidth = ActiveChart.Parent.Width

For Each chtObj In ActiveSheet.ChartObjects

    chtObj.Height = chtHeight
    chtObj.Width = chtWidth

Next chtObj

End Sub

Refresh all Pivot Tables in workbook

What does it do?

Refresh all the Pivot Tables in the active workbook.

VBA code

Sub RefreshAllPivotTables()

'Refresh all pivot tables
ActiveWorkbook.RefreshAll

End Sub

Turn off auto fit columns on all Pivot Tables

What does it do?

By default, PivotTables resize columns to fit the contents. This macro changes the setting for every PivotTable in the active workbook, so that column widths set by the user are maintained.

VBA code

Sub TurnOffAutofitColumns()

'Create a variable to hold worksheets
Dim ws As Worksheet

'Create a variable to hold pivot tables
Dim pvt As PivotTable

'Loop through each sheet in the activeworkbook
For Each ws In ActiveWorkbook.Worksheets

    'Loop through each pivot table in the worksheet
    For Each pvt In ws.PivotTables

        'Turn off auto fit columns on PivotTable
        pvt.HasAutoFormat = False

    Next pvt

Next ws

End Sub

Get color code from cell fill color

What does it do?

Returns the RGB and Hex for the active cell’s fill color.

VBA code

Sub GetColorCodeFromCellFill()

'Create variables hold the color data
Dim fillColor As Long
Dim R As Integer
Dim G As Integer
Dim B As Integer
Dim Hex As String

'Get the fill color
fillColor = ActiveCell.Interior.Color

'Convert fill color to RGB
R = (fillColor Mod 256)
G = (fillColor  256) Mod 256
B = (fillColor  65536) Mod 256

'Convert fill color to Hex
Hex = "#" & Application.WorksheetFunction.Dec2Hex(fillColor)

'Display fill color codes
MsgBox "Color codes for active cell" & vbNewLine & _
    "R:" & R & ", G:" & G & ", B:" & B & vbNewLine & _
    "Hex: " & Hex, Title:="Color Codes"

End Sub

Create a table of contents

What does it do?

Creates or refreshes a hyperlinked table of contents on a worksheet called “TOC”, which is placed at the start of a workbook.

VBA code

Sub CreateTableOfContents()

Dim i As Long
Dim TOCName As String

'Name of the Table of contents
TOCName = "TOC"

'Delete the existing Table of Contents sheet if it exists
On Error Resume Next
Application.DisplayAlerts = False
ActiveWorkbook.Sheets(TOCName).Delete
Application.DisplayAlerts = True
On Error GoTo 0

'Create a new worksheet
ActiveWorkbook.Sheets.Add before:=ActiveWorkbook.Worksheets(1)
ActiveSheet.Name = TOCName

'Loop through the worksheets
For i = 1 To Sheets.Count

    'Create the table of contents
    ActiveSheet.Hyperlinks.Add _
        Anchor:=ActiveSheet.Cells(i, 1), _
        Address:="", _
        SubAddress:="'" & Sheets(i).Name & "'!A1", _
        ScreenTip:=Sheets(i).Name, _
        TextToDisplay:=Sheets(i).Name

Next i

End Sub

Excel to speak the cell contents

What does it do?

Excel speaks back the contents of the selected cells

VBA code

Sub SpeakCellContents()

'Speak the selected cells
Selection.Speak

End Sub

Fix the range of cells which can be scrolled

What does it do?

Fixes the scroll range to the selected cell range. It prevents a user from scrolling into other parts of the worksheet.

If a single cell is selected, the scroll range is reset.

VBA code

Sub FixScrollRange()

If Selection.Cells.Count = 1 Then

    'If one cell selected, then reset
    ActiveSheet.ScrollArea = ""

Else

    'Set the scroll area to the selected cells
    ActiveSheet.ScrollArea = Selection.Address

End If

End Sub

Invert the sheet selection

What does it do?

Select some worksheet tabs, then run the macro to reverse the selection.

VBA code

Sub InvertSheetSelection()

'Create variable to hold list of selected worksheet
Dim selectedList As String

'Create variable to hold worksheets
Dim ws As Worksheet

'Create variable to switch after the first sheet selected
Dim firstSheet As Boolean

'Convert selected sheest to a text string
For Each ws In ActiveWindow.SelectedSheets
    selectedList = selectedList & ws.Name & "[|]"
Next ws

'Set the toggle of first sheet
firstSheet = True

'Loop through each worksheet in the active workbook
For Each ws In ActiveWorkbook.Sheets

    'Check if the worksheet was not previously selected
    If InStr(selectedList, ws.Name & "[|]") = 0 Then

        'Check the worksheet is visible
        If ws.Visible = xlSheetVisible Then

            'Select the sheet
            ws.Select firstSheet

            'First worksheet has been found, toggle to false
            firstSheet = False

        End If

    End If

Next ws

End Sub

Assign a macro to a shortcut key

What does it do?

Assigns a macro to a shortcut key.

VBA code

Sub AssignMacroToShortcut()

'+ = Ctrl
'^ = Shift
'{T} = the shortcut letter

Application.OnKey "+^{T}", "nameOfMacro"

'Reset shortcut to default - repeat without the name of the macro
'Application.OnKey "+%{T}"

End Sub

Apply single accounting underline to selection

What does it do?

Single accounting underline is a formatting style which is not available in the ribbon. The macro below applies single accounting underline to the selected cells.

VBA code

Sub SingleAccountingUnderline()

'Apply single accounting underline to selected cells
Selection.Font.Underline = xlUnderlineStyleSingleAccounting

End Sub

Excel macro codes can be used to automate regular Excel tasks and prevent you from performing them manually. This results in time saved and more reliable work.

This VBA code library is a list of useful VBA codes for Excel that you can start using immediately.

These codes are perfect for beginners who have not used Excel VBA before, or are just starting out.

Let us first describe what a macro code is and how you can start using them. Then we will get to the exciting part and explore the Excel macro examples in this list.

What is macro code?

Macro code refers to the VBA (Visual Basic for Applications) code for the macro.

You can create macros in Excel by either recording the steps you want it to perform (the VBA is written for you), or by writing the VBA yourself.

Writing this VBA or macro code yourself gives you far greater control over your macro.

The VBA code can be simple, and perform a basic formatting step or freeze panes. Or it could do something greater such as export all sheets of a workbook as a separate PDF.

This VBA code library provides a list of macro codes for you to copy and paste to get started.

This saves you from having to create them yourself, but is also a great way to begin learning VBA.

Show the Developer tab

To use the VBA codes, you will need access to the Developer tab.

If you do not have the Developer tab on your Ribbon, follow these steps to enable it.

1. Click File > Options.
2. Select the Customize Ribbon category and then check the box for the Developer tab.

1. Click Ok.

How to use the macro code

Using the macro codes require just a simple copy and paste. However, you need to ensure that you paste them to the correct place.

1. Click Developer > Visual Basic, or press Alt + F11.

The Visual Basic Editor opens. The Project Explorer window is shown on the left. It lists the open workbooks and other projects.

1. Click within the workbook where you want to insert the VBA code, click Insert > Module.

1. Copy and paste the code from this article into the code window.

The macro will then be available to run in the Macros window.

1. Click Developer > Macros. Select the macro from the list and click Run.

In this VBA code library, there is a category named Events. These macros will not be stored in modules, but in the object where the event occurs.

This will be explained when we present the code. The majority of the macros in this list are stored in modules and follow the procedure explained above.

Adding a button to trigger your macros

Although it is possible to run the macro from the macros window. Assigning the macro to a button that you can click, will make it easier to run your macros.

You can insert buttons on the Quick Access Toolbar (where the Save and Undo buttons reside), the Ribbon, or onto a worksheet.

The approach you take depends on what the macro does, and when you want to run it.

For this example, we will show you how to add a button to the Quick Access Toolbar to run your macros.

1. Click the Customize Quick Access Toolbar arrow and click More Commands.

1. Click the Popular Commands list arrow and select Macros. Select the macro you want and click Add.

1. Click the Modify button to change the image and the display name of the button.

The button will appear on the Quick Access Toolbar and will run your macro when clicked.

The display name is shown as you position your mouse over the button.

Excel VBA code examples

The macro code examples in this list have been split into categories to make it easier to find those that you are interested in using.

Common Excel tasks

• AutoFit column widths
• Copy and paste
• Clear all hyperlinks on a sheet
• Format cells with formulas
• Convert formulas to values

Worksheet codes

• Unhide all columns
• Protect a worksheet
• Loop through all the worksheets of a workbook

Workbook codes

• Unhide all worksheets
• Protect a workbook
• Opening and closing a workbook
• Email the active workbook with Outlook

Files and folders

• Export each worksheet as a single PDF
• Export the active sheet as a PDF
• Export multiple sheets to a single PDF
• Loop through all the files of a folder
• Selecting a file with a FileDialog

Useful Excel features

• Sorting columns
• Filter your data
• Create a chart

Events

• Go to a specific worksheet on Open
• Perform an action on Cell Change

A recap!

Common Excel tasks

These VBA codes will perform common Excel tasks quickly.

AutoFit column widths

This code will automatically fit the column widths for all the columns of the worksheet. 

Sub AutofitAllColumns()

Cells.EntireColumn.AutoFit

End Sub

This code will automatically fit the widths of specific columns on a worksheet. In this example, it is columns D and F.

Sub AutofitSpecificColumns()

Range("D:D,F:F").EntireColumn.AutoFit

End Sub

Copy and paste

Copy and paste is one of the most common actions in Excel. It can be written with just one line of VBA code.

The following code copies range A1:B6 into A1 of another worksheet.

Sub CopyAndPaste()

Range("A1:B6").Copy Worksheets("Sheet2").Range("A1")

End Sub

You may not have a specific range to paste the content into. Often you are trying to append the copied data to the bottom of another list.

This code copies the used range around cell A2 and pastes it to the first empty cell at the bottom of column A on a sheet named Archive.

Sub CopyAndPaste()

Range("A2").CurrentRegion.Copy Worksheets("Archive").Range("A1").End(xlDown).Offset(1, 0)

End Sub

Finally, you may want to use some of the paste special options available in Excel. To access these in VBA, we will separate the copy and paste operation into two statements.

This code uses the PasteSpecial method to paste the values only.

Sub CopyAndPasteValues()

Range("A1:B6").Copy
Worksheets("Sheet2").Range("A1").PasteSpecial Paste:=xlPasteValues

End Sub

Clear all hyperlinks on a sheet

The following macro code will clear all the hyperlinks on a worksheet.

Sub ClearHyperlinks()

ActiveSheet.Hyperlinks.Delete

End Sub

Format cells with formulas

Formatting cells that contain formulas makes them easy to identify on a worksheet. This macro code will format the formula cells with a yellow fill color (ColorIndex = 6).

It declares a range variable named rng and uses it to loop through each cell that contains a formula.

Sub FormatFormulas()

Dim rng As Range

For Each rng In Cells.SpecialCells(xlCellTypeFormulas)

rng.Interior.ColorIndex = 6

Next rng

End Sub

Convert formulas to values

Another common action with formulas is to convert them into values. This VBA code will do this for all formulas on the worksheet.

Sub ConvertFormulastoValues()

Dim rng As Range

For Each rng In Cells.SpecialCells(xlCellTypeFormulas)

rng.Formula = rng.Value

Next rng

End Sub

Worksheet codes

These codes will perform some typical worksheet tasks.

Unhide all columns

Hiding columns is great for reducing worksheet clutter and protecting data. This macro code will unhide all the hidden columns with the click of a button.

Sub UnhideAllColumns()

Columns.EntireColumn.Hidden = False

End Sub

Protect a worksheet

The following code will protect the active sheet.

Sub ProtectWS()

ActiveSheet.Protect

End Sub

You may want to take this further and assign a password or specify actions to be allowed. This macros code assigns the password Excel and allows the inserting of rows only.

If you know worksheet protection well, you will know that there are various actions that you can allow or prevent. And we can do this with our VBA code.

Sub ProtectWS()

ActiveSheet.Protect Password:=”Excel”, AllowInsertingRows:=True

End Sub

A common reason to protect a worksheet is to save your formulas from accidental damage. This code will protect only cells on a worksheet that contains formulas.

It begins by unprotecting the sheet and unlocking all cells. It then locks those containing formulas before applying protection.

Sub ProtectFormulas()

With ActiveSheet

.Unprotect
.Cells.Locked = False
.Cells.SpecialCells(xlCellTypeFormulas).Locked = True
.Protect

End With

End Sub

Loop through all the worksheets of a workbook

It is simple to set up a loop to perform an action to all the worksheets of a workbook. You can insert any action you require.

In this example, we protect the worksheets. Replace the line ws.Protect with the actions that you require. Use the variable ws when referencing the worksheet.

Sub LoopAllSheets()

Dim ws As Worksheet

For Each ws In ActiveWorkbook.Worksheets
ws.Protect
Next ws

End Sub

Workbook codes

The following codes will perform some common workbook tasks.

Unhide all worksheets

In Excel, you can only unhide one worksheet at a time. So, this code will unhide all the worksheets with one click.

Sub UnhideAllWorksheets()

Dim ws As Worksheet

For Each ws In ActiveWorkbook.Worksheets
ws.Visible = xlSheetVisible
Next ws

End Sub

Protect a workbook

The following code will protect a workbook to prevent structure changes. It sets a password, but this is optional and can be excluded.

Sub ProtectWorkbook()

ThisWorkbook.Protect Password:="Excel"

End Sub

Opening and closing a workbook

The following code follows a procedure to copy data from the currently active workbook to a workbook named North.

It assigns the active workbook to a variable, then opens the North workbook to copy data from range A1:C250 into it. This workbook is then saved and closed.

There are many techniques to reference workbooks and a few are demonstrated in this small code.

Sub OpenCloseWorkbooks()

Dim wbk As Workbook
Set wbk = ActiveWorkbook

Workbooks.Open "C:UsersAdminOneDriveDesktopSalesNorth.xlsx"
wbk.Sheets("Sheet1").Range("A1:C250").Copy Destination:=Range("A1")

ActiveWorkbook.Close SaveChanges:=True

End Sub

Email the active workbook with Outlook

The following VBA code creates a new email in Microsoft Outlook with the recipient’s email, subject line, and the body text all populated. The active workbook is added as an attachment.

The email is displayed so that the email can be checked and changes made before sending. Change .display to .send to email the attached workbook with one click.

Sub AttachToEmail()

Dim OutApp As Object
Dim OutMail As Object
Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)

With OutMail
.to = "admin@computergaga.com"
.Subject = "A Fabulous Spreadsheet"
.Body = "Hello, I hope you enjoy the fabulous spreadsheet that is attached to this email."
.Attachments.Add ActiveWorkbook.FullName
.display
End With

Set OutMail = Nothing
Set OutApp = Nothing

End Sub

Files and folders

Using VBA to automate working with files and folders during a process is very helpful.

Export each worksheet as a single PDF

This code exports all the worksheets as a separate PDF. The sheet name is used as the PDF file name, and they are saved to the folder that is assigned to the FolderPath variable. Simply change this path to what you need.

Sub ExportAsPDF()

Dim FolderPath As String
Dim ws As Worksheet

FolderPath = "C:UsersComputergagaDesktopSales"

For Each ws In ActiveWorkbook.Worksheets

ws.ExportAsFixedFormat Type:=xlTypePDF, Filename:=FolderPath & "" &
ws.Name, openafterpublish:=False

Next

MsgBox "All PDF's have been successfully exported."

End Sub

Export the active sheet as a PDF

If you only need to export the active worksheet, then only the following few lines of code are required.

Sub ExportAsPDF()

FolderPath = "C:UsersComputergagaDesktopSales"

ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=FolderPath & "" &
Activesheet.Name, openafterpublish:=False

End Sub

Export multiple sheets to a single PDF

You may want to export the worksheets into a single PDF. This code exports the worksheets named London and Berlin into one PDF file.

The sheets are referenced by their name in this example, but you can also reference them using their index number. For example, Sheets(Array(3, 6)).Select

Sub ExportAsPDF()

Dim FolderPath As String

FolderPath = "C:UsersTrainee1DesktopPDFs"

Sheets(Array("London", "Berlin")).Select
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=FolderPath & "Sales", openafterpublish:=False, ignoreprintareas:=False   

MsgBox "All PDF's have been successfully exported."

End Sub

Loop through all the files of a folder

The following VBA code will loop through each file in a folder, the Sales folder on the desktop.

Each file is opened, the number 20 entered into cell A1 of Sheet1 then saved and closed. This is a simple operation, but this code can be replaced with whatever actions you want to perform on each file in the folder.

The Dir function is used for this process. The first instance of Dir is when the file path is provided. It grabs the filename of the first file in the folder.

It is then used again at the end of the loop to grab the name of the next file.

Sub LoopAllFiles()

Dim fileName As Variant
fileName = Dir("C:UsersadminOneDriveDesktopSales")

Do While fileName <> ""    

    Workbooks.Open fileName
    Worksheets("Sheet1").Range("A1").Value = 20
    ActiveWorkbook.Close savechanges:=True    

    fileName = Dir

Loop

End Sub

You can loop through specific files only by using wildcards. The code below can be used to replace the first instance of the Dir function and loop through .xlsx files only.

fileName = Dir("C:UsersadminOneDriveDesktopSales*.xlsx")

Selecting a file with a FileDialog

When interacting with files, the FileDialogs in Excel VBA are very useful. They are an environment that the user is instantly familiar with.

There are FileDialogs for the file open, save, picker, and a folder picker. In this example, the open dialog is used. This is known as msoFileDialogOpen.

Now, this is a little misleading, because the dialog will not actually open the file. It only provides the environment to locate and select it easily. You can then do whatever actions you want to it.

In this VBA code, different properties of the FileDialog are manipulated so it is used with the With construct.

The selected workbook is opened and the number 20 written into cell A1. Once again a sample action that you can replace with whatever you want.

Sub UsingFileDialog()

Dim Filename As String

With Application.FileDialog(msoFileDialogOpen)
.AllowMultiSelect = False
.Title = "Select a workbook to use"
.Show
Filename = .SelectedItems(1)
End With

Workbooks.Open Filename
Worksheets("Sheet1").Range("A1").Value = 20
ActiveWorkbook.Close SaveChanges:=True

MsgBox "Workbook updated"

End Sub

Useful Excel features

These VBA codes will simplify the use of some of the most useful features of Excel.

Sorting columns

The following code sorts range A1:K250 by a single column. It assumes that the range has headers in the first row.

The Key1 argument specifies the column to sort by. In this example, the argument is set to C1, so the range is sorted by column C in descending order.

Sub SortSingleColumn()

Range("A1:K250").Sort Key1:=Range("C1"), Order1:=xlDescending

End Sub

In the following macro code, the defined name of Sales is used as the range to sort by. The defined name does not include the headers.

This time the range is sorted by column B in ascending order.

Sub SortSingleColumn()

Range("Sales").Sort Key1:=Range("B1"), Order1:=xlAscending

End Sub

Extra Key and Order arguments can be added to sort by multiple columns.

In this example, the defined name Sales was used as the range. The range is sorted by column D first in ascending order, and then by column J in descending order.

Sub SortMultipleColumns()

Range("Sales").Sort Key1:=Range("D1"), Order1:=xlAscending, Key2:=Range("J1"), Order2:=xlDescending

End Sub

Finally, if your data is formatted as a table, the following VBA code can be used.

In this example, the table is named Sales and the table is sorted by the Country field in ascending order.

Sub SortTable()

With ActiveSheet.ListObjects("Sales").Sort
   .SortFields.Clear
   .SortFields.Add Key:=Range("Sales[Country]"), Order:=xlAscending
   .Apply
End With

End Sub

Filter your data

The following macro code can be used to turn on the AutoFilter feature. It applies to the active worksheet and uses the current region for range A1.

Sub TurnFilterOn()

Range("A1").AutoFilter

End Sub

To turn the AutoFilter feature off, you can use this code.

Sub TurnFilterOff()

ActiveSheet.AutoFilterMode = False

End Sub

In this example, a filter is applied to column D  (Field:=4) to show the records for Denmark only.

Sub FilterByText()

Range("A1").AutoFilter Field:=4, Criteria1:="Denmark"

End Sub

To filter by more than one text value, the xlOr operator can be used. Here, the data is filtered to show the rows for Denmark and the UK.

Sub FilterByText()

Range("A1").AutoFilter Field:=4, Criteria1:="Denmark", Operator:=xlOr, Criteria2:="UK"

End Sub

There are plenty of operators available for use such as xlFilterIcon and xlTop10Items.

To filter with numbers, ensure you enter the logical operators into the criteria string. The code below filters column H to only show rows where the number is greater than 5 and less than 20.

Sub FilterByNumber()

Range("A1").AutoFilter Field:=8, Criteria1:=">5", Operator:=xlAnd, Criteria2:="<20"

End Sub

The following example filters the list by multiple columns. It filters column D for Denmark only and column H for numbers greater than 5 and less than 20.

Sub FilterByTwoColumns()

With Range("A1")

.AutoFilter Field:=4, Criteria1:="Denmark"
.AutoFilter Field:=8, Criteria1:=">5", Operator:=xlAnd, Criteria2:="<20"

End With

End Sub

To clear any applied filters and show all data, use the following code. This code checks if any filters have been applied first, and if so, clears them to show all the data. 

Sub ClearFilters()

If ActiveSheet.FilterMode = True Then

ActiveSheet.ShowAllData

End If

End Sub

The AutoFilter is not the only filter in Excel. Learn how to use the Advanced Filter with VBA in Excel.

Create a chart

You can use Excel VBA to create charts at the click of a button.

This VBA code will create a column chart (default chart type) from range C3:D8. It uses the chart object variable, so parameters are set for the chart area size and position. Data is then set for the chart.

Sub CreateChart()

Dim MChart As ChartObject

Set MyChart = ActiveSheet.ChartObjects.Add(Top:=50, Left:=100, Width:=450, Height:=250)
MyChart.Chart.SetSourceData Range("C3:D8")

End Sub

You may want to use a different type of chart, so this code will change the chart to a line chart. A list of all chart types will appear as you type.

Sub ChangeChartType()

Dim MyChart As Chart
Set MyChart = ActiveSheet.ChartObjects(1).Chart

MyChart.Chart.ChartType = xlLine

End Sub

Finally, you might want to add or remove chart elements. This code adds a chart title and also data labels.

When using the SetElement method, a list of chart elements will appear. It is important that you choose one to work with your type of chart. The msoElementDataLabelOutSideEnd used in this example works with column charts, but not line charts so it would produce an error.

Sub EditChartElements()

Dim MyChart As Chart
Set MyChart = ActiveSheet.ChartObjects(1).Chart

MyChart.HasTitle = True
MyChart.ChartTitle.Text = "Product Sales"
MyChart.SetElement msoElementDataLabelOutSideEnd

End Sub

The code here is a start guide to give you the foundation to work off of. It is sure to require some minor editing to work for your spreadsheets.

Events

These macro codes are run when events are triggered as someone uses Excel. These events can include changing cell values, opening Excel workbooks, and changing sheet tabs.

They do not require the user to consciously click a button to run the macro. They occur naturally as and when the specified event happens.

Go to a specific worksheet on Open

This VBA code example will occur automatically when the Excel workbook is opened. For this to happen, we need to use the Workbook Open procedure.

1. In the Visual Basic Editor, double click the workbook object from the Project Explorer window that you want to use the code with.

1. Select Workbook from the Object list.
2. Select Open from the Procedure list.
3. Paste the required code in the procedure which is shown in the Code window.

For this code to be activated when the workbook is opened, do not edit the procedure name.

You can use any code you want here. In this example, you are automatically taken to a sheet named Table of Contents and cell A2.

Private Sub Workbook_Open()

Worksheets("Table of Contents").Select
Range("A2").Select

End Sub

There are many other workbook events including BeforeSave, NewSheet, and SheetActivate. These events can be very useful when automating processes such as validating data entry, setting print settings and so on.

Perform an action on Cell Change

The Change event is found on the Worksheet object. It is very useful as it is triggered when a cell value is changed.

To create the Worksheet_Change procedure:

1. Double click the worksheet you want to use in the Project Explorer window to open its code window.
2. Select Worksheet from the Object list, Change from the Procedure list and the procedure will appear in the Code window.

In this code, the changed cell is tested with an If statement to check if the changed cell was in column 5, and if the result of the change was the value Yes.

The variable Target is provided by the worksheet change event. This is the changed cell.

If these conditions are met, the row contents are copied to the bottom of the list on sheet 2 and the cell fill changes to a yellow color.

The Application.EnableEvents statement is used as best practice because the procedures actions can trigger another change event whilst this one is still running.

In this example, it is unnecessary but I wanted to provide it with the code to protect the actions you set from producing errors.

Private Sub Worksheet_Change(ByVal Target As Range)

If Target.Column = 5 And Target = "Yes" Then

Application.EnableEvents = False
Target.EntireRow.Copy Worksheets("Sheet2").Range("A1").End(xlDown).Offset(1, 0)
Target.Interior.ColorIndex = 6

End If

Application.EnableEvents = True

End Sub

What next?

These VBA codes are a great time-saver, but it is just the beginning.

You should learn Excel VBA to really take advantage of its potential in improving your Excel productivity.

Enroll in our Excel Macros and VBA course to start your journey today.