Excel named range in formulas

In Excel for the web, you can use the named ranges you’ve defined in Excel for Windows or Mac. Select a name from the Name Box to go to the range’s location, or use the Named Range in a formula.

For now, creating a new Named Range in Excel for the web is not available.

What’s in the name?

If you are working with Excel spreadsheets, it could mean a lot of time saving and efficiency.

In this tutorial, you’ll learn how to create Named Ranges in Excel and how to use it to save time.

Named Ranges in Excel – An Introduction

If someone has to call me or refer to me, they will use my name (instead of saying a male is staying in so and so place with so and so height and weight).

Right?

Similarly, in Excel, you can give a name to a cell or a range of cells.

Now, instead of using the cell reference (such as A1 or A1:A10), you can simply use the name that you assigned to it.

For example, suppose you have a data set as shown below:

In this data set, if you have to refer to the range that has the Date, you will have to use A2:A11 in formulas. Similarly, for Sales Rep and Sales, you will have to use B2:B11 and C2:C11.

While it’s alright when you only have a couple of data points, but in case you huge complex data sets, using cell references to refer to data could be time-consuming.

Excel Named Ranges makes it easy to refer to data sets in Excel.

You can create a named range in Excel for each data category, and then use that name instead of the cell references. For example, dates can be named ‘Date’, Sales Rep data can be named ‘SalesRep’ and sales data can be named ‘Sales’.

You can also create a name for a single cell. For example, if you have the sales commission percentage in a cell, you can name that cell as ‘Commission’.

Benefits of Creating Named Ranges in Excel

Here are the benefits of using named ranges in Excel.

Use Names instead of Cell References

When you create Named Ranges in Excel, you can use these names instead of the cell references.

For example, you can use =SUM(SALES) instead of =SUM(C2:C11) for the above data set.

Have a look at ṭhe formulas listed below. Instead of using cell references, I have used the Named Ranges.

• Number of sales with value more than 500: =COUNTIF(Sales,”>500″)
• Sum of all the sales done by Tom: =SUMIF(SalesRep,”Tom”,Sales)
• Commission earned by Joe (sales by Joe multiplied by commission percentage):
  =SUMIF(SalesRep,”Joe”,Sales)*Commission

