Функция СУММЕСЛИМН используется для суммирования переданных значений с учетом нескольких критериев отбора данных, которые указываются в качестве аргументов функции, и возвращает полученное суммарное значение.
Примеры использования функции СУММЕСЛИМН в Excel
В отличие от СУММЕСЛИ, в рассматриваемой функции предусмотрена возможность внесения до 127 критериев отбора данных для суммирования. СУММЕСЛИМН удобна для работы с объемными таблицами, содержащими большое число полей данных. Например, если требуется рассчитать общую сумму средств, полученных в результате поставки определенного типа товара указанной компанией в определенную страну, удобно использовать функцию СУММЕСЛИМН.
Динамический диапазон суммирования по условию в Excel
Пример 1. В таблице содержатся данные о успеваемости студентов по некоторому предмету в университете. Определить итоговую оценку для студентов с фамилией, начинающейся на букву «А» при условии, что минимальный балл должен быть не менее 5 (успеваемость студентов оценивается по 10-бальной шкале).
Вид таблицы данных:
Для расчета суммарного балла согласно установленным критериям используем следующую формулу:
Описание аргументов:
- C3:C14 – диапазон ячеек с баллами, из которых будут автоматически выбраны значения для расчета суммы, которые соответствуют установленным критериям;
- C3:C14 – первый диапазон ячеек, к которому будет применен первый критерий;
- «>5» – первое условие отбора значений из указанного выше диапазона;
- B3:B14 – второй диапазон ячеек (с фамилиями студентов), к которому будет применен второй критерий;
- «А*» – второе условие отбора значений (все фамилии, которые начинаются с буквы «А»).
Результат расчетов:
В результате формула автоматически определила динамически изменяемый диапазон в соответствии с условиями отбора значений и просуммировала его.
Выборочное суммирование по условию в Excel
Пример 2. В таблице указаны данные об отгрузках трех товаров в различные страны на протяжении трех месяцев. Определить суммарный доход от отгрузок товара №2 в Казахстан за июнь и август.
Вид таблицы данных:
Для расчета итоговой суммы используем формулу:
Результат расчетов:
Примечание: формула выглядит громоздкой несмотря на то, что для столбца «Месяц» было использовано всего 2 критерия отбора. Формулы с несколькими критериями для одного диапазона данных можно существенно сократить способом, который будет показан в следующем примере.
СУММЕСЛИМН для суммирования значений по нескольким условиям в Excel
Пример 3. Используя таблицу из второго примера определить суммарной прибыли от поставок товара №1 в Китай и Грузию на протяжении всего периода (трех месяцев).
Для нахождения искомого значения используем формулу массива (для ввода жмем CTRL+SHIFT+Enter):
Функция СУММЕСЛИМН возвращает массив значений для критериев «Китай» и «Грузия» соответственно, которые суммируются функцией СУММ.
Примечание: если критерии переданы в качестве константы массива для двух и более пар диапазон_условияN; условиеN, результат выполнения формулы будет некорректным.
Полученное значение:
Особенности использования функции СУММЕСЛИМН в Excel
Функция имеет следующую синтаксическую запись:
=СУММЕСЛИМН(диапазон_суммирования; диапазон_условия1; условие1; [диапазон_условия2; условие2]; …)
Описание аргументов:
- диапазон_суммирования – обязательный аргумент, принимающий ссылку на ячейки с числами, для которых будет вычислено суммарное значение с учетом установленных критериев;
- диапазон_условия1 – обязательный аргумент, принимающий ссылку на ячейки, в которых содержатся данные для проверки на соответствие заданному критерию;
- условие1 – обязательный аргумент, принимающий ссылку на ячейку с условием поиска, текстовую запись логического выражения (например, «>=100» или «<>0»), проверяемый текст (например, «Продавец_1», «Товар_1») или числовое значение (Например, 20), определяющие ячейки в диапазоне условия1, для которых будут отобраны и просуммированы данные из диапазона суммирования.
Последующие аргументы являются необязательными для заполнения, а их смысл соответствует аргументам диапазон_условия1; условие1. Всего может быть задано до 127 условий отбора данных для суммирования.
Примечания:
- Если в качестве аргумента диапазон_суммирования была передана ссылка на диапазон ячеек, содержащие текстовые строки или пустые значения, функция СУММЕСЛИМН будет их игнорировать.
- В качестве условий суммирования данных могут выступать числовые значения, логические выражения, текстовые строки, формулы, ссылки на ячейки, содержащие условия.
- Условия проверки в виде текста или выражений с логическими и математическими символами должны быть указаны в кавычках.
- Максимальная длина условия, переданного в качестве аргумента условие1 (условие2 и т. д.) не должна превышать 255 символов.
- Для создания неточных текстовых критериев поиска требуемых значений можно использовать подстановочные знаки «?» и «*», замещающие один или несколько символов соответственно.
- Если в диапазоне ячеек, переданных в качестве аргумента диапазон_суммирования, есть ячейки, содержащие логические ИСТИНА или ЛОЖЬ, они будут автоматически преобразованы к числовым значениям 1 и 0 соответственно и будут учтены в итоговой сумме.
- Число ячеек в диапазонах суммирования и условиях должно быть одинаковым, иначе функция СУММЕСЛИМН вернет код ошибки #ЗНАЧ!.
Excel для Microsoft 365 Excel для Microsoft 365 для Mac Excel для Интернета Excel 2021 Excel 2021 для Mac Excel 2019 Excel 2019 для Mac Excel 2016 Excel 2016 для Mac Excel 2013 Excel Web App Excel 2010 Excel Starter 2010 Еще…Меньше
Функция СУММЕСЛИМН — одна из математических и тригонометрических функций, которая суммирует все аргументы, удовлетворяющие нескольким условиям. Например, с помощью функции СУММЕСЛИМН можно найти число всех розничных продавцов, (1) проживающих в одном регионе, (2) чей доход превышает установленный уровень.
Синтаксис
СУММЕСЛИМН(диапазон_суммирования; диапазон_условия1; условие1; [диапазон_условия2; условие2]; …)
-
=СУММЕСЛИМН(A2:A9; B2:B9; «=Я*»; C2:C9; «Артем»)
-
=СУММЕСЛИМН(A2:A9; B2:B9; «<>Бананы»; C2:C9; «Артем»)
|
Имя аргумента |
Описание |
|---|---|
|
Диапазон_суммирования (обязательный аргумент) |
Диапазон ячеек для суммирования. |
|
Диапазон_условия1 (обязательный аргумент) |
Диапазон, в котором проверяется Условие1.
|
|
Условие1 (обязательный аргумент) |
Условие, определяющее, какие ячейки суммируются в аргументе Диапазон_условия1. Например, условия могут вводится в следующем виде: 32, «>32», B4, «яблоки» или «32». |
|
Диапазон_условия2, Условие2, … (необязательный аргумент) |
Дополнительные диапазоны и условия для них. Можно ввести до 127 пар диапазонов и условий. |
Примеры
Чтобы использовать эти примеры в Excel, выделите нужные данные в таблице, щелкните их правой кнопкой мыши и выберите команду Копировать. На новом листе щелкните правой кнопкой мыши ячейку A1 и в разделе Параметры вставки выберите команду Использовать форматы конечных ячеек.
|
Проданное количество |
Продукт |
Продавец |
|---|---|---|
|
5 |
Яблоки |
Артем |
|
4 |
Яблоки |
Ольга |
|
15 |
Артишоки |
Артем |
|
3 |
Артишоки |
Ольга |
|
22 |
Бананы |
Артем |
|
12 |
Бананы |
Ольга |
|
10 |
Морковь |
Артем |
|
33 |
Морковь |
Ольга |
|
Формула |
Описание |
|
|
=СУММЕСЛИМН(A2:A9; B2:B9; «=Я*»; C2:C9; «Артем») |
Суммирует количество продуктов, названия которых начинаются с Я и которые были проданы продавцом Артем. Подстановочный знак (*) в аргументе Условие1 («=Я*») используется для поиска соответствующих названий продуктов в диапазоне ячеек, заданных аргументом Диапазон_условия1 (B2:B9). Кроме того, функция выполняет поиск имени «Артем» в диапазоне ячеек, заданных аргументом Диапазон_условия2 (C2:C9). Затем функция суммирует соответствующие обоим условиям значения в диапазоне ячеек, заданном аргументом Диапазон_суммирования (A2:A9). Результат — 20. |
|
|
=СУММЕСЛИМН(A2:A9; B2:B9; «<>Бананы»; C2:C9; «Артем») |
Суммирует количество продуктов, которые не являются бананами и которые были проданы продавцом по имени Артем. С помощью оператора <> в аргументе Условие1 из поиска исключаются бананы («<>Бананы»). Кроме того, функция выполняет поиск имени «Артем» в диапазоне ячеек, заданных аргументом Диапазон_условия2 (C2:C9). Затем функция суммирует соответствующие обоим условиям значения в диапазоне ячеек, заданном аргументом Диапазон_суммирования (A2:A9). Результат — 30. |
Распространенные неполадки
|
Проблема |
Описание |
|---|---|
|
Вместо ожидаемого результата отображается 0 (нуль). |
Если выполняется поиск текстовых значений, например имени человека, убедитесь в том, что значения аргументов Условие1, 2 заключены в кавычки. |
|
Неверный результат возвращается в том случае, если диапазон ячеек, заданный аргументом Диапазон_суммирования, содержит значение ИСТИНА или ЛОЖЬ. |
Значения ИСТИНА и ЛОЖЬ в диапазоне ячеек, заданных аргументом Диапазон_суммирования, оцениваются по-разному, что может приводить к непредвиденным результатам при их суммировании. Ячейки в аргументе Диапазон_суммирования, которым присвоено значение ИСТИНА, оцениваются как 1. Ячейки, которым присвоено значение ЛОЖЬ, оцениваются как 0 (ноль). |
Рекомендации
|
Необходимые действия |
Описание |
|---|---|
|
Использование подстановочных знаков |
Подстановочные знаки, такие как вопросительный знак (?) или звездочка (*), в аргументах Условие1, 2 можно использовать для поиска сходных, но не совпадающих значений. Вопросительный знак соответствует любому отдельно взятому символу. Звездочка — любой последовательности символов. Если требуется найти именно вопросительный знак или звездочку, следует ввести значок тильды (~) перед вопросительным знаком. Например, формула =СУММЕСЛИМН(A2:A9; B2:B9; «=Я*»; C2:C9; «Арте?») будет суммировать все значения с именем, начинающимся на «Арте» и оканчивающимся любой буквой. |
|
Различия между функциями СУММЕСЛИ и СУММЕСЛИМН |
Порядок аргументов в функциях СУММЕСЛИ и СУММЕСЛИМН различается. Например, в функции СУММЕСЛИМН аргумент Диапазон_суммирования является первым, а в функции СУММЕСЛИ — третьим. Этот момент часто является источником проблем при использовании данных функций. При копировании и изменении этих похожих формул нужно следить за правильным порядком аргументов. |
|
Одинаковое количество строк и столбцов для аргументов, задающих диапазоны ячеек |
Аргумент Диапазон_условия должен иметь то же количество строк и столбцов, что и аргумент Диапазон_суммирования. |
К началу страницы
Дополнительные сведения
Вы всегда можете задать вопрос специалисту Excel Tech Community или попросить помощи в сообществе Answers community.
См. также
Просмотрите видео об использовании усложненных функций ЕСЛИ, таких как функция СУММЕСЛИМН.
Функция СУММЕСЛИ суммирует только те значения, которые соответствуют одному условию
Функция СУММКВ суммирует несколько значений, предварительно возведя каждое из них в квадрат
Функция СЧЁТЕСЛИ подсчитывает только те значения, которые соответствуют одному условию
Функция СЧЁТЕСЛИМН подсчитывает только те значения, которые соответствуют нескольким условиям
Функция ЕСЛИМН (Microsoft 365, Excel 2016 и более поздние версии)
Полные сведения о формулах в Excel
Рекомендации, позволяющие избежать появления неработающих формул
Поиск ошибок в формулах
Математические и тригонометрические функции
Функции Excel (по алфавиту)
Функции Excel (по категориям)
Нужна дополнительная помощь?
Skip to content
В этом руководстве объясняется различие между функциями СУММЕСЛИ (SUMIF) и СУММЕСЛИМН (SUMIFS) с точки зрения их синтаксиса и использования, а также приводятся примеры формул для суммирования значений с несколькими критериями в Excel 2016, 2013, 2010, 2007, 2003 и ниже.
Как известно, Microsoft Excel предоставляет множество функций для выполнения различных расчетов с данными. Мы уже рассмотрели СУММЕСЛИ, которая суммирует числа, соответствующие указанным критериям. Теперь пришло время перейти к расширенной версии этой функции СУММЕСЛИМН, которая позволяет найти сумму по нескольким условиям.
Те, кто знаком с функцией СУММЕСЛИ, могут подумать, что преобразование ее в СУММЕСЛИМН потребует лишь букв «МН» и некоторого количества дополнительных критериев. Это может показаться вполне логичным… но «логично» — это не всегда имеет место при работе с Microsoft:)
Как работает СУММЕСЛИМН?
При помощи СУММЕСЛИМН можно найти сумму величин, для которых есть много условий. Она появилась впервые в MS Excel 2007, поэтому вы можете использовать ее во всех современных версиях программы.
По сравнению с СУММЕСЛИ, синтаксис СУММЕСЛИМН немного сложнее:
СУММЕСЛИМН(диапазон_суммирования, диапазон_условия1, условие1, [диапазон_условия2, условие2],…)
Первые 3 аргумента являются обязательными, а вот дополнительные диапазоны и связанные с ними условия являются необязательными.
диапазон_суммирования — требуется одна или более ячеек для суммирования. Это может быть отдельная клеточка, область или именованный диапазон. Суммируются только ячейки с чисами; пустые и текстовые значения игнорируются.
диапазон_условия1 — обязательный первый диапазон, который должен быть оценен по соответствующим критериям.
условие1— обязательное первое условие, которое должно быть выполнено. Вы можете предоставить его в виде числа, логического выражения, ссылки, текста или другой функции Excel. Например, вы можете использовать такие критерии, как 10, «> = 10», A1, «яблоко» или СЕГОДНЯ().
Все, что следует далее — это дополнительные диапазоны и связанные с ними критерии. Они не являются обязательными, но если у вас только одно ограничение, то зачем вам эта функция? Просто используйте СУММЕСЛИ. Тем не менее, вы можете использовать до 127 пар диапазон/условие.
Важно! Функция СУММЕСЛИМН работает с логикой «И». Это означает, что число в диапазоне суммирования учитывается, только если оно удовлетворяет всем указанным критериям (все требования соблюдаются для этой ячейки).
Использование СУММЕСЛИМН и СУММЕСЛИ в Excel — что нужно запомнить?
Поскольку целью этого руководства является охват всех возможных способов суммирования значений по большому количеству ограничений, мы обсудим примеры выражений с обеими функциями — СУММЕСЛИМН и СУММЕСЛИ с несколькими критериями. Чтобы использовать их правильно, вам необходимо четко понимать, что общего между этими двумя функциями и чем они отличаются.
Хотя общая часть ясна — схожий пункт назначения и параметры – но различия не так очевидны, хотя и достаточно существенны.
1. Порядок аргументов
Аргументы применяются по-разному. В частности, диапазон_сумирования является 1-м параметром в СУММЕСЛИ, но является третьим в СУММЕСЛИМН.
На первый взгляд может показаться, что Microsoft намеренно усложняет процесс обучения для своих пользователей. Однако при ближайшем рассмотрении вы увидите причины этого. Дело в том, что этот диапазон является необязательным в СУММЕСЛИ. Если вы его опустите, то нет никаких проблем, ваша формула будет складывать в диапазоне поиска (первый параметр).
В СУММЕСЛИМН он, напротив, очень важен и обязателен, и поэтому и стоит первым. Вероятно, ребята из Microsoft подумали, что после добавления 10- й или 100- й пары диапазон/критерий кто-то может забыть указать диапазон для суммирования:)
2. Диапазон суммирования и область критериев должны быть одинакового размера
В функции СУММЕСЛИ эти аргументы не обязательно должны иметь одинаковую размерность. Достаточно указать начальную точку. В СУММЕСЛИМН они должны содержать одинаковое количество строк и столбцов.
Выражение =СУММЕСЛИМН(E2:E21;C2:C21;I2;F2:F22;I3) вернет сообщение об ошибке #ЗНАЧ!, так как второй параметр поиска (F2:F22) не совпадает по размеру с остальными (E2:E21) и (C2:C21).
Хорошо, хватит стратегии (т.е. теории), давайте перейдем к тактике (к примерам).
Суммирование с множеством условий.
Имеются данные о заказах и продаже шоколада. Подсчитаем итог совершённых продаж по молочному шоколаду. То есть, у нас два требования: должно совпадать наименование товара и в колонке «Выполнен» должно быть указано «Да».
Первым аргументом мы указываем диапазон суммирования E2:E21, а затем попарно – диапазон условия и само условие для него.
=СУММЕСЛИМН(E2:E21;C2:C21;I2;F2:F21;I3)
В C2:C21 будем искать слово «молочный» с любым его вхождением. То есть, до и после него могут быть еще любые другие символы.
В F2:F21 ищем «Да», то есть отметку о том, что заказ выполнен.
Если ОБА эти требования выполняются, то такой заказ нам подходит, и его стоимость мы учтём.
Как видите, у нас найдено 2 совпадения, в которых был продан молочный шоколад.
Использование операторов сравнения.
Рассчитаем по покупателю «Красный» стоимость заказов, в которых было более 100 единиц товара. Как видим, здесь нужно использовать и текстовый, и числовой критерий.
Критерии можно записать в саму формулу, и выглядеть это будет так:
=СУММЕСЛИМН(E2:E21;B2:B21;”Красный”;D2:D21;”>100”)
Но более рационально использовать ссылки, как это и сделано на рисунке:
=СУММЕСЛИМН(E2:E21;B2:B21;I2;D2:D21;I4)
Примечание. Обратите внимание, что в формулах логические выражения с операторами сравнения всегда должны быть заключены в двойные кавычки («»).
Синтаксис, а также работа с числами, текстом и датами у этой функции точно такие же, как и СУММЕСЛИ. Поэтому рекомендую обратиться к нашему предыдущему материалу о условном суммировании.
А как еще можно решить нашу задачу?
Способ 2. Используем функцию СУММПРОИЗВ.
Разберем подробнее, как работает СУММПРОИЗВ():
=СУММПРОИЗВ(—(B2:B21=$I$12);—(D2:D21>I13);E2:E21)
Результатом вычисления B2:B21=$I$12 является массив
{ЛОЖЬ:ИСТИНА:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ИСТИНА:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ИСТИНА:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ}.
ИСТИНА означает соответствие кода покупателя условию, т.е. слову Красный. Массив этот можно увидеть, выделив в строке формул B2:B21=$I$12, а затем нажав F9.
А что за странные знаки «минус» перед этими выражениями? Дело в том, что нам необходимы не эти логические выражения, а числа, чтобы их затем можно было перемножать и складывать. Если Эксель производит математическую операцию с логическим выражением, то он автоматически преобразует его в число. А знак минус означает умножение на -1. А если дважды умножить на -1, то число в результате не изменится. Это мы помним еще из школьной математики 😊
И в результате логический массив превратится в массив чисел {0:1:0:0:0:0:0:0:0:0:0:0:1:0:0:0:1:0:0:0}.
Результатом вычисления D2:D21>I13 является массив
{ИСТИНА:ИСТИНА:ИСТИНА:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ИСТИНА:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ:ИСТИНА:ЛОЖЬ:ИСТИНА:ЛОЖЬ:ЛОЖЬ:ЛОЖЬ}.
ИСТИНА соответствует ограничению «количество больше 100». Здесь мы также применяем двойное отрицание, чтобы преобразовать логические переменные в числа.
И, наконец, результатом вычисления В2:В13 является массив {11250:23210:12960:3150:5280:9750:3690:18300:5720:6150: 8400:2160:7200:1890:17050:3450:15840:2250:7200:8250}, т.е. просто числа из столбца E.
Результатом поэлементного умножения этих трех массивов является {0:23210:0:0:0:0:0:0:0:0:0:0:0:0:0:0:15840:0:0:0}. Суммируем эти произведения и получаем 39050.
Способ 3. Формула массива.
И еще один вариант расчета – применим формулу массива. В I14 запишем:
=СУММ((B2:B21=I12)*(D2:D21>I13)*(E2:E21))
Не забудьте в конце нажать комбинацию клавиш CTRL+SHIFT+ENTER, чтобы обозначить это выражение как формулу массива. Фигурные скобки в начале и в конце программа добавит автоматически. Вновь получим результат 39050.
Способ 4. Автофильтр.
Еще один альтернативный вариант – применение автофильтра. Для этого преобразуйте диапазон данных A1:F21 в «умную» таблицу. Напомню, что для этого в меню «Главная» выберите «Форматировать как таблицу». После этого добавьте в нее строку итогов (вкладка «Конструктор») и установите необходимые фильтры.
Без всяких формул итог по отфильтрованным строкам будет определён.
Как СУММЕСЛИМН работает с датами?
Если вы хотите отобрать и сложить какие-то показатели в определенном временном интервале на основе текущей даты, используйте функцию СЕГОДНЯ() в ваших ограничениях, как это показано ниже.
Следующая формула суммирует числа в столбце D, если соответствующая дата в столбце А попадает в последние 7 дней, включая сегодняшний день (предполагается, что сегодня 7 февраля):
=СУММЕСЛИМН(D2:D21;A2:A21;»<=»&СЕГОДНЯ();A2:A21;»>=»&СЕГОДНЯ()-6)
Замечание. Когда вы при составлении ограничения используете другую функцию Excel вместе с логическим оператором, нужно использовать амперсанд (&) для объединения всего выражения в виде текста, например «<=»&СЕГОДНЯ().
Аналогичным образом вы можете использовать функцию Excel СУММЕСЛИ для суммирования каких-то показателей в заданном диапазоне дат. Например, следующая формула также решит нашу задачу:
=СУММЕСЛИ(A2:A21;»>=»&СЕГОДНЯ()-6;D2:D21) — СУММЕСЛИ(A2:A21;»<=»&СЕГОДНЯ();D2:D21)
Однако СУММЕСЛИМН сложение делает гораздо проще и понятнее, не так ли?
Суммирование по пустым и непустым ячейкам.
При анализе отчетов и других данных вам часто может потребоваться суммировать данные, соответствующие пустым или непустым клеткам таблицы.
| Критерии | Описание | Содержание | |
| Пустые ячейки | «=» | Суммируйте числа, соответствующие пустым, которые не содержат абсолютно ничего — ни формулы, ни строки нулевой длины. | =СУММЕСЛИМН(C2:C10;A2:A10;»=»;B2:B10,»=») Суммируйте в C2:C10, если соответствующие ячейки в столбцах A и B абсолютно пусты. |
| «» | Суммируйте числа, соответствующие «визуально» пустым, включая те, которые содержат пустые строки, возвращаемые какой-либо другой функцией Excel (например, ячейки с формулой вроде = «»). | =СУММЕСЛИМН(C2:C10;A2:A10;»»;B2:B10,»») Суммируйте в C2:C10 с теми же параметрами, что и в приведенной выше формуле, но с пустыми строками. |
|
| Непустые ячейки | «<>» | Суммируйте числа, соответствующие непустым, включая строки нулевой длины. | =СУММЕСЛИМН(C2:C10;A2:A10;»<>»;B2:B10,»<>») Суммируйте в C2: C10, если соответствующие ячейки в столбцах A и B не пусты, включая ячейки с пустыми строками. |
| Суммируйте числа, соответствующие непустым, не включая строки нулевой длины. | =СУММ(C2:C10) — СУММЕСЛИМН(C2:C10;A2:A10;»»;B2:B10,»») или {=СУММ((C2:C10)*(ДЛСТР(A2:A10)>0)*(ДЛСТР(B2: B10)>0))} Если в столбцах A и B содержится текст ненулевой длины, тогда соответствующее число из C складывается. Внимание! Это формула массива! Фигурные скобки вводить не нужно! |
А теперь давайте посмотрим, как вы можете использовать формулу СУММЕСЛИМН с «пустыми» и «непустыми» ячейками для реальных данных.
По покупателю «Красный» рассчитаем количество товара в невыполненных заказах. Для этого в столбце B ищем соответствующее название клиента, а в F – пустую ячейку. Если оба требования совпадают, складываем количество товара из столбца D.
=СУММЕСЛИМН(D2:D21;F2:F21;»»;B2:B21;»Красный»)
или
=СУММЕСЛИМН(D2:D21;F2:F21;»=»;B2:B21;»Красный»)
Каждое из этих выражений дает верный результат – 144 единицы в заказе от 4 февраля.
Сумма нескольких условий.
А теперь давайте рассчитаем общую стоимость выполненных заказов по двум товарам.
Если мы просто добавим второй критерий в I3, и вместо I2 используем область I2:I3, то расчет будет неверным, поскольку в C2:C21 будем искать товар, в названии которого есть И «черный», И «молочный» одновременно. Ведь таких просто нет.
Поэтому первый вариант расчета таков:
=СУММЕСЛИМН(E2:E21;C2:C21;I2;F2:F21;I4)+СУММЕСЛИМН(E2:E21;C2:C21;I3;F2:F21;I4)
Просто складываем выполненные заказы сначала по первому, а затем по второму наименованию.
Второй вариант: используем элемент массива критериев и функцию СУММ.
=СУММ(СУММЕСЛИМН(E2:E21;C2:C21;{«*молочный*»;»*черный*»};F2:F21;I4))
Как видите, результаты получены одинаковые. Выбирайте способ, который будет для вас проще и понятнее.
Ещё примеры расчета суммы:
17 авг. 2022 г.
читать 2 мин
Вы можете использовать следующие формулы для объединения функции СУММЕСЛИ с функцией ИЛИ в Excel:
Метод 1: СУММЕСЛИ с ИЛИ (один столбец)
=SUM(SUMIFS( B2:B13 , A2:A13 ,{"Value1","Value2", "Value3"}))
Эта конкретная формула находит сумму значений в B2:B13 , где соответствующее значение в A2:A13 содержит «Value1», «Value2» или «Value3».
Метод 2: СУММЕСЛИ с ИЛИ (несколько столбцов)
=SUMIF( A2:A13 ,"Value1", C2:C13 )+SUMIF( B2:B13 ,"Value2", C2:C13 )
Эта конкретная формула находит сумму значений в C2:C13 , где соответствующее значение в A2:A13 содержит «Value1» или соответствующее значение в B2:B13 содержит «Value2».
В следующем примере показано, как использовать каждый метод на практике со следующим набором данных в Excel:
Пример 1: СУММЕСЛИ с ИЛИ (один столбец)
Мы можем использовать следующую формулу для суммирования значений в столбце Points , где значение в столбце Team равно «Mavs» или «Rockets»:
=SUM(SUMIFS( C2:C13 , A2:A13 ,{"Mavs","Rockets"}))
На следующем снимке экрана показано, как использовать эту формулу на практике:
Сумма значений в столбце « Очки », где значение в столбце « Команда » равно «Mavs» или «Rockets», составляет 53 .
Пример 2: СУММЕСЛИ с ИЛИ (несколько столбцов)
Мы можем использовать следующую формулу для суммирования значений в столбце Points , где значение в столбце Team равно «Mavs» или значение в столбце Position равно «Center»:
=SUMIF( A2:A13 ,"Mavs", C2:C13 )+SUMIF( B2:B13 ,"Center", C2:C13 )
На следующем снимке экрана показано, как использовать эту формулу на практике:
Сумма значений в столбце « Очки », где значение в столбце « Команда » равно «Mavs» или значение в столбце « Позиция » равно «Центру», составляет 87 .
Дополнительные ресурсы
В следующих руководствах объясняется, как выполнять другие распространенные операции СУММЕСЛИ в Excel:
Как использовать СУММЕСЛИМН с диапазоном дат в Excel
Как суммировать, если ячейки содержат текст в Excel
Сумма в Excel — одна из самых частых операций. Однако зачастую недостаточно просто просуммировать все ячейки, а нужно сделать сумму ячеек, соответствующих определенному условию или нескольким условиям. В этой статье рассмотрим, как сделать суммирование ячеек в Excel по условию и по нескольким условиям.
- Функция СУММЕСЛИ в Excel для суммирования по одному условию
- Суммирование по нескольким условиям в Excel при помощи функции СУММЕСЛИМН
- Суммирование по текстовому условию
- Суммирование по числовому условию
- Суммирование по условию даты
- Почему СУММЕСЛИ или СУММЕСЛИМН не работает
- СУММЕСЛИ или СУММЕСЛИМН в Excel — что лучше использовать?
Чтобы сделать суммирование ячеек в Excel по одному условию, можно использовать функцию СУММЕСЛИ (SUMIF в англ. версии).
Синтаксис функции:
=СУММЕСЛИ(диапазон;критерий;[диапазон_суммирования])
диапазон — область ячеек, в которых будет осуществляться поиск критерия суммирования
критерий — значение, по которому будет осуществляться поиск в диапазоне. Может быть текстом, числом, ссылкой на ячейку или шаблоном.
[диапазон_суммирования] — необязательный параметр, указывается в том случае, когда совпадение с критерием ищем в одном диапазоне,а суммируем значения из другого. Если этот параметр не указан, то будут суммироваться значения из первой области диапазон (если они могут быть просуммированы).
Рассмотрим функцию СУММЕСЛИ в Excel на примере.
У нас есть таблица с данными о сотрудниках.
Получим сумму заработной платы у всех сотрудников мужского пола.
Способ 1. С указанием критерия напрямую в формуле.
В ячейке, в которой нужно получить результат суммирования по условию, напишем формулу:
=СУММЕСЛИ(D3:D12;»муж»;G3:G12)
D3:D12 — диапазон, в котором будет происходить поиск совпадения с критерием. В нашем примере это столбец Пол.
«муж» — критерий поиска. Поскольку это текстовый критерий, он заключен в кавычки.
G3:G12 — диапазон, значения из которого будут просуммированы при наличии совпадений диапазона с критерием. В примере это столбец Заработная плата.
Способ 2. С указанием критерия ссылкой на ячейку
Этот способ наиболее распространен и универсален.
В ячейке слева от рабочей укажем критерий поиска (без кавычек!).
Формула будет выглядеть так:
=СУММЕСЛИ(D3:D12;I4;G3:G12)
где первый и третий аргументы — такие же, как в предыдущем способе.
I4 — это ссылка на ячейку, в которой содержится критерий суммирования значений.
Если формулу нужно “протянуть” (скопировать) в другие ячейки — не забывайте закреплять диапазоны и критерий абсолютными или относительными ссылками (знак $).
Суммирование по нескольким условиям в Excel при помощи функции СУММЕСЛИМН
Если критерием для суммирования больше одного, то на помощь придет функция СУММЕСЛИМН (SUMIFS в англ. версии).
Синтаксис функции:
=СУММЕСЛИМН(диапазон_суммирования; диапазон_условия 1; условие 1;…;диапазон_условия n; условие n)
У функции СУММЕСЛИМН такие же аргументы, как у СУММЕСЛИ, но немного другой их порядок — на первом месте указывает диапазон суммирования (область значений, которые должны быть просуммированы), а затем — диапазон условий и условие поиска.
Рассмотрим на примере: нужно просуммировать заработную плату всех женщин бухгалтеров.
Соответственно, условия суммирований будут:
Должность: Бухгалтер
Пол: жен
Формула суммирования по нескольким условиям в Excel будет такая:
=СУММЕСЛИМН(G3:G12;C3:C12;I4;D3:D12;J4)
где G3:G12 — диапазон суммирования
C3:C12 — первый диапазон условия, в котором будет искаться первое условие
I4 — ссылка на ячейку, содержащую первое условие поиска
D3:D12 — второй диапазон условия, в котором будет искаться второе условие
J4 — ссылка на ячейку, содержащую второе условие поиска
Как видите, Excel верно просуммировал заработную плату всех сотрудников с полом жен и должностью Бухгалтер.
Обратите внимание:
- Функцию СУММЕСЛИМН можно использовать только для одного условия поиска (не обязательно их должно быть несколько)
- для функции СУММЕСЛИМН действуют те же правила, как и для функции СУММЕСЛИ (регистр критерия поиска, абсолютные и относительные ссылки)
- условия поиска можно располагать в любом порядке. В примере мы указали сначала условие Должность, затем условие Пол — можно сделать наоборот.
Главное правило: диапазон условия и условие, которое идет следом за ним, должны соответствовать друг другу.
- условия поиска также можно указывать как в самой формуле, так и ссылкой на ячейку.
- критерии поиска в стандартном варианте должны находиться в разных столбцах. Если несколько критериев суммирования находятся в одном столбце, то нужно использовать формулу массива.
Суммирование по текстовому условию
Пример суммирования по текстовому условию мы рассмотрели в первом пункте этой статьи.
Текстовые значения суммировать сами по себе нельзя, но можно получить сумму соответствующих им чисел.
Рассмотрим простой пример использования функции СУММЕСЛИ в эксель таблице: просуммируем заработную плату всех кассиров в таблице из предыдущего примера.
Точно так же можно сделать сумму значений по условию, указав критерий прямо в формуле. Текстовый критерий обязательно нужно заключить в кавычки!
Обратите внимание:
- функции СУММЕСЛИ и СУММЕСЛИМН не чувствительны к регистру критерия. Например, сейчас критерий поиска Кассир
можно указать критерий с большой буквы или даже всеми большими буквами, например:
Как видите, формула работает и выдает тот же результат.
Но если добавить любой знак, например пробел или точку в конце — формула не будет работать, т.к. нет точного совпадения критерия со значениями диапазона для поиска.
- в качестве критерия всегда лучше использовать ссылку на ячейку, а не указывать его непосредственно в формуле. Так будет проще корректировать формулу, и меньше вероятности совершить ошибку при указании критерия. К тому же, в этом случае не нужно заключить в кавычки критерий поиска.
Поэтому в следующих примерах будем использовать только вариант со ссылкой на ячейку — лучше сразу приучить себя к такому способу.
СУММЕСЛИ или СУММЕСЛИМН по части текста
А вы знали, что можно сделать суммирование ячеек в Excel по одному или нескольким текстовым условиям, указав только часть текста? Подробно этот вариант рассмотрен в статье.
Например, получим сумму заработных плат сотрудниц по имени Елена. Критерием поиска в данном случае будет имя Елена — но ведь в нашей таблице нет столбца, в котором находится имя. Только ФИО. Однако, не нужно создавать дополнительных столбцов и разделять ФИО на компоненты.
Напишем следующую формулу:
=СУММЕСЛИ(B3:B12;»*елена*»;G3:G12)
Здесь критерием поиска будет «*елена*».
Используются два значка-оператора — кавычки и звездочка.
- звездочка * — заменяет любое количество символов. Т.е. перед и после слова елена может находиться любое количество любых символов.
- кавычки «» — обязательно ставятся для текстового аргумента поиска в функциях excel.
Вместо звездочки можно использовать знак вопроса ?. Отличие — символ * заменяем любое количество символов, а ? — только один символ.
Суммирование по числовому условию в Excel
Как правило, нужно определить сумму если больше чем, меньше чем или равно определенному числу.
Сумма чисел, если больше или меньше чем заданное число
Задача: получить сумму заработных плат, если величина заработной платы больше 50000 руб.
Формула будет такая:
=СУММЕСЛИ(G3:G12;»>50000″)
где G3:G12 — диапазон для поиска заданных значений и одновременно диапазон суммирования, поэтому третий критерий (не обязательный) в формуле не указывается.
«>50000» — критерий поиска.
Обратите внимание, что, несмотря на то, что критерий не текстовый, а числовой, используются кавычки.
Обязательно использовать кавычки, если в формуле применяются знаки больше > или меньше < ( а также >= и <=)
Если в качестве критерия используется знаки >, <, >=, <= и ссылка на ячейку, содержащую критерий (например >50000), то критерий поиска будет записан таким образом:
Знак сравнения должен быть заключен в кавычки, далее ставится амперсанд & и указывается ссылка на ячейку с критерием.
Сумма чисел, если равно заданному числу
В этом случае кавычки для критерия не используются.
Получим сумму заработных плат, равных 45000 руб.
Критерий поиска 45000 указывается без кавычек.
Также, если критерий указывается в ячейке, то формула будет как для текстового критерия:
Суммирование по условию даты
Чтобы сделать суммирование ячеек в excel по условию даты — равно определенной дате или больше или меньше определенной даты — то нужно указать эту дату в качестве критерия.
При этом дату также можно указывать непосредственно в формуле, а также ссылкой на ячейку, содержащую дату.
Для примера определим сумму заработных плат сотрудников, трудоустроенных после 1 января 2018 г.
Формула:
=СУММЕСЛИ(F3:F12;»>=»&I4;G3:G12)
Обратите внимание, как указан критерий — знак сравнения “больше или равно” заключен в кавычки и используется знак амперсанд &.
Если дату указывать напрямую в формуле, то ее нужно также заключить в кавычки:
Почему СУММЕСЛИ или СУММЕСЛИМН не работает
Формула СУММЕСЛИ иногда может выдавать ошибку #ЗНАЧ, если диапазон суммирования и диапазон условий имеют разный размер. Эта проблема решена в новых версиях Excel, но в ранних версиях она присутствует.
Также ошибка #ЗНАЧ может возникать, если формула ссылается на данные из другого файла, а этот файл в момент пересчета формулы закрыт. Необходимо просто открыть файл-источник, и ошибка исчезнет.
Если функция СУММЕСЛИ или СУММЕСЛИМН выдает значение 0 (при условии, что значение суммы никак не может быть равно 0), необходимо проверить критерий — не закрались ли в него лишние пробелы или знаки препинания.
СУММЕСЛИ или СУММЕСЛИМН в Excel — что лучше использовать?
Как вы могли заметить, эти функции похожи между собой.
В своей практике, я часто замечаю, что пользователи разграничивают действие этих функций: для суммирования по одному критерию используют строго функцию СУММЕСЛИ, по нескольким критериям — СУММЕСЛИМН.
Но обратите внимание:
Функцию СУММЕСЛИМН можно использовать для суммирования как по одному критерию, так и по нескольким критериям.
Другими словами, функция СУММЕСЛИМН универсальная. И функцию СУММЕСЛИ таким образом можно вообще не использовать, заменив ее СУММЕСЛИМН.
Почему СУММЕСЛИМН удобнее при суммировании по одному критерию?
Потому что условия задачи всегда могут измениться. Сейчас вы суммируете по одному критерию (например, по должности), а в следующий момент понадобилось добавить еще одно условие (пол). В случае с функцией СУММЕСЛИМН вы просто внесете дополнительное условие в ту же формулу, а функция СУММЕСЛИ здесь вовсе не подойдет (придется все равно переписывать на СУММЕСЛИМН).
Поэтому совет практика: использовать только функцию СУММЕСЛИМН.
Однако, окончательное решение в выборе функции всегда остается за вами.
В этой статье мы узнали, как сделать суммирование ячеек в excel по условию и познакомились с возможностью сделать суммирование по нескольким условиям.
Сообщество Excel Analytics | обучение Excel
Канал на Яндекс.Дзен
Вам может быть интересно: