Excel нет данных как убрать

Deok1982 Пользователь Сообщений: 9 Регистрация: 30.04.2015

Здравствуйте, Уважаемые Гуру Подскажите, пожалуйста. Есть 4 ячейки. Ячейка D27 выпадающий список с размерами (ширина подоконников), E27 ячейка для ввода данных (длина подконников), ячейка F27 с формулой =ВПР(D27;таблица;2;ЛОЖЬ) и в четвертой ячейке G27 получаю данные =(E27*F27)*B4, где B4 это курс валют. Так вот, если мы не вводим значение в E27 и в D27 стоит какое-нибудь значение, тогда все нормально, в F27 показывается прайсовая цена по таблице, в G27 стоит 0. Но стоит убрать выпадающий список D27 (Delete) как появляется #Н/Д в ячейках F27 и G27. Как сделать чтобы в этих ячейках или вообще ничего не было или нули стояли, вместо #Н/Д? Заранее благодарен!

JeyCi Пользователь Сообщений: 3357 Регистрация: 27.11.2013	#2 04.05.2015 08:13:40 Цитата Deok1982 написал: F27 с формулой =ВПР(D27;таблица;2;ЛОЖЬ) Код =ЕСЛИОШИБКА(ВПР(D27;таблица;2;ЛОЖЬ);"") чтобы не гадать на кофейной гуще, кто вам отвечает и после этого не совершать кучу ошибок — обратитесь к собеседнику на ВЫ — ответ на ваш вопрос получите — а остальное вас не касается (п.п.п. на форумах)

Deok1982 Пользователь Сообщений: 9 Регистрация: 30.04.2015	JeyCi , вашу формулу ввел в F27, теперь вместо #Н/Д появилось #Имя?

Pelena Пользователь Сообщений: 1416 Регистрация: 22.12.2012	Попробуйте так =ЕСЛИ(ЕНД(ВПР(D27;таблица;2;ЛОЖЬ));«»;ВПР(D27;таблица;2;ЛОЖЬ))

МВТ Пользователь Сообщений: 1198 Регистрация: 01.02.2015	Или установите Excel 2007 или «старше»: до него функции ЕСЛИОШИБКА() не было.

Deok1982 Пользователь Сообщений: 9 Регистрация: 30.04.2015	Pelena, в F27 стало пусто, но в G27 появилось #ЗНАЧ!

Deok1982 Пользователь Сообщений: 9 Регистрация: 30.04.2015	#7 04.05.2015 10:07:12 Цитата МВТ написал: Или установите Excel 2007 или «старше» К сожалению, но работаем на 2003, т.к. макросы которые когда то писали в 2003, не работают в 2007

Deok1982 Пользователь Сообщений: 9 Регистрация: 30.04.2015	Pelena, вроде бы разобрался, в вашу формулу «0» еще добавил =ЕСЛИ(ЕНД(ВПР(D27;таблица;2;ЛОЖЬ));«0»;ВПР(D27;таблица;2;ЛОЖЬ)) Вроде все заработало как надо.Спасибо Изменено: Deok1982 — 04.05.2015 10:11:56

V Пользователь Сообщений: 5018 Регистрация: 22.12.2012	П.С. цифры можно без кавычек писать. вместо ЛОЖЬ можно писать 0 (или оставить пустой) покороче будет. Изменено: V — 04.05.2015 10:16:14

Юрий М Модератор Сообщений: 60570 Регистрация: 14.09.2012 Контакты см. в профиле	#10 04.05.2015 10:31:46 Цитата Deok1982 написал: макросы которые когда то писали в 2003, не работают в 2007 Это что за макросы такие?

Deok1982 Пользователь Сообщений: 9 Регистрация: 30.04.2015	Юрий М , есть два файла екселевских. Сначала запускается один, через него второй. Во втором появляется определенное меню с добавлением объектов, с введением размеров и т.д.  Так вот в 2007 работать не хочет

