Excel vba chart свойства

Excel charts and graphs are used to visually display data. In this tutorial, we are going to cover how to use VBA to create and manipulate charts and chart elements.

You can create embedded charts in a worksheet or charts on their own chart sheets.

Creating an Embedded Chart Using VBA

We have the range A1:B4 which contains the source data, shown below:

You can create a chart using the ChartObjects.Add method. The following code will create an embedded chart on the worksheet:

Sub CreateEmbeddedChartUsingChartObject()

Dim embeddedchart As ChartObject

Set embeddedchart = Sheets("Sheet1").ChartObjects.Add(Left:=180, Width:=300, Top:=7, Height:=200)
embeddedchart.Chart.SetSourceData Source:=Sheets("Sheet1").Range("A1:B4")

End Sub

The result is:

You can also create a chart using the Shapes.AddChart method. The following code will create an embedded chart on the worksheet:

Sub CreateEmbeddedChartUsingShapesAddChart()

Dim embeddedchart As Shape

Set embeddedchart = Sheets("Sheet1").Shapes.AddChart
embeddedchart.Chart.SetSourceData Source:=Sheets("Sheet1").Range("A1:B4")

End Sub

Specifying a Chart Type Using VBA

We have the range A1:B5 which contains the source data, shown below:

You can specify a chart type using the ChartType Property. The following code will create a pie chart on the worksheet since the ChartType Property has been set to xlPie:

Sub SpecifyAChartType()

Dim chrt As ChartObject

Set chrt = Sheets("Sheet1").ChartObjects.Add(Left:=180, Width:=270, Top:=7, Height:=210)
chrt.Chart.SetSourceData Source:=Sheets("Sheet1").Range("A1:B5")
chrt.Chart.ChartType = xlPie

End Sub

The result is:

These are some of the popular chart types that are usually specified, although there are others:

• xlArea
• xlPie
• xlLine
• xlRadar
• xlXYScatter
• xlSurface
• xlBubble
• xlBarClustered
• xlColumnClustered

Adding a Chart Title Using VBA

We have a chart selected in the worksheet as shown below:

You have to add a chart title first using the Chart.SetElement method and then specify the text of the chart title by setting the ChartTitle.Text property.

The following code shows you how to add a chart title and specify the text of the title of the Active Chart:

Sub AddingAndSettingAChartTitle()

ActiveChart.SetElement (msoElementChartTitleAboveChart)
    ActiveChart.ChartTitle.Text = "The Sales of the Product"
    
End Sub

The result is:

Note: You must select the chart first to make it the Active Chart to be able to use the ActiveChart object in your code.

Changing the Chart Background Color Using VBA

We have a chart selected in the worksheet as shown below:

You can change the background color of the entire chart by setting the RGB property of the FillFormat object of the ChartArea object. The following code will give the chart a light orange background color:

Sub AddingABackgroundColorToTheChartArea()

ActiveChart.ChartArea.Format.Fill.ForeColor.RGB = RGB(253, 242, 227)

End Sub

The result is:

You can also change the background color of the entire chart by setting the ColorIndex property of the Interior object of the ChartArea object. The following code will give the chart an orange background color:

Sub AddingABackgroundColorToTheChartArea()

ActiveChart.ChartArea.Interior.ColorIndex = 40

End Sub

The result is:

Note: The ColorIndex property allows you to specify a color based on a value from 1 to 56, drawn from the preset palette, to see which values represent the different colors, click here.

Changing the Chart Plot Area Color Using VBA

We have a chart selected in the worksheet as shown below:

You can change the background color of just the plot area of the chart, by setting the RGB property of the FillFormat object of the PlotArea object. The following code will give the plot area of the chart a light green background color:

Sub AddingABackgroundColorToThePlotArea()

ActiveChart.PlotArea.Format.Fill.ForeColor.RGB = RGB(208, 254, 202)
    
End Sub

The result is:

Adding a Legend Using VBA

We have a chart selected in the worksheet, as shown below:

You can add a legend using the Chart.SetElement method. The following code adds a legend to the left of the chart:

Sub AddingALegend()

ActiveChart.SetElement (msoElementLegendLeft)

End Sub

The result is:

You can specify the position of the legend in the following ways:

• msoElementLegendLeft – displays the legend on the left side of the chart.
• msoElementLegendLeftOverlay – overlays the legend on the left side of the chart.
• msoElementLegendRight – displays the legend on the right side of the chart.
• msoElementLegendRightOverlay – overlays the legend on the right side of the chart.
• msoElementLegendBottom – displays the legend at the bottom of the chart.
• msoElementLegendTop – displays the legend at the top of the chart.

Adding Data Labels Using VBA

We have a chart selected in the worksheet, as shown below:

You can add data labels using the Chart.SetElement method. The following code adds data labels to the inside end of the chart:

Sub AddingADataLabels()

ActiveChart.SetElement msoElementDataLabelInsideEnd

End Sub

The result is:

You can specify how the data labels are positioned in the following ways:

• msoElementDataLabelShow – display data labels.
• msoElementDataLabelRight – displays data labels on the right of the chart.
• msoElementDataLabelLeft – displays data labels on the left of the chart.
• msoElementDataLabelTop – displays data labels at the top of the chart.
• msoElementDataLabelBestFit – determines the best fit.
• msoElementDataLabelBottom – displays data labels at the bottom of the chart.
• msoElementDataLabelCallout – displays data labels as a callout.
• msoElementDataLabelCenter – displays data labels on the center.
• msoElementDataLabelInsideBase – displays data labels on the inside base.
• msoElementDataLabelOutSideEnd – displays data labels on the outside end of the chart.
• msoElementDataLabelInsideEnd – displays data labels on the inside end of the chart.

Adding an X-axis and Title in VBA

We have a chart selected in the worksheet, as shown below:

You can add an X-axis and X-axis title using the Chart.SetElement method. The following code adds an X-axis and X-axis title to the chart:

Sub AddingAnXAxisandXTitle()

With ActiveChart
.SetElement msoElementPrimaryCategoryAxisShow
.SetElement msoElementPrimaryCategoryAxisTitleHorizontal
End With


End Sub

The result is:

Adding a Y-axis and Title in VBA

We have a chart selected in the worksheet, as shown below:

You can add a Y-axis and Y-axis title using the Chart.SetElement method. The following code adds an Y-axis and Y-axis title to the chart:

Sub AddingAYAxisandYTitle()

With ActiveChart
.SetElement msoElementPrimaryValueAxisShow
.SetElement msoElementPrimaryValueAxisTitleHorizontal
End With
End Sub

The result is:

VBA Programming | Code Generator does work for you!

Changing the Number Format of An Axis

We have a chart selected in the worksheet, as shown below:

You can change the number format of an axis. The following code changes the number format of the y-axis to currency:

Sub ChangingTheNumberFormat()

ActiveChart.Axes(xlValue).TickLabels.NumberFormat = "$#,##0.00"

End Sub

The result is:

Changing the Formatting of the Font in a Chart

We have the following chart selected in the worksheet as shown below:

You can change the formatting of the entire chart font, by referring to the font object and changing its name, font weight, and size. The following code changes the type, weight and size of the font of the entire chart.

Sub ChangingTheFontFormatting()

With ActiveChart


.ChartArea.Format.TextFrame2.TextRange.Font.Name = "Times New Roman"
.ChartArea.Format.TextFrame2.TextRange.Font.Bold = True
.ChartArea.Format.TextFrame2.TextRange.Font.Size = 14

End With

The result is:

Deleting a Chart Using VBA

We have a chart selected in the worksheet, as shown below:

We can use the following code in order to delete this chart:

Sub DeletingTheChart()

ActiveChart.Parent.Delete

End Sub

Referring to the ChartObjects Collection

You can access all the embedded charts in your worksheet or workbook by referring to the ChartObjects collection. We have two charts on the same sheet shown below:

We will refer to the ChartObjects collection in order to give both charts on the worksheet the same height, width, delete the gridlines, make the background color the same, give the charts the same plot area color and make the plot area line color the same color:

Sub ReferringToAllTheChartsOnASheet()

Dim cht As ChartObject

For Each cht In ActiveSheet.ChartObjects
cht.Height = 144.85
cht.Width = 246.61

