Excel multiple if in one formula

We use the IF statement in Excel to test one condition and return one value if the condition is met and another if the condition is not met.

However, we use multiple or nested IF statements when evaluating numerous conditions in a specific order to return different results.

This tutorial shows four examples of using nested IF statements in Excel and gives five alternatives to using multiple IF statements in Excel.

General Syntax of Nested IF Statements (Multiple IF Statements)

The general syntax for nested IF statements is as follows:

=IF(Condition1, Value_if_true1, IF(Condition2, Value_if_true2, IF(Condition3, Value_if_true3, Value_if_false)))

This formula tests the first condition; if true, it returns the first value.

If the first condition is false, the formula moves to the second condition and returns the second value if it’s true.

Each subsequent IF function is incorporated into the value_if_false argument of the previous IF function.

This process continues until all conditions have been evaluated, and the formula returns the final value if none of the conditions is true.

The maximum number of nested IF statements allowed in Excel is 64.

Now, look at the following four examples of how to use nested IF statements in Excel.

Example #1: Use Multiple IF Statements to Assign Letter Grades Based on Numeric Scores

Let’s consider the following dataset showing some students’ scores on a Math test. 

We want to use nested IF statements to assign student letter grades based on their scores. 

We use the following steps:

1. Select cell C2 and type in the below formula:

=IF(B2>=90,"A",IF(B2>=80,"B",IF(B2>=70,"C",IF(B2>=60,"D","F"))))

1. Click Enter in the cell to get the result of the formula in the cell.

1. Copy the formula for the rest of the cells in the column

The assigned letter grades appear in column C.

Explanation of the formula

=IF(B2>=90,”A”,IF(B2>=80,”B”,IF(B2>=70,”C”,IF(B2>=60,”D”,”F”))))

This formula evaluates the value in cell B2 and assigns an “A” if the value is 90 or greater, a “B” if the value is between 80 and 89, a “C” if the value is between 70 and 79, a “D” if the value is between 60 and 69, and an “F” if the value is less than 60.

Notice that it can be challenging to keep track of which parentheses go with which arguments in nested IF functions.

Therefore, as we enter the formula, Excel uses different colors for the parentheses at each level of the nested IF functions to make it easier to see which parts of the formula belong together. 

Also read: How to use Excel If Statement with Multiple Conditions Range

Example #2: Use Multiple IF Statements to Calculate Commission Based on Sales Volume

Here’s the dataset showing the sales of specific salespeople in a particular month.

We want to use multiple IF statements to calculate the tiered commission for the salespeople based on their sales volume. 

We proceed as follows:

1. Select cell C2 and enter the following formula:

=IF(B2>=40000, B2*0.14,IF(B2>=20000,B2*0.12,IF(B2>=10000,B2*0.105,IF(B2>0,B2*0.08,0))))

1. Press the Enter key to get the result of the formula.
2. Double-click or drag the Fill Handle to copy the formula down the column.

The commission for each salesperson is displayed in column D.

Explanation of the formula

=IF(B2>=40000, B2*0.14,IF(B2>=20000,B2*0.12,IF(B2>=10000,B2*0.105,IF(B2>0,B2*0.08,0))))

This formula evaluates the value in cell B2 and then does the following:

• If the value in cell B2 is greater than or equal to 40,000, the figure is multiplied by 14% (0.14).
• If the figure in cell B2 is less than 40,000 but greater than or equal to 20,000, the value is multiplied by 12% (0.12).
•  If the number in cell B2 is less than 20,000 but greater than or equal to 10,000, the figure is multiplied by 10.5% (0.105).
• If the value in cell B2 is less than 10,000 but greater than 0 (zero), the number is multiplied by 8% (0.08).
• If the value in cell B2 is 0 (zero), 0 (zero) is returned.

Example #3: Use Multiple IF Statements to Assign Sales Performance Rating Based On Sales Target Achievement

The following is a dataset showing regional sales data of a specific technology company in a particular year.

We want to use multiple IF statements to assign a sales performance rating to each region based on their sales target achievement.

We use the following steps:

1. Select cell C2 and type in the below formula:

=IF(B2>500000, "Excellent", IF(B2>400000, "Good", IF(B2>275000, "Average", "Poor")))

1. Click Enter on the Formula bar.
2. Drag or double-click the Fill Handle to copy the formula down the column.

The performance ratings of the regions are shown in column C.

Explanation of the formula

=IF(B2>500000, “Excellent”, IF(B2>400000, “Good”, IF(B2>275000, “Average”, “Poor”)))

In this formula, if the sales target in cell B2 is greater than 500,000, the formula returns “Excellent.”