You would agree that these formulas are easy to create and easy to understand (especially when you share it with someone else or revisit it yourself.

No Need to Go Back to the Dataset to Select Cells

Another significant benefit of using Named Ranges in Excel is that you don’t need to go back and select the cell ranges.

You can just type a couple of alphabets of that named range and Excel will show the matching named ranges (as shown below):

Named Ranges Make Formulas Dynamic

By using Named Ranges in Excel, you can make Excel formulas dynamic.

For example, in the case of sales commission, instead of using the value 2.5%, you can use the Named Range.

Now, if your company later decides to increase the commission to 3%, you can simply update the Named Range, and all the calculation would automatically update to reflect the new commission.

How to Create Named Ranges in Excel

Here are three ways to create Named Ranges in Excel:

Method #1 –  Using Define Name

Here are the steps to create Named Ranges in Excel using Define Name:

This will create a Named Range SALESREP.

Method #2: Using the Name Box

• Select the range for which you want to create a name (do not select headers).
• Go to the Name Box on the left of Formula bar and Type the name of the with which you want to create the Named Range.
• Note that the Name created here will be available for the entire Workbook. If you wish to restrict it to a worksheet, use Method 1.

Method #3: Using Create From Selection Option

This is the recommended way when you have data in tabular form, and you want to create named range for each column/row.

For example, in the dataset below, if you want to quickly create three named ranges (Date, Sales_Rep, and Sales), then you can use the method shown below.

Here are the steps to quickly create named ranges from a dataset:

This will create three Named Ranges – Date, Sales_Rep, and Sales.

Note that it automatically picks up names from the headers. If there are any space between words, it inserts an underscore (as you can’t have spaces in named ranges).

Naming Convention for Named Ranges in Excel

There are certain naming rules you need to know while creating Named Ranges in Excel:

• The first character of a Named Range should be a letter and underscore character(_), or a backslash(). If it’s anything else, it will show an error. The remaining characters can be letters, numbers, special characters, period, or underscore.
• You can not use names that also represent cell references in Excel. For example, you can’t use AB1 as it is also a cell reference.
• You can’t use spaces while creating named ranges. For example, you can’t have Sales Rep as a named range. If you want to combine two words and create a Named Range, use an underscore, period or uppercase characters to create it. For example, you can have Sales_Rep, SalesRep, or SalesRep.
  • While creating named ranges, Excel treats uppercase and lowercase the same way. For example, if you create a named range SALES, then you will not be able to create another named range such as ‘sales’ or ‘Sales’.
• A Named Range can be up to 255 characters long.

Too Many Named Ranges in Excel? Don’t Worry

Sometimes in large data sets and complex models, you may end up creating a lot of Named Ranges in Excel.

What if you don’t remember the name of the Named Range you created?

Don’t worry – here are some useful tips.

Getting the Names of All the Named Ranges

Here are the steps to get a list of all the named ranges you created:

This will give you a list of all the Named Ranges in that workbook. To use a named range (in formulas or a cell), double click on it.

Displaying the Matching Named Ranges

• If you have some idea about the Name, type a few initial characters, and Excel will show a drop down of the matching names.

How to Edit Named Ranges in Excel

If you have already created a Named Range, you can edit it using the following steps:

Useful Named Range Shortcuts (the Power of F3)

Here are some useful keyboard shortcuts that will come handy when you are working with Named Ranges in Excel:

• To get a list of all the Named Ranges and pasting it in Formula: F3
• To create new name using Name Manager Dialogue Box: Control + F3
• To create Named Ranges from Selection: Control + Shift + F3

Creating Dynamic Named Ranges in Excel

So far in this tutorial, we have created static Named Ranges.

This means that these Named Ranges would always refer to the same dataset.

For example, if A1:A10 has been named as ‘Sales’, it would always refer to A1:A10.

If you add more sales data, then you would have to manually go and update the reference in the named range.

In the world of ever-expanding data sets, this may end up taking up a lot of your time. Every time you get new data, you may have to update the Named Ranges in Excel.

To tackle this issue, we can create Dynamic Named Ranges in Excel that would automatically account for additional data and include it in the existing Named Range.

For example, For example, if I add two additional sales data points, a dynamic named range would automatically refer to A1:A12.

This kind of Dynamic Named Range can be created by using Excel INDEX function. Instead of specifying the cell references while creating the Named Range, we specify the formula. The formula automatically updated when the data is added or deleted.

Let’s see how to create Dynamic Named Ranges in Excel.

Suppose we have the sales data in cell A2:A11.

Here are the steps to create Dynamic Named Ranges in Excel:

1. 1. Go to the Formula tab and click on Define Name.
   2. In the New Name dialogue box type the following:
      • Name: Sales
      • Scope: Workbook
      • Refers to: =$A$2:INDEX($A$2:$A$100,COUNTIF($A$2:$A$100,”<>”&””))
   3. Click OK.

Done!

You now have a dynamic named range with the name ‘Sales’. This would automatically update whenever you add data to it or remove data from it.

How does Dynamic Named Ranges Work?

To explain how this work, you need to know a bit more about Excel INDEX function.

Most people use INDEX to return a value from a list based on the row and column number.

But the INDEX function also has another side to it.

It can be used to return a cell reference when it is used as a part of a cell reference.

For example, here is the formula that we have used to create a dynamic named range:

=$A$2:INDEX($A$2:$A$100,COUNTIF($A$2:$A$100,"<>"&""))

INDEX($A$2:$A$100,COUNTIF($A$2:$A$100,”<>”&””) –> This part of the formula is expected to return a value (which would be the 10th value from the list, considering there are ten items).

However, when used in front of a reference (=$A$2:INDEX($A$2:$A$100,COUNTIF($A$2:$A$100,”<>”&””))) it returns the reference to the cell instead of the value.

Hence, here it returns =$A$2:$A$11

If we add two additional values to the sales column, it would then return =$A$2:$A$13

When you add new data to the list, Excel COUNTIF function returns the number of non-blank cells in the data. This number is used by the INDEX function to fetch the cell reference of the last item in the list.

Note:

• This would only work if there are no blank cells in the data.
• In the example taken above, I have assigned a large number of cells (A2:A100) for the Named Range formula. You can adjust this based on your data set.

You can also use OFFSET function to create a Dynamic Named Ranges in Excel, however, since OFFSET function is volatile, it may lead a slow Excel workbook. INDEX, on the other hand, is semi-volatile, which makes it a better choice to create Dynamic Named Ranges in Excel.

You may also like the following Excel resources:

• Free Excel Templates.
• Free Online Excel Training (7-Part Online Video Course).
• Useful Excel Macro Code Examples.
• 10 Advanced Excel VLOOKUP Examples.
• Creating a Drop Down List in Excel.
• Creating a Named Range in Google Sheets.
• How to Reference Another Sheet or Workbook in Excel
• How to Delete Named Range in Excel?

Names are one convenient identity. Imagine how we’d be addressed if we didn’t have names? Excel tries to make our lives easier by providing us with a similar convenience.

Excel’s Names feature can be surprisingly powerful for organizing data in Excel. Named Ranges let you name a group of cells and then refer to them as a unit as if they were a single cell.

Using named ranges can make formulas easier to read and understand and provides simple navigation via the Name Box. Named ranges are easy to create and can be used for a variety of purposes.

This tutorial will teach you how to use Names feature in Excel.

What are Named Ranges

In Excel, a cell or a range of cells can be named to make their usage easier. It would be simpler to use a named range directly in a formula or select said range.

You can name:

• a Range of cells,
• a Formula,
• a Constant or
• a Table

Benefits of Creating Named Ranges in Excel

• The prime advantage of named ranges is the ease they provide. You don’t have to keep glancing at certain cells or tables to pick up values or cell references and can use a named range instead.
• Using a named range will save typos that may otherwise occur while typing values or formulas since entering named ranges is a clickable option.
• They are of great help to use in formulas as the named range appears upon typing the first letter of the name.
• Named ranges make formulas movable and they can be used from sheet to sheet and workbook to workbook.
• A dynamic named range can automatically account for expanding and contracting data (when values are added or deleted from a dataset) without having to change the formula or recalculate.
• A named range can be used for data validation (creating drop-down menus) without much hassle.
• Hyperlinks can quickly be created from existing named ranges.
• Named ranges make navigation and directing very easy. You can click on a named range in the Name Box and arrive at the named range.
• For all the above benefits that named ranges deliver, they are very simple and quick to create.

Rules for naming Named Ranges

There are several pointers not to trespass while creating named ranges:

• A name should have less than 255 characters.
• A name should not have space and punctuation characters (exceptions mentioned as follows).
• A name’s first character has to be a letter, an underscore ( _ ), or a backslash ( ).
• A name may contain a question mark but never as a first character.
• A name is not case-sensitive. (sale, Sale, and SALE are treated as one name).
• A name must not resemble a cell reference (e.g., A1, A$1).
• A name may be a single letter name but must not be r, R, c, or C as «R» and «C» signify row and column selection shortcuts.

How to Create Named Ranges in Excel

There are two methods to create named ranges in excel. We will see both these methods in this section.

Let’s say we have the data as shown below and we want to create two named ranges – one for the History marks and the second one for the Geography marks.

We will create these two named ranges using two different methods to help you get a hang of both methods.

Method 1 – Creating Named Ranges from the Name Box

The how-to here is pretty simple. Select the range, enter the desired name in the «name box» and press Enter. Done! Really! We can show you how easy this is with a visual.

Here’s how it’s done:

• For naming the History marks range, we will select the History marks i.e., range C3:C7.

• Click on the name box.
• Enter the desired name («History» in this case).

• Press the Enter key.

Method 2 – Creating Named Ranges from the ‘Define Name’ Option

Names can also be created from the  «Define Name» button, in the formulas tab. To use this method follow the below steps:

• Select the range which you want to name, in our case it will be D3:D7.
• Navigate to the «Formulas Tab» and click the «Define Name» button.

• Now, in the «New Name» window enter the desired name for the named range.

• After entering the desired name click the «OK» button and it is done.

How to Edit Named Ranges in Excel

Suppose you accidentally missed a cell in the range or want to change the name of your named range. This means the named range needs to be edited.

Named ranges can be managed through the «Name Manager» which can be found under the «Formulas» tab > Name Manager or can be accessed through the keyboard shortcut Ctrl + F3.

This is what you will see when you open the Name Manager:

Here, you can see the named ranges in your sheet and their details. Double click the named range you wish to edit or select the named range and click the «Edit…» button.

Clicking on the «Edit…» button will open the «Edit Name» window where you can edit the name or the cell range of the named range. When done, click «OK» and then click the «Close» button on the Name Manager.

How to Delete Named Ranges

The Name Manager can also be used to delete named ranges. Click the named range you wish to remove, press the «Delete» button.

You will get a pop-up confirmation asking whether you want to delete the named range or not. Press «OK» and that will delete your chosen named range.

Note that the Name Manager also has a «Filter» button that can be used for filtering the names and only viewing the relevant names at a given time. It can be quite handy when you have a lot of names to deal with.

Recommended Reading: How to Lock and Protect Cells in Excel

How to Create Names from Cell Text

For batch information where the data is in the columnar or row format (i.e., in either columnar form with headings at the top and its relevant data below. Or in rows with headings on the left and its data on the right) there is a quicker way of naming ranges. We can use the «Create from Selection» feature in Excel to give the heading’s name to the range. Here is how:

So, we have the dataset containing marks scored by students in various subjects. The layout is in columnar form. We can use the «Create from Selection» feature in this case as –

• Select the range and the heading. We will select columns C, D, E, and F to name each range according to its heading.

• In the «Formulas» tab, click «Create from Selection» or use the keyboard shortcut Ctrl + Shift + F3. This is what you should see:

• According to the layout of your dataset, select the row or column where the headings need to be picked from. For our case, we will select the «Top row» option as headings. «Marks in History», «Marks in Geography», «Marks in Science», and «Marks in Math» are in the top row.
• After selecting the appropriate options click «OK».

Doing this has created multiple named ranges for our data. You can see from the drop-down in the Name Box that we have 4 named ranges created according to the headings of each column.

Note that the spaces in headings are replaced with underscores while creating the names.

Named Ranges with Hyperlinks

If you thought named ranges made you bounce around with ease through worksheets, wait for their synergy with hyperlinks. Named ranges make hyperlinking a smoother process as data required for hyperlinking would already be grouped and named. Let’s show you how this will work.

For the sake of this example let’s assume that we have another named range «Student» in Sheet2 as shown.

We will hyperlink the Student column from Sheet1 to direct us to the student range in Sheet2.

• Select the Student range in Sheet2 (i.e., B3:B7).

• Right-click the selected area and click on «Link». The «Insert Hyperlink» window is what you should see.

• We will select «Student» from «Defined Names» which we have already defined in Sheet2.
• Click «OK».

We have hyperlinked the Student Names to Sheet2 using the «Student» named range. Clicking on any of the marks should take us to the «Student» range on Sheet2. Let’s check.

Affirmative!

How to Create an Excel Name for a Constant

The Name Manager can also be used to create a name for a constant value. This constant value will not be a cell reference on the sheet but it can be used by its name in formulas.

For our example, we will use a named constant to calculate the percentage of the overall marks of each of 5 students. We start by accessing the Name Manager and applying for a new name.

The percentage will be calculated by dividing the sum of the attained marks by the total (each subject is marked out of 50. Which makes 50 x 4 = 200). We will set «200» as our named constant and give it the name «total».

Using «total», we can calculate the percentages without having to refer to «200».

Here, we have substituted «200» for «total» and calculated each student’s overall percentage.

How to Make a Named Formula

Taking the above example, what if we named the whole formula and get the same results? Sounds like a good bargain for smart input. Let’s see how to do that.

We first head to good old Name Manager and «New Name» again. We will name our formula «Percentage». The reference of this name is shown as

=SUM(Sheet2!$C3:$F3)/total

The range of the SUM in the formula is «C3:F3». The columns have been locked into absolute references by the $ sign. Notice that the rows have not been locked as absolute references so that the formula can be dragged to apply to all the rows.

Now just by using «Percentage», we can use the named formula to calculate the students’ percentages.

Named Ranges for Data Validation

Named ranges make the «Data Validation» feature in Excel a breeze. You can create a drop-down menu with values from a named range.

This comes with some advantages. You can simply refer to the named range in the Data Validation window instead of having to directly enter the cell ranges. It also gives a point of relevance to see the named range in sight. Let’s see how it’s done.

Let’s assume – we have a list of products and their prices and discounts. Our objective here is to calculate the discounted price for each product after entering its relevant discount. Instead of copy-pasting each discount, we want the option to select the discount from a drop-down menu for each cell in column D.

We will create a drop-down menu with the «Discount» named range (G3:G6).

• Select the cells for which you want to create the drop-downs (D3:D9 for our case).

• Under the «Data» tab, in the «Data Tools» section, select «Data Validation» dropdown and click the next «Data Validation» option.
• Inside the «Data Validation» window, under «Allow», choose «List» and enter the required named range under «Source». We will enter the reference of our «Discount» range here.

• Click «OK». This has very conveniently created drop-down menus for all cells D3:D9, taking values from the «Discount» named range.

• Now we can select the respective discounts and arrive at our «Price after discount».

See all Names Directly on the Worksheet

There is a small hack that allows you to see all the names directly on the worksheet. You can view all your named ranges (marked with the names) on the sheet if you zoom out to anything less than 40%. We’ll follow that religiously and zoom out at 39%.

The only thing amiss about this is that the named range text is like a watermark; it’s not opaque and will not work so well for small and narrow columns. This hack is suitable for data with a wide-set column or several more rows so the name of the range can be seen. Otherwise, it would be on the brink of being unnoticeable.

Scope of a Name

If you open the Name Manager and have a look at the named ranges, you will find that each named range has a scope (e.g., Sheet1, Sheet2, Workbook, etc.) against it.

Scope refers to the location, or level, within which the name is recognized. For instance, in the above image «range4» can only be used within Sheet1 whereas all the other names can be used across the entire workbook.

Based on this there can be 2 levels of scopes:

• Local worksheet scope
• Global workbook scope

Local Worksheet Scope

Locally scoped names can only be recognized and used on the sheet it is created upon. This implies that inside a single workbook we can have the same locally scoped names (each within a separate worksheet). For instance – you can have a yearly expense workbook with a worksheet for each month and then we can have a single locally scoped name within each worksheet.

Pro Tip: Named ranges made using the Name Box have global scope by default. However, you can tie the named range down to a sheet (in other words, make it locally scoped) simply by using the sheet’s name before the range’s name (with an exclamation mark).

Sheet1!Expenses

Global Workbook scope

Globally scoped names can be recognized and used across the whole workbook. Global names must always be unique within the workbook. For instance – we can create a global name to define the value of a constant like pi (as 3.14) and use it across the whole workbook.

Creating Dynamic Named Ranges in Excel

Up until now with all the examples above, we can say that if we were to expand on the data by adding more values, the formulas already applied wouldn’t account for the new values. This means that whenever values will be added to the dataset of the named range (e.g., B2:B15) which expands the dataset to B2:B20, the named range will still not account for the additional 5 values and remain a named range for B2:B15. This means the named range is static as opposed to a dynamic named range. The additional step that would need to be taken to fix this is to edit the named range and modify the range mentioned.

A dynamic named range on the contrary will itself adjust for changes in the range. To make our named range dynamic, we will add a function to the reference of the named range. If this sounds too complicated, let us show you how it’s done.

There are a couple of ways of creating a dynamic named range. One of them is using the OFFSET function. The drawback is however that OFFSET is a volatile function; with each and every change in a worksheet, OFFSET recalculates. This is not an issue for an uncomplicated worksheet with small datasets. But with complex and large worksheets, you will find that OFFSET slows things down. In such a case, the other way to create a dynamic named range is using the INDEX function.

So if you can use OFFSET for small datasets and INDEX for large ones, why not just master the INDEX function and use that? So this use of the INDEX function for dynamic named ranges is what we’ll be tapping into right now. Let’s see an example:

Taking simple sales data, we will add a dynamic named range that we will later use to calculate the total sales:

• Open the «Name Manager» > click the «New Name» option.
• Set the desired name (we are naming our named range «Sales»).

• In «Refers to», feed the following formula, and click «OK».

=$C$3:INDEX($C$3:$C$1048576,COUNTIF($C$3:$C$1048576,"<>"&" "))

We have used the SUM function to total the named range «Sales». It has given us a total of «3186» which is also confirmed from selecting the cells with the results displayed in the status bar below.

Now let’s add some values to this dataset to see if the formula applied complies with changes in the data.

We have added new sales data and the named range has updated itself because of the formula we have put in to build the range. So how does this formula work?

Let’s see the formula again:

=$C$3:INDEX($C$3:$C$1048576,COUNTIF($C$3:$C$1048576,"<>"&" "))

Since we’re using the INDEX function in the formula, let’s get familiar with it. The INDEX function returns a value or cell reference of a particular cell in a given range. The part we need to work with right now is the return of a cell reference.

The COUNTIF function counts the number of cells within a range that meets the given condition. The range given to COUNTIF is C3:C1048576. COUNTIF needs to look through the entire C column ahead of C3 (if you press Ctrl + down key, you will find the last row given in Excel which is row number 1048576. That is why we have used C1048576 in our formula. According to how big or small your data is, you can refer to any row ahead of your last value, suppose 100 rows ahead of your last value. In this way the formula will account for all changes made up to the last-mentioned row).

The condition given to COUNTIF is counting the number of cells from C3 to C1048576 that should not be equal to (defined by «<>») blank cells (defined by » «). Take note that this will work only if the data does not consist of blank cells as the blank cells are the ones to be ignored by the function.

According to this condition, the non-blank cells that COUNTIF was able to find from the given range were C3:C9. Passing this result to the INDEX function, INDEX then returns the value of the last item of the list (which would be C9’s value i.e., 404). The formula starts with the first cell that we need to include in our named range (i.e. C3, fed as an absolute reference by «$» signs). Using this reference before the INDEX function makes INDEX return the cell reference instead of the value which will then be C9.

The result of the whole formula has worked like this:

Note: Dynamic named ranges aren’t shown in the Name Box. Use the Name Manager to see all named ranges (static and dynamic).

Named Range Shortcuts

The more matters are sitting on your fingertips, the better. To wrap things up, here are some useful keyboard shortcuts with named ranges that should move you around the sheet even faster.

• F3 – Pops up a «Paste Name» dialogue box for pasting a named range from the full list of named ranges.
• Ctrl + F3 – Opens «Name Manager»
• Ctrl + alt + F3 – Pops up «New Name» dialog box for creating a new named range.
• Ctrl + shift + F3 – Pops up «Create Names from Selection» dialog box for creating named ranges from headings/titles.
• F5 – Pops up the «Go To» dialog box for navigating to the chosen named range from the full list of named ranges.

With that, we’ve discussed the ins and outs of the Named Ranges in Excel. They are simple, but extremely useful while working with larger datasets and multiple ranges. While you solidify your expertise with some practice, we’ll have another awesome tutorial ready for you ready!

In Excel, a dynamic range is a reference (or a formula you use to create a reference) that may change based on user input or the results of another cell or function. It is more than just a fixed group of cells like $A1:$A100. I use dynamic ranges mostly for customizable drop-down lists. To avoid showing a bunch of blanks in the list, I use a formula to reference a range that extends to the last value in a column. The image below shows 4 different formulas that reference the range A2:A9 and can expand to include more rows if the user adds more categories to the list.

When we talk about a dynamic named range, we’re talking about using the Name Manager (via the Formula tab) to define a name for the formula, such as categoryList. We can then use that Name in other formulas or as the Source for drop-down lists.

This article isn’t about the awesome advantages of using Excel Names, though there are many. Instead, it is about the many different formulas you can use to create the dynamic named ranges.

To see these examples in action, download the Excel file below.

Download the Example File (DynamicRanges.xlsx)

Do you have a Dynamic Named Range challenge you need to solve? If you can’t figure it out after reading this article, go ahead and ask your question by commenting below.

Watch the Video

A) The OFFSET Function

The most common function used to create a dynamic named range is probably the OFFSET function. It allows you to define a range with a specific number of rows and columns, starting from a reference cell. The syntax for the OFFSET function is:

=OFFSET(reference,offset_rows,offset_cols,[height],[width])

The offset_rows and offset_cols values tell the function where you want the upper-left cell of your range to be, relative to the reference cell. The height and width values tell the function how many rows and columns you want to include in your range.

A Basic Customizable List

In the meal planner template, I have a list of meals that I use as the Source for many different drop-down lists. I want to allow the user to edit and add to the list, so the dynamic named range used by the drop-down needs to extend to the last value in the list. I could define the range as $A:$A (the entire column) or $A1:$A1000 (assuming they won’t add more than 1000 items to the list), but then I’d end up with a bunch of blank cells at the end of my drop-down list.

Using the OFFSET function, I define a range that starts at cell $A$1 and ends at the cell containing the last value in the column. If the last value in the column was on row 15, the formula for the named range would be:

=OFFSET($A$1,0,0,15,1)

To make this formula dynamic, I’ll use a formula or reference in place of the height value (15) to specify how many rows I want the range to include. I expect only text values in this list, so I’ll use the MATCH function to find the last text value in the column like this:

=OFFSET($A$1,0,0,MATCH("zzzz",$A:$A),1)

There are many formulas you can use to determine the height or width of the range, such as COUNTA, COUNT, VLOOKUP, LOOKUP, MATCH or various array formulas. What formula you use may depend on whether you expect there to be blank cells in the list, error values (like #N/A or #DIV/0!), or data of different types (text or numeric or both), and whether calculation speed is an issue.

Later in this article I’ll talk more about the various formulas for finding the last value in the range. For now, we’ll continue using MATCH.

A Robust Dynamic Range

When you allow a user to edit a list, they may end up deleting the first row in the list, or they might insert a row above the first row in the list (between the label row and the first item). To create a formula that works in spite of these actions by the user, I like to use a label for the reference and include the label in the range, as shown in the following examples.

Example 1: Include the label in the list

=OFFSET(reference,0,0,MATCH("zzz",range),1)

Example 2: Exclude the label from the list

=OFFSET(reference,1,0,MATCH("zzz",range)-1,1)

Notice in the second example that reference and range have not changed. To exclude the label from the list, we are using an offset of 1 row and subtracting one row from the number returned by the MATCH function.

B) The INDEX Function for a Non-Volatile Dynamic Range

A volatile function within a cell or named range is recalculated every time any cell in the worksheet recalculates (instead of just when one of the function’s arguments changes). Also, any formula that depends on a cell containing a volatile function is also recalculated. If you have a large file with thousands of inefficient formulas that reference a cell containing a volatile function, Excel may seem to take forever to recalculate. OFFSET is a volatile function. INDEX is not, so some people prefer to use INDEX for dynamic ranges.

The INDEX function can return the reference to a range or cell instead of just the value. That means that just like OFFSET, you can use INDEX in many places where Excel is expecting a cell reference. For example, to create the range A1:A4 you can use INDEX(A:A,1):INDEX(A:A,4).

We can use INDEX to create the same dynamic ranges shown in the OFFSET examples:

Example 1: Include the label in the list

=INDEX(range,1):INDEX(range,MATCH("zzz",range))

Example 2: Exclude the label from the list

=INDEX(range,2):INDEX(range,MATCH("zzz",range))

To exclude the label (the first cell in the range), the only change we needed to make was the «2» in INDEX(range,2). Using INDEX(range,1) and INDEX(range,2) instead of just a cell reference makes the formula more robust. It prevents the problem of having the reference changed to #REF! if the reference row gets deleted.

NOTEWhen using INDEX, the formulas cannot be entered directly as the Source for a drop-down list. But, if you create the formula as a dynamic named range, you can use the name as the Source for the drop-down list.

By the way, I learned about using the INDEX function to make a non-volatile dynamic range from Mynda Treacy at MyOnlineTrainingHub.com and Debra Dalgleish at Contextures.com.

C) The INDIRECT Function