cht.Chart.Axes(xlValue).MajorGridlines.Delete
cht.Chart.PlotArea.Format.Fill.ForeColor.RGB = RGB(242, 242, 242)
cht.Chart.ChartArea.Format.Fill.ForeColor.RGB = RGB(234, 234, 234)
cht.Chart.PlotArea.Format.Line.ForeColor.RGB = RGB(18, 97, 172)

Next cht

End Sub

The result is:

Inserting a Chart on Its Own Chart Sheet

We have the range A1:B6 which contains the source data, shown below:

You can create a chart using the Charts.Add method. The following code will create a chart on its own chart sheet:

Sub InsertingAChartOnItsOwnChartSheet()

Sheets("Sheet1").Range("A1:B6").Select
Charts.Add

End Sub

The result is:

See some of our other charting tutorials:

Charts in Excel

Create a Bar Chart in VBA

Chart Elements in Excel VBA (Part 2) — Chart Title, Chart Area, Plot Area, Chart Axes, Chart Series, Data Labels, Chart Legend

Contents:

Chart Series

DataLabels Object / DataLabel Object

Chart Legend

This chapter discusses some important chart elements contained on a chart, which include: chart area (ChartArea object); chart title (ChartTitle object); plot area (PlotArea object); chart series (Series object — single series in a chart, SeriesCollection object — a collection of all the Series objects in a chart, Error Bars, Leader Lines, Trendlines, Point object — single points, Points object — collection of all Point objects in a series); chart axis (Axis Object — a single axis, Axes Object  — collection of all the Axis objects in a chart, Gridlines object — major & minor gridlines, TickLabels Object — tick marks on an axis); chart Legend (Legend object, LegendEntry object — a single legend entry, LegendEntries object — a collection of legend entries, LegendKey object); data labels (DataLabel object — a single data label, DataLabels object — all data labels in a chart or series).

Individual chart elements can be formatted & manipulated in vba code, such as: Chart Area (A 2-D chart’s chart area contains: the axes, the chart title, the axis titles & the legend. A 3-D chart’s chart area contains the chart title & the legend, without including the plot area); Plot Area (area where chart data is plotted — the Plot Area is surrounded by the Chart Area. A 2-D chart’s plot area contains: the data markers, gridlines, data labels, trendlines & optional chart items placed in the chart area. A 3-D chart’s plot area additionally contains: the walls, floor, axes, axis titles & tick-mark labels in the chart.); Data Series (chart series are related data points plotted in a chart, each series having a distinct color or pattern and is represented in the chart legend); Chart Axis (the plot area is bordered by a line that is used as a frame of reference for measurement — axis which displays categories is referred as the x-axis, axis which displays values is referred as y-axis, for 3-D charts the z-axis represents depth of the chart); Chart or Axis Title (descriptive text displaying title for chart or axis, by default centered at the chart top or aligned to an axis); Tick Marks (small lines of measurement which intersect an axis, equated to divisions on a ruler); Gridlines (tick marks are extended by Gridlines from horizontal or vertical axis across the chart’s plot area which enables easier display & readability of chart data); Data Labels (applied to a chart series, a label provides additional information about a data marker or a point in a series — you can apply data labels to each or all points of a data series to display the series name / category names / data values / percentages / bubble size), Chart Legend (a graphic visually linking a legend entry with its associated series or trendline so that any formatting change in one automatically changes the other’s formatting).

This Chapter illustrates Chart Series, Data Labels & Chart Legend. Chart Elements — Chart Title, Chart Area, Plot Area & Chart Axes — are illustrated in Part 1.

Chart Series

A SeriesCollection object refers to a collection of all the Series objects in a chart. The Series object refers to a single series in a chart, and is a member of the SeriesCollection object.

The SeriesCollection method of the Chart object (SeriesCollection Method) returns either a single Series object or the SeriesCollection object. Syntax: objChart.SeriesCollection(Index). The Index argument (optional) specifies the number or name of the series — index number represents the order in which the series were added, with the first series added to the chart being index number 1 ie. objChart.SeriesCollection(1), and the last added series index number being objChart.SeriesCollection(objSeriesCollection.Count).

SeriesCollection.Item Method. To refer to a single Series (ie. Series object) from Series collection, use the the Item Method of the SeriesCollection object. Syntax: objSeriesCollection.Item(Index), where the Index argument is necessary, and it specifies the number or name of the series — index number represents the order in which the series were added, with the first series added to the chart being index number 1, as explained above. Use the Count Property of the SeriesCollection object to return the number of Series in a Series Collection viz. MsgBox Sheets(«Sheet1»).ChartObjects(1).Chart.SeriesCollection.Count.

Sub SeriesCollectionObj_SeriesObj()
‘series collection & series object

Dim objSeries As Series

’embedded chart

With Sheets(«Sheet12»).ChartObjects(1).Chart

‘returns number of series in the series collection

MsgBox .SeriesCollection.count

‘refer single series (series object) — last series in the series collection — you can alternatively use: With .SeriesCollection(.SeriesCollection.count)

With .SeriesCollection.Item(.SeriesCollection.count)

‘turn on data labels

.HasDataLabels = True

End With

‘refer series collection using the Chart.SeriesCollection method — each series object in the series collection

For Each objSeries In .SeriesCollection

‘return name of each series in the series collection

MsgBox objSeries.Name

If objSeries.HasDataLabels = True Then

‘return series name if data labels is turned on

MsgBox objSeries.Name & » series has data labels»

End If

Next objSeries

End With

End Sub

The Add method of the SeriesCollection object is used to create a new series and add to the chart as a member of its SeriesCollection. Syntax: objSeriesCollection.Add(Source, Rowcol, SeriesLabels, CategoryLabels, Replace). All arguments except the Source argument are optional to specify. The Source argument specifies the range for Source Data, for the new series. The Rowcol argument can either specify, xlRows (value 1) which specifies that values for the new series are in the rows of the source range, or, xlColumns (value 2)  which specifies that values for the new series are in the columns of the source range. For the SeriesLabels & CategoryLabels argument, True setting will indicate that the Series Lables (name of the data series) or Category Labels are contained in the first row or column of the source range, False setting indicates otherwise, and omitting the argument will make Excel attempt to determine if Labels are located in the first row or column. Setting the Replace argument to True where CategoryLabels is True, the current categories existing for the series will be replaced by the categories specified in the source range, and setting Replace to False (default) will not replace. You cannot use this method for PivotChart reports.

You can also use the NewSeries Method of the SeriesCollection object, to create a new series — Syntax: objSeriesCollection.NewSeries. Using this method returns a Series object representing the new series whereas the Add method does not return a Series object. This method however, like the Add method, also cannot be used for PivotChart reports.

The Extend Method of the SeriesCollection object is used to extend an existing series collection by adding new data points. Syntax: objSeriesCollection.Extend(Source, Rowcol, CategoryLabels). All arguments have the same meaning as in the SeriesCollection.Add method above, and only the Source argument is necessary to specify. Ex. to extend the chart series by adding data points as per values in cells B6:C6 in Sheet1: Sheets(«Sheet1»).ChartObjects(1).Chart.SeriesCollection.Extend Source:=Worksheets(«Sheet12»).Range(«B6:C6»). This method also cannot be used for PivotChart reports.

Child Objects for the Series Object: Above, we have discussed: the ChartFormat object — use the Format Property — objSeries.Format — to return the ChartFormat object which contains the line, fill & effect formatting for the chart series; ErrorBars object — use the ErrorBars Property — objSeries.ErrorBars — to turn on error bars for a series which indicate the degree of uncertainty for chart data; LeaderLines object — use the LeaderLines property — objSeries.LeaderLines — to get a reference to the LeaderLines object which manipulates the appearance of leader lines. Some other child objects which are often used with the Series Object include: ChartFillFormat Object — use the Fill Property — objSeries.Fill — to return a ChartFillFormat object (valid only for charts), to manipulate fill formatting for chart elements; Interior Object — use the Interior property — objSeries.Interior — to return the Interior object, to manipulate the chart element’s interior (inside area); Border Object — use the Border Property — objSeries.Border — to return a Border object, to manipulate a chart element’s border.

Example: Create & manipulate error bars for a 2-D line chart — refer Images 6a & 6b

To download Excel file with live code, click here.

Sub ErrorBars_1()
‘create & manipulate error bars for a 2-D line chart — refer Images 6a & 6b

Dim oChObj As ChartObject, rngSourceData As Range, ws As Worksheet