If it’s between 400,000 and 500,000, the formula returns “Good.”

If it’s between 275,000 and 400,000, the formula returns “Average.” And if it’s below 275,000, the formula returns “Poor.”

Example #4: Use Multiple IF Statements in Excel to Check For Errors and Return Error Messages

Suppose we have the following dataset of students’ English test scores. Some scores are less than 0 or greater than 100, and there are no scores in some cases.

We want to use nested IF statements to check for scores in column B and display error messages in column C if there are no scores or the scores are less than 0 or greater than 100.

If the score in column B is valid, we want the formula to return an empty string in column C.

Here are the steps to follow:

1. Select cell C2 and enter the following formula:

=IF(OR(B2<0,B2>100),"Score out of range",IF(ISBLANK(B2),"Invalid score",""))

1. Click Enter on the Formula bar.
2. Drag the Fill Handle to copy the formula down the column.

The error messages are shown in column C.

Explanation of the formula 

=IF(OR(B2<0,B2>100),”Score out of range”,IF(ISBLANK(B2),”Invalid score”,””))

This formula uses the OR function to check if the score in cell B2 is less than 0 or greater than 100, and if it is, it returns the error message “Score out of range.”

The formula also uses the ISBLANK function to check if cell B2 is blank, and if it is, it returns the error message “Invalid score.”

If there is no error, the formula returns an empty string, meaning no message is displayed in column B.

Alternatives to Using Multiple IF Statements in Excel

Formulas using nested IF statements can become difficult to read and manage if we have more than a few conditions to test.

In addition, if we exceed the maximum allowed limit of 64 nested IF statements, we will get an error message.

Fortunately, Excel offers alternative ways to use instead of nested IF functions, especially when we need to test more than a few conditions. 

We present the alternative ways in this tutorial.

Alternative #1: Use the IFS Function

The IFS function tests whether one or more conditions are met and returns a value corresponding to the first TRUE condition.

Before the release of the IFS function in 2018 as part of the Excel 365 update, the only way to test multiple conditions and return a corresponding value in Excel was to use nested IF statements.

However, multiple IF statements have the downside of resulting in unwieldy formulas that are difficult to read and maintain.

In some situations, the IFS function is designed to replace the need for multiple IF functions.

The syntax of the IFS function is more straightforward and easier to read than nested IF statements, and it can handle up to 127 conditions.

Here’s an example:

Let’s consider the following dataset showing some students’ scores on a Math test. 

We want to use the IFS function to assign letter grades to the students based on their scores. 

We use the following steps:

1. Select cell C2 and type in the below formula:

=IFS(B2>=90, "A", B2>=80, "B", B2>=70, "C", B2>=60, "D", B2<60, "F")

1. Click Enter on the Formula bar.
2. Drag or double-click the Fill Handle to copy the formula down the column.

The student’s letter grades are shown in column C.

Explanation of the formula

=IFS(B2>=90, “A”, B2>=80, “B”, B2>=70, “C”, B2>=60, “D”, B2<60, “F”)

This formula tests the score in cell B2 against each condition and returns the corresponding grade letter when the condition is true. 

Limitation of IFS Function

The IFS function in Excel is designed to simplify complex nested IF statements.

However, there are situations where the IFS function may not be able to replace nested IF functions completely.

One such situation is when you must calculate or operate based on a condition or set of conditions.

While the IFS function can return a value or text string based on a condition, it cannot perform calculations or operations on that value like nested IF statements.

Another situation where the IFS function may be less useful is when you need to test for a range of conditions rather than just a specific set.

This is because the IFS function requires you to specify each condition and corresponding result separately, which can become cumbersome if you have many conditions to test—in contrast, nested IF statements allow you to test for a range of conditions using logical operators like AND and OR.

The IFS function is a powerful tool for simplifying complex logical tests in Excel.

However, there may be situations where nested IF statements are more appropriate for your needs.

We recommend that you consider both options and choose the one that best fits the specific requirements of your task.

Alternative #2: Use Nested IF Functions

We can use multiple IFS functions in a formula if we have more than one condition to test.

For example, let’s say we have the following dataset of student names and scores on a Physics test in columns A and B.

We want to assign a letter grade to each score and include a pass or fail designation based on whether the score is above or below 75.

Here are the steps to use:

1. Select cell C2 and enter the following formula

=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")&"  "&IFS(B2>=75,"Pass",B2<75,"Fail")

1. Click Enter on the Formula bar.
2. Drag or double-click the Fill Handle to copy the formula down the column.

The letter grade and designation of the student scores are displayed in column C.

Explanation of the formula