The INDIRECT function is another awesome function for creating dynamic ranges. It is also a volatile function, but like I mentioned above, that might not matter. The INDIRECT function lets you define a reference from a text string, and you can use concatenation to create the text string, like this:

=INDIRECT("Sheet1!A1:A"&row_num)

In the example shown at the top of this post, to create the reference «Sheet1!A2:A9» we replace row_num with MATCH(«zzz»,$A:$A) to return the row number of the last text value.

Important: When using INDIRECT to reference a range on a different worksheet, don’t forget to include the worksheet name in the string. When you enter a reference in the Refers To field via the Name Manager, Excel will automatically change $A:$A to «Sheet1!$A:$A» but it won’t know how to change your text string. This is one of the cons to using INDIRECT because if you change the name of the worksheet, you’ll need to remember to update your INDIRECT formula.

D) Structured References with Excel Tables

Beginning with Excel 2007, Microsoft introduced a new way to work with data in what are called Excel Tables, not to be confused with Data Tables, or other generic uses of the term table (yes, it is confusing).

If you use an official «Excel Table,» you can use a type of reference known as a structured reference. The structured reference uses the table name and the column labels like this:

=Table1[Categories]

You don’t need to know how to type the correct structured reference. While you are entering a formula, if you select the column in the Table, Excel will automatically change your reference to the structured reference.