Set ws = Sheets(«Sheet1»)

Set rngSourceData = ws.Range(«B1:C7»)

Set oChObj = ws.ChartObjects.Add(Left:=ws.Columns(«A»).Left, Width:=290, Top:=ws.Rows(8).Top, Height:=190)

With oChObj.Chart

.ChartType = xlLineMarkers

.SetSourceData Source:=rngSourceData, PlotBy:=xlColumns

.Axes(xlCategory).CategoryNames = ws.Range(«A2:A7»)

.HasTitle = True

With .ChartTitle

.Caption = ws.Range(«B1″) & » — » & ws.Range(«C1»)

.Font.Size = 12

.Font.Bold = True

End With

With .SeriesCollection(1)

‘specifies bars for y-axis values which receives error bars; includes both positive & negative error range; range to be covered by the error bars is specified as percentage; error amount specified as 10%;

.ErrorBar Direction:=xlY, Include:=xlErrorBarIncludeBoth, Type:=xlErrorBarTypePercent, Amount:=10

‘where you specify bars to include only positive error range, the error bar will NOT be drawn in the negative direction — refer Image 28b

‘where a positive error bar has negative values, it will be drawn in the negative direction.

‘.ErrorBar Direction:=xlY, Include:=xlErrorBarIncludePlusValues, Type:=xlErrorBarTypePercent, Amount:=10

‘set color/style formatting for the vertical(Y) Error Bars

With .ErrorBars

.Format.Line.Visible = msoFalse

.Format.Line.Visible = msoTrue

‘using ErrorBars.EndStyle Property — to not apply caps, use xlNoCap

.EndStyle = xlCap

‘.Format.Line.DashStyle = msoLineSysDash

.Format.Line.Transparency = 0

.Format.Line.Weight = 1.5

.Format.Line.ForeColor.RGB = RGB(255, 0, 0)

End With

End With

End With

End Sub

For below Examples, refer section on «Create Line, Column, Pie, Scatter, Bubble charts».

Example: Create a pie chart with leader lines & custom color the slices of the pie — refer above section.

Example: Create XY Scatter chart having single series with X & Y values — refer above section.

Example: Create XY Scatter chart with multiple series where all series share the same Y values with distinct X values — refer above section.

Example: Create Bubble chart multiple series where all series share the same Y values with distinct X values — refer above section.

Example: Create & manipulate both X & Y error bars, types xlErrorBarTypePercent & xlErrorBarTypeCustom, for a bubble chart — refer above section.

Example: Setting forth the object heirarchy for formatting series line & points of embedded chart (chart type line & markers) — refer Image 7 — series 4

Sub Object_Heirarchy()
‘Setting forth the object heirarchy for formatting series line & points of embedded chart (chart type line & markers)
‘refer Image 7 — series 4

‘—————————————————

‘set red inside color (ie. fill color) for all markers of a chart series — does not set the series line color or the border color for markers

‘Setting forth the object heirarchy:

‘»Sheet1″ contains a collection of embedded charts (ChartObjects object)

‘»Chart 5″ is the name of a single embedded chart (ChartObject object) in that collection

‘the Chart Property of the ChartObject returns a Chart object which refers to a chart contained in the ChartObject object

‘The Chart object has SeriesCollection object (a collection of all the Series objects in a chart), and one of the Series object has an index number 4

‘The Format property of the Series object returns a ChartFormat object which contains the line, fill & effect formatting for that Series

‘The Fill Property of the ChartFormat Object returns a FillFormat object containing fill formatting properties

‘The ForeColor Property returns a ColorFormat object that represents the foreground fill ‘ solid color

‘The RGB property (explicit Red-Green-Blue value) sets a color for the ColorFormat object

Sheets(«Sheet1»).ChartObjects(«Chart 5»).Chart.SeriesCollection(4).Format.Fill.ForeColor.RGB = RGB(0, 255, 0)

‘—————————————————

‘set the Line color AND the Marker Border Line (for all markers) color of a chart series

‘Setting forth the object heirarchy:

‘»Sheet1″ contains a collection of embedded charts (ChartObjects object)

‘»Chart 5″ is the name of a single embedded chart (ChartObject object) in that collection

‘the Chart Property of the ChartObject returns a Chart object which refers to a chart contained in the ChartObject object

‘The Chart object has SeriesCollection object (a collection of all the Series objects in a chart), and one of the Series object has an index number 4

‘The Format property of the Series object returns a ChartFormat object which contains the line, fill & effect formatting for that Series

‘The Line Property of the ChartFormat Object returns a LineFormat object (can be a Line itself or a border) containing line & arrowhead formatting properties

‘The ForeColor Property returns a ColorFormat object that represents the foreground fill / solid color

‘The RGB property (explicit Red-Green-Blue value) sets a color for the ColorFormat object

Sheets(«Sheet1»).ChartObjects(«Chart 5»).Chart.SeriesCollection(4).Format.Line.ForeColor.RGB = RGB(255, 0, 0)

‘—————————————————

‘set the dash style for BOTH the Series Line AND the Marker Border Line, for a single point of a chart series — for marker point no 3 & series line point no 2 to point no 3

‘Setting forth the object heirarchy:

‘»Sheet1″ contains a collection of embedded charts (ChartObjects object)

‘»Chart 5″ is the name of a single embedded chart (ChartObject object) in that collection

‘The Chart Property of the ChartObject returns a Chart object which refers to a chart contained in the ChartObject object

‘The Chart object has SeriesCollection object (a collection of all the Series objects in a chart), and one of the Series object has an index number 4

‘The Points Method of the Series object returns a Point object (single point)

‘The Format property of the Series object returns a ChartFormat object which contains the line, fill & effect formatting for that Series

‘The Line Property of the ChartFormat Object returns a LineFormat object (can be a Line itself or a border) containing line & arrowhead formatting properties

‘The DashStyle Property of the LineFormat object sets the dash style for the line

Sheets(«Sheet1»).ChartObjects(«Chart 5»).Chart.SeriesCollection(4).Points(3).Format.Line.DashStyle = msoLineDashDotDot

‘—————————————————

‘set color for chart series line, for a single point — series line from point no 1 to point no 2

‘Setting forth the object heirarchy:

‘»Sheet1″ contains a collection of embedded charts (ChartObjects object)

‘»Chart 5″ is the name of a single embedded chart (ChartObject object) in that collection

‘The Chart Property of the ChartObject returns a Chart object which refers to a chart contained in the ChartObject object

‘The Chart object has SeriesCollection object (a collection of all the Series objects in a chart), and one of the Series object has an index number 4

‘The Points Method of the Series object returns a Point object (single point)

‘The Border Property returns a Border object

‘The Color Property (of the Border object) sets the primary color for the Border object

‘The RGB function creates a color value

Sheets(«Sheet1»).ChartObjects(4).Chart.SeriesCollection(4).Points(2).Border.Color = RGB(0, 0, 255)

‘—————————————————

End Sub

A Combination Chart means where two or more chart types are combined for a single chart. Combination charts can be created using the Chart.ApplyCustomType Method, however the ApplyCustomType Method may not work in Excel 2007, & you might alternatively need to use ApplyChartTemplate Method or ApplyLayout Method of the Chart object
Below is an illustration to create a Combination Chart in Excel 2007 — a dynamic Column-Line chart (clustered columns combined with line marker), wherein first you create a clustered column chart type and then add a new series of Type «xlLine» on secondary axis.

Example: Combination Chart — create a dynamic ColumnLine chart — clustered columns combined with line marker — refer Image 8

Sub Chart_Combination_ColumnLine_Dynamic()
‘Combination Chart (where two or more chart types are combined for a single chart), without using the Chart.ApplyCustomType Method
‘create a dynamic Column-Line chart — clustered columns combined with line marker — create a clustered column chart type and then add a new series of Type «xlLine» on secondary axis — refer Image 8

‘Dynamic Chart — the parent data is given in the range «A10:F16». You can select the Student Names in range «A3:A6» and the appropriate data will update from the Parent Data

Dim rngSourceData As Range, ws As Worksheet

Set ws = Sheets(«Sheet1»)

Set rngSourceData = ws.Range(«B2:E6»)

‘declare a ChartObject

Dim oChObj As ChartObject

‘delete existing embedded charts in the worksheet

For Each oChObj In ws.ChartObjects

oChObj.Delete

Next