=IFS(B2>=90,”A”,B2>=80,”B”,B2>=70,”C”,B2>=60,”D”,B2<60,”F”)&”  “&IFS(B2>=75,”Pass”,B2<75,”Fail”)

This formula uses the first IFS function to assign a letter grade based on the score in column A and the second IFS function to give a pass/fail designation based on the score in column A.

The two IFS functions are combined using the ampersand (&) operator to create a single text string that displays each score’s letter grade and pass/fail designation.

Alternative #3: Use the Combination of CHOOSE and XMATCH Functions

The CHOOSE function selects a value or action from a value list based on an index number.

The XMATCH function locates and returns the relative position of an item in an array. We can combine these functions in a formula instead of nested IF functions.

Here’s an example:

Suppose we have the following dataset showing some students’ scores and letter grades on a Biology test. 

We want to use a formula combining the CHOOSE and XMATCH functions to assign corresponding grade points in column D to each letter grade.

We use the following steps:

1. Select cell D2 and type in the below formula:

=CHOOSE(XMATCH(C2,{"F","E","D","C","B","A"},0),0,1,2,3,4,5)

1. Click Enter on the Formula bar.
2. Drag or double-click the Fill Handle to copy the formula down the column.

The grade points for each student are displayed in column D.

Explanation of the formula

=CHOOSE(XMATCH(C2,{“F”,”E”,”D”,”C”,”B”,”A”},0),0,1,2,3,4,5)

This formula applies the XMATCH function to find the position of the letter grade in the array {“F”,”E”,”D”,”C”,”B”,”A”}, and then uses the CHOOSE function to return the corresponding grade points.

Alternative #4: Use the VLOOKUP Function

The VLOOKUP function looks for a value in the leftmost column of a table and then returns a value in the same row from a specified column.

We can use the VLOOKUP function instead of nested IF functions in Excel.

The following is an example of using the VLOOKUP function instead of nested IF functions in Excel:

Suppose we have the following dataset showing some students’ scores and letter grades on a Biology test. 

We want to use the VLOOKUP function to assign grade points to each student’s letter grade in column D.

We use the steps below:

1. Create a table that lists the grades and their corresponding grade points in cell range F1:G7.

1. In cell D2, type the following formula:

=VLOOKUP(C2,$F$2:$G$7,2,FALSE)

Note: Use the dollar signs to lock down the cell range F2:G7.

1. Click Enter on the Formula bar.
2. Drag or double-click the Fill Handle to copy the formula down the column.

The grade points for each student appear in column D.

Explanation of the formula

=VLOOKUP(C2,$F$2:$G$7,2,FALSE)

This formula uses the VLOOKUP function to look up the grade in cell C2 in the table in F2:G7 and return the corresponding grade point in the second column (i.e., column G).

The “FALSE” argument ensures that an exact match is required.

Alternative #5: Use a User-Defined Function

If you need to test more than a few conditions, consider creating a User Defined Function in VBA that can handle many conditions. 

Here’s an example of using VBA code to replace nested IF functions in Excel:

Suppose we have the following dataset showing the sales of specific salespeople in a particular month.

We want to use a User Defined Function to calculate the commission for each salesperson based on the following rates:

• If the total sales are less than $10,000, the commission rate is 8%.
• If the total sales are equal to or greater than $10,000 but less than $20,000, the commission rate is 10.5%.
• If the total sales are equal to or greater than $20,000 but less than $40,000, the commission rate is 12%.
• If the sales are equal to or greater than $40,000, the commission rate is 14%

We use the following steps:

1. Open the worksheet containing the sales dataset.
2. Press Alt + F11 to launch the Visual Basic Editor.
3. Click Insert on the menu bar and choose Module to insert a new module.

1. Enter the following VBA code.

'Code developed by Steve Scott from https://spreadsheetplanet.com
Function COMMISSION(Sales As Double) As Double
    Const Rate1 = 0.08
    Const Rate2 = 0.105
    Const Rate3 = 0.12
    Const Rate4 = 0.14

'Calculate sales commissions

    Select Case Sales
        Case 0 To 9999.99: COMMISSION = Sales * Rate1
        Case 10000 To 19999.99: COMMISSION = Sales * Rate2
        Case 20000 To 39999.99: COMMISSION = Sales * Rate3
        Case Is >= 40000: COMMISSION = Sales * Rate4
    End Select

End Function

1. Save the function procedure and the workbook as a Macro-Enabled Workbook.
2. Press Alt + F11 to switch to the active worksheet with the sales dataset.
3. Select cell C2 and enter the following formula:

=COMMISSION(B2)

1. Click Enter on the Formula bar.
2. Drag or double-click the Fill Handle to copy the formula down the column.