Deok1982 Пользователь Сообщений: 9 Регистрация: 30.04.2015	#12 04.05.2015 10:55:45 Цитата цифры можно без кавычек писать. вместо ЛОЖЬ можно писать 0 Вы имеете ввиду так? =ЕСЛИ(ЕНД(ВПР(D27;таблица;2;0));0;ВПР(D27;таблица;2;0)) Изменено: Deok1982 — 04.05.2015 13:06:57

V Пользователь Сообщений: 5018 Регистрация: 22.12.2012	да. это была инфа для общего развития. Изменено: V — 04.05.2015 13:05:32

Мотя Пользователь Сообщений: 3218 Регистрация: 25.12.2012	#14 04.05.2015 14:14:04 Цитата МВТ написал: Или установите Excel 2007 или «старше»: до него функции ЕСЛИОШИБКА() не было. Однако, аргумент… А чем плоха в EXCEL 2003 комбинация ЕСЛИ(ЕОШИБКА(ВПР(… Работает распрекрасно хорошо (см.)! Прикрепленные файлы 111.xls (13.5 КБ)

Мотя Пользователь Сообщений: 3218 Регистрация: 25.12.2012	#15 04.05.2015 14:17:19 Цитата Deok1982 написал: макросы которые когда то писали в 2003, не работают в 2007 Значит, эти макросы писали «кривые» руки!

The_Prist Пользователь Сообщений: 14181 Регистрация: 15.09.2012 Профессиональная разработка приложений для MS Office

#16 04.05.2015 19:55:12 Цитата Мотя написал: Значит, эти макросы писали «кривые» руки! Не факт. Если использовался метод FileSearch, то он заблокирован в версиях старше 2003. И поэтому код в самом начале сообщит об ошибке, т.к. не обнаружит этот метод. Хотя код написан будет верно. Вместо FileSearch в версиях 2007 и выше приходится применять рекурсию. Даже самый простой вопрос можно превратить в огромную проблему. Достаточно не уметь формулировать вопросы…

Мотя Пользователь Сообщений: 3218 Регистрация: 25.12.2012	#17 04.05.2015 21:06:36 Цитата The_Prist написал: метод FileSearch заблокирован в версиях старше 2003 Если макрос представляет собой прикладную ценность, проблему всегда можно решить.

МВТ Пользователь Сообщений: 1198 Регистрация: 01.02.2015	Мотя, хотя бы тем, что ВПР() в этой ситуации придется вычислять дважды. А если таблица объемная, это может тормозить работу. Тем более, это не аргумент, а совет

Мотя Пользователь Сообщений: 3218 Регистрация: 25.12.2012	#19 04.05.2015 21:48:52 Цитата МВТ написал: если таблица объемная, это может тормозить работу Птичку жалко… Безысходка…

МВТ Пользователь Сообщений: 1198 Регистрация: 01.02.2015	#20 04.05.2015 21:53:12 Цитата Мотя написал: Безысходка… Бесперспективняк — круче

The_Prist Пользователь Сообщений: 14181 Регистрация: 15.09.2012 Профессиональная разработка приложений для MS Office	#21 04.05.2015 23:12:50 Цитата Мотя написал: Если макрос представляет собой прикладную ценность, проблему всегда можно решить Проблему вообще всегда можно решить. Я про то, что не надо сразу валить вину на руки разработчика. Вы же именно «кривыми руками» прокомментировали тот факт, что код перестал работать. Я привел аргумент из реальной жизни, когда даже грамотный код откажется работать при переходе на более новую версию Excel. Даже самый простой вопрос можно превратить в огромную проблему. Достаточно не уметь формулировать вопросы…

При работе с формулами в Excel можно столкнуться с ошибкой #Н/Д (частая история с функцией ВПР). В этом уроке мы разберем, как можно исправить ошибку #Н/Д в Excel. Вообще эта ошибка обозначает, что используемая формула не нашла интересующее нас значение.

Способ 1. Функция ЕСЛИОШИБКА()

Предположим, что у нас есть небольшая база данных, в которой для каждого имени указана фамилия и мы хотим при помощи функции ВПР() найти фамилии для указанных выше имен.

ВПР(B6;БД!B:C;2;0)