The reason these types of references can be considered dynamic is because of the unique way that table references behave when you expand or contract the table. Meaning, if you extend the table down by dragging the resize handle in the lower-right corner of the table, the reference =Table1[Categories] will automatically include the new rows.

So, instead of using an OFFSET formula to extend a range to the last value in a customizable list, we can let the user change the size of the list using the drag handle. Of course, this requires the user to know how to use Tables and the drag handle. That is one of the reasons I don’t often use this technique in my templates (that, and lack of compatibility with OpenOffice and Google Sheets).

E) The CHOOSE and IF Functions

Although I don’t use the CHOOSE function or nested IF formulas to create lists of variable length, they are pretty powerful functions for creating other types of dynamic ranges. For example, the two formulas below both return a different range (range_1, range_2 or range_3) based on a given number:

=CHOOSE(number,range_1,range_2,range_3,...)

=IF(number=1,range_1,IF(number=2,range_2,IF(number=3,range_3)))

The CHOOSE function is basically a shortcut for the nested IF formula in this case. When possible, I prefer using CHOOSE over nested IF formulas (if only to avoid having a million closing parentheses at the end of the formula ))))))))))).

See CHOOSE in action: My article «Create a Drop Down List in Excel» shows an example using CHOOSE to create a dependent drop down list.