The commission for each salesperson is displayed in column C.

This VBA function takes the sales amount as an argument and returns the corresponding commission.

The User-Defined Function is a much simpler and easier-to-read solution than using nested IF functions.

This tutorial showed four examples of using nested IF statements in Excel and gave five alternatives to using multiple IF statements in Excel. We hope you found the tutorial helpful.

Other Excel tutorials you may find useful:

• Excel Logical Test Using Multiple If Statements in Excel [AND/OR]
• How to Compare Two Columns in Excel (using VLOOKUP & IF)
• Using IF Function with Dates in Excel (Easy Examples)
• COUNTIF Greater Than Zero in Excel
• BETWEEN Formula in Excel (Using IF Function) – Examples
• Count Cells Less than a Value in Excel (COUNTIF Less)

The IF function is one of the most commonly used in Excel. The function can test a single condition as well as perform multiple complex logic tests. We can thus control the execution of Excel tasks using the IF function.

This is important since it enables us to perform actions depending on whether they meet certain conditions defined by the IF formula. We can also add data to cells using the function if other cells meet any of the conditions defined in the IF formula.

To add multiple conditions to an IF formula, we simply add nested IF functions.

In this article, you will learn the basics of the IF function and how to come up with an array of IF formulas. You will also learn the nested IF’s function.

Let’s get started!

1. Basic IF formula that tests a single condition

A single IF statement tests whether a condition is met and returns a value if TRUE and another value if FALSE.

IF (logical test, ‘value_if_true’, ‘value_if_false’)

In the example below, let us test whether the price is less than or equal to 2000. If the condition is true return cheap, otherwise return expensive!

Go to Cell C2 and type ‘=IF(B2<=2000,»CHEAP», «EXPENSIVE»)’

The if formula above records or posts the String Good whenever the single condition B2<=2000.

2. IF formula with multiple conditions (Nested IF Functions.

If you have complex data or want to perform powerful data analysis, you might need to test multiple conditions at a time. You might need to perform a logical test across multiple conditions.

In such cases, you have to use an IF statement with multiple conditions/ranges in a single formula. These multiple IF conditions are normally called nested IF Functions.  The function is used if want more than 3 different results. 

The general syntax for IF function with multiple conditions is

=IF (condition one is true, do something, IF (condition two is true, do something, IF (conditions three is true, do something, else do something)))

Commas are used to separate conditions and IF functions in the IF formula. The «)» is used to close all IFs at the End of the formula while the » (» opens all IF functions. The number of «(» should be equal to that of «)».

In our above example, we can include multiple conditions in the IF formula as follows

=IF(B2<=2000,»CHEAP»,IF(B2<=6000,»AFFORDABLE»,IF(B2<=10000,»EXPENSIVE»,»LUXURIOUS»)))

Press Enter to get the results and use the AutoFill feature to copy the formula to the rest of the cells.

3. IF formula with logical test

You can use an IF statement with AND and OR conditions to perform a logical test. IF your formula has AND function, the logical test returns TRUE if all the conditions are met; otherwise, it will return FALSE. While the OR Function returns TRUE if any of the conditions is met; otherwise it returns FALSE.

3.1 IF with AND Function

In the example below, a student is deemed to pass the exam if he/she has a score of 42 in Maths and 50 in English.

With this information, we can write the condition as follows;

AND (C14>=42, D14>=50)

To know whether the student passed or failed the exam. You can use the IF statement.

= IF(AND (C14>=42, D14>=50),”PASS”,”FAIL”)

Press enter and use the AutoFill feature to copy the formula to the rest of the cells.

3.2 IF with OR Function

The IF with OR Function works the same way as the AND function we have seen above. The only difference is that, if one of the conditions is TRUE then the result will be TRUE.

Follow the above process to apply the OR Function.

In cell E14, type = IF(OR (C14>=42, D14>=50),”PASS”,”FAIL”)

Press enter to get the results.

3. IF with ISNUMBER and ISTEXT Functions

You can use ISNUMBER and ISTEXT formula to find whether the cells have text value, number, or blank.

=IF(ISTEXT(A1), «Text», IF(ISNUMBER(A1), «Number», IF(ISBLANK(A1), «Blank», «»)))

You can only apply AND & OR functions at a time if your task requires you to evaluate several sets of conditions. For example, if you are checking exam results using these criteria:

Condition 1: exam1>50 and exam2>50

Condition 2: exam1>40 and exam2>60

In this case, the exam is deemed passed if either of the conditions is passed.

Although the formula may seem tricky, you only need to express each condition as an AND statement and nest them in the OR function. That is because meeting all the conditions is not necessary, but either statement will serve the purpose. Therefore, the general formula will be:

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

You can now use the OR function to test the logic of IF and supply the desired value_if_true and value_if_false values. In the end, the final IF formula with multiple AND & OR statements will turn into:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), «Pass», «Fail»)