‘the Add method (of the ChartObjects object) is used to create a new empty embedded chart and add it to the collection (ChartObjects object) in the specified sheet — left edge align to the left edge of column I, top edge align to the

top of row 2

Set oChObj = ws.ChartObjects.Add(Left:=ws.Columns(«I»).Left, Width:=370, Top:=ws.Rows(2).Top, Height:=210)

‘using the Chart Property of the ChartObject object returns a Chart object which refers to a chart (contained in the ChartObject object)

With oChObj.Chart

‘use ChartType Property of the Chart object to set type of chart — Clustered Column

.ChartType = xlColumnClustered

‘use SetSourceData Method of the Chart object to set the range of source data for the chart

.SetSourceData Source:=rngSourceData, PlotBy:=xlColumns

‘the ChartTitle object exists and can be used only if the HasTitle property (of the Chart object) is True

.HasTitle = True

‘refer the Axis object — category axis

With .Axes(xlCategory, xlPrimary)

‘use the CategoryNames property for setting the category names for a category axis, as a text array, to the values contained in a range of cells (ie. Range object) or to a text array containing category names.

.CategoryNames = ws.Range(«A3:A6»)

‘the TickLabels object represents all the tick-mark labels (as a unit) — set font to bold

.TickLabels.Font.Bold = True

End With

‘use the NewSeries Method of the SeriesCollection object, to create a new series. Using this method returns a Series object representing the new series whereas the Add method does not return a Series object.

Dim MySeries As Series

Set MySeries = .SeriesCollection.NewSeries

‘plot the new series as line with markers, on secondary axis

With MySeries

.Type = xlLine

‘set the axis group (Primary axis group) for the specified series using the Series.AxisGroup Property

.AxisGroup = xlSecondary

‘using the MarkerStyle Property of the Series object to set the marker style for the series, per the XlMarkerStyle constants (using a diamond-shaped marker here)

.MarkerStyle = xlMarkerStyleDiamond

‘using the MarkerSize property of the Series object to set the data-marker size, in points

.MarkerSize = 7

.Name = ws.Range(«F2»)

‘using the Values property of the Series object, set Y values for new series

.Values = ws.Range(«F3:F6»)

‘set red color for series line

.Border.ColorIndex = 3

‘set red border line color for marker

.MarkerForegroundColor = RGB(255, 0, 0)

‘set red inside color (ie. fill color) for marker

.MarkerBackgroundColor = RGB(255, 0, 0)

End With

‘Format property of the Series object returns returns the ChartFormat object — use the Fill Property of the ChartFormat object to return a FillFormat object (which contains fill formatting properties), to set the foreground fill color for

the Series

‘set fill color for each series (columns)

.SeriesCollection(ws.Range(«B2»).Value).Format.Fill.ForeColor.RGB = RGB(0, 176, 240)

.SeriesCollection(ws.Range(«C2»).Value).Format.Fill.ForeColor.RGB = RGB(228, 108, 10)

.SeriesCollection(ws.Range(«D2»).Value).Format.Fill.ForeColor.RGB = RGB(126, 194, 52)

.SeriesCollection(ws.Range(«E2»).Value).Format.Fill.ForeColor.RGB = RGB(153, 130, 180)

‘set fill color for chart area

.ChartArea.Format.Fill.ForeColor.RGB = RGB(252, 213, 181)

‘set fill color for plot area

.PlotArea.Format.Fill.ForeColor.RGB = RGB(242, 220, 219)

‘the ChartTitle object represents the chart title

With .ChartTitle

‘set the text for the chart title, using the Text Property of the ChartTitle object

.Text = «Column-Line Chart: Student Marks«

‘set the font to Bold Arial 11 points

.Font.Name = «Arial«

.Font.Size = 11

.Font.Bold = True

‘set font color for chart title

.Font.Color = RGB(0, 30, 90)

‘set fill color for the ChartTitle

.Format.Fill.ForeColor.RGB = RGB(255, 192, 0)

‘set border color using Color Property of the Border object

.Border.Color = RGB(0, 30, 90)

End With

End With

End Sub

Example: Part 5 of 8 — Manipulate Chart Series — refer Image 1.5

Sub EmbChart_ChartSeries_5()
‘manipulate Chart Series — refer Image 1.5

Dim wsData As Worksheet, wsChart As Worksheet

‘declare a ChartObject object

Dim oChObj As ChartObject

Set wsData = Sheets(«Sheet18»)

Set wsChart = Sheets(«Sheet19»)

‘set ChartObject object by index number

Set oChObj = wsChart.ChartObjects(1)

‘using the Chart Property of the ChartObject returns a Chart object which refers to a chart

With oChObj.Chart

‘using the Chart.SeriesCollection Method to return a single series (Series object) by its name

With .SeriesCollection(wsData.Range(«C1»).Value)

‘using the MarkerStyle Property of the Series object to set the marker style for the series, per the XlMarkerStyle constants (using a diamond-shaped marker here)

.MarkerStyle = xlMarkerStyleDiamond

‘using the MarkerSize property of the Series object to set the data-marker size, in points

.MarkerSize = 8

‘use the Border property to return a Border object — set the primary color of the Border using the Color property of the Border object — use the RGB function to create a color value, or use the ColorIndex Property of the Border object

to set the border color

‘set red color for series line

.Border.Color = RGB(255, 0, 0)

‘alternatively:

‘.Border.ColorIndex = 3

‘set red line color for marker border

.MarkerForegroundColorIndex = 3

‘alternatively:

‘.MarkerForegroundColor = RGB(255, 0, 0)

‘set red inside color (ie. fill color) for marker

.MarkerBackgroundColorIndex = 3

‘alternatively:

‘.MarkerBackgroundColor = RGB(255, 0, 0)

‘you might need to differentiate a period or point for an important happening

‘use the Points Method of the Series object to return a single point (Point object) ie. point no 3

With .Points(3)

‘use the MarkerStyle Property of the Point object to set the marker style for a point: xlMarkerStyleCircle — Circular marker

.MarkerStyle = xlMarkerStyleCircle

‘Use the Format Property of the Point object to return the ChartFormat object which contains the line, fill & effect formatting for the series, and provides access to the Office Art formatting options so that you can apply many new

graphics. The Line property of the ChartFormat object returns a LineFormat object that contains line formatting properties.

‘this sets — the Marker weight (marker’s border line width) & color, and also sets the series line thickness & color — for point no 2 to point no 3

.Format.Line.Weight = 3

.Format.Line.Visible = msoFalse

.Format.Line.Visible = msoTrue

‘dark red

.Format.Line.ForeColor.RGB = RGB(192, 0, 0)

‘set orange inside color (ie. fill color) for marker

.MarkerBackgroundColor = RGB(255, 192, 0)

End With

End With

‘———————————————-

‘Series2

With .SeriesCollection(wsData.Range(«D1»).Value)

‘set blue color for series line

.Border.ColorIndex = 5

‘set blue border line color for marker

.MarkerForegroundColor = RGB(0, 0, 255)

‘set blue inside color (ie. fill color) for marker

.MarkerBackgroundColor = RGB(0, 0, 255)

.Format.Line.Style = msoLineThinThin

‘use the Points Method of the Series object to return a single point (Point object) or a collection of all the points (Points collection)

Dim pt As Point

For Each pt In .Points

With pt

‘use the MarkerStyle Property of the Point object set the marker style for a point

.MarkerStyle = xlMarkerStyleCircle

‘this sets the Marker weight (marker’s border line width) and also sets the series line width / thickness

.Format.Line.Weight = 3

End With

Next

End With

‘———————————————-

‘use the NewSeries Method of the SeriesCollection object, to create a new series. Using this method returns a Series object representing the new series whereas the Add method does not return a Series object.

With .SeriesCollection.NewSeries

‘set the axis group (Primary axis group) for the specified series using the Series.AxisGroup Property

.AxisGroup = xlPrimary

‘using the MarkerStyle Property of the Series object to set the marker style for the series, per the XlMarkerStyle constants (using a diamond-shaped marker here)

.MarkerStyle = xlMarkerStyleDiamond

‘using the MarkerSize property of the Series object to set the data-marker size, in points

.MarkerSize = 8

.Name = wsData.Range(«E1»)

‘using the Values property of the Series object, set Y values for new series

.Values = wsData.Range(«E2:E9»)

