Excel отменить действия макроса excel

Хитрости »

24 Февраль 2012              61044 просмотров

Как отменить действия макроса

Многие из тех, кто программирует в VBA знают, что после действий макроса пропадает возможность отмены действий. И если с отменой тех действий, которые были совершены до выполнения макроса совершенно точно можно распрощаться(невозможно будет это сделать), то отменить действия макроса возможно. И рано или поздно каждый программирующий в VBA задается вопросом: как можно отменить действия, совершенные макросом? Для начала надо понять, в каких ситуациях это нам надо. Например был выполнен код, который испортил или удалил данные в файле, но эти данные еще нужны. Самое простое, что можно сделать это закрыть файл без сохранения и открыть заново. Все данные будут на месте(если, конечно, в коде не было строки, сохраняющей файл). Второй способ: это перед выполнением макроса делать резервную копию файла — тогда Ваши исходные данные всегда будут целы.

Но как же сделать отмену действий макроса через стандартную кнопку на панели или сочетанием клавиш

Ctrl

+

Z

и можно ли? Ответ — можно. Но сразу вопрос: а насколько это нужно? В каких ситуациях это может пригодиться? Я навскидку сразу не сказал бы, если бы не являлся разработчиком программ и надстроек в среде Microsoft Excel. Именно в надстройках отмена действий наиболее востребована, на мой взгляд. Например надстройка объединяет ячейки. Объединили случайно и…В стандартной ситуации после такого макроса нельзя отменить действия. Закрывать файл без сохранения? Как-то некрасиво получается, если продукт является коммерческим. И тогда приходится извращаться и пытаться сделать возможным отмену действий макроса. В моей надстройке MulTEx в некоторых командах отмена действий команд как раз и применяется. Наиболее распространенное решение по отмене действий макроса заключается в запоминании свойств изменяемых ячеек:

'Создаем свой пользовательский тип данных
Type SaveRange
    vFormula As Variant
    sAddr As String
    lColor As Long
    lColorIndex As Long
End Type
'Переменные для запоминания данных
Public wbWBook As Excel.Workbook
Public wsSh As Excel.Worksheet
Public vOldVals() As SaveRange
'---------------------------------------------------------------------------------------
' Procedure : Fill_Numbers
' Purpose   : Основная процедура. Это тот код, который вносит изменения на лист
'             и действия которого нам необходимо отменить
'             Процедура заполняет выделенные ячейки номерами
'             и изменяет цвет заливки
'---------------------------------------------------------------------------------------
Sub Fill_Numbers()
    Dim rCell As Range, li As Long
    '   Сначала запоминаем значения выделенных ячеек на листе
    ReDim vOldVals(1 To Selection.Count)
    'Запоминаем активную книгу
    'это на случай, если отмена действий будет производиться из другой книги
    Set wbWBook = ActiveWorkbook
    'Запоминаем активный лист
    'на случай, если отмена действий будет производиться из другого листа
    Set wsSh = ActiveSheet
    'Запоминаем значения(заносим в массив)
    li = 1
    For Each rCell In Selection
        'запоминаем адрес ячейки
        vOldVals(li).sAddr = rCell.Address
        'запоминаем формулу(если нет формулы - значение)
        vOldVals(li).vFormula = rCell.Formula
        'запоминаем цвет заливки ячейки
        vOldVals(li).lColor = rCell.Interior.Color
        'запоминаем индекс цвета заливки(чтобы на заливать бесцветные ячейки)
        vOldVals(li).lColorIndex = rCell.Interior.ColorIndex
        li = li + 1
    Next rCell
    '======================================
    'Выполняем основные действия(собственно тот код, который надо будет отменить)
    li = 1
    For Each rCell In Selection
        rCell = li
        rCell.Interior.ColorIndex = li
        li = li + 1
    Next rCell
    '======================================
    'Назначаем стандартному вызову отмены действий выполнение нашего макроса возвращения значений
    Application.OnUndo "Отменить заполнение ячеек номерами", "Restore_Vals"
End Sub
 