5. Using the Array Formula

An Array formula can also help to get an Excel IF to test multiple conditions. For example, to evaluate the AND logical condition, you can use the asterisk:

IF(condition1) * (condition2) * …, value_if_true, value_if_false)

While to test conditions using OR logic, you will apply the plus sign:

IF(condition1) + (condition2) + …, value_if_true, value_if_false)

Finally, you can complete the Array formula by pressing Ctrl + Shift + Enter buttons together. The trick can also work as a regular formula in Excel 365 and Excel 2021 since it supports dynamic arrays.

Example: We can get “Pass” if cells B2 and C2 are greater than 50 by applying the formulas;

=IF((B2>50) * (C2>50), «Pass», «Fail») for AND logic

…, and

=IF((B2>50) + (C2>50), «Pass», «Fail») for OR logic.

6. IF With Other Excel Functions

Other Excel functions that can give the IF formula for multiple conditions include

6.1 IF#N/A Error in VLOOKUP Function

The VLOOKUP or any other lookup function returns a N/A error if it cannot find something. Therefore, you can return zero, blank, or text if #N/A to make your table neat. Here, you will need the following generic formula:

IF(ISNA(VLOOKUP(…)), value_if_na, VLOOKUP(…))

Example 1. If the lookup value in a cell (E1) is not found, the formula returns 0 as shown below;

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

Example 2: If the lookup value is not found, the formula returns blank as shown below;

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), «», VLOOKUP(E1, A2:B10, 2, FALSE))

Example 3: If the lookup value is not available, the formula returns a specific text as shown below;

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), «Not found», VLOOKUP(E1, A2:B10, 2, FALSE))

6.2 IF With SUM, AVERAGE, MIN, and MAX Functions

Excel has the SUMIF and SUMIFS functions that you can use, to sum up values in cells using certain criteria. You can use the SUM function to test the IF logic of your business. For instance, you can apply this formula to determine the text labels based on the sum of cells B2 and C2 values;

=IF(SUM(B2:C2)>130, «Good», IF(SUM(B2:C2)>110, «Satisfactory», «Poor»))

From the formula, the return text label is “Good” if the sum of the two cells is greater than 130. If the sum is greater than 110, the return text is “Satisfactory”, while if the sum is 110 or below, the return text is “Poor”.

You can still embed the AVERAGE function similarly to test the IF logic and return a different text label based on the average score of the two cells. In this case, the generic formula will be;

=IF(AVERAGE(B2:C2)>65, «Good», IF(AVERAGE(B2:C2)>55, «Satisfactory», «Poor»))

If the sum of cells B2 and C2 is indicated in cell D2, you can use the MAX and MIN functions to identify the highest and lowest values through the formulas;

=IF(D2=MAX($D$2: $D$10), «Best result», «»)

=IF(D2=MAX($D$2: $D$10), «Best result», «»)

Lastly, you can nest the two functions into one another to have both text labels in one column to get the formula;

=IF(D2=MAX($D$2:$D$10), «Best result», IF(D2=MIN($D$2:$D$10), «Worst result», «»))

6.3 IF with CONCATENATE Function

You can also use the CONCATENATE and IF functions to output the result of IF and some text into one cell. Here, you can use the formula;

=CONCATENATE(«You performed «, IF(B1>100,»fantastic!», IF(B1>50, «well», «poor»)))

From the formula, the student will get a «fantastic» result if the score in cell B1 is greater than 100. On the other hand, the result will be «well» if the score in cell B1 is greater than 50.

6.4 IF with ISERROR and ISNA Functions

These functions can only work in modern Excel versions where they trap and replace errors with another predefined value. For instance, the IFERROR function works in Excel 2007 and later, while the IFNA function works in Excel 2013 and later. When using earlier Excel versions, you will need the combinations of IF ISERROR and IF ISNA. So, what is the difference between these applications?

The answer is simple: IFERROR and ISERROR functions can handle all the possible errors resulting from Excel calculations, including VALUE, N/A, NAME, REF, NUM, DIV/0, and NULL errors. Contrary, IFNA, and ISNA handle only N/A errors.

Example: If you want to replace the #DIV/0 (divide by zero error) with a predefined text or value, you can use the formula;

=IF(ISERROR(A2/B2), «N/A», A2/B2), where;

A2 represents the value in cell A2

B2 represents the value in cell B2.

A2/B2 represents the results attained after dividing A2 by B2.