‘using the XValues property of the Series object, set an array of X values or Category Labels, for new series

.XValues = wsData.Range(«A2:B9»)

‘use the Format Property of the Series object to return the ChartFormat object which contains the line, fill & effect formatting for the series

With .Format

‘set red inside color (ie. fill color) for marker

.Fill.ForeColor.RGB = RGB(149, 55, 53)

‘using the Line Property of the ChartFormat object, returns a LineFormat object that contains line formatting properties

‘switching the line visibility off & on seems necessary to set the line colour using the ForeColor Property of the LineFormat object (in Excel 2007)

.Line.Visible = msoFalse

.Line.Visible = msoTrue

‘set the Series Line color AND the Marker Border Line color

.Line.ForeColor.RGB = RGB(149, 55, 53)

‘using the Style Property of the LineFormat object to set the style for the line (using a MsoLineStyle value)

.Line.Style = msoLineSingle

‘using the DashStyle Property of the LineFormat object to set the dash style for the line (using a MsoLineDashStyle constant) — this sets the dash style for BOTH the Series Line AND the Marker Border Line — set a solid line

.Line.DashStyle = msoLineSolid

‘using the Weight Property of the LineFormat object to set the weight for the line

‘sets both Series Line width AND Marker Border Line width to 2.5 pts

.Line.Weight = 2.5

End With

‘use the Weight Property of the Border object to set the border weight (using a XlBorderWeight enumeration value)

‘reapply series line thickness only — sets series line width to 2 pts (so that Marker Border Line width remains at 2.5 pts)

.Border.Weight = xlMedium

‘using the LineStyle Property of the Border object to set (reapply) the line style for the series line, using the XlLineStyle Enumeration of xlDash to specify the line style

.Border.LineStyle = xlDash

End With

End With

End Sub

DataLabels Object / DataLabel Object

Above we have discussed using the DataLabels Method to return (read-only) either a single data label (DataLabel object) or all data labels (DataLabels object) in a series, and using the ApplyDataLabels Method to to apply data labels to a chart series. We now explain how you can manipulate the data label(s) for a series, using the properties & methods of the DataLabels Object / DataLabel Object. DataLabels.Count Property — objDataLabels.Count — returns the number of data labels in a collection / series. The DataLabels.Item Method — objDataLabels.Item(Index) — returns a single data label in the collection or series.

Example: Manipulate data labels in a series, using the DataLabels object / DataLabel object

Sub Series_DataLabels_1()
‘manipulate data labels in a series, using the DataLabels object / DataLabel object

Dim i As Integer

‘refer series 1 of embedded chart

With Sheets(«Sheet1»).ChartObjects(1).Chart.SeriesCollection(1)

‘a chart series will have data labels only if the HasDataLabels property (of the Series object) is True

If .HasDataLabels = True Then

MsgBox «No of data labels in series is » & .DataLabels.count

‘use the Format property of the DataLabels object to return a ChartFormat object which contains the line, fill & effect formatting for the data labels collection

With .DataLabels.Format.Fill

‘set white background for all data labels

.ForeColor.RGB = RGB(255, 255, 255)

End With

‘use the Border property of the DataLabels object to return a Border object for the data labels collection

With .DataLabels.Border

‘set linestyle as dotted line

.LineStyle = xlDot

‘set the weight / thickness

.Weight = xlThin

‘set line color to red

.Color = vbRed

End With

‘Count property returns the number of data labels in a series

For i = 1 To .DataLabels.count

‘set the format code for data labels, using a String value

.DataLabels(i).NumberFormat = «0.0«

‘use the Font property of the DataLabel object to return a Font object for a data label

With .DataLabels(i).Font

.Bold = True

‘set different font color for each data label

.ColorIndex = 2 + i

‘set increasing font size, subject to maximum of 10 points

.Size = WorksheetFunction.Min(10, 7 + i)

End With

‘return caption of each data label

MsgBox .DataLabels(i).Caption

Next i

Else

‘if series does not have data labels

MsgBox «No Data Labels in Series»

End If

End With

End Sub

Child Objects for DataLabels Object / DataLabel Object: Above, we have discussed the ChartFormat object — use the Format Property — objDataLabels.Format — to return the ChartFormat object which contains the line, fill & effect formatting for the chart DataLabels / DataLabel objects. Some other child objects which are often used with both DataLabels / DataLabel Objects include: ChartFillFormat Object — use the Fill Property — objDataLabels.Fill — to return a ChartFillFormat object (valid only for charts), to manipulate fill formatting for chart elements; Interior Object — use the Interior property — objDataLabels.Interior — to return the Interior object, to manipulate the chart element’s interior (inside area); Border Object — use the Border Property— objDataLabels.Border — to return a Border object, to manipulate a chart element’s border; Font Object — use the Font Property — objDataLabels.Font — to return a Font object, to manipulate the font attributes viz. font name, font size, font color, … For the DataLabel object, there is an additional child object as discussed above — the Characters object — use the Characters property — objDataLabel.Characters(Start, Length) — to return a Characters object representing a range of characters within the text string of data label, and this will enable formatting these specific characters.

Example: Apply & manipulate data labels in a chart — refer image 9

To download Excel file with live code, click here.

Sub Series_DataLabels()
‘apply & manipulate data labels in a chart — refer image 9

Dim i As Integer

‘refer embedded chart

With Sheets(«Sheet1»).ChartObjects(1).Chart

‘refer series «Avg» of embedded chart

With .SeriesCollection(«Avg»)

.ApplyDataLabels ShowCategoryName:=False, AutoText:=True, LegendKey:=False

With .DataLabels

.AutoScaleFont = True

.Font.Size = 10

.Font.Italic = True

‘use ColorIndex 3 for red, 5 for blue, 4 for green, 6 for yellow, …

.Font.ColorIndex = 3

.ShowSeriesName = True

.Position = xlLabelPositionRight

.Orientation = xlHorizontal

.Separator = xlDataLabelSeparatorDefault

End With

End With

‘refer series «Total» of embedded chart

With .SeriesCollection(«Total»)

.ApplyDataLabels ShowCategoryName:=True, LegendKey:=False

With .DataLabels

.ShowValue = False

.ShowSeriesName = True

.AutoScaleFont = False

.Font.Name = «Arial«

.Font.Size = 9

.Font.Bold = True

.Font.Color = RGB(0, 32, 96)

.Position = xlLabelPositionAbove

.Orientation = 10

.Separator = « / «

End With

End With

‘refer series «Physics» of embedded chart

With .SeriesCollection(«Physics»)

.ApplyDataLabels

With .DataLabels

.AutoScaleFont = False

.Font.Name = «Calibri«

.Font.Size = 9

.Font.Bold = True

.Font.Color = RGB(0, 176, 240)

.Position = xlLabelPositionAbove

.ShowValue = True

.Orientation = -7

.ShowCategoryName = True

.ShowSeriesName = True

.Separator = «—«

End With

‘set below position the data point, for every odd data label in series

For i = 1 To .DataLabels.count

If i Mod 2 <> 0 Then

.DataLabels(i).Position = xlLabelPositionBelow

End If

Next i

End With

End With

End Sub

Chart Legend

The Legend Property of the Chart object returns a Legend object, which refers to the chart legend and can be manipulated through its properties & methods. Syntax: objChart.Legend. The Legend is visible and the Legend object’s properties & methods can be used only if the HasLegend property (of the Chart object) is True. The HasLegend property uses a Boolean value — True displays and turns on a legend for the chart (Read-write) — Syntax: objChart.HasLegend.

There can be only one Legend in a chart, and multiple LegendEntry objects can be contained in the Legend object. The LegendEntries Object is a collection of LegendEntries containing all LegendEntry objects in a Legend. The LegendEntries Method of the Legend object is used to return a single legend entry (LegendEntry object) or a collection of legend entries (LegendEntries object) for the legend — Syntax: objLegend.LegendEntries(Index). To return a single LegendEntry object use the Index argument, where the index is the number of the legend entry’s position in the legend starting from top ie. LegendEntries(1), to bottom ie. LegendEntries(LegendEntries.Count). A Legend entry cannot be returned by name.