'---------------------------------------------------------------------------------------
' Procedure : Restore_Vals
' Purpose   : Процедура отмены действия(возврат значений)
'---------------------------------------------------------------------------------------
Sub Restore_Vals()
    Dim li As Long
    'В случае непредвиденной ошибки переходим на метку
    'и показываем сообщение об ошибке
    On Error GoTo Erreble
    'Активируем книгу, в которой были сделаны изменения
    wbWBook.Activate
    'Активируем лист, в котором были сделаны изменения
    wsSh.Activate
    'Возвращаем значения
    For li = 1 To UBound(vOldVals)
        Range(vOldVals(li).sAddr).Formula = vOldVals(li).vFormula
        'если заливка была безцветная, то ColorIndex = xlNone
        'значит выставляем безцветность
        If Not vOldVals(li).lColorIndex = xlNone Then
            Range(vOldVals(li).sAddr).Interior.Color = vOldVals(li).lColor
        Else 'если цвет был - возвращаем его
            Range(vOldVals(li).sAddr).Interior.ColorIndex = xlNone
        End If
    Next li
    Exit Sub
 
    'Показываем сообщение о невозможности отмены действия
Erreble:
    MsgBox "Нельзя отменить действие!", vbCritical, "Error"
End Sub

Комментарии к коду я старался сделать максимально подробными, поэтому думаю, что больше нечего разъяснять. К тому же по древней традиции я приложил к статье пример с данным кодом Единственное, что могу добавить: пользовательский тип SaveRange может быть дополнен еще какими-либо переменными, помимо vFormula, sAddr и lColor. Например цвет границ ячейки, цвет шрифта и т.д. Все зависит от того, какие изменения Вы будете делать кодом и что захотите затем вернуть.

Скачать пример

  Отменить действия макроса.xls (62,0 KiB, 3 360 скачиваний)

Код, приведенный выше, несомненно хорош, но если кол-во изменяемых ячеек достаточно велико, то код будет очень замедлять работу. Поэтому если есть возможность добавлять/удалять листы в книгах, то можно схитрить: сделать резервную копию листа, лист сделать очень скрытым и как только потребуется отмена действия — вернуть этот лист, удалив исходный(с уже испорченными данными):

'Переменные для запоминания данных
Public wbWBook As Workbook
Public wsSh As Worksheet, wsActSh As Worksheet, sSh_Name As String, lShPoz As Long
'---------------------------------------------------------------------------------------
' Procedure : Fill_Numbers
' Purpose   : Основная процедура. Это тот код, который вносит изменения на лист
'             и действия которого нам необходимо отменить
'             Процедура заполняет выделенные ячейки номерами
'             и изменяет цвет заливки
'---------------------------------------------------------------------------------------
Sub Fill_Numbers()
    Dim rCell As Range, li As Long
    'Запоминаем активную книгу
    'это на случай, если отмена действий будет производиться из другой книги
    Set wbWBook = ActiveWorkbook
    'Запоминаем активный лист
    'на случай, если отмена действий будет производиться из другого листа
    Set wsActSh = ActiveSheet
    lShPoz = wsActSh.Index
    sSh_Name = wsActSh.Name
    Application.ScreenUpdating = 0
    wsActSh.Copy , wbWBook.Sheets(wbWBook.Sheets.Count)
    Set wsSh = wbWBook.Sheets(wbWBook.Sheets.Count)
    wsSh.Visible = xlVeryHidden
    wsActSh.Activate
    Application.ScreenUpdating = 1
    '======================================
    'Выполняем основные действия(собственно тот код, который надо будет отменить)
    li = 1
    For Each rCell In Selection
        rCell = li
        rCell.Interior.ColorIndex = li
        li = li + 1
    Next rCell
    '======================================
    'Назначаем стандартному вызову отмены действий выполнение нашего макроса возвращения значений
    Application.OnUndo "Отменить заполнение ячеек номерами", "Restore_Vals"
End Sub
 