If the value in cell B2 is 0, the formula will return a N/A text.

I hope you found this tutorial useful.

What is Multiple IF Statements?

Multiple IF statements are also known as “Nested IF Statement” is a formula containing 2 or more IF functions. A single IF function only analyze two criteria. If there are more than two criteria, then it should use the multiple IF statements (nested IF). The number of IF functions required in multiple IF statements is the number of criteria minus 1.

Multiple IF Statements in Excel

What is the weight category of each name below based on BMI value? to get the value of BMI, divide the weight (in KG) by the height (in Meter²)

The following is a weight category based on BMI value.

There are six criteria means it takes 5 IF function to assemble multiple IF statements.

IF Function #1 – Underweight or Not

The first IF function looking for “Who has Underweight Body and Who is Not.”

Here are the steps to write the first IF function.

• Place the cursor in cell E2
• Type the formula for the IF Function
• logical_test argument, analyze whether the BMI value is less than 18.5?, type D2<18.5
• value_if_true argument, type “Underweight”
• value_if_false argument, type “” (blank space)

Look below for the resulting formula

=IF(D2<18.5,"Underweight","")

Do a copy in cell E2, then do a paste in range E3:13. The results are as shown below.

The result is two names in “Underweight” category; the other ten names are not in the underweight category. There are five possibilities; it could be Normal, Overweight, Class I Obesity, Class II Obesity or Class III Obesity.

Who has the ideal body? Second IF function answer the question.

IF Function #2 – Normal Weight or Not

The second IF function fills the value_if_false argument of the first IF function. The second IF function is searching “Who has Normal Weight Body and Who is Not.”

Here are the steps to write the second IF function.

• Edit the formula in cell E2 by pressing F2 key
• Change value_if_false argument of first IF function from “” to the second IF function
• logical_test argument, analyze whether the BMI value is less than 25, D2<25
• value_if_true argument, type “Normal”
• value_if_false argument, type “” (blank space)

Look below for the resulting formula

=IF(D2<18.5,"Underweight"
,IF(D2<25,"Normal",""))

Do a copy in cell E2, then do a paste in range E3:13. The results are as shown below.

Two names in “Normal Weight” category and there are already four names and their weight category.

There are eight other names with no weight category. There are four possibilities; it could be Overweight, Class I Obesity, Class II Obesity or Class III Obesity.

Who has the overweight body? Third IF function answer the question.

IF Function #3 – Overweight or Not

The third IF function takes the value_if_false argument of the second IF function, seeking “Who has Overweight Body and Who is Not.”

Here are the steps to write the third IF function.

• Edit the formula in cell E2 by pressing F2 key
• Change value_if_false argument of second IF function from “” to the third IF function
• logical_test argument, analyze whether the BMI value is less than 30, D2<30
• value_if_true argument, type “Overweight”
• value_if_false argument, type “” (blank space)

Look below for the resulting formula

=IF(D2<18.5,"Underweight"
,IF(D2<25,"Normal"
,IF(D2<30,"Overweight","")))

Do a copy in cell E2, then do a paste in range E3:13. The results are as shown below.

Two additional names appear in “Overweight” category. There were six names known their weight category; there are still six other names not yet known. There are three possibilities left; it could be Class I Obesity, Class II Obesity or Class III Obesity.

Who has the class I obesity body? Fourth IF function answer the question.

IF Function #4 – Class I Obesity or Not

The fourth IF function occupies the value_if_false argument of the third IF function. The fourth IF function seeking “Who has a Class I Obesity Body and Who is Not.”

Here are the steps to write the fourth IF function.

• Edit the formula in cell E2 by pressing F2 key
• Change value_if_false argument of third IF function from “” to the fourth IF function
• logical_test argument, analyze whether the BMI value is less than 30, D2<35
• value_if_true argument, type “Class I Obesity”
• value_if_false argument, type “” (blank space)

Look below for the resulting formula

=IF(D2<18.5,"Underweight"
,IF(D2<25,"Normal"
,IF(D2<30,"Overweight"
,IF(D2<35,"Class I Obesity",""))))

Do a copy in cell E2, then do a paste in range E3:13. The results are as shown below.

Again, two additional names appear, but in “Class I Obesity” category. There were eight names known their weight category; there are four names remain unknown. There are remaining two possibilities; it could be Class II Obesity or Class III Obesity.

Who has the class II obesity body? Fifth IF function answer the question.

IF Function #5 – Class II Obesity or Class III Obesity

The fifth IF function, the last IF function to determine weight category for each name, it takes the value_if_false argument of the fourth IF function, looking for “Who has a Class II Obesity Body and Who is Not.”