A Legend Entry has 2 parts — text & entry marker. The text part refers to the series (or trendline) name which is associated with the legend entry. The legend entry is visually linked with its associated series or trendline, by the entry marker which can be formatted using the LegendKey object (using the LegendKey object will format both the entry marker & its associated series or trendline). To restore a legend entry after its deletion, you will need to remove and recreate the legend (wherein the legend entry was contained) by first setting the HasLegend property of the chart to False and then setting it back to True. The Text part cannot be changed, font can be formatted but not the pattern, and you cannot return the legend entry’s associated series or trendline.

The LegendKey object controls the appearance of the series or trendline associated with a legend entry. The LegendKey Object refers to the legend key in a Legend which is a graphic visually linking a legend entry with its associated series or trendline so that any formatting change in one automatically changes the other’s formatting. In this manner the LegendKey object contains the formatting properties for the entry marker and its associated series or trendline. The LegendKey object is returned by using the LegendKey property of the Legend Entry, & a LegendKey object is contained in each LegendEntry object.

Example: Manipulate legend font (font for all legend entries) — use the Font property of the Legend object to return the Font object

Sub legend_Font()
‘manipulate legend font (font for all legend entries) — use the Font property of the Legend object to return the Font object

With Sheets(«Sheet1»).ChartObjects(1).Chart.Legend.Font

.Name = «Arial«

.Italic = True

.Size = 9

.Color = RGB(0, 0, 255)

.Strikethrough = False

.Superscript = False

.Subscript = False

.Background = xlAutomatic

.Underline = xlUnderlineStyleSingle

End With

End Sub

Example: format shadow, border & fill for chart Legend — refer Image 1

Sub legend_Format()
‘format shadow, border & fill for chart legend — refer Image 1

‘remove shadow, border & fill for chart legend — set fill / interior color — remove fill

With Sheets(«Sheet1»).ChartObjects(1).Chart.Legend

‘remove shadow

.Shadow = False

‘remove border

.Format.Line.Visible = False

‘remove fill

.Format.Fill.Visible = msoFalse

‘sets fill / interior color

.Interior.Color = RGB(230, 185, 184)

‘changes fill / interior color to green

.Interior.Color = vbGreen

‘.Interior.ColorIndex = 4

‘remove fill

.Format.Fill.Visible = msoFalse

End With

With Sheets(«Sheet1»).ChartObjects(1).Chart.Legend

‘turn on the border for the chart area

.Format.Line.Visible = True

‘using the Weight Property of the LineFormat object, to set the weight of the border

.Format.Line.Weight = 1.25

‘use the ColorIndex Property of the Border object to set the border color: to set no line color use ColorIndex = xlNone, or use ColorIndex 3 for red, 5 for blue, 4 for green, 6 for yellow, and so on.

.Border.ColorIndex = 3

.Border.LineStyle = xlDot

.Shadow = True

End With

With Sheets(«Sheet1»).ChartObjects(1).Chart.Legend.Format.Shadow

.Visible = msoTrue

‘specify the type of shadow displayed as second shadow type

‘.Type = msoShadow2

‘set the style as outer shadow effect

.Style = msoShadowStyleOuterShadow

‘set blurr degree of the shadow

.Blur = 4

‘do not rotate the shadow when rotating the shape

.RotateWithShape = msoFalse

‘set the fill color

.ForeColor.RGB = RGB(255, 0, 0)

‘set the horizontal offset of the shadow from the legend, in points — a positive value offsets the shadow to the right while a negative value offsets it to the left

.OffsetX = 2

‘set the vertical offset of the shadow from the legend, in points — a positive value offsets the shadow to the right while a negative value offsets it to the left

.OffsetY = 4

‘set the degree of transparency as a value from 0.0 (opaque) through 1.0 (clear)

.Transparency = 0.4

‘set the size of the shadow

.Size = 100

End With

With Sheets(«Sheet1»).ChartObjects(1).Chart.Legend.Format.Fill

‘set the fill to be visible

.Visible = msoTrue

‘set the fill color that is mapped to the theme color scheme — specify the Accent 2 theme color

.ForeColor.ObjectThemeColor = msoThemeColorAccent2

‘set a value to lighten or darken a color —  a number from -1 (darkest) to 1 (lightest) where Zero (0) is neutral

.ForeColor.TintAndShade = 0.65

‘specify fill to a two-color gradient — gradient running vertically down the shape — and specify gradient variant as 2

.TwoColorGradient msoGradientVertical, 2

End With

End Sub

Use the LegendKey Property of the LegendEntry object to return a LegendKey object which represents the legend entry’s associated legend key. The legend key is a graphic visually linking a legend entry with its associated series or trendline so that any formatting change in one automatically changes the other’s formatting. In this manner the LegendKey object contains the formatting properties for the entry marker and its associated series or trendline. This legend key, besides having the the ChartFormat object (returned by its Format property: objLegendKey.Format) which contains the line, fill & effect formatting, has its Interior, Border & ChartFillFormat child objects.

Sub LegendKey_1()
‘format legend key, series markers / points & series line
‘use the legend key’s Interior / Fill / Border / Format properties to return Interior Object / ChartFillFormat Object / Border Object / ChartFormat object respectively

‘for markers / points of legend entry 1

With Sheets(«Sheet1»).ChartObjects(1).Chart.Legend.LegendEntries(1).LegendKey

With .Interior

‘set the interior pattern for markers / points to automatic — let Excel control it

.Pattern = xlPatternAutomatic

‘set the interior pattern to Checkerboard

.Pattern = xlChecker

‘set the color of the interior pattern as an RGB value, to yellow.

.PatternColor = RGB(255, 255, 0)

‘set the color of the interior pattern as an index into the current color palette, to yellow

‘.PatternColorIndex = 6

End With

End With

‘for markers / points of legend entry 2

With Sheets(«Sheet1»).ChartObjects(1).Chart.Legend.LegendEntries(2).LegendKey

With .Fill

‘remove fill color from legend key & all points in the associated series

.Visible = msoFalse

‘set a solid fill of uniform color

.Solid

‘set the interior color to Yellow

.ForeColor.SchemeColor = 6

End With

End With

With Sheets(«Sheet1»).ChartObjects(1).Chart.Legend.LegendEntries(3).LegendKey

‘sets the marker background / fill color, as an index, for the legend entry & all points in the associated series (which must support data markers).

.MarkerBackgroundColorIndex = 5

‘set the marker foreground (border line) color as an RGB value for all points in the associated series

.MarkerForegroundColor = RGB(255, 255, 0)

‘sets the data-marker size, in points

.MarkerSize = 8

‘set the marker style as Triangular markers

.MarkerStyle = xlMarkerStyleTriangle

‘this sets the Marker weight (marker’s border line width) and also sets the series line thickness

.Format.Line.Weight = 2

End With

With Sheets(«Sheet1»).ChartObjects(1).Chart.Legend.LegendEntries(4).LegendKey

With .Format.Fill

‘remove marker fill color from legend key & all points in the associated series

.Visible = msoFalse

‘sets the marker fill color for the legend entry & all points in the associated series (which must support data markers).

.ForeColor.RGB = RGB(255, 0, 0)

End With

End With

With Sheets(«Sheet1»).ChartObjects(1).Chart.Legend.LegendEntries(5).LegendKey

‘legend key’s border property returns the series line

With .Border

‘set series linestyle as continuous line

.LineStyle = xlContinuous

‘set series linestyle as dotted line

.LineStyle = xlDot

‘set the weight / thickness

.Weight = xlMedium

‘set the line color to red

.Color = vbRed

End With

End With

End Sub

Child Objects for the Legend Object: Above we have discussed: the ChartFormat object — use the Format Property — objLegend.Format — to return the ChartFormat object which contains the line, fill & effect formatting for the chart legend. Some other child objects which are often used with the Legend Object include: ChartFillFormat Object — use the Fill Property — objLegend.Fill — to return a ChartFillFormat object (valid only for charts), to manipulate fill formatting for chart elements; Interior Object — use the Interior property — objLegend.Interior — to return the Interior object, to manipulate the chart element’s interior (inside area); Border Object — use the Border Property — objLegend.Border — to return a Border object, to manipulate a chart element’s border; Font Object — use the Font Property — objLegend.Font — to return a Font object, to manipulate the font attributes viz. font name, font size, font color, … The difference between ChartFillFormat object & the Interior object may be somewhat blurred, but seemingly the ChartFillFormat object emphasises gradient & texture fills, whereas the Interior object emphasises solid fills & pattern fills (though ChartFillFormat object also has a Pattern property).