'---------------------------------------------------------------------------------------
' Procedure : Restore_Vals
' Purpose   : Процедура отмены действия(возврат значений)
'---------------------------------------------------------------------------------------
Sub Restore_Vals()
    'В случае непредвиденной ошибки переходим на метку
    'и показываем сообщение об ошибке
    On Error GoTo Erreble
    Application.ScreenUpdating = 0
    'Активируем книгу, в которой были сделаны изменения
    wbWBook.Activate
    'делаем видимым резервный лист
    wsSh.Visible = -1
    'Удаляем исходный лист, данные в котором уже изменены
    Application.DisplayAlerts = 0
    wsActSh.Delete
    Application.DisplayAlerts = 1
    'назначаем резервному листу имя исходного
    wsSh.Name = sSh_Name
    wsSh.Move wbWBook.Sheets(lShPoz)
    'Активируем резервный лист
    wsSh.Activate
    Application.ScreenUpdating = 0
    Exit Sub
    'Показываем сообщение о невозможности отмены действия
Erreble:
    MsgBox "Нельзя отменить действие!", vbCritical, "www.excel-vba.ru"
End Sub

Скачать пример

  Tips_Restore_Macro_HiddenSh.xls (45,0 KiB, 2 366 скачиваний)

Конечно, в этом приеме тоже есть недостаток — если на этот лист ссылаются формулы из других листов есть большой шанс получить в этих формулах ошибку

#ССЫЛКА!(#REF!)

, т.к. исходный лист удаляется.
В этом случае можно из резервного листа копировать все ячейки и вставлять на рабочий лист. Да и вообще можно много чего придумать — вплоть до сохранения и последующего извлечения резервных копий файлов. Все как всегда зависит от задач и ситуации.

И самая большая ложка дегтя к обоим кодам: VBA не позволяет таким образом делать МНОГОКРАТНЫЕ отмены действий(многократное Ctrl+Z), что делает бесполезными попытки запомнить пошагово несколько разных изменений макросами. Отменить можно будет все равно только последнее запомненное действие.

Статья помогла? Поделись ссылкой с друзьями!

    Видеоуроки

Поиск по меткам



Access
apple watch
Multex
Power Query и Power BI
VBA управление кодами
Бесплатные надстройки
Дата и время
Записки
ИП
Надстройки
Печать
Политика Конфиденциальности
Почта
Программы
Работа с приложениями
Разработка приложений
Росстат
Тренинги и вебинары
Финансовые
Форматирование
Функции Excel
акции MulTEx
ссылки
статистика

KukLP  
«столкнулся с необходимостью отменять косяки неотлаженного макроса»  

  С макросами которые у меня выполняют сложные задачи мне отменться не нужно, они все весьма нелохо работают, а вот этому маленькому макросу, который я потом повешу на конпку на панеле быстрого доступа всё же нужна отмена, так как это действие вставка+сложить  
и даже если чисто механически случайно поставишь при подобной вставке курсор не в ту ячейку, то уже действие безвозратно, да я понимаю что можно сразу нажать на вставка-вычесть и всё станет прежним, но всё же првыйчнее Undo.  

  Следуя совету The_Prist  
я оставил то что он сказал, и вышло вот так  

  ‘Custom data type for undoing  
   Type SaveRange  
       Val As Variant  
       Addr As String  
   End Type  

      ‘   Stores info about current selection  
   Public OldWorkbook As Workbook  
   Public OldSheet As Worksheet  
   Public OldSelection() As SaveRange  

    Sub PasteAdd()  
   If TypeName(Selection) <> «Range» Then Exit Sub  
   Application.ScreenUpdating = False  

      ‘Специальная вставка-значения-сложить (тоесть действие которое нужно отменить)  
   Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlAdd, SkipBlanks _  
:=False, Transpose:=False  
End Sub  

      ‘   Specify the Undo Sub  
   Application.OnUndo «Undo the PasteAdd macro», «UndoAdd»  
End Sub  

    Sub UndoAdd()  
‘   Undoes the effect of the ZeroRange sub  

      ‘   Tell user if a problem occurs  
   On Error GoTo Problem  

     Application.ScreenUpdating = False  

      ‘   Make sure the correct workbook and sheet are active  
   OldWorkbook.Activate  
   OldSheet.Activate  

      ‘   Restore the saved information  
   For i = 1 To UBound(OldSelection)  
       Range(OldSelection(i).Addr).Formula = OldSelection(i).Val  
   Next i  
   Exit Sub  

  ‘   Error handler  
Problem:  
   MsgBox «Can’t undo»  