Here are the steps to write the fifth IF function.

• Edit the formula in cell E2 by pressing F2 key
• Change value_if_false argument of fourth IF function from “” to the fifth IF function
• logical_test argument, analyze whether the BMI value is less than 30, D2<40
• value_if_true argument, type “Class II Obesity”
• value_if_false argument, type “” (blank space)

Look below for the resulting formula

=IF(D2<18.5,"Underweight"
,IF(D2<25,"Normal"
,IF(D2<30,"Overweight"
,IF(D2<35,"Class I Obesity"
,IF(D2<40,"Class II Obesity","")))))

Do a copy in cell E2, then do a paste in range E3:13. The results are as shown below.

There are still two names and unknown weight category, all if function already used. “Who has a Class III Obesity Body,” which if function answer this question?

If only one weight category left, then the last one takes the value_if_false argument of the fifth IF function.

Edit the formula in cell E2, change the value_if_false argument of fifth IF function from “” to “Class III Obesity.”

Look below for the resulting formula.

=IF(D2<18.5,"Underweight"
,IF(D2<25,"Normal"
,IF(D2<30,"Overweight"
,IF(D2<35,"Class I Obesity"
,IF(D2<40,"Class II Obesity","Class III Obesity")))))

Do a copy in cell E2, then do a paste in range E3:13. The results are as shown below.

Video Tutorial for Multiple IF Statements

Here is a video explains step by step writing multiple IF statements one by one from the first IF function until the fifth IF function

The next video explains how to write all the IF functions at once

Another Alternative for Multiple IF Statements

IFS Function

The IFS function is available if you have an Office 365 subscription, make sure you have the latest version of Office 365. Microsoft provides the IFS function as an alternative and an improvement of nested IF, no need to use multiple IF statements to analyze more than two criteria.

With the same example above, what is the weight category of each name below based on BMI value? Here is a solution using the IFS function. Look below for the resulting formula.

=IFS(D2<18.5,"Underweight"
,D2<25,"Normal"
,D2<30,"Overweight"
,D2<35,"Class I Obesity"
,D2<40,"Class II Obesity"
,TRUE,"Class III Obesity")

It makes no difference, multiple IF statements result and IFS function result.

VLOOKUP Function

The VLOOKUP function instead of multiple IF statements? Yes, you are not wrong, you can use VLOOKUP function to analyze more than two criteria. The key is the TRUE value for the range_lookup argument.

Using the same example as the previous case, what is the weight category of each name below based on BMI value?. Here is a solution using the VLOOKUP function. Look below for the resulting formula.

=VLOOKUP(D12,$A$3:$C$8,3,TRUE)

What is the difference? The multiple IF statements vs. the VLOOKUP function result.

Which One is the Best to Analyze more than 2 Criteria

Multiple IF Statements vs. IFS Function vs. VLOOKUP Function, which one is your choice?

Multiple IF statements tend to be difficult to use for the inexperienced, especially more than 5 IF functions in a formula. The biggest weakness of nested IF is there is a maximum limit. Before Excel 2007, seven is the maximum number in one formula, after Excel 2007 you can use up to 64 IF functions in one formula.

Although the latest version of Excel can accommodate a lot of IF functions, multiple IF statements are not the best solution, try to avoid it as much as possible.

The IFS function is an improvement for multiple IF statements provided by Microsoft, able to analyze up to 127 criteria. The disadvantage appears if there are any additional criteria; all formula must be edited to accommodate the addition of new criteria.

What about the VLOOKUP function? What is the maximum number of criteria allowed to be analyzed? If there is a new criterion added, should the formula be edited?

There are no maximum criteria for the VLOOKUP function; the number of rows in the excel worksheet is the limitation.

Look at the VLOOKUP function above, a VLOOKUP function and a table answering all the questions. If there are new criteria, then add the criteria in the table, by using the dynamic named range, no need to change the formula at all.

For me VLOOKUP is my choice, what is yours?

Related Function

I received a lot of questions on how to use IF function with 3 conditions, so I’ve decided to write an article on this topic.

The IF examples described in this article assume that you have a basic understanding of how the IF function works. All examples from this article work in Excel for Microsoft 365 or Excel 2021, 2019, 2016, 2013, 2010, and 2007.

IF is one of the most used Excel functions. In case you are unfamiliar with the IF function, then I strongly recommend reading my article on Excel IF function first. It’s a step-by-step guide, and it includes a lot of useful examples. It also shows the basics of writing an Excel IF statement with multiple conditions, but it’s not as detailed as this guide. Make sure you also download the exercise file.