Example: Part 8 of 8 — Manipulate Chart Legend — refer Image 1.8

To download Excel file with live code, click here.

Sub EmbChart_Legend_8()
‘manipulate Chart Legend — refer Image 1.8

Dim wsChart As Worksheet

‘declare a ChartObject object

Dim oChObj As ChartObject

Set wsChart = Sheets(«Sheet19»)

‘set ChartObject object by name

Set oChObj = wsChart.ChartObjects(«QtrlySalesProfitChart»)

‘using the Chart Property of the ChartObject object returns a Chart object which refers to a chart

With oChObj.Chart

‘use the Legend Property of the Chart object to return the Legend object, which represents the chart Legend

With .Legend

‘use the Font property of the Legend object to return the Font object — set font for the Legend (all legend entries) to bold

.Font.Bold = True

‘set font for the Legend (all legend entries) to italic

.Font.Italic = True

‘the LegendEntry object represents a legend entry in a chart legend, which is a member of the LegendEntries collection

‘use the LegendEntries method of the Legend object to return the LegendEntries Object (LegendEntries collection) which is a collection of all the LegendEntry objects in a chart legend

‘set font color of the legend entry 1 (index number represents the legend entry’s position in the legend), which is at the top of the legend, to red

.LegendEntries(1).Font.ColorIndex = 3

‘set font color of the legend entry 2

.LegendEntries(2).Font.Color = RGB(149, 55, 53)

‘set font color of the legend entry 3 to blue

.LegendEntries(3).Font.ColorIndex = 5

‘use the LegendKey property (of the LegendEntry object) to return the LegendKey object which refers to the legend key in a Legend which is a graphic visually linking a legend entry with its associated series or trendline so that any

formatting change in one automatically changes the other’s formatting

‘using the MarkerStyle Property of the LegendKey object to set the marker style for a point or marker in the line chart — use the XlMarkerStyle Enumeration of xlMarkerStyleTriangle for Triangular markers

.LegendEntries(2).LegendKey.MarkerStyle = xlMarkerStyleTriangle

‘set the data-marker size, in points, using the MarkerSize Property of the LegendKey object

.LegendEntries(2).LegendKey.MarkerSize = 8

‘set the marker foreground (marker border line) color as an RGB value for all points in the associated series — set color to black

.LegendEntries(2).LegendKey.MarkerForegroundColor = RGB(0, 0, 0)

End With

End With

End Sub

Свойства — участники объекта Chart

Объекты, вложенные в Chart, представлены на рис. 3.18, а на следующем рисунке показана структура объектов ChartGroup и Series.

Давайте познакомимся с объектами, вложенными в Chart:

• PivotLayout — это новый объект, появившийся в Office 2000. Его появление связано с усилением внимания к обработке многомерных источников данных, а, следовательно, и к сводным таблицам и диаграммам. Объект имеет много свойств, позволяющих добраться до полей сводной таблицы, и много методов, например, метод AddFields, позволяющий добавить новое поле. С его помощью можно также работать с осями сводной диаграммы.
• ChartArea — представляет область, отведенную под диаграмму. Для двумерных диаграмм эта область включает заголовок диаграммы, легенду, оси и их заголовки, а для трехмерных — только заголовок диаграммы и легенду. Вложенные в ChartArea объекты: Border, Font, Interior, FillFormat позволяют задать границы области, используемый для подписей шрифт, формат заполнения, цвет, образец заполнения фона и другие характеристики. Терминальные свойства Height, Width, Left, Top задают границы области. Методы Select, Clear, Copy позволяют выделить область, очистить ее содержимое или поместить его в буфер.
• PlotArea — задает внутреннюю часть области диаграммы, отведенную непосредственно для графического отображения данных. Эту область окружает область объекта ChartArea. В область объекта PlotArea для двумерных диаграмм входят маркеры данных, линии сетки, линии тренда и те возможные элементы диаграммы, которые помещаются в ее область. Для трехмерных диаграмм к этой области относятся также оси и их заголовки, а также нижняя грань и боковые грани трехмерного куба, рисуемого для создания иллюзии трехмерного пространства. PlotArea имеет свойства и методы, сходные с объектом ChartArea.
• ChartTitle — является «полноценным» объектом. Помимо свойства Text, задающего текст заголовка диаграммы в него встроены собственные объекты: Border, Font, Interior, FillFormat. Кроме этого можно задать ориентацию заголовка, выравнивание, расположение. Есть даже собственные методы — Select и Delete.
• Axes(Axis) — С осями диаграммы есть смысл разобраться подробнее. Во-первых, есть некоторая путаница в классификации — что есть Axes -метод или свойство? Будем считать, что есть и метод и свойство. Метод Axes(Type, AxisGroup) возвращает одну ось — объект Axis. Параметр Type имеет три значения: xlValue, xlCategory, или xlSeriesAxis (только для трехмерных диаграмм), указывающих, какая из трех возможных осей возвращается. Второй параметр — AxisGroup указывает, какая ось возвращается — основная или вспомогательная. Этот параметр имеет два значения: xlPrimary или xlSecondary. Для трехмерных диаграмм возможно использование только основных осей. Свойство Axes (или метод, вызываемый без параметров) возвращает коллекцию осей. Метод Item этой коллекции позволяет добраться до нужной оси. Пример работы с этим объектом был приведен. Замечу, что вспомогательные оси полезны,
  когда на диаграмме
  отображаются несколько рядов данных, имеющих разные масштабы. Соответствующий пример построения такой оси уже был приведен.
• SeriesCollection(Series) — коллекция рядов данных. Как обычно, параметр Index или метод Item позволяют добраться до элемента коллекции — объекта класса Series, представляющего конкретный ряд данных. Коллекция имеет следующие методы:
  • Add, позволяющий добавить новый ряд данных,
  • Extend, добавляющий новые точки в ряды данных коллекции,
  • NewSeries, создающий новый ряд данных и возвращающий в качестве результата объект класса Series.

  Конечно, непросто устроен и объект Series, задающий сам ряд данных. Его структура показана на рис. 3.19, а некоторые из основных его свойств были продемонстрированы в предыдущем примере.

• DataTable — объект, представляющий таблицу данных. Основными методами являются Select и Delete, основные свойства связаны с рамкой, строящейся вокруг таблицы. Вся содержательная работа с данными таблицы ведется через другие объекты (ряды данных). Так что по существу этот объект представляет рамку таблицы данных.
• Legend — задает легенду диаграммы. O сущности этого объекта мы уже говорили, так что его поведение должно быть понятно.
• Shapes — эта коллекция нам хорошо знакома. В диаграммах она используется редко, но иногда можно категории изображать рисунками, что повышает эстетику диаграммы.
• ChartGroups(ChartGroup) — возвращает коллекцию групп. Элементами коллекции являются объекты класса ChartGroup. Каждый такой объект представляет группу, связанную с одним или несколькими рядами данных, отображаемых диаграммой одного и того же типа, о чем я уже подробно рассказывал. Параметр Index позволяет добраться до конкретной группы в коллекции. Поскольку при форматировании одной из группы индексы изменяются, то иногда удобнее пользоваться специальными методами, которые возвращают группы фиксированного типа. Такими методами являются: AreaGroups, BarGroups, ColumnGroups, DoughnutGroups, LineGroups и PieGroups. Эти методы для двумерных диаграмм возвращают коллекцию групп типа, указанного методом. К конкретной группе можно добраться опять — таки с помощью индекса. Для трехмерных диаграмм может быть только одна группа определенного формата. Поэтому есть методы, возвращающие эту единственную группу: Area3DGroup, Bar3DGroup,
  Column3DGroup, Line3DGroup, Pie3DGroup, SurfaceGroup.
• Floor, Walls и Corners объекты используются при работе с трехмерными диаграммами. При отображении таких диаграмм для создания иллюзии трехмерного пространства диаграмма отображается на фоне открытого куба, имеющего основание, заданное объектом Floor, и две боковые грани — объекты Walls. Объект Corners задает углы куба. Манипулируя этими объектами, можно, например, развернуть куб или изменить заливку и узор стенок куба, добиваясь большей наглядности изображения.

Терминальные свойства объекта Chart

Основные терминальные свойства сведены в таблицу.

Методы объекта Chart

Мы не будем рассматривать методы, которые так или иначе уже встречались. Рассмотрим только основные методы, определяющие новое поведение объекта Chart:

• Sub ChartWizard([Source], [Gallery], [Format], [PlotBy], [CategoryLabels], [SeriesLabels], [HasLegend], [Title], [CategoryTitle], [ValueTitle], [ExtraTitle]) Этот метод позволяет построить или модифицировать существующую диаграмму. В отличие от мастера диаграмм (ChartWizard), который вызывается при построении диаграммы вручную, метод не является интерактивным, более того он не позволяет задать все возможные свойства. С его помощью можно выполнить основную работу, а детали строятся с использованием других свойств и методов объекта Chart. В одном из ранее приведенных примеров (процедуре AddChart ) я демонстрировал применение этого метода для программного построения диаграммы. Дадим краткое описание параметров метода, все из которых являются необязательными:
  • Source — объект Range, содержащий исходные данные для построения новой диаграммы. Если параметр опущен, то метод позволяет отредактировать существующую диаграмму — либо выделенную диаграмму рабочего листа, либо диаграмму активного листа диаграмм.
  • Gallery — задает тип диаграммы и может быть одной из следующих констант: xlArea, xlBar, xlColumn, xlLine, xlPie, xlRadar, xlXYScatter, xlCombination, xl3DArea, xl3DBar, xl3DColumn, xl3DLine, xl3DPie, xl3DSurface, xlDoughnut, или xlDefaultAutoFormat.
  • Format — задает формат для данного типа диаграммы. Каждому типу диаграммы соответствует некоторое число возможных форматов. Параметр задает номер формата, по умолчанию выбирается первый формат данного типа.
  • PlotBy — соответствует терминальному свойству PlotBy.
  • CategoryLabels и SeriesLabels — целые, указывающие число строк или столбцов с метками категорий и рядов данных в области, заданной параметром Source. Указывать эти числа нужно на единицу меньше фактического значения.
  • Остальные параметры позволяют добавить легенду, задать название диаграммы и ее осей — они совпадают с соответствующими терминальными свойствами.
• Sub SetSourceData(Source As Range, [PlotBy]) Устанавливает источник данных диаграммы. Второй параметр соответствует терминальному свойству PlotBy.
• Sub ApplyCustomType(ChartType As XlChartType, [TypeName]) Метод позволяет модифицировать диаграмму, применив к ней новый тип — стандартный или настраиваемый. Если этот тип стандартный, то тогда первый параметр полностью его определяет. Его возможные значения совпадают со значениями соответствующего терминального свойства ChartType. Если же тип настраиваемый, то первый параметр должен иметь одно из следующих значений: xlBuiltIn, xlUserDefined или xlAnyGallery. В этом случае второй параметр задает имя типа диаграммы.
• Function Export(Filename As String, [FilterName], [Interactive]) As Boolean Позволяет экспортировать диаграмму, преобразуя ее в графический формат. Первый параметр задает имя файла, в который будет записана диаграмма в графическом формате, второй — задает имя графического фильтра в том виде, как оно записано в системном регистре. Булев параметр Interactive должен иметь значение True, если мы хотим вызвать диалоговое окно в процессе фильтрации. Функция Export возвращает значение True в случае успешного завершения работы.
• Sub GetChartElement(X As Long, Y As Long, ElementID As Long, Arg1 As Long, Arg2 As Long). Представьте себе, что пользователь щелкнул кнопку мыши где-то над диаграммой. Обработав это событие, можно получить координаты курсора мыши — X и Y. Если теперь вызвать метод GetChartElement с этими координатами, то он вернет значение параметра ElementID — идентификатор элемента диаграммы и значения двух параметров, связанных с этим элементом. Конечно, параметры зависят от типа того элемента, чьи координаты X и Y заданы.
• Function Location(Where As XlChartLocation, [Name]) As Chart. Передвигает диаграмму в новое местоположение. Параметр Where имеет следующие значения: xlLocationAsNewSheet, xlLocationAsObject, или xlLocationAutomatic.

  В первом случае диаграмма помещается на новый лист диаграммы и параметр Name задает имя этого листа. Во втором случае диаграмма помещается как встроенный объект и Name задает имя рабочего листа. Вот пример, в котором диаграмму, построенную на рабочем листе книги «BookOne» мы переносим на отдельный лист диаграмм:

  Public Sub MoveChart()
  Workbooks("BookOne").Worksheets("Sheet1").ChartObjects(4) _
  .Chart.Location Where:=xlLocationAsNewSheet, Name:="Динамика продаж"
  End Sub

• Sub SetSourceData(Source As Range, [PlotBy]) Позволяет установить новый источник данных. Параметры в пояснениях не нуждаются.

В заключение приведем процедуру, создающую трехмерную диаграмму по данным нашего примера с дилерами и продажами:

Public Sub Chart3D()
	Workbooks("BookFour").Activate
	With Worksheets("Лист3")
		Dim myRange As Range
		Set myRange = .Range("C23:F27")
		Dim myChart As ChartObject
		'Создаем контейнер объекта Chart
		Set myChart = .ChartObjects.Add(myRange.Left - 100, _
		myRange.Top + myRange.Height, 400, 300)
	End With
	'Определяем параметры объекта Chart
	With myChart.Chart
		.ChartType = xl3DColumn
		.SetSourceData Source:=myRange, PlotBy:=xlRows
		.Location Where:=xlLocationAsObject, Name:="Лист3"
	End With
	With ActiveChart
		.HasTitle = True
		.ChartTitle.Characters.Text = "Динамика продаж"
	End With
	'Диалог с пользователем
	If MsgBox("Хотите изменить угол зрения?", vbYesNo) = vbYes Then
		ActiveChart.RightAngleAxes = True
	End If
End Sub

Дадим некоторые комментарии к этой программе:

• В качестве источника данных выступает известная по предыдущим примерам таблица Excel.
• Я ввел объекты myRange и myChart класса ChartObjects. Это позволило задать нужные размеры и положение диаграммы, привязанное к таблице данных.
• Ранее при построении диаграмм я использовал метод ChartWizard и работу с коллекциями SEriesCollection. Теперь продемонстрирован еще один способ, когда задаются свойства и методы объекта Chart, в частности, для указания источника данных используется метод SetSourceData.
• Свойство ChartType позволяет указать тип диаграммы, а метод Location определяет ее, как встроенный объект.
• В диалоге с пользователем изменяется угол зрения, задаваемый булевым свойством RightAngleAxes.
• Задав еще заголовок диаграммы, и приняв остальные свойства диаграммы по умолчанию, я получил диаграмму, представленную на рис.3.14.

События объекта Chart

В отличие от объекта Worksheet, все события которого могут быть обработаны на верхнем уровне, объект Chart имеет специфические события, сообщения о которых направляются только ему одному. Встроенные диаграммы и листы диаграмм, имеют одни и те же события. Разница состоит в том, что события встроенных диаграмм по умолчанию выключены, поэтому необходимо потрудиться, чтобы стало возможным их подключение и написание обработчиков событий. Рассмотрим список событий, связанных с объектом Chart:

Построение обработчиков событий

Обработчики событий для объектов Workbook, Worksheet и объектов Chart, задающих листы диаграмм, построить нетрудно. Все эти события по умолчанию включены, поэтому для построения обработчика достаточно перейти в окно проектов, выбрать модуль, обрабатывающий события этого объекта, в окне объектов этого модуля выбрать нужный объект, а затем в окне событий и процедур выбрать из списка имя события. В результате этих действий появится заготовка, содержащая заголовок обработчика события, после чего останется написать код обработчика. Более сложно строятся обработчики событий для объектов Chart, задающих встроенные диаграммы. О том как создаются обработчики событий для тех объектов, у которых события по умолчанию выключены, я подробно рассказал при рассмотрении событий объекта Application. Остается только коротко напомнить схему действий:

• Вначале нужно создать класс, в котором следует объявить объект Chart с событиями (With Events)
• Затем нужно объявить глобальный объект созданного класса — объект, уже имеющий события. После этого остается написать инициализирующую процедуру, в которой связывается глобальный объект с объектом, задающим встроенную диаграмму.
• Поскольку объект Chart с событиями появляется в окне созданного класса, то к нему применяется обычная схема создания обработчиков событий.
• После запуска инициализирующей процедуры, объект, задающий встроенную диаграмму, будет реагировать на события.

Возможно, следует обратиться к началу главы, где все подробно описано на примере работы с объектом Application.