Так получилось, что для имени Василий в базе данных нет фамилии и Excel выдал ошибку #Н/Д. (Если так случилось, что вы еще не знакомы с функцией ВПР, то настоятельно рекомендую ознакомиться со статьей на нашем сайте «Функция ВПР в Excel»). Для того, что бы избавиться от этой ошибки с помощь функции ЕСЛИОШИБКА(), должны должны в качестве первого аргумента указать нашу формулу ВПР, а в качестве второго аргумента то значение, которое будет выдаваться в случае, если формула вернет ошибку.

ЕСЛИОШИБКА(ВПР(B6;БД!B:C;2;0);»Нет фамилии в базе данных.»)

Функция ЕСЛИОШИБКА() является универсальной функцией для обработки ошибок, во втором способе мы рассмотрим функцию, которая создана специально для обработки только ошибки #Н/Д.

Способ 2. Функция ЕСНД()

Синтаксис функции ЕСНД() аналогичен функции ЕСЛИОШИБКА(), которую мы рассматривали в способе выше, поэтому в качестве первого аргумента мы снова указываем ту функцию, в результате работы которой мы ожидаем ошибку #Н/Д, а в качестве второго аргумента то значение, которое будет выдано вместо ошибки.

ЕСНД(ВПР(B6;БД!B:C;2;0);»Нет фамилии в базе данных.»)

Это были два основные способа, которые можно использовать при обработке ошибки #Н/Д в Экселе. Спасибо что причитали статью до конца.

Перейти к содержимому

Этот урок объясняет, как быстро справиться с ситуацией, когда функция ВПР (VLOOKUP) не хочет работать в Excel 2013, 2010, 2007 и 2003, а также, как выявить и исправить распространённые ошибки и преодолеть ограничения ВПР.

В нескольких предыдущих статьях мы изучили различные грани функции ВПР в Excel. Если Вы читали их внимательно, то сейчас должны быть экспертом в этой области. Однако не без причины многие специалисты по Excel считают ВПР одной из наиболее сложных функций. Она имеет кучу ограничений и особенностей, которые становятся источником многих проблем и ошибок.

В этой статье Вы найдёте простые объяснения ошибок #N/A (#Н/Д), #NAME? (#ИМЯ?) и #VALUE! (#ЗНАЧ!), появляющихся при работе с функцией ВПР, а также приёмы и способы борьбы с ними. Мы начнём с наиболее частых случаев и наиболее очевидных причин, почему ВПР не работает, поэтому лучше изучать примеры в том порядке, в каком они приведены в статье.

• Исправляем ошибку #Н/Д
• Исправляем ошибку #ЗНАЧ! в формулах с ВПР
• Ошибка #ИМЯ? в ВПР
• ВПР не работает (проблемы, ограничения и решения)
• ВПР – работа с функциями ЕСЛИОШИБКА и ЕОШИБКА

Исправляем ошибку #Н/Д функции ВПР в Excel

В формулах с ВПР сообщение об ошибке #N/A (#Н/Д) – означает not available (нет данных) – появляется, когда Excel не может найти искомое значение. Это может произойти по нескольким причинам.

1. Искомое значение написано с опечаткой

Хорошая мысль проверить этот пункт в первую очередь! Опечатки часто возникают, когда Вы работаете с очень большими объёмами данных, состоящих из тысяч строк, или когда искомое значение вписано в формулу.

2. Ошибка #Н/Д при поиске приближённого совпадения с ВПР

Если Вы используете формулу с условием поиска приближённого совпадения, т.е. аргумент range_lookup (интервальный_просмотр) равен TRUE (ИСТИНА) или не указан, Ваша формула может сообщить об ошибке #Н/Д в двух случаях:

• Искомое значение меньше наименьшего значения в просматриваемом массиве.
• Столбец поиска не упорядочен по возрастанию.

3. Ошибка #Н/Д при поиске точного совпадения с ВПР

Если Вы ищете точное совпадение, т.е. аргумент range_lookup (интервальный_просмотр) равен FALSE (ЛОЖЬ) и точное значение не найдено, формула также сообщит об ошибке #Н/Д. Более подробно о том, как искать точное и приближенное совпадение с функцией ВПР.