As a data analyst, you need to be able to evaluate multiple conditions at the same time and perform an action or display certain values when the logical tests are TRUE. This means that you will need to learn how to write more complex formulas, which sooner or later will include multiple IF statements in Excel, nested one inside the other.

Let’s take a look at how to write a simple IF function with 3 logical tests.

The first example uses an IF statement with three OR conditions. We will use an IF formula which sets the Finance division name if the department is Accounting, Financial Reporting, or Planning & Budgeting.

The IF statement from cell E31 is:
=IF(OR(D31="Accounting", D31="Financial Reporting", D31="Planning & Budgeting"), "Finance", "Other")

This IF formula works by checking three OR conditions:

• Is the data from the cell D31 equal to Accounting? In our case, the answer is no, and the formula continues and evaluates the second condition.
• Is the text from the cell D31 equal to Financial Reporting? The answer is still no, and the formula continues and evaluates the third condition.
• Is the text from the cell D31 equal to Planning & Reporting? The answer is yes, our IF function returns TRUE, and displays the word Finance in cell E31.

Next, we focus our attention on an example that uses an IF statement with three AND conditions.

Our table shows exam scores for three exams. If the student received a score of at least 70 for all three exams, then we will return Pass. Otherwise, we will display Fail.

The IF statement from cell H53 is:
=IF(AND(E53>=70, F53>=70, G53>=70), "Pass", "Fail")

This IF formula works by checking all three AND conditions:

• Is the score for Exam 1 higher than or equal to 70? In our case, the answer is yes, and the formula continues and evaluates the second condition.
• Is the score for Exam 2 higher than or equal to 70? Well, yes it is. Now the formula moves to the third condition.
• Is the score for Exam 3 higher than or equal to 70? Yes, it is. Since all three conditions are met, the IF statement is TRUE and returns the word Pass in cell H53.

Excel IF statement with multiple conditions

The final section of this article is focused on how to write an Excel IF statement with multiple conditions, and it includes two examples:

• multiple nested IF statements (also known as nested IFS)
• formula with a mix of AND, OR, and NOT conditions

How many IF statements can you nest in Excel? The answer is 64, but I’ve never seen a formula that uses that many. Also, I’m sure that there are far better alternatives to using such a complicated formula.

Multiple nested IF statements

In this example, I have calculated the grade of the students based on their scores using a formula with 4 nested IF functions.

=IF(E107<60, "F", IF(E107<70, "D", IF(E107<80, "C", IF(E107<90, "B" ,"A"))))

Note: In this case, the order of the conditions influences the result of your formula. When your conditions overlap, Excel will return the [value_if_true] argument from the first IF statement that is TRUE and ignores the rest of the values. If you want your formula to work properly, always pay attention to the logical flow and the order of your nested IF functions.

If you have to write an IF statement with 3 outcomes, then you only need to use one nested IF function. The first IF statement will handle the first outcome, while the second one will return the second and the third possible outcomes.

Note: If you have Office 365 installed, then you can also use the new IFS function. You can read more about IFS on Microsoft’s website.

Multiple IF statements in Excel with AND, OR, and NOT conditions

I have saved the best for last. This example is the most advanced from this article, as it involves an IF statement with several other logical functions.

In the exercise file, I have included a list of orders. Each row includes the order date, the order value, the product category, and the free shipping flag. We want to flag orders as eligible if the following cumulative logical conditions are met:

• the order was placed during 2020
• the order includes products from only two categories: PC or Laptop
• the order was not flagged as Free shipping

The formula I’ve used for cell H80 is shown below:

=IF(AND(D80>=DATE(2020,1,1), D80<=DATE(2020,12,31), OR(F80="PC", F80="Laptop"), NOT(G80="Yes")), "Eligible", "Not eligible")

Here’s how this works:

1. AND makes sure that all the logical conditions need to be met to flag the order as Eligible. If any of them is FALSE, then our entire IF statement will return the [value_if_false] argument.
2. D80>=DATE(2020,1,1) and D80<=DATE(2020,12,31) check if the order was placed between January 1st and December 31st, 2020.
3. OR is used to check whether the product category is PC or Laptop.
4. Finally, NOT is used to check if the Free shipping flag is different from Yes.

I’ve also added a video that shows how to nest IF functions in case you are still having difficulties understanding how a nested IF formula works.

And there you have it. I hope that after reading this guide, you have a much better understanding of using IF function with 3 logical tests (or any number actually). While it may seem intimidating at first, I guarantee that if you write an IF formula with multiple criteria daily, your productivity will eventually skyrocket.

This is why, if you have any questions on how to use IF function with 3 conditions, please leave a comment below and I will do my best to help you out. I reply to every comment or email that I receive.