Find the Position of the LAST Value in the Column

When using a dynamic named range for lists of variable length, we need to know how to find the numeric position of the last value in the column. In the examples above we used MATCH(«zzz»,range) for text values, but for numeric data or a combination of text and numeric data we may need to use something different. The formulas below cover all the scenarios I’ve come across.

The following image will be used for the example. It shows the reference and range and the position numbers of the values in the range.

1. Find the Position of the Last Numeric Value

The following formulas will allow the range to include blanks, error values, and text values, but the formulas will only return the position of the last numeric value. The result would be 4 in the example above.

=MATCH(1E+100,range,1)

=LOOKUP(42,1/ISNUMBER(range),ROW(range)-ROW(reference)+1)

See my article about VLOOKUP and INDEX-MATCH for a more detailed explanation of these MATCH and LOOKUP formulas. LOOKUP does not behave the same way in OpenOffice and Google Sheets. So, for maximum compatibility, I still prefer to use MATCH.

The value 9.99999999999999E+307 could be used for the MATCH function because it is the largest numeric value that can be stored in a cell, but that is kind of overkill. I prefer to use something more concise like 1E+100 or 10^100 (a googol).

2. Find the Position of the Last Text Value

The following formulas will allow the range to include blanks, error values, and numeric values, but the formulas will only return the position of the last text value (row 5 in the example above).