4. Столбец поиска не является крайним левым

Как Вы, вероятно, знаете, одно из самых значительных ограничений ВПР это то, что она не может смотреть влево, следовательно, столбец поиска в Вашей таблице должен быть крайним левым. На практике мы часто забываем об этом, что приводит к не работающей формуле и появлению ошибки #Н/Д.

Решение: Если нет возможности изменить структуру данных так, чтобы столбец поиска был крайним левым, Вы можете использовать комбинацию функций ИНДЕКС (INDEX) и ПОИСКПОЗ (MATCH), как более гибкую альтернативу для ВПР.

5. Числа форматированы как текст

Другой источник ошибки #Н/Д в формулах с ВПР – это числа в текстовом формате в основной таблице или в таблице поиска.

Это обычно случается, когда Вы импортируете информацию из внешних баз данных или когда ввели апостроф перед числом, чтобы сохранить стоящий в начале ноль.

Наиболее очевидные признаки числа в текстовом формате показаны на рисунке ниже:

Кроме этого, числа могут быть сохранены в формате General (Общий). В таком случае есть только один заметный признак – числа выровнены по левому краю ячейки, в то время как стандартно они выравниваются по правому краю.

Решение: Если это одиночное значение, просто кликните по иконке ошибки и выберите Convert to Number (Конвертировать в число) из контекстного меню.

Если такая ситуация со многими числами, выделите их и щелкните по выделенной области правой кнопкой мыши. В появившемся контекстном меню выберите Format Cells (Формат ячеек) > вкладка Number (Число) > формат Number (Числовой) и нажмите ОК.

6. В начале или в конце стоит пробел

Это наименее очевидная причина ошибки #Н/Д в работе функции ВПР, поскольку зрительно трудно увидеть эти лишние пробелы, особенно при работе с большими таблицами, когда большая часть данных находится за пределами экрана.

Решение 1: Лишние пробелы в основной таблице (там, где функция ВПР)

Если лишние пробелы оказались в основной таблице, Вы можете обеспечить правильную работу формул, заключив аргумент lookup_value (искомое_значение) в функцию TRIM (СЖПРОБЕЛЫ):

=VLOOKUP(TRIM($F2),$A$2:$C$10,3,FALSE)
=ВПР(СЖПРОБЕЛЫ($F2);$A$2:$C$10;3;ЛОЖЬ)

Решение 2: Лишние пробелы в таблице поиска (в столбце поиска)

Если лишние пробелы оказались в столбце поиска – простыми путями ошибку #Н/Д в формуле с ВПР не избежать. Вместо ВПР Вы можете использовать формулу массива с комбинацией функций ИНДЕКС (INDEX), ПОИСКПОЗ (MATCH) и СЖПРОБЕЛЫ (TRIM):

=INDEX($C$2:$C$10,MATCH(TRUE,TRIM($A$2:$A$10)=TRIM($F$2),0))
=ИНДЕКС($C$2:$C$10;ПОИСКПОЗ(ИСТИНА;СЖПРОБЕЛЫ($A$2:$A$10)=СЖПРОБЕЛЫ($F$2);0))

Так как это формула массива, не забудьте нажать Ctrl+Shift+Enter вместо привычного Enter, чтобы правильно ввести формулу.

Ошибка #ЗНАЧ! в формулах с ВПР

В большинстве случаев, Microsoft Excel сообщает об ошибке #VALUE! (#ЗНАЧ!), когда значение, использованное в формуле, не подходит по типу данных. Что касается ВПР, то обычно выделяют две причины ошибки #ЗНАЧ!.

1. Искомое значение длиннее 255 символов

Будьте внимательны: функция ВПР не может искать значения, содержащие более 255 символов. Если искомое значение превышает этот предел, то Вы получите сообщение об ошибке #ЗНАЧ!.

Решение: Используйте связку функций ИНДЕКС+ПОИСКПОЗ (INDEX+MATCH). Ниже представлена формула, которая отлично справится с этой задачей:

=INDEX(C2:C7,MATCH(TRUE,INDEX(B2:B7=F$2,0),0))
=ИНДЕКС(C2:C7;ПОИСКПОЗ(ИСТИНА;ИНДЕКС(B2:B7=F$2;0);0))

2. Не указан полный путь к рабочей книге для поиска

Если Вы извлекаете данные из другой рабочей книги, то должны указать полный путь к этому файлу. Если говорить точнее, Вы должны указать имя рабочей книги (включая расширение) в квадратных скобках [ ], далее указать имя листа, а затем – восклицательный знак. Всю эту конструкцию нужно заключить в апострофы, на случай если имя книги или листа содержит пробелы.

Вот полная структура функции ВПР для поиска в другой книге:

=VLOOKUP(lookup_value,'[workbook name]sheet name'!table_array, col_index_num,FALSE)
=ВПР(искомое_значение;'[имя_книги]имя_листа'!таблица;номер_столбца;ЛОЖЬ)

Настоящая формула может выглядеть так:

=VLOOKUP($A$2,'[New Prices.xls]Sheet1'!$B:$D,3,FALSE)
=ВПР($A$2;'[New Prices.xls]Sheet1'!$B:$D;3;ЛОЖЬ)

Эта формула будет искать значение ячейки A2 в столбце B на листе Sheet1 в рабочей книге New Prices и извлекать соответствующее значение из столбца D.

Если любая часть пути к таблице пропущена, Ваша функция ВПР не будет работать и сообщит об ошибке #ЗНАЧ! (даже если рабочая книга с таблицей поиска в данный момент открыта).

Для получения дополнительной информации о функции ВПР, ссылающейся на другой файл Excel, обратитесь к уроку: Поиск в другой рабочей книге с помощью ВПР.

3. Аргумент Номер_столбца меньше 1

Трудно представить ситуацию, когда кто-то вводит значение меньше 1, чтобы обозначить столбец, из которого нужно извлечь значение. Хотя это возможно, если значение этого аргумента вычисляется другой функцией Excel, вложенной в ВПР.

Итак, если случилось, что аргумент col_index_num (номер_столбца) меньше 1, функция ВПР также сообщит об ошибке #ЗНАЧ!.

Если же аргумент col_index_num (номер_столбца) больше количества столбцов в заданном массиве, ВПР сообщит об ошибке #REF! (#ССЫЛ!).

Ошибка #ИМЯ? в ВПР

Простейший случай – ошибка #NAME? (#ИМЯ?) – появится, если Вы случайно напишите с ошибкой имя функции.

Решение очевидно – проверьте правописание!

ВПР не работает (ограничения, оговорки и решения)

Помимо достаточно сложного синтаксиса, ВПР имеет больше ограничений, чем любая другая функция Excel. Из-за этих ограничений, простые на первый взгляд формулы с ВПР часто приводят к неожиданным результатам. Ниже Вы найдёте решения для нескольких распространённых сценариев, когда ВПР ошибается.

1. ВПР не чувствительна к регистру

Функция ВПР не различает регистр и принимает символы нижнего и ВЕРХНЕГО регистра как одинаковые. Поэтому, если в таблице есть несколько элементов, которые различаются только регистром символов, функция ВПР возвратит первый попавшийся элемент, не взирая на регистр.

Решение: Используйте другую функцию Excel, которая может выполнить вертикальный поиск (ПРОСМОТР, СУММПРОИЗВ, ИНДЕКС и ПОИСКПОЗ) в сочетании с СОВПАД, которая различает регистр. Более подробно Вы можете узнать из урока — 4 способа сделать ВПР с учетом регистра в Excel.

2. ВПР возвращает первое найденное значение

Как Вы уже знаете, ВПР возвращает из заданного столбца значение, соответствующее первому найденному совпадению с искомым. Однако, Вы можете заставить ее извлечь 2-е, 3-е, 4-е или любое другое повторение значения, которое Вам нужно. Если нужно извлечь все повторяющиеся значения, Вам потребуется комбинация из функций ИНДЕКС (INDEX), НАИМЕНЬШИЙ (SMALL) и СТРОКА (ROW).

3. В таблицу был добавлен или удалён столбец

К сожалению, формулы с ВПР перестают работать каждый раз, когда в таблицу поиска добавляется или удаляется новый столбец. Это происходит, потому что синтаксис ВПР требует указывать полностью весь диапазон поиска и конкретный номер столбца для извлечения данных. Естественно, и заданный диапазон, и номер столбца меняются, когда Вы удаляете столбец или вставляете новый.

Решение: И снова на помощь спешат функции ИНДЕКС (INDEX) и ПОИСКПОЗ (MATCH). В формуле ИНДЕКС+ПОИСКПОЗ Вы раздельно задаёте столбцы для поиска и для извлечения данных, и в результате можете удалять или вставлять сколько угодно столбцов, не беспокоясь о том, что придётся обновлять все связанные формулы поиска.

4. Ссылки на ячейки исказились при копировании формулы

Этот заголовок исчерпывающе объясняет суть проблемы, правда?

Решение: Всегда используйте абсолютные ссылки на ячейки (с символом $) при записи диапазона, например $A$2:$C$100 или $A:$C. В строке формул Вы можете быстро переключать тип ссылки, нажимая F4.

ВПР – работа с функциями ЕСЛИОШИБКА и ЕОШИБКА

Если Вы не хотите пугать пользователей сообщениями об ошибках #Н/Д, #ЗНАЧ! или #ИМЯ?, можете показывать пустую ячейку или собственное сообщение. Вы можете сделать это, поместив ВПР в функцию ЕСЛИОШИБКА (IFERROR) в Excel 2013, 2010 и 2007 или использовать связку функций ЕСЛИ+ЕОШИБКА (IF+ISERROR) в более ранних версиях.

ВПР: работа с функцией ЕСЛИОШИБКА

Синтаксис функции ЕСЛИОШИБКА (IFERROR) прост и говорит сам за себя:

IFERROR(value,value_if_error)
ЕСЛИОШИБКА(значение;значение_если_ошибка)

То есть, для первого аргумента Вы вставляете значение, которое нужно проверить на предмет ошибки, а для второго аргумента указываете, что нужно возвратить, если ошибка найдётся.

Например, вот такая формула возвращает пустую ячейку, если искомое значение не найдено:

=IFERROR(VLOOKUP($F$2,$B$2:$C$10,2,FALSE),"")
=ЕСЛИОШИБКА(ВПР($F$2;$B$2:$C$10;2;ЛОЖЬ);"")

Если Вы хотите показать собственное сообщение вместо стандартного сообщения об ошибке функции ВПР, впишите его в кавычках, например, так:

=IFERROR(VLOOKUP($F$2,$B$2:$C$10,2,FALSE),"Ничего не найдено. Попробуйте еще раз!")
=ЕСЛИОШИБКА(ВПР($F$2;$B$2:$C$10;2;ЛОЖЬ);"Ничего не найдено. Попробуйте еще раз!")

ВПР: работа с функцией ЕОШИБКА

Так как функция ЕСЛИОШИБКА появилась в Excel 2007, при работе в более ранних версиях Вам придётся использовать комбинацию ЕСЛИ (IF) и ЕОШИБКА (ISERROR) вот так:

=IF(ISERROR(VLOOKUP формула),"Ваше сообщение при ошибке",VLOOKUP формула)
=ЕСЛИ(ЕОШИБКА(ВПР формула);"Ваше сообщение при ошибке";ВПР формула)

Например, формула ЕСЛИ+ЕОШИБКА+ВПР, аналогична формуле ЕСЛИОШИБКА+ВПР, показанной выше:

=IF(ISERROR(VLOOKUP($F$2,$B$2:$C$10,2,FALSE)),"",VLOOKUP($F$2,$B$2:$C$10,2,FALSE))
=ЕСЛИ(ЕОШИБКА(ВПР($F$2;$B$2:$C$10;2;ЛОЖЬ));"";ВПР($F$2;$B$2:$C$10;2;ЛОЖЬ))

На сегодня всё. Надеюсь, этот короткий учебник поможет Вам справиться со всеми возможными ошибками ВПР и заставит Ваши формулы работать правильно.