End Sub  

  но мой Sub PasteAdd() в этой ситуации неработает теперь вообще, подправьте пожалуйста, и не нужно язвить (этот форум ведь создан для взаимопомощи и общения, так давайте помогать друг другу, поскольку, то что для кого то кажеться простым, для другого вызывает трудности).

Надстройка ЁXCEL — это набор макросов (микропрограмм) которые могут производить операции с данными во всех файлах MS Excel независимо от версии программы, в которой они созданы.

Так как макросы не являются частью MS Excel их использование сопряжено с рядом ограничений, которые накладывает MS Excel, в частности:

• MS Excel не запоминает действия, которые выполняют макросы, и соответственно отмена этих действий связана с определенными ограничениями;
• Иногда MS Excel не считает действия, выполненные макросами — изменением данных в файле, соответственно при сохранении файлов это необходимо учитывать;
• Функции (формулы) надстройки можно использовать только на компьютерах, где установлена надстройка.

Использование надстройки:

Чтобы все команды и функции надстройки работали правильно, необходимо соответствующим образом настроить параметры безопасности (подробнее в статье «Как подключать надстройки к MS Excel?»).

Отмена действий, выполненных надстройкой:

MS Excel не умеет производить отмену действий, произведенных макросами, поэтому для отмены большинства действий, выполняемых надстройкой, в самой надстройке записан соответствующий макрос, который отвечает за отмену того или иного действия. По этой же причине существует ограничение по отмене действий, а именно: Вы можете отменить только одно действие, произведенное с использованием надстройки.

Пример:

Допустим, Вы хотите отформатировать текст в некой ячейке. Вы выделяете эту ячейку и выбираете команду надстройки «Прописные В Начале Слова»:

Первые буквы слов станут прописными, а в меню отмены появляется возможность «Отменить Прописные В Начале Слова»:

Если вы нажмете кнопку «Отменить», данные вернуться в исходное состояние. Если Вы захотите произвести еще какие-либо действия, используя стандартные команды MS Excel (например, выделить текст жирным), в меню отмены появиться еще один пункт и возможность отменить «Прописные В Начале Слова» останется:

Если Вы после этого отформатируете текст еще раз, с помощью команд надстройки (например, ВСЕ ПРОПИСНЫЕ), в меню отмены пропадут все предыдущие пункты и останется возможность отменить только «ВСЕ ПРОПИСНЫЕ»:

После нажатия кнопки отмены, отмениться команда «ВСЕ ПРОПИСНЫЕ» и кнопка отмены станет неактивной, иными словами «Выделить жирным» и «Прописные В Начале Слова» отменить будет уже нельзя.

Учитывайте это ограничение при работе с данными и по возможности, если вас не устраивает результат, сразу же отменяйте действие той или иной команды.

Еще один принципиальный момент заключается в том, что, если вы выполнили какую-либо команду надстройки ЁXCEL, например, отформатировали текст ячейки и после этого переименовали лист с этой ячейкой — отмена операции выполненной надстройкой будет невозможна.

Для некоторых команд надстройки «ЁXCEL» отмена не предусмотрена, в справке по этим командам есть соответствующие предупреждение:

Будьте внимательны, всегда делайте резервные копии важных данных.

Сохранение файла после действий, выполненных надстройкой:

MS Excel не запоминает действия, произведенные макросами и соответственно не считает эти действия изменением данных в рабочей книге. По этой причине, если Вы после выполнения той или иной команды надстройки нажмете кнопку «Закрыть» (закрыть файл), MS Excel закроет рабочую книгу, не спросив Вас: «Сохранить ли изменения?». При следующем открытии файла вы не обнаружите тех изменений, которые произвели с помощью надстройки.

Если вы используете команды надстройки в активной рабочей книге, никогда не закрывайте книгу, предварительно не сохранив ее с помощью команды MS Excel «Сохранить» или «Сохранить как…».

Использование функций (формул) надстройки в файлах:

Если вы используете в своем файле функции надстройки, учитывайте то факт, что если вы отправите файл с этими функциями другому пользователю, то он (пользователь) увидит вместо этих функций лишь ошибку, ссылку на несуществующий файл. Поэтому, при пересылке таких файлов замените все формулы надстройки на значения.