=MATCH("zzzz",range,1)

=LOOKUP(42,1/ISTEXT(range),ROW(range)-ROW(reference)+1)

Note: Using «zzzz» for the lookup value is not fool proof. The Greek, Cyrillic, Hebrew, and Arabic Unicode characters (and possibly other Unicode characters) come after z in the sort order. You might try using a high-value unicode symbol such as 🗿 if you expect the list to contain symbols.

3. Find the Position of the Last Non-Blank Value

When we want to return the last non-blank value, we can use the largest position returned by the two MATCH formulas listed above, or we can use the LOOKUP formula.

=MAX(MATCH(9E+307,range),MATCH("🗿",range))

=LOOKUP(42, 1/NOT(ISBLANK(range)), ROW(range)-ROW(reference)+1 )

Note that the empty string «» is not blank. It is treated as a text value.

A cell containing a formula is not blank, even if the formula returns an empty string. So, use the next method if you want to find the last non-empty value when you are using formulas that might return an empty string.

4. Find the Position of the Last Non-Empty Value «»

In many practical applications (like loan calculators), we may not necessarily want to find the last non-blank cell ( meaning no values or formulas), but instead may want to find the last non-empty cell.

If we define «empty» as the empty string «», then we can return the last non-empty value using the formula below. This might look like an array formula, but it isn’t, thanks to the way LOOKUP works (See this article on exceljet.net).

=LOOKUP(42, 1/(range<>""), ROW(range)-ROW(reference)+1 )

As I mentioned before, LOOKUP does not work the same way in OpenOffice and Google Sheets, but SUMPRODUCT provides a good solution.

=SUMPRODUCT(MAX((range<>"")*(ROW(range)-ROW(reference)+1)))

The SUMPRODUCT function allows you to avoid entering the formula as an array formula (not having to use Ctrl+Shift+Enter). Inside the SUMPRODUCT function, we are multiplying the boolean (FALSE=0 or TRUE=1) result for the (range<>»») comparison by the relative row number, so that the maximum result is the row number of the last blank cell.

Bonus: Create a Dynamic Print Area

When you create a print area in Excel via Page Layout > Print Area > Set Print Area, Excel actually creates a special named range called Print_Area. You can then go to Formulas > Name Manager and edit that named range to use a formula like this:

=OFFSET(start_cell,0,0,rows,columns)

This is a technique I use in some financial templates like the Home Mortgage Calculator to limit the print area based on the length of the payment schedule.

The catch: If you edit the Page Layout (margins, scaling, etc.), the Print_Area reference is changed to a regular reference. I’m not sure why the formula is removed, but this is basically a bug in Excel that has yet to be resolved. To avoid recreating the formula, I typically copy the formula and paste it into a text editor so that I can easily recreate the dynamic print area after I’m done making changes to the page layout.

No Dynamic Named Ranges in Google Sheets

Perhaps things will change in the future, but as of my last update (Sep 28, 2017), you cannot create named formulas using the Named Ranges feature in Google Sheets. This means that although you can use a Named Range for a drop-down list, you can’t create a Dynamic Named Range using a formula in Google Sheets.

Ben Collins shows how you can use a cell to create a text string like «A1:A»&row_num, name the cell, and then use INDIRECT(theName) to get some of the function of a dynamic named range. Unfortunately, that still doesn’t work for drop-down lists, because you can’t use INDIRECT(theCell) as the Range for a drop-down list.