Excel copy selection vba excel

In this tutorial, you will learn several different methods to Copy & Paste and Cut & Paste using a VBA macro. Read the companion tutorial on Value Pasting and PasteSpecial for more advanced copying and pasting options.

To use this code: Open the Visual Basic Editor (Alt + F11), Insert a new module (Insert > Module) and copy & paste the desired code into the module.

Copy (Cut) and Paste a Single Cell

This example copies or cuts and pastes a single cell, A1 over to B1:

Sub Paste_OneCell()

    'Copy and Paste Single Cell
    Range("A1").Copy Range("B1")

    'Cut and Paste Single Cell
    Range("A1").Cut Range("B1")

End Sub

Copy Selection

If you want to copy the active selection use this:

Sub CopySelection()

'Paste to a Defined Range
Selection.copy range("b1")

'Offset Paste (offsets 2 cells down and 1 to the right
Selection.copy
Selection.offset(2,1).Select
ActiveSheet.Paste

Application.CutCopyMode = False

End Sub

Copy (Cut) and Paste a Range of Cells

This example copies or cuts and pastes a range of cells, A1:A3 over to B1:B3 :

Sub Paste_Range()

    'Copy and Paste a Range of Cells
    Range("A1:A3").Copy Range("B1:B3")

    'Cut and Paste a Range of Cells
    Range("A1:A3").Cut Range("B1:B3")

End Sub

Copy (Cut) and Paste an Entire Column

Below we will demonstrate a couple of quick examples. Read our article on Copying and Pasting Rows and Columns for detailed examples, explanations, and variations.

This example copies or cuts and pastes an entire column, A over to B:

Sub PasteOneColumn()

    'Copy and Paste Column
    Range("A:A").Copy Range("B:B")


    'Cut and Paste Column
    Range("A:A").Cut Range("B:B")

End Sub

Copy (Cut) and Paste an Entire Row

This example copies or cuts and pastes an entire row, 1 over to 2:

Sub Paste_OneRow()

    'Copy and Paste Row
    Range("1:1").Copy Range("2:2")


    'Cut and Paste Row
    Range("1:1").Cut Range("2:2")

End Sub

Copy (Cut) and Paste to Another Worksheet or Workbook

Sub Paste_Other_Sheet_or_Book()

    'Cut or Copy and Paste to another worksheet
    Worksheets("sheet1").Range("A1").Copy Worksheets("sheet2").Range("B1") 'Copy
    Worksheets("sheet1").Range("A1").Cut Worksheets("sheet2").Range("B1") 'Cut

    'Cut or Copy and Paste to another workbook
    Workbooks("book1.xlsm").Worksheets("sheet1").Range("A1").Copy _ 
    Workbooks("book2.xlsm").Worksheets("sheet1").Range("B1") 'Copy
    Workbooks("book1.xlsm").Worksheets("sheet1").Range("A1").Cut _ 
    Workbooks("book2.xlsm").Worksheets("sheet1").Range("B1") 'Cut

    Application.CutCopyMode = False
End Sub

Value Paste

Normally, when you Copy and Paste you Paste all the properties of a cell: formatting, formulas, etc.. Value Pasting allows you to Copy and Paste cells’ values and nothing else. The easiest way to Value Paste in VBA is to define the cell’s value directly:

Sub ValuePaste()

    'Value Paste Cells
    Range("B1").value = Range("A1").value
    Range("B1:B3").value = Range("A1:A3").value

    'Set Values Between Worksheets
    Worksheets("sheet2").range("A1").value = Worksheets("sheet1").range("A1").value

    'Set Values Between Workbooks
    Workbooks("book2.xlsm").Worksheets("sheet1").range("A1").value = _
    Workbooks("book1.xlsm").Worksheets("sheet1").range("A1").value

    Application.CutCopyMode = False
End Sub

Paste Special

Paste Special allows you to Copy and Paste specific properties of cells (examples: formats, values, column widths, etc.). It also allows you to perform special paste operations (examples: skip blanks, transpose). We will look at several examples below, but for an in-depth read our tutorial on Value Pasting and Paste Special.

Sub PasteSpecial()

    'Perform one Paste Special Operation:
    Range("A1").Copy
    'Paste Formats
    Range("B1").PasteSpecial Paste:=xlPasteFormats
    'Paste Column Widths
    Range("B1").PasteSpecial Paste:=xlPasteColumnWidths
    'Paste Formulas
    Range("B1").PasteSpecial Paste:=xlPasteFormulas

    'Perform Multiple Paste Special Operations at Once:
    Range("A1").Copy
    'Paste Formats and Transpose
    Range("B1").PasteSpecial Paste:=xlPasteFormats, Operation:=xlNone, SkipBlanks:= _
        False, Transpose:=True

    Application.CutCopyMode = False
End Sub

Clear Clipboard

After Copying & Pasting you might want to clear the clipboard (we do in some of the code examples above).  To clear the Excel clipboard, we set Application.CutCopyMode to False:

Application.CutCopyMode = False

This will clear Excel’s clipboard. However, it will not clear the Windows Clipboard. To clear the Window’s clipboard follow the instructions here.

When we write the VBA coding to save ourselves from the repetitive work, selection of data plays a very important role. So, in this article you will learn how to select the data by row, column and whole documents data through VBA coding in Microsoft Excel.

You’ll learn:

• How to select entire column?
• How to select entire row?
• How to select entire data?

How to select entire column through VBA?

We have data in the range A1:C19, in which column A contains Name, column B Gender and column C contains Age.

To select the Entire column A in this data, follow below given steps and code:-

• Open VBA Page press the key Alt+F11
• Insert a module
• Write the below mentioned code:

Sub Columnselect()

Range("A1").Entirecolumn.Select

End Sub

• Press the key F5 to run the Macro in Excel
• Column A will get selected

If you want data should be selected till the last active cell to the column, follow below mentioned steps and code:-

• Write the below mentioned code:-

Sub Columnselect()

lastrow = Worksheets("Sheet1").Cells(Rows.count, 1).End(xlUp).Row

Worksheets("Sheet1").Range("A1:A" & lastrow).Select

End Sub

 
Code Explanation:- First we will define that what will be last active cell in data, and then last row we will use to define the range in coding.

• Press the key F5 to run the Macro in Excel
• Column A1:A19 will get selected

In this way by using VBA, you can select the code to select the column till last active cell. When we don’t know what the last active cell is, we can use this code while writing the VBA code for the selection in Microsoft Excel.

How to select entire row through VBA?

• Open VBA Page press the key Alt+F11
• Insert a module
• Write the below mentioned code:-

Sub rowselect()

Range("A2").EntireRow.Select

End Sub

• Press the key F5 to run the Macro in Excel
• Column A will get selected

• Write the below mentioned code:-

Sub rowselect()

Dim lastcolumn As Long

lastcolumn = Worksheets("Sheet1").Cells(1, Columns.count).End(xlToLeft).Column

Worksheets("Sheet1").Range("A1", Cells(1, lastcolumn)).Select

End Sub

Code Explanation: In this code we had defined the last column first, then we will use that to define the range.

• Press F5 to run the Macro in Excel
• First row will get selected till the last active cell to the row

In this way we can select the entire row or select the row till the last active cell in Microsoft Excel through VBA.

How to select entire data through VBA?

Let’s take an example and understand:-

We have data in the range A1:C19, in which column A contains Name, column B Gender and column C contains Age.

• Open VBA Page press the key Alt+F11
• Insert a module
• Write the below mentioned code:

Sub Selectionoflastcell()

Dim lastrow As Long, lastcolumn As Long

lastrow = Worksheets("Sheet1").Cells(Rows.count, 1).End(xlUp).Row

lastcolumn = Worksheets("Sheet1").Cells(1, Columns.count).End(xlToLeft).Column

Worksheets("Sheet1").Range("A1", Cells(lastrow, lastcolumn)).Select

End Sub

Code Explanation: First we have defined the Subject name of Code, then we have defined all the variables. Then we have defined what would be our last row and last column.

• Press the key F5 to run the Macro in Excel
• In the worksheet all data will get selected

Now, if you want to copy same data and paste it use below mentioned code:-
 

Sub Selectionoflastcell()

Dim lastrow As Long, lastcolumn As Long

lastrow = Worksheets("Sheet1").Cells(Rows.count, 1).End(xlUp).Row

lastcolumn = Worksheets("Sheet1").Cells(1, Columns.count).End(xlToLeft).Column

Worksheets("Sheet1").Range("A1", Cells(lastrow, lastcolumn)).Copy Sheets("Sheet2").Range("A1")

End Sub

Run the code all data will get copied and pasted in sheet2.

This is the way we can write the macro for select the data from first cell to last active cell and then paste in other sheet in Microsoft Excel.

If you liked our blogs, share it with your friends on Facebook. And also you can follow us on Twitter and Facebook.

We would love to hear from you, do let us know how we can improve, complement or innovate our work and make it better for you. Write us at info@exceltip.com.

Bottom line: Learn 3 different ways to copy and paste cells or ranges in Excel with VBA Macros.  This is a 3-part video series and you can also download the file that contains the code.

Skill level: Beginner

Copy & Paste: The Most Common Excel Action

Copy and paste is probably one of the most common actions you take in Excel.  It’s also one of the most common tasks we automate when writing macros.

There are a few different ways to accomplish this task, and the macro recorder doesn’t always give you the most efficient VBA code.

In the following three videos I explain:

• The most efficient method for a simple copy and paste in VBA.
• The easiest way to paste values.
• How to use the PasteSpecial method for other paste types.

You can download the file I use in these videos below.  The code is also available at the bottom of the page.

Video #1: The Simple Copy Paste Method

You can watch the playlist that includes all 3 videos at the top of this page.

Video #2: An Easy Way to Paste Values

Video #3: The PasteSpecial Method Explained

VBA Code for the Copy & Paste Methods

Download the workbook that contains the code.

'3 Methods to Copy & Paste with VBA
'Source: https://www.excelcampus.com/vba/copy-paste-cells-vba-macros/
'Author: Jon Acampora

Sub Range_Copy_Examples()
'Use the Range.Copy method for a simple copy/paste

    'The Range.Copy Method - Copy & Paste with 1 line
    Range("A1").Copy Range("C1")
    Range("A1:A3").Copy Range("D1:D3")
    Range("A1:A3").Copy Range("D1")
    
    'Range.Copy to other worksheets
    Worksheets("Sheet1").Range("A1").Copy Worksheets("Sheet2").Range("A1")
    
    'Range.Copy to other workbooks
    Workbooks("Book1.xlsx").Worksheets("Sheet1").Range("A1").Copy _
        Workbooks("Book2.xlsx").Worksheets("Sheet1").Range("A1")

End Sub


Sub Paste_Values_Examples()
'Set the cells' values equal to another to paste values

    'Set a cell's value equal to another cell's value
    Range("C1").Value = Range("A1").Value
    Range("D1:D3").Value = Range("A1:A3").Value
     
    'Set values between worksheets
    Worksheets("Sheet2").Range("A1").Value = Worksheets("Sheet1").Range("A1").Value
     
    'Set values between workbooks
    Workbooks("Book2.xlsx").Worksheets("Sheet1").Range("A1").Value = _
        Workbooks("Book1.xlsx").Worksheets("Sheet1").Range("A1").Value
        
End Sub


Sub PasteSpecial_Examples()
'Use the Range.PasteSpecial method for other paste types

    'Copy and PasteSpecial a Range
    Range("A1").Copy
    Range("A3").PasteSpecial Paste:=xlPasteFormats
    
    'Copy and PasteSpecial a between worksheets
    Worksheets("Sheet1").Range("A2").Copy 
    Worksheets("Sheet2").Range("A2").PasteSpecial Paste:=xlPasteFormulas
    
    'Copy and PasteSpecial between workbooks
    Workbooks("Book1.xlsx").Worksheets("Sheet1").Range("A1").Copy
    Workbooks("Book2.xlsx").Worksheets("Sheet1").Range("A1").PasteSpecial Paste:=xlPasteFormats
    
    'Disable marching ants around copied range
    Application.CutCopyMode = False

End Sub

Paste Data Below the Last Used Row

One of the most common questions I get about copying and pasting with VBA is, how do I paste to the bottom of a range that is constantly changing?  I first want to find the last row of data, then copy & paste below it.

To answer this question, I created a free training video on how to paste data below the last used row in a sheet with VBA.  Can I send you the video?  Please click the image below to get the video.

Free Training on Macros & VBA

The 3 videos above are from my VBA Pro Course.  If you want to learn more about macros and VBA then checkout my free 3-part video training series.

I will also send you info on the VBA Pro Course, that will take you from beginner to expert.  Click the link below to get instant access.

Free Training on Macros & VBA

Please leave a comment below with any questions.  Thanks!

When working with Excel, most of your time is spent in the worksheet area – dealing with cells and ranges.

And if you want to automate your work in Excel using VBA, you need to know how to work with cells and ranges using VBA.

There are a lot of different things you can do with ranges in VBA (such as select, copy, move, edit, etc.).

So to cover this topic, I will break this tutorial into sections and show you how to work with cells and ranges in Excel VBA using examples.

Let’s get started.

All the codes I mention in this tutorial need to be placed in the VB Editor. Go to the ‘Where to Put the VBA Code‘ section to know how it works.

If you’re interested in learning VBA the easy way, check out my Online Excel VBA Training.

Selecting a Cell / Range in Excel using VBA

To work with cells and ranges in Excel using VBA, you don’t need to select it.

In most of the cases, you are better off not selecting cells or ranges (as we will see).

Despite that, it’s important you go through this section and understand how it works. This will be crucial in your VBA learning and a lot of concepts covered here will be used throughout this tutorial.

So let’s start with a very simple example.

Selecting a Single Cell Using VBA

If you want to select a single cell in the active sheet (say A1), then you can use the below code:

Sub SelectCell()
Range("A1").Select
End Sub

The above code has the mandatory ‘Sub’ and ‘End Sub’ part, and a line of code that selects cell A1.

Range(“A1”) tells VBA the address of the cell that we want to refer to.

Select is a method of the Range object and selects the cells/range specified in the Range object. The cell references need to be enclosed in double quotes.

This code would show an error in case a chart sheet is an active sheet. A chart sheet contains charts and is not widely used. Since it doesn’t have cells/ranges in it, the above code can’t select it and would end up showing an error.

Note that since you want to select the cell in the active sheet, you just need to specify the cell address.

But if you want to select the cell in another sheet (let’s say Sheet2), you need to first activate Sheet2 and then select the cell in it.

Sub SelectCell()
Worksheets("Sheet2").Activate
Range("A1").Select
End Sub

Similarly, you can also activate a workbook, then activate a specific worksheet in it, and then select a cell.

Sub SelectCell()
Workbooks("Book2.xlsx").Worksheets("Sheet2").Activate
Range("A1").Select
End Sub

Note that when you refer to workbooks, you need to use the full name along with the file extension (.xlsx in the above code). In case the workbook has never been saved, you don’t need to use the file extension.

Now, these examples are not very useful, but you will see later in this tutorial how we can use the same concepts to copy and paste cells in Excel (using VBA).

Just as we select a cell, we can also select a range.

In case of a range, it could be a fixed size range or a variable size range.

In a fixed size range, you would know how big the range is and you can use the exact size in your VBA code. But with a variable-sized range, you have no idea how big the range is and you need to use a little bit of VBA magic.

Let’s see how to do this.

Selecting a Fix Sized Range

Here is the code that will select the range A1:D20.

Sub SelectRange()
Range("A1:D20").Select
End Sub

Another way of doing this is using the below code:

Sub SelectRange()
Range("A1", "D20").Select
End Sub

The above code takes the top-left cell address (A1) and the bottom-right cell address (D20) and selects the entire range. This technique becomes useful when you’re working with variably sized ranges (as we will see when the End property is covered later in this tutorial).

If you want the selection to happen in a different workbook or a different worksheet, then you need to tell VBA the exact names of these objects.

For example, the below code would select the range A1:D20 in Sheet2 worksheet in the Book2 workbook.

Sub SelectRange()
Workbooks("Book2.xlsx").Worksheets("Sheet1").Activate
Range("A1:D20").Select
End Sub

Now, what if you don’t know how many rows are there. What if you want to select all the cells that have a value in it.

In these cases, you need to use the methods shown in the next section (on selecting variably sized range).

Selecting a Variably Sized Range

There are different ways you can select a range of cells. The method you choose would depend on how the data is structured.

In this section, I will cover some useful techniques that are really useful when you work with ranges in VBA.  

Select Using CurrentRange Property

In cases where you don’t know how many rows/columns have the data, you can use the CurrentRange property of the Range object.

The CurrentRange property covers all the contiguous filled cells in a data range.

Below is the code that will select the current region that holds cell A1.

Sub SelectCurrentRegion()
Range("A1").CurrentRegion.Select
End Sub

The above method is good when you have all data as a table without any blank rows/columns in it.

But in case you have blank rows/columns in your data, it will not select the ones after the blank rows/columns. In the image below, the CurrentRegion code selects data till row 10 as row 11 is blank.

In such cases, you may want to use the UsedRange property of the Worksheet Object.

Select Using UsedRange Property

UsedRange allows you to refer to any cells that have been changed.

So the below code would select all the used cells in the active sheet.

Sub SelectUsedRegion()
ActiveSheet.UsedRange.Select
End Sub

Note that in case you have a far-off cell that has been used, it would be considered by the above code and all the cells till that used cell would be selected.

Select Using the End Property

Now, this part is really useful.

The End property allows you to select the last filled cell. This allows you to mimic the effect of Control Down/Up arrow key or Control Right/Left keys.

Let’s try and understand this using an example.

Suppose you have a dataset as shown below and you want to quickly select the last filled cells in column A.

The problem here is that data can change and you don’t know how many cells are filled. If you have to do this using keyboard, you can select cell A1, and then use Control + Down arrow key, and it will select the last filled cell in the column.

Now let’s see how to do this using VBA. This technique comes in handy when you want to quickly jump to the last filled cell in a variably-sized column

Sub GoToLastFilledCell()
Range("A1").End(xlDown).Select
End Sub

The above code would jump to the last filled cell in column A.

Similarly, you can use the End(xlToRight) to jump to the last filled cell in a row.

Sub GoToLastFilledCell()
Range("A1").End(xlToRight).Select
End Sub

Now, what if you want to select the entire column instead of jumping to the last filled cell.

You can do that using the code below:

Sub SelectFilledCells()
Range("A1", Range("A1").End(xlDown)).Select
End Sub

In the above code, we have used the first and the last reference of the cell that we need to select. No matter how many filled cells are there, the above code will select all.

Remember the example above where we selected the range A1:D20 by using the following line of code:

Range(“A1″,”D20”)

Here A1 was the top-left cell and D20 was the bottom-right cell in the range. We can use the same logic in selecting variably sized ranges. But since we don’t know the exact address of the bottom-right cell, we used the End property to get it.

In Range(“A1”, Range(“A1”).End(xlDown)), “A1” refers to the first cell and Range(“A1”).End(xlDown) refers to the last cell. Since we have provided both the references, the Select method selects all the cells between these two references.

Similarly, you can also select an entire data set that has multiple rows and columns.

The below code would select all the filled rows/columns starting from cell A1.

Sub SelectFilledCells()
Range("A1", Range("A1").End(xlDown).End(xlToRight)).Select
End Sub

In the above code, we have used Range(“A1”).End(xlDown).End(xlToRight) to get the reference of the bottom-right filled cell of the dataset.

Difference between Using CurrentRegion and End

If you’re wondering why use the End property to select the filled range when we have the CurrentRegion property, let me tell you the difference.

With End property, you can specify the start cell. For example, if you have your data in A1:D20, but the first row are headers, you can use the End property to select the data without the headers (using the code below).

Sub SelectFilledCells()
Range("A2", Range("A2").End(xlDown).End(xlToRight)).Select
End Sub

But the CurrentRegion would automatically select the entire dataset, including the headers.

So far in this tutorial, we have seen how to refer to a range of cells using different ways.

Now let’s see some ways where we can actually use these techniques to get some work done.

Copy Cells / Ranges Using VBA

As I mentioned at the beginning of this tutorial, selecting a cell is not necessary to perform actions on it. You will see in this section how to copy cells and ranges without even selecting these.

Let’s start with a simple example.

Copying Single Cell

If you want to copy cell A1 and paste it into cell D1, the below code would do it.

Sub CopyCell()
Range("A1").Copy Range("D1")
End Sub

Note that the copy method of the range object copies the cell (just like Control +C) and pastes it in the specified destination.

In the above example code, the destination is specified in the same line where you use the Copy method. If you want to make your code even more readable, you can use the below code:

Sub CopyCell()
Range("A1").Copy Destination:=Range("D1")
End Sub

The above codes will copy and paste the value as well as formatting/formulas in it.

As you might have already noticed, the above code copies the cell without selecting it. No matter where you’re on the worksheet, the code will copy cell A1 and paste it on D1.

Also, note that the above code would overwrite any existing code in cell D2. If you want Excel to let you know if there is already something in cell D1 without overwriting it, you can use the code below.

Sub CopyCell()
If Range("D1") <> "" Then
Response = MsgBox("Do you want to overwrite the existing data", vbYesNo)
End If
If Response = vbYes Then
Range("A1").Copy Range("D1")
End If
End Sub

Copying a Fix Sized Range

If you want to copy A1:D20 in J1:M20, you can use the below code:

Sub CopyRange()
Range("A1:D20").Copy Range("J1")
End Sub

In the destination cell, you just need to specify the address of the top-left cell. The code would automatically copy the exact copied range into the destination.

You can use the same construct to copy data from one sheet to the other.

The below code would copy A1:D20 from the active sheet to Sheet2.

Sub CopyRange()
Range("A1:D20").Copy Worksheets("Sheet2").Range("A1")
End Sub

The above copies the data from the active sheet. So make sure the sheet that has the data is the active sheet before running the code. To be safe, you can also specify the worksheet’s name while copying the data.

Sub CopyRange()
Worksheets("Sheet1").Range("A1:D20").Copy Worksheets("Sheet2").Range("A1")
End Sub

The good thing about the above code is that no matter which sheet is active, it will always copy the data from Sheet1 and paste it in Sheet2.

You can also copy a named range by using its name instead of the reference.

For example, if you have a named range called ‘SalesData’, you can use the below code to copy this data to Sheet2.

Sub CopyRange()
Range("SalesData").Copy Worksheets("Sheet2").Range("A1")
End Sub

If the scope of the named range is the entire workbook, you don’t need to be on the sheet that has the named range to run this code. Since the named range is scoped for the workbook, you can access it from any sheet using this code.

If you have a table with the name Table1, you can use the below code to copy it to Sheet2.

Sub CopyTable()
Range("Table1[#All]").Copy Worksheets("Sheet2").Range("A1")
End Sub

You can also copy a range to another Workbook.

In the following example, I copy the Excel table (Table1), into the Book2 workbook.

Sub CopyCurrentRegion()
Range("Table1[#All]").Copy Workbooks("Book2.xlsx").Worksheets("Sheet1").Range("A1")
End Sub

This code would work only if the Workbook is already open.

Copying a Variable Sized Range

One way to copy variable sized ranges is to convert these into named ranges or Excel Table and the use the codes as shown in the previous section.

But if you can’t do that, you can use the CurrentRegion or the End property of the range object.

The below code would copy the current region in the active sheet and paste it in Sheet2.

Sub CopyCurrentRegion()
Range("A1").CurrentRegion.Copy Worksheets("Sheet2").Range("A1")
End Sub

If you want to copy the first column of your data set till the last filled cell and paste it in Sheet2, you can use the below code:

Sub CopyCurrentRegion()
Range("A1", Range("A1").End(xlDown)).Copy Worksheets("Sheet2").Range("A1")
End Sub

If you want to copy the rows as well as columns, you can use the below code:

Sub CopyCurrentRegion()
Range("A1", Range("A1").End(xlDown).End(xlToRight)).Copy Worksheets("Sheet2").Range("A1")
End Sub

Note that all these codes don’t select the cells while getting executed. In general, you will find only a handful of cases where you actually need to select a cell/range before working on it.

Assigning Ranges to Object Variables

So far, we have been using the full address of the cells (such as Workbooks(“Book2.xlsx”).Worksheets(“Sheet1”).Range(“A1”)).

To make your code more manageable, you can assign these ranges to object variables and then use those variables.

For example, in the below code, I have assigned the source and destination range to object variables and then used these variables to copy data from one range to the other.

Sub CopyRange()
Dim SourceRange As Range
Dim DestinationRange As Range
Set SourceRange = Worksheets("Sheet1").Range("A1:D20")
Set DestinationRange = Worksheets("Sheet2").Range("A1")
SourceRange.Copy DestinationRange
End Sub

We start by declaring the variables as Range objects. Then we assign the range to these variables using the Set statement. Once the range has been assigned to the variable, you can simply use the variable.

Enter Data in the Next Empty Cell (Using Input Box)

You can use the Input boxes to allow the user to enter the data.

For example, suppose you have the data set below and you want to enter the sales record, you can use the input box in VBA. Using a code, we can make sure that it fills the data in the next blank row.

Sub EnterData()
Dim RefRange As Range
Set RefRange = Range("A1").End(xlDown).Offset(1, 0)
Set ProductCategory = RefRange.Offset(0, 1)
Set Quantity = RefRange.Offset(0, 2)
Set Amount = RefRange.Offset(0, 3)
RefRange.Value = RefRange.Offset(-1, 0).Value + 1
ProductCategory.Value = InputBox("Product Category")
Quantity.Value = InputBox("Quantity")
Amount.Value = InputBox("Amount")
End Sub

The above code uses the VBA Input box to get the inputs from the user, and then enters the inputs into the specified cells.

Note that we didn’t use exact cell references. Instead, we have used the End and Offset property to find the last empty cell and fill the data in it.

This code is far from usable. For example, if you enter a text string when the input box asks for quantity or amount, you will notice that Excel allows it. You can use an If condition to check whether the value is numeric or not and then allow it accordingly.

Looping Through Cells / Ranges

So far we can have seen how to select, copy, and enter the data in cells and ranges.

In this section, we will see how to loop through a set of cells/rows/columns in a range. This could be useful when you want to analyze each cell and perform some action based on it.

For example, if you want to highlight every third row in the selection, then you need to loop through and check for the row number. Similarly, if you want to highlight all the negative cells by changing the font color to red, you need to loop through and analyze each cell’s value.

Here is the code that will loop through the rows in the selected cells and highlight alternate rows.

Sub HighlightAlternateRows()
Dim Myrange As Range
Dim Myrow As Range
Set Myrange = Selection
For Each Myrow In Myrange.Rows
If Myrow.Row Mod 2 = 0 Then
Myrow.Interior.Color = vbCyan
End If
Next Myrow
End Sub

The above code uses the MOD function to check the row number in the selection. If the row number is even, it gets highlighted in cyan color.

Here is another example where the code goes through each cell and highlights the cells that have a negative value in it.

Sub HighlightAlternateRows()
Dim Myrange As Range
Dim Mycell As Range
Set Myrange = Selection
For Each Mycell In Myrange
If Mycell < 0 Then
Mycell.Interior.Color = vbRed
End If
Next Mycell
End Sub

Note that you can do the same thing using Conditional Formatting (which is dynamic and a better way to do this). This example is only for the purpose of showing you how looping works with cells and ranges in VBA.

Where to Put the VBA Code

Wondering where the VBA code goes in your Excel workbook?

Excel has a VBA backend called the VBA editor. You need to copy and paste the code in the VB Editor module code window.

Here are the steps to do this:

1. Go to the Developer tab.
2. Click on the Visual Basic option. This will open the VB editor in the backend.
3. In the Project Explorer pane in the VB Editor, right-click on any object for the workbook in which you want to insert the code. If you don’t see the Project Explorer, go to the View tab and click on Project Explorer.
4. Go to Insert and click on Module. This will insert a module object for your workbook.
5. Copy and paste the code in the module window.

You May Also Like the Following Excel Tutorials:

• Working with Worksheets using VBA.
• Working with Workbooks using VBA.
• Creating User-Defined Functions in Excel.
• For Next Loop in Excel VBA – A Beginner’s Guide with Examples.
• How to Use Excel VBA InStr Function (with practical EXAMPLES).
• Excel VBA Msgbox.
• How to Record a Macro in Excel.
• How to Run a Macro in Excel.
• How to Create an Add-in in Excel.
• Excel Personal Macro Workbook | Save & Use Macros in All Workbooks.
• Excel VBA Events – An Easy (and Complete) Guide.
• Excel VBA Error Handling.
• How to Sort Data in Excel using VBA (A Step-by-Step Guide).
• 24 Useful Excel Macro Examples for VBA Beginners (Ready-to-use).

This article covers everything you need to know about Excel VBA Copy methods.

By “Excel VBA Copy Methods”, I mean the different methods you can use to copy data from one range or worksheet to another.

In this article, I’m going to show you the fastest and most efficient way to copy and filter data no matter what your task is.

I say “Copy and Filter” because in most cases you will want to filter the data before you copy it. If you just want to copy data from one place to another then I cover that too.

The article is broken down as follows:

1. 1. Which Excel VBA Copy and Filter method is the fastest(section 6) – What the professionals know and how you can use it to your advantage.
   2. How to pick the best Excel VBA copy method for each task(section 7) – miss this and you’re wasting countless hours of your time.
   3. How to ensure your application runs at its optimal speed(section – It’s not hard to do once you know the secret.
   4. The Copy and Filter methods explained with full code examples(sections 9 and 10) – Learn these methods and watch your macros run like magic.

Useful Links

The following are some related articles with more information about certain topics:

Ranges and Cells
Arrays
Dictionary
For Loop
For Each Loop
The Workbook object
The Worksheet object

Glossary

Range.Value2 – returns the underlying value in the call. Value is similar but slower and may not return the correct value if there is currency or data formatting. See this article for more information.

ADO – stands for ActiveX Database Objects. It is a library that allows us to run queries on databases. We can also use it with Excel spreadsheets.

The Webinar

Members of the Webinar Archives can access the webinar for this article by clicking on the image below.

(Note: Website members have access to the full webinar archive.)

Download the Source Code and Data

In this article I will be using the following dataset:

Unless specified, most examples will use the 2 worksheets:

1. 1. 1. • Transactions – contains the above data.
         • Report – the data will be copied to this worksheet.

How to use this article

In the next section you can see how the different VBA Copy Methods compare in terms of speed. This is vital when you are determining which one to use.

You can use section 4 to help you determine which method you should use based on your requirements.

Section 5 shows you the basic ground work you should have in your application.

The rest of the article provides a description and code example of each method.

Which Excel VBA Copy Method is the Fastest?

In this section you will see how the different methods compare in terms of speed.

Using the fastest method is vital when dealing with large amounts of data. As you can see from the results, some of the methods are incredibly slow.

I have run speed tests on the different methods to see which methods are the fastest for different types of tasks.

I ran the tests on 20000 , 100000 and 200000 records. You can see the average results for each method in milliseconds in the tables below:

Copying Data By Rows

In this test, I filtered by rows that contain a given first name in the first column. About 1% of the records will match the criteria and will be copied. So for 20000 records, there will be 200 records copied.

You can see that using Autofilter and Advanced filter are the fastest methods for copying and filtering rows.

At the other end you can see that a For Loop with Range.Copy takes almost 215 times longer than using AutoFilter. I didn’t even run the 200,000 test for this as I expected it would take 15 minutes plus!

Copying Data By Individual Cells

In this tests we want to copy some of the cells but not the entire row. In most cases we need to copy the cells individually so this makes it more complicated than copying an entire row. This may seem counter intuitive at first that copying serveral cells requires more work than the copying the entire row.

Using the Advanced Filter is the clear winner here. Autofilter doesn’t have it’s own copy method so after filtering we have to copy the data using some other method.

Advanced Filter automatically copies the data and we can specify the columns we want to be copied. Advanced filter then takes care of the rest.

I have created two different methods of copying using AutoFilter for individual rows. The methods may be faster or slower depending on the number of columns:

1. 1. 1. • The Copy Columns method would be slower with more columns to copy.
         • The Delete Columns method would be slower with more columns to delete.

Copying Data and Summing Totals

In these tests we are summing data for a particular item. Summing means to get the total amount of a given column for a particular item. For example, getting the total volume for “Laptop Model A”.

There are 3 VBA copy methods that we can use to do this. These are:

1. 1. 1. 1. Pivot Tables
         2. For Loop with a Dictionary
         3. ADO(ActiveX Database Objects)

Using a Pivot Table is the fastest method for summing data. There is not much difference between the other two methods.

The downside of the Pivot Table is that the code may be slightly complex for a new user. ADO is very flexible but it does require knowledge of SQL(Structured Query Language).

Copying and Transposing Data

Both methods here are pretty fast. If you are doing a large volume of transpose copies then Application.Transpose tends to be quicker than PasteSpecial Transpose.

Which Excel VBA Copy Method Should I Use?

With so many different methods, you may be feeling overwhelmed. Don’t worry, in this section I will provide a complete guide to selecting the correct Excel VBA copy method to use.

Note that you can download the source code for this post from the start or end of this post. This is an invaluable with of practicing the method shown here.

Straight Copy with no Filter

To copy without any filter use the copy by assignment method like this:

shWrite.Range("F1:G4").Value2 = shRead.Range("A1:B4").Value2

Filter columns(AND Logic) and Copy Rows

Advanced Filter is the fastest and easiest method to use if you want to filter by column values using AND logic:

e.g Item is “Laptop Model A” And Volume is greater than 20

Filter columns(OR Logic) and Copy Rows

Advanced Filter is the fastest method to do an OR filter. It’s not possible to do this with AutoFilter.

e.g Item is “Laptop Model A” Or Volume > 20″

Filter and Copy Individual Columns

Sometimes you will not want to copy the entire row. Instead you may want to copy individual columns. Advanced Filter is fastest VBA Copy method for doing this.

e.g. return the columns Item, Volume and Sales where Item is “Laptop Model A” And Volume > 20″

Sum totals for individual items

If you want to get the total amount for each item then using a Pivot Table is faster than the other two methods. ADO(ActiveX Database Objects) is slightly faster than using the For Loop with the Dictionary.

Using a Pivot Table is very flexible. Once you create the table it pretty easy to display the data in many different ways. The downside is that the code may be a bit complex for a VBA beginner.

ADO is much more flexible but requires some knowledge of SQL(a database query language). It also requires using an external library which may be a bit advanced for a VBA beginner.

Using the For Loop and a Dictionary requires more code and is less flexible. But it is still pretty fast for up to 200,000 records and doesn’t require any SQL or external libraries.

Transpose

Transposing means to copy data so that the rows become columns and the columns become rows

There are two methods of transposing data:

1. Range.Copy and Transpose using PasteSpecial.
2. Assignment and Transpose using Application.Transpose.

There is not much difference between these in terms of speed. However, if your application is doing multiple transpose operations then Range.Copy tends to be much slower.

Before You Start Copying and Filtering

No matter which Excel VBA Copy method we use there are some tasks we must perform first.

These include getting the range of data, turning off certain Excel functionality etc.

We will look at these tasks in this section.

The first thing we will look at is the mistake that most VBA beginners make – using Select.

Never Use Select

When copying data in Excel VBA, don’t use Select – ever!

A big mistake that new VBA users make is thinking that they need to select the cell or range before they copy it.

For example

shRead.Activate
shRead.Range("A1").Select
shWrite.Activate
Selection.Copy ActiveSheet.Range("H1")

Keep these two important things in mind before you use VBA to copy data:

1. You don’t need to select the cell or range of cells.
2. You don’t need to select or activate the worksheet.

You will see Select used in many places online. But you don’t need to use it for copying cells – ever!

Speed Up Your Code

If you want your code to run fast then it is important to turn off certain VBA functionality at the start of our code. We then turn it back on, at the end of our code.

We can use the following subs to do this:

' Procedure : TurnOffFunctionality
' Source    : www.ExcelMacroMastery.com
' Author    : Paul Kelly
' Purpose   : Turn off automatic calculations, events and screen updating
' https://excelmacromastery.com/
Public Sub TurnOffFunctionality()
    Application.Calculation = xlCalculationManual
    Application.DisplayStatusBar = False
    Application.EnableEvents = False
    Application.ScreenUpdating = False
End Sub

' Procedure : TurnOnFunctionality
' Source    : www.ExcelMacroMastery.com
' Author    : Paul Kelly
' Purpose   : turn on automatic calculations, events and screen updating
' https://excelmacromastery.com/
Public Sub TurnOnFunctionality()
    Application.Calculation = xlCalculationAutomatic
    Application.DisplayStatusBar = True
    Application.EnableEvents = True
    Application.ScreenUpdating = True
End Sub

We can use them like this

Sub Main()

    ' Turn off at the start
    TurnOffFunctionality
    
    ' Your code here
    
    ' Turn back on at the end
    TurnOnFunctionality

End Sub

Sometimes when you run your code, it won’t reach the TurnOnFunctionality code.

This could because of an error or because you stop the code at a certain point and don’t restart.

If this happens you can turn everything on again by clicking in the TurnOnFunctionality sub and pressing F5.

Get the correct worksheet

When copying data, we need to specify the range which we will copy from. When using VBA we need to select the worksheet before we can select the range. There are many ways of selecting the worksheet which can be confusing.

I have broken it down into three scenarios:

1. The worksheet is in the same workbook as the code.
2. The worksheet is in a different workbook but we only want to read from it.
3. The worksheet is in a different workbook but we want to write to it.

You can see the code for each of these scenarios in the next subsections:

The worksheet is in the current workbook

The worksheet is in the current workbook so we can use either:

1. The code name of the worksheet.
2. The worksheet name: ThisWorkbook.Worksheets(“worksheet name”).

In the screenshot below we have changed the codename and worksheet name:

We would use the following code to reference the sheet

' https://excelmacromastery.com/
Sub WorksheetCodeName()

    Dim shRead As Worksheet
    
    ' Use the code name
    Set shRead = CodeName
    
    ' OR
    
    ' Use the worksheet name
    Set shRead = ThisWorkbook.Worksheets("SheetName")
    
End Sub

The worksheet is in a different workbook – reading only

If the worksheet is in a different workbook than the code, then we need to open the workbook. In this case we will only be reading from the worksheet so we can simply make it read-only.

Then it doesn’t matter if it’s already open. Making it read-only also prevents us from accidentally changing the data in the workbook.

' WorksheetRead()
'
' HOW TO RUN:
' 1. Place this code in a new workbook and save it as a .xlsm file.
' 2. Create a workbook called Writedata.xlsx and place it in the same
'    folder as the workbook you just created.
' 3. Place any value in cell A1 on sheet1 from Writedata.xlsx.
' 4. Run the code(Press F5).
'
' RESULT: The value in cell A1 on sheet1 from Writedata.xlsx
'         will be displayed in a message box.
' https://excelmacromastery.com/
Sub WorksheetRead()

    ' Get the full filename and path of "WriteData.xlsx"
    Dim sFilename As String
    sFilename = _
         ThisWorkbook.Path & Application.PathSeparator & "WriteData.xlsx"

    ' Open workbook as read-only and store in variable wk
    Dim wk As Workbook
    Set wk = Workbooks.Open(sFilename, ReadOnly:=True)

    ' Store the worksheet Sheet1 in the variable shRead
    Dim shRead As Worksheet
    Set shRead = wk.Worksheets("Sheet1")
    
    ' Print the value from the worksheet cell A1
    If IsEmpty(shRead.Range("A1").Value2) Then
        MsgBox "No value was found in cell Sheet1:A1 of WriteData.xlsx."
    Else
        MsgBox "The value found in Sheet1:A1 is of WriteData.xlsx is: " _
            & shRead.Range("A1").Value2
    End If
    
    wk.Close SaveChanges:=False
End Sub

The worksheet is in a different workbook – reading and writing

Just like the last example, the worksheet is in a different workbook than the code. In this case we want to write to the worksheet in the workbook.

We first check if the workbook is already open, and if so we display a message informing the user to close it before running the code again:

' WorksheetWrite()
'
' HOW TO RUN:
' 1. Place this code in a new workbook and save it as a .xlsm file.
' 2. Create a workbook called Writedata.xlsx and place it in the same
'    folder as the workbook you just created.
' 3. Click in the WorksheetWrite sub and press F5 to run the code.
' 4. Open the Writedata.xlsx and check if the value was correctly
'    written to cell A1 in sheet1.
'
' RESULT: If the file is already open then and error message will be
'         displayed to the user asking them to close the file.
'         If the file is not already open then the value 99 will be
'         written to cell A1 on sheet1 of Writedata.xlsx.
' https://excelmacromastery.com/
Sub WorksheetWrite()

    Dim sFilename As String
    sFilename = _
         ThisWorkbook.Path & Application.PathSeparator & "WriteData.xlsx"

    ' Ensure that the workbook is not already open
    If IsWorkBookOpen("WriteData.xlsx") Then
        MsgBox "Please close workbook " & sFilename & " and try again."
        Exit Sub
    End If

    ' Open workbook and store in variable wk
    Dim wk As Workbook
    Set wk = Workbooks.Open(sFilename, ReadOnly:=False)

    ' Store the worksheet Sheet1 in the variable shRead
    Dim shRead As Worksheet
    Set shRead = wk.Worksheets("Sheet1")
    
    ' Write a value to the worksheet cell A1
    shRead.Range("A1").Value2 = Now

    ' Close the file when finished with it
    wk.Close saveChanges:=True
    
End Sub

' Helper function to check if workbook is already open
Function IsWorkBookOpen(strBookName As String) As Boolean
    
    Dim oBk As Workbook
    
    On Error Resume Next
    Set oBk = Workbooks(strBookName)
    On Error GoTo 0
    
    If Not oBk Is Nothing Then
        IsWorkBookOpen = True
    End If
    
End Function

Now that we can get any worksheet we require, we can focus on how to copy the data.

Get the Data Range

In many online Excel VBA Copy examples, you will see a fixed range like Range(“A1:D6”).

When dealing with real-world applications it is rare that the data will be of a fixed size.

For example, imagine you stored student marks for each class in a worksheet. Obviously, each class will have a different number of students. Each time you read a worksheet you cannot be sure in advance what the range will be.

Your code should be able to figure out the full range of data, even if the size changes each time it runs.

There are two types of data:

1. Rectangular data where the data is in a list of rows with no blank rows or columns.
2. Fragmented data where the data may contain blank rows or columns.

Using CurrentRegion

The CurrentRegion property of Range is very useful for returning the entire range of data. CurrentRegion returns all the adjacent data from a given range.

You can see the CurrentRegion in Excel by selecting a cell and pressing Ctrl + Shift + *.

In the screenshot below you can see two groups of adjacent data. By selecting any cell with data and pressing Ctrl + Shift + *, Excel will select all the data in that group. This is the current region.

We can also use the CurrentRegion in VBA:

The Current region will work as long as there are no blank rows or columns between the data.

' CurrentRegion()
'
' HOW TO RUN:
' 1. Create a worksheet called "CurrentRegion".
' 2. Add data to all cells in the range B3:D14.
' 3. Run this sub(F5).
'
' RESULT: The current region for B3, C9 and D14 will
'         be displayed in the Immediate Window(Ctrl + G).
' https://excelmacromastery.com/
Sub CurrentRegion()

     ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("CurrentRegion")
    
    Dim rg1 As Range, rg2 As Range, rg3 As Range
    
    ' Get the current region
    ' All the below examples with return B3:D14
    Set rg1 = shRead.Range("B3").CurrentRegion
    Set rg2 = shRead.Range("C9").CurrentRegion
    Set rg3 = shRead.Range("D14").CurrentRegion
    
    ' Display the addresses to the Immediate Window(Ctrl + G)
    Debug.Print "B3 CurrentRegion is: " & rg1.Address
    Debug.Print "C9 CurrentRegion is: " & rg2.Address
    Debug.Print "D14 CurrentRegion is: " & rg3.Address

End Sub

Using End with xlUp and xlToLeft

If there are blank rows and/or blank columns then CurrentRegion will not return all the data.

For example, in the data shown here there are blank rows and a blank column:

We need to get the last row with data and/or the last column with data. We can then use these cells to build our Range.

' UseLastRowCol()
'
' HOW TO RUN:
' 1. Create a worksheet called "Fragmented".
' 2. Add any data to the cells A1:E13 but make sure you
'    have the same blank cells as in the above screenshot.
' 3. Run this sub(F5)
'
' RESULT: The range A1:E13 will be displayed in the
'         Immediate Window(Ctrl + G).
' https://excelmacromastery.com/
Sub UseLastRowCol()

     ' Get the worksheet
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Fragmented")
    
    Dim lastRow As Long, lastCol As Long
        
    ' Get the last cell with data in column A
    lastRow = shRead.Cells(shRead.Rows.count, 1).End(xlUp).row
    
    ' Get the last cell with data in row 1
    lastCol = shRead.Cells(1, shRead.Columns.count).End(xlToLeft).column
    
    Dim rg As Range
    With shRead
        ' Get the full range of data from A1 to last row and column
        Set rg = .Range(.Cells(1, 1), .Cells(lastRow, lastCol))
    End With
    
    ' Print the rg address(i.e. A1:E13) to the Immediate Window(Ctrl + G)
    Debug.Print "The range of data is: " & rg.Address

End Sub

Excel VBA Copy Methods

In this section we are going to look at the copying methods.

There are three ways of copying data in VBA:

1. The Range.Copy function
2. The assignment operator(i.e. equals sign)
3. The Range.CopyFromRecordset function(ADO only)

In the following sub sections we will look at these in turn. We will be using these Excel VBA copy methods with the different filter methods.

Range.Copy

We can use the Copy method of the Range to copy data.

' https://excelmacromastery.com/
Sub SimpleCopy()

     ' Get the worksheet
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    ' Copy the data from A1:D1 to H1:K1
    shRead.Range("A1:D1").Copy Destination:=shRead.Range("H1")
    
    ' Using Destination is optional
    shRead.Range("A1:D1").Copy shRead.Range("H1")

End Sub

We can copy between worksheets using this Excel VBA method. The only thing that will change in the code is the worksheets that we use.

' UsingRangeCopy()
'
' HOW TO RUN:
' 1. Create a workbook called Data.xlsx and place it in the same
'    folder as the workbook with the code.
' 2. Rename sheet1 to "CustomerData".
' 3. Add data to the range A1:D19.
' 4. Save the file.
' 5. Have a worksheet called "Report" in the current workbook
' 6. Click in this sub and press F5 to run
'
' RESULT: The data in the range A1:D19 from the CustomerData
'          worksheet in Data.xlsx will have been copied to
'         the Report worksheet in the current workbook.
' https://excelmacromastery.com/
Sub UsingRangeCopy()

    Dim sFilename As String
    sFilename = _
            ThisWorkbook.Path & Application.PathSeparator & "Data.xlsx"

    ' Open a workbook called Data.xlsx from the current folder
    Dim wk As Workbook
    Set wk = Workbooks.Open(sFilename, ReadOnly:=True)
    
    ' shRead stores the worksheet CustomerData
    ' shWrite store the Report sheet
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = wk.Worksheets("CustomerData")
    Set shWrite = ThisWorkbook.Worksheets("Report")

    ' Clear the data from the report worksheet
    shWrite.Cells.Clear

    ' Copy from CustomerData to Report
    shRead.Range("A1:D19").Copy shWrite.Range("A1")
    
    ' Activate the report worksheet
    shWrite.Activate
    
    ' Close the "Data.xlsx" workbook
    wk.Close

End Sub

This Range.Copy method copies everything. In other words it will copy values, formulas, formats etc.

If we only want to copy the data we can use the PasteSpecial property of Range.

Using PasteSpecial

We can use PasteSpecial with Range.Copy to paste the values only

' https://excelmacromastery.com/
Sub UsingPasteSpecial()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    ' Clear any existing data from report
    shWrite.Cells.Clear
    
    ' This will copy the values only
    shRead.Range("A1:E13").Copy
    shWrite.Range("A1").PasteSpecial xlPasteValues
    
End Sub

You can also copy formats, formulas and comments using PasteSpecial. You can read more about it here.

Range.Copy and Transpose

Transposing data means that the rows become columns and the columns become rows:

We can use the Range.PasteSpecial function to transpose data:

' https://excelmacromastery.com/
Sub RangeCopy_Transpose()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transpose")
    
    ' Clear any existing data
    shRead.Range("F1:I2").Clear
    
    ' This will copy from A1:B4 to F1:I2
    shRead.Range("A1:B4").Copy
    shRead.Range("F1").PasteSpecial Transpose:=True
    
End Sub

Copying by Assignment

We can assign values using the equals sign in VBA.

We can copy values from one range to another using assignment.

The value to the right of the equals is placed in cell to the left of the equals as you can see in these examples:

' https://excelmacromastery.com/
Sub AssignExamples()"
    
    ' Copy a value to a cell
    Range("A1").Value2 = 56
    Range("A2").Value2 = "Mary"
    
    ' Copy cell to cell
    Range("G1").Value2 = Range("F1").Value2
    Range("G2").Value2 = Range("F2").Value2
    
    ' Copy multiple cells - the source and destination range
    ' must be the same size
    Range("A1:C5").Value2 = Range("D1:F5").Value2
    
End Sub

The code below shows an example of copying the data from the data shown in the screenshot at the start of this section.

We will copy the range A1:D11 on the worksheet Transactions to the range A1:D11 on worksheet Report.

' UsingAssignment()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' RESULT: The data will be copied from the Transaction worksheet
'         to the report worksheet
' https://excelmacromastery.com/
Sub UsingAssignment()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "dd/mm/yyyy"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        .Columns(4).NumberFormat = "0"
        .Columns(5).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Copy the data
    shWrite.Range("A1:D11").Value2 = shRead.Range("A1:D11").Value2

End Sub

The key thing to remember about assigning values is that the destination must be the same size as the source.

If it is smaller than the source range then not all the data will be written.

If it is bigger than the source then there will be #N/A errors in the extra cells.

Assignment with Transpose

We can use the WorksheetFunction.Transpose function to transpose using the assignment operator(i.e. equals sign) to copy:

' https://excelmacromastery.com/
Sub TransposeAssign()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transpose")
    
    ' Clear any existing data
    shRead.Range("F1:I2").Clear
    
    shRead.Range("F1:I2").Value2 = _
            WorksheetFunction.Transpose(shRead.Range("A1:B4").Value2)

End Sub

Using Range.CopyFromRecordset

A Recordset is the collection of data we get when we run a database query.

We can run database queries on worksheet data using ADO (ActiveX Data Objects).

We will look at this Excel VBA Copy method in more detail in the ADO section below.

Excel VBA Filter Methods

Whenever you are copying data in VBA you will almost always apply some type of filter. This could be selection rows based on certain criteria or it could be summing data.

In this section, we are going to look at the various ways of filtering data. If you want working examples using the Filter methods then you can download the source code at the top or bottom of this post.

Filtering using For and If

The most common way of filtering data in VBA is using a For Loop and If Statement.

This is the least flexible and most long-winded method of filtering data in VBA. By long-winded, I mean that it requires lots of code compared to the other methods.

Using For and IF is the method you will see used the most in examples or in legacy VBA code.

We use the For Loop to read through data one row at a time. For each row, we will use the If Statement to check for certain criteria.

Here is a simple outline:

' https://excelmacromastery.com/
Sub ForIf_Basic()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    Dim i As Long
    For i = 1 To 13
        If shRead.Range("A" & i).Value2 = "Laptop Model A" Then
            ' Code for copying here
        End If
    Next i
    
End Sub

We can use both And and Or operators in the if statement.

Here are some examples:

If Item = "Laptop Model A" And Volume > 20 Then

If Item = "Laptop Model A" Or Volume > 20 Then

If Item = "Laptop Model A" Or Item = "Laptop Model B" Then

How to Copy Rows

The following code reads through the data. It checks each line to see if the first cell contains “Laptop Model A” .

If the row with these criteria is found, the row will be copied to the output worksheet.

The first version of the code below will use Range.Copy and the second will use the assign copy method:

' For_RangeCopy()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' https://excelmacromastery.com/
Sub For_RangeCopy()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    Dim shWrite As Worksheet
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    With shWrite

        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "dd/mm/yyyy"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        .Columns(4).NumberFormat = "0"
        .Columns(5).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Read through the data
    Dim i As Long, row As Long
    row = 1
    For i = 1 To rg.Rows.count
        
        If rg.Cells(i, 1).Value2 = "Laptop Model A" Or i = 1 Then
            
            ' Copy using Range.Copy
            rg.Rows(i).Copy
            shWrite.Range("A" & row).PasteSpecial xlPasteValues
            
            ' move to the next output row
            row = row + 1
            
        End If
        
    Next i
    
End Sub

' For_Assign()
'
' Requirements:
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' https://excelmacromastery.com/
Sub For_Assign()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    Dim shWrite As Worksheet
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    With shWrite

        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "dd/mm/yyyy"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        .Columns(4).NumberFormat = "0"
        .Columns(5).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Read through the data
    Dim i As Long, row As Long
    row = 1
    For i = 1 To rg.Rows.count
        
        If rg.Cells(i, 1).Value2 = "Laptop Model A" Or i = 1 Then
           
            ' Get the destination range
            Dim rgDest As Range
            Set rgDest = _
                shWrite.Range("A" & row).Resize(1, rg.Columns.count)
            
            ' Copy using Assignment
            rgDest.Value2 = rg.Rows(i).Value2
            
            ' move to the next output row
            row = row + 1
            
        End If
        
    Next i
    
End Sub

In the above code, we use Range.Resize when copying by assignment. You can read more about this here.

Using an Array to Read Faster

If you are reading through a lot of data then reading directly from the worksheet range is very slow.

It is much quicker to copy the data to an array and then read through that array. Then when we are finished, we write the array back to the worksheet

We cannot use Range.Copy because it obviously can only be used on an actual range.

Let’s update our last example so it will use an array:

' https://excelmacromastery.com/
Sub ForUsingArray_Assign()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    Dim shWrite As Worksheet
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    ' Copy the range to an array
    Dim arr As Variant
    arr = shRead.Range("A1").CurrentRegion.Value2
    
    With shWrite
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "dd/mm/yyyy"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        .Columns(4).NumberFormat = "0"
        .Columns(5).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Read through the data
    Dim i As Long, j As Long
    Dim row As Long, Columns As Long
    row = 1
    For i = LBound(arr) To UBound(arr)
        
        ' If "Laptop Model A" or header row then copy
        If arr(i, 1) = "Laptop Model A" Or i = 1 Then
            
            ' Copy each column
            For j = LBound(arr, 2) To UBound(arr, 2)
                shWrite.Cells(row, j).Value2 = arr(i, j)
            Next j
            
            ' move to the next output row
            row = row + 1
            
        End If
        
    Next i
    
End Sub

We could also use the Worksheet Function Index to copy. However, it is incredibly slow. In the speed tests it was over 4000 times slower than using the AutoFilter.

' Copy using Index
Columns = UBound(arr, 2)
shRepAssign.Range("A" & row).Resize(1, Columns).Value2 = _
        Application.WorksheetFunction.Index(arr, i, 0)

Copying Individual Fields

Copying individual items in a row is actually very straightforward.

We simply copy each cell individually:

' For_Assign_Individual()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' https://excelmacromastery.com
Sub For_Assign_Individual()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    Dim shWrite As Worksheet
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    With shWrite
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Read through the data
    Dim i As Long, rgWrite As Range, row As Long
    row = 1
    For i = 1 To rg.Rows.count
    
        ' If "Laptop Model A" or the header row
        If rg.Cells(i, 1).Value2 = "Laptop Model A" Or i = 1 Then
    
            ' Copy from column A to column A
            shWrite.Cells(row, 1).Value2 = rg.Cells(i, 1).Value2
            
            ' Copy from column E to column B
            shWrite.Cells(row, 2).Value2 = rg.Cells(i, 5).Value2
            
            ' Move to the next row for writing
            row = row + 1
        
        End If
        
    Next i

End Sub

The method below using Range.Copy – it is very slow so it is best to avoid using it.

' WARNING: DON'T USED THIS METHOD - IT IS INCREDIBLY SLOW
' https://excelmacromastery.com/
Sub For_RangeCopy_Individual()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    Dim shWrite As Worksheet
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    ' Read through the data
    Dim i As Long, rgWrite As Range, row As Long
    row = 1
    For i = 1 To rg.Rows.count
    
        ' If "Laptop Model A" or the header row
        If rg.Cells(i, 1).Value2 = "Laptop Model A" Or i = 1 Then
    
            ' Copy using Range.Copy
            rg.Cells(i, 1).Copy
            shWrite.Range("A" & row).PasteSpecial xlPasteValues
            
            rg.Cells(i, 5).Copy
            shWrite.Range("B" & row).PasteSpecial xlPasteValues
            
            ' Move to the next row for writing
            row = row + 1
        
        End If
        
    Next i

In this example we use an array with the For loop to copy. It is the fastest way to copy individual columns using the For loop but it is still way slower than using the AutoFilter.

' ForUsingArray_Assign_Individual()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' https://excelmacromastery.com/
Sub ForUsingArray_Assign_Individual()

    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    Dim shWrite As Worksheet
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Get the range
    Dim arr As Variant
    arr = shRead.Range("A1").CurrentRegion.Value2
    
    ' Read through the data
    Dim i As Long, rgWrite As Range, row As Long
    row = 1
    For i = LBound(arr) To UBound(arr)
    
        ' If "Laptop Model A" or the header row
        If arr(i, 1) = "Laptop Model A" Or i = 1 Then
    
            ' Copy from column A to column A on the report worksheet
            shWrite.Cells(row, 1).Value2 = arr(i, 1)
            
            ' Copy from column E to column B on the report worksheet
            shWrite.Cells(row, 2).Value2 = arr(i, 5)
            
            ' Move to the next row for writing
            row = row + 1
        
        End If
        
    Next i

End Sub

If the original data has a lot of columns and you only require a few of them, then this method may be as fast as AutoFilter but you will need to test both methods.

Summing Totals

In the data shown below we want to get the total sales for each item:

Our result should look like this:

Summing data like this is much trickier than simply filtering data.

For each item, we need to store a running total somewhere. Each time we read an item we need to either create a new entry or add the current sales amount to the existing entry.

The easiest way to do this is to use a Dictionary.

You can see the code to do this below. You will notice that it is split into two parts:

• In part one we read the values from the worksheet to the dictionary.
• In part two we write the values from the dictionary to the worksheet.

' ForDictionary_Assign_Sum()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' IMPORTANT: Add the Dictionary reference to use the dictionary
'            Tools->Reference and check "Microsoft Scripting Runtime"
' https://excelmacromastery.com/
Sub ForDictionary_Assign_Sum()

    ' PART 1 - Read the data
    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    ' Create the dictionary
    Dim dict As New Dictionary
    
    ' Read through the data
    Dim i As Long, Item As String, Sales As Long
    For i = 2 To rg.Rows.count
        ' Store the values in a variable
        Item = rg.Cells(i, 1).Value2
        Sales = rg.Cells(i, 5).Value2
        
        ' The item will be automatically added if it doesn't exist
        dict(Item) = dict(Item) + Sales
    Next i
    
    ' PART 2 - Write the data
    Dim shWrite As Worksheet
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "$#,##0;[Red]$#,##0"
        
        ' Write header
        .Cells(1, 1).Value2 = "Item"
        .Cells(1, 2).Value2 = "Sales"
        
    End With
    
    Dim key As Variant, row As Long
    row = 2
    ' Read through each item in the Dictionary
    For Each key In dict.Keys
    
        shWrite.Cells(row, 1) = key
        shWrite.Cells(row, 2) = dict(key)
        
        row = row + 1
    Next key
    
End Sub

Summing Multiple Totals

In the previous example we were summing one item. This time we are going to sum the volume and the price fields.

The Dictionary stores a key and a value. If we want to store more than one value then we use a class module.

In the next example, I have split up the code into procedures to make it easier to read and to be more flexible:

' Class Module: clsSales
Public Items As String
Public Volume As Long
Public Sales As Long

' https://excelmacromastery.com/
Sub CreateReport()

    ' Declare a Dictionary variable
    Dim dict As Dictionary

    ' Read the data to the Dictionary
    Set dict = ReadData
    
    ' Write the Data from the Dictionary to the Worksheet
    WriteData dict

End Sub

' Read the data from the worksheet into a Dictionary
'
' IMPORTANT: Add the Dictionary reference to use the dictionary
' Tools->Reference and check "Microsoft Scripting Runtime"
' https://excelmacromastery.com/
Private Function ReadData() As Dictionary
    
    ' Create the dictionary
    Dim dict As New Dictionary
    
    ' Get the worksheets
    Dim shRead As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    ' Read through the data
    Dim i As Long, Item As String, Volume As Long, Sales As Long
    Dim oSales As clsSales, oSalesCurrent As clsSales
    For i = 2 To rg.Rows.count

        Item = rg.Cells(i, 1).Value2
        Volume = rg.Cells(i, 4).Value2
        Sales = rg.Cells(i, 5).Value2
        
        ' Check if the Item has already been added
        If dict.Exists(Item) = False Then
            ' Add Item and new class module object
            Set oSales = New clsSales
            dict.Add Item, oSales
        End If
        
        ' Get the current item
        Set oSalesCurrent = dict(Item)
        
        ' Update the data
        With oSalesCurrent
            .Volume = .Volume + Volume
            .Sales = .Sales + Sales
        End With
        
    Next i
    
    Set ReadData = dict
    
End Function

' Write the summed data to the worksheet
' https://excelmacromastery.com/
Sub WriteData(dict As Dictionary)

    Dim shWrite As Worksheet
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "0"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        
        ' Write header
        .Cells(1, 1).Value2 = "Item"
        .Cells(1, 2).Value2 = "Volume"
        .Cells(1, 3).Value2 = "Sales"
        
    End With
    
    Dim key As Variant, oData As clsSales, row As Long
    row = 2
    
    ' Read through each item in the Dictionary
    For Each key In dict.Keys
    
        Set oData = dict(key)
        
        shWrite.Cells(row, 1) = key
        shWrite.Cells(row, 2) = oData.Volume
        shWrite.Cells(row, 3) = oData.Sales
        
        row = row + 1
        
    Next key
    
End Sub

Using AutoFilter

The methods that we have looked at so far require a lot of code.

There is actually a much simpler way of reading and filtering data. We can use the AutoFilter. This is the filter we use in Excel to filter data. Once the data is filtered we can easily copy and paste it.

In terms of speed, AutoFilter came out on top in the speed tests that I performed. It is the best one to use for selecting or copying either rows or individual columns.

These are some examples of using AutoFilter in VBA:

' Field 1 = "Ipsum Corporation" and field 3 >=50
rg.AutoFilter Field:=1, Criteria1:="Ipsum Corporation" _ 
       , Operator:=xlAnd, Field:=3, Criteria1:=">=50"

' Field 1 starts with "I"
rg.AutoFilter Field:=1, Criteria1:="I*"

' Field 1 ends with "Ltd"
rg.AutoFilter Field:=1, Criteria1:="*Ltd"

' Field 1 contains "Su"
rg.AutoFilter Field:=1, Criteria1:="*Su*"

' Field 1 does not contain "Su"
rg.AutoFilter Field:=1, Criteria1:="<>*Su*"

' Get the top 10 items based on the value in Field 3
rg.AutoFilter Field:=3, Criteria1:="10", Operator:=xlTop10Items

' Field 3 is in the value list of 100,17 and 2
rg.AutoFilter Field:=3, Criteria1:=Array("100", "17", "2") _
     , Operator:=xlFilterValues

Now that we understand the basics, let’s look at some practical examples of using AutoFilter.

How to Copy Rows

Using AutoFilter is the fastest way to copy filtered rows of data.

Let’s use AutoFilter to copy all the rows that contain “Laptop Model A”.

The following code shows how to do this:

' AutoFilter_RangeCopy_Row()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' https://excelmacromastery.com/
Sub AutoFilter_RangeCopy_Row()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "dd/mm/yyyy"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        .Columns(4).NumberFormat = "0"
        .Columns(5).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    ' Remove any existing filters
    rg.AutoFilter
    
    ' Apply the Autofilter
    rg.AutoFilter Field:=1, Criteria1:="Laptop Model A"
    
    ' Copy the data using Range Copy
    shRead.Range("A1").CurrentRegion.SpecialCells(xlCellTypeVisible).Copy
    shWrite.Range("A1").PasteSpecial xlPasteValues
    
    ' Remove any existing filters
    rg.AutoFilter
    
    ' Active the output sheet so it is visible
    shWrite.Activate

End Sub

We can also use assign to copy the data. It is almost as fast but requires slightly more complex code.

It is actually not necessary to use this code but I am including it for completeness:

' AutoFilter_Assign_Row()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' https://excelmacromastery.com/
Sub AutoFilter_Assign_Row()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "dd/mm/yyyy"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        .Columns(4).NumberFormat = "0"
        .Columns(5).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
        
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    ' Remove any existing filters
    rg.AutoFilter
    
    ' Apply the Autofilter
    rg.AutoFilter Field:=1, Criteria1:="Laptop Model A"
     
    ' Get the read range
    Dim rgRead As Range
    Set rgRead = _
        shRead.Range("A1").CurrentRegion.SpecialCells(xlCellTypeVisible)

    Dim rgRow As Range, row As Long
    row = 1
    ' Read through each row
    For Each rgRow In rgRead.Rows
        
        ' Copy the row
        shWrite.Cells(row, 1).Resize(1, rgRead.Columns.count).Value2 _
                   = rgRow.Value2
        
        ' move to the next output row
        row = row + 1
        
    Next rgRow
    
    ' Remove any existing filters
    rg.AutoFilter

End Sub

Using AutoFilter code is much easier to write because we don’t need a For Loop and an If Statement. We can filter the data in just one line.

Copying Individual Fields

Copy individual cells is more long winded than copying the row.

It may seem counter intuitive at first but we have to specify the cells we are copying. With a row, we can just copy the entire thing.

There are 2 main ways we can do this:

1. Copy the individual columns from the filtered data.
2. Copy filtered data and delete the columns that are not required.

Copy the Columns

The first method is the most basic way to do this. We simple copy each column that we require

' AutoFilter_CopyColumns()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' Details: Use AutoFilter with Range.Copy to filter and copy individual
'          column data.
'          The resulting data should contain the columns Items and Sales.
' https://excelmacromastery.com/
Sub AutoFilter_CopyColumns()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    ' Remove any existing filters
    rg.AutoFilter
    
    ' Apply the Autofilter
    rg.AutoFilter Field:=1, Criteria1:="Laptop Model A"
    
    Dim arr As Variant
    arr = Array(1, 5)
    
    ' Remove unnecessary columns
    Dim i As Long, column As Long
    column = 1
    For i = LBound(arr) To UBound(arr)
        rg.Cells(1, arr(i)).EntireColumn.Copy
        shWrite.Cells(1, column).PasteSpecial xlPasteValues
        column = column + 1
    Next i
    
    ' Remove any existing filters
    rg.AutoFilter
    
End Sub

Copy and Delete Unwanted Columns

The second method is the fastest for data with a reasonable number of columns. We simply copy all the data and delete the columns we don’t need:

' AutoFilter_DeleteColumns()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' Details: Use AutoFilter with Range.Copy to filter and copy individual
'          column data.
'          Copy the entire data and then delete the unnecessary columns.
'          The result should be Item and Sales columns only.
' https://excelmacromastery.com/
Sub AutoFilter_DeleteColumns()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
    
    ' Remove any existing filters
    rg.AutoFilter
    
    ' Apply the Autofilter
    rg.AutoFilter Field:=1, Criteria1:="Laptop Model A"

    ' Copy the filtered data to the output worksheet
    rg.SpecialCells(xlCellTypeVisible).Copy
    shWrite.Range("A1").PasteSpecial xlPasteValues
    
    ' Remove unnecessary columns
    Dim rgOut As Range, i As Long
    Set rgOut = shWrite.Range("A1").CurrentRegion
    For i = rgOut.Columns.count To 1 Step -1
        Select Case i
            Case 1, 5
            Case Else
                rgOut.Columns(i).EntireColumn.Delete
        End Select
    Next i
    
    ' Remove any existing filters
    rg.AutoFilter
    
End Sub

Summing Totals

We cannot use the Filters to sum data. We need to use either a For Loop with a Dictionary or ADO.

Using Advanced Filter

See the main article on Advanced Filter here

Advanced Filter has 4 major advantages over AutoFilter:

1. It has more advanced filtering.
2. It can automatically copy the results to another range.
3. When copying the results it automatically copies the format.
4. You can select specific columns and the order of columns.

The AutoFilter has a drawback when filtering data. We cannot use the logic:

If Value1 is in Column1 OR Value2 is in Column2

For example, we cannot say we want all the records where the Item is “Laptop Model A” or Volume > 6.

We can use the AdvancedFilter to get around this. AdvancedFilter is very similar to AutoFilter. The major difference is that the criteria must be a range on the worksheet.

The screenshot below shows how to use AND. It means item is “Laptop Model A” and Volume > 16. The Criteria Range for this must be G1:K2.

The result of using these criteria is:

The screenshot below shows how to use OR. It means item is “Laptop Model A” OR Volume > 16. The Criteria Range for this must be G1:K3.

The result of using these criteria is

The code below shows how we create an advanced filter for the above and criteria.

Range("A1:D12").AdvancedFilter Action:=xlFilterInPlace _
     , CriteriaRange:=Range("G1:K2")

For OR it would be

Range("A1:D12").AdvancedFilter Action:=xlFilterInPlace _
     , CriteriaRange:=Range("G1:K3")

Important: You will notice here that the Criteria range is different for the two examples. Make sure that you don’t have a blank line in the criteria (e.g. G1:K4 instead of G1:K3). This will result in all records being returned i.e. no filter being applied.

How to Copy Rows

Advanced filter will not only automatically copy the results for us. It is also the fastest VBA method for copying and filter in most scenarios.

We simple set the Action parameter to xlFilterCopy and set the CopyToRange parameter to the output range:

' ----------------------------------------------------------------
' Procedure Name: AdvancedFilterExample
' Purpose: An example of using the Advanced Filter to copy rows
'
' Result: The result depends on the values set in the criteria range
'         G to K columns on the "Transaction Filter" worksheet.
' Website: https://excelmacromastery.com/
' ----------------------------------------------------------------
' https://excelmacromastery.com/
Sub AdvancedFilterExample()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions Filter")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    ' Clear any existing data
    shWrite.Cells.Clear

    ' Remove the any existing filters
    If shRead.FilterMode = True Then
        shRead.ShowAllData
    End If
    
    ' Get the source data range
    Dim rgData As Range, rgCriteria As Range
    Set rgData = shRead.Range("A1").CurrentRegion
    
    ' IMPORTANT: Do not have any blank rows in the criteria range
    Set rgCriteria = shRead.Range("G1:K2")
   
    ' Apply the filter
    rgData.AdvancedFilter Action:=xlFilterCopy, CriteriaRange:=rgCriteria _
                , CopyToRange:=shWrite.Range("A1")

 End Sub

Copying Individual Fields

To copy specific columns is pretty simple. We place the columns in our output range and Advanced Filter will only write data to this columns.

For example, If we only want the Item and Sales columns then we need to make two changes to Advanced filter example above:

1. Set the Headers before we run advanced filter.
2. Set the CopyToRange parameter to include the Range of headers.

We can see the updated code here:

' ----------------------------------------------------------------
' Procedure Name: AdvancedFilter_Columns
' Purpose: Uses Advanced Filter to copy individual columns
'
' Result: The result will be the Item and Sales column in the Report
'         worksheet.
' Website: https://excelmacromastery.com/
' ----------------------------------------------------------------
' https://excelmacromastery.com/
Sub AdvancedFilter_Columns()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions Filter")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    ' Clear any existing data
    shWrite.Cells.Clear
    
    ' Specify the output columns
    shWrite.Range("A1").Value2 = "Item"
    shWrite.Range("B1").Value2 = "Sales"

    ' Remove the filter
    If shRead.FilterMode = True Then
        shRead.ShowAllData
    End If
    
    ' Get the source data range
    Dim rgData As Range, rgCriteria As Range
    Set rgData = shRead.Range("A1").CurrentRegion
    
    ' IMPORTANT: Do not have any blank rows in the criteria range
    Set rgCriteria = shRead.Range("G1:K2")
   
    ' Apply the filter
    rgData.AdvancedFilter Action:=xlFilterCopy, CriteriaRange:=rgCriteria _
                , CopyToRange:=shWrite.Range("A1:B1")

End Sub

Using ADO and SQL

ADO is an external Library that allows us to perform queries on databases. It stands for ActiveX Database Objects.

ADO can also perform queries on data in worksheets. This means we can do very powerful queries that run very fast.

Just like using AutoFilter and Advanced filter, we can use most of the same VBA code each time. The main difference will be the query line. The disadvantage is that it requires some basic knowledge of SQL.

If you want to see working examples using ADO and SQL then you can download the source code at the top or bottom of this post.

The following code returns all the records where the item is “Laptop Model A”:

' ReadFromWorksheetADO()

'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' Details: Returns all the records for item "Laptop Model A".
' https://excelmacromastery.com/
Sub ReadFromWorksheetADO()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    With shWrite
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "dd/mm/yyyy"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        .Columns(4).NumberFormat = "0"
        .Columns(5).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' To add ADO reference select Tools->Reference and
    ' check "Microsoft ActiveX Data Objects Objects 6.1 Library"
    Dim conn As New ADODB.Connection
    conn.Open "Provider=Microsoft.ACE.OLEDB.12.0;" & _
        "Data Source=" & ThisWorkbook.FullName & ";" & _
            "Extended Properties=""Excel 12.0;HDR=Yes;"";"

    ' Store the query in a string
    Dim query As String
    query = "Select * from [" & shRead.name _
                    & "$] Where Item='Laptop Model A' "
    
    ' Run the query and store in a recordset
    Dim rs As New Recordset
    rs.Open query, conn

    ' Write header
    Dim i As Long
    For i = 0 To rs.Fields.count - 1
        shWrite.Cells(1, i + 1).Value2 = rs.Fields(i).name
    Next i
    
    ' Write data
    shWrite.Range("A2").CopyFromRecordset rs
    
    ' Close the connection
    conn.Close
    
End Sub

Here are some examples of ADO queries

' Item is "Laptop Model A" AND the volume is greater than or equal 20
query = "Select Item,Day,Price,Volume,Sales from [Transactions$] " _
         & " Where Item = 'Laptop Model A' and Volume>=20"

' Item is "Laptop Model A" OR the volume is greater than or equal 20
query = "Select Item,Day,Price,Volume,Sales from [Transactions$] " _
         & " Where Item = 'Laptop Model A' or Volume>=20"

' Item starts with "Laptop"  
query = "Select Item,Day,Price,Volume,Sales from [Transactions$] " _
         & " Where Item like 'Laptop%' "   

' Item Ends with "Model A"
query = "Select Item,Day,Price,Volume,Sales from [Transactions$] " _
         & " Where Item like '%Model A' "

' Item contains "top"
query = "Select Item,Day,Price,Volume,Sales from [Transactions$] " _
         & " Where Item like '%top%' "

 ' Item does not contain "top"
query = "Select Item,Day,Price,Volume,Sales from [Transactions$] " _
         & " Where Item Not like '%top%' "

' Return the total volume for each monitor type
query = "Select Item, Sum(Volume) As [Total Vol] from [Transactions$] " _
         & " Where Item like 'Monitor%' " _
         & " Group by Item"

It is important to note that for multiple queries you don’t need to connect to the workbook each time.

One connection to the workbook is enough. Then you can run all your queries. When your queries are finished you can close the connection.

The following outline shows what I mean:

' Open the connection
Dim conn As New ADODB.Connection
conn.Open "Provider=Microsoft.ACE.OLEDB.12.0;" & _
    "Data Source=" & ThisWorkbook.FullName & ";" & _
        "Extended Properties=""Excel 12.0;HDR=Yes;"";"

' Run all queries
...
...

' When finished close the connection
conn.Close

How to Copy Rows Using ADO

Copying a row is pretty straightforward using ADO.

There is a function Range.CopyFromRecordset which writes out the entire data from the query.

This is very convenient but it doesn’t copy the header and it is slower than many other methods.

In the code below we write out all the items that are “Laptop Model A”:

' ADO_CopyRow()
'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' Details: Returns the records for item "Laptop Model A".
' https://excelmacromastery.com/
Sub ADO_CopyRow()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions Filter")
    Set shWrite = ThisWorkbook.Worksheets("Report")
     
    With shWrite
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "dd/mm/yyyy"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        .Columns(4).NumberFormat = "0"
        .Columns(5).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' To add ADO reference select Tools->Reference and
    ' check "Microsoft ActiveX Data Objects Objects 6.1 Library"
    Dim conn As New ADODB.Connection
    conn.Open "Provider=Microsoft.ACE.OLEDB.12.0;" & _
        "Data Source=" & ThisWorkbook.FullName & ";" & _
            "Extended Properties=""Excel 12.0;HDR=Yes;"";"

    ' Store the query in a string
    Dim query As String
    query = "Select Item,Day,Price,Volume,Sales from [" & shRead.name _
            & "$] Where Item='Laptop Model A' "
    
    Dim rs As New Recordset
    rs.Open query, conn
    
    ' Write header
    Dim i As Long
    For i = 0 To rs.Fields.count - 1
        shWrite.Cells(1, i + 1).Value2 = rs.Fields(i).name
    Next i
    
    ' Write data
    shWrite.Range("A2").CopyFromRecordset rs
    
    conn.Close
    
End Sub

Copying Individual Fields

Copying individual fields using ADO couldn’t be simpler.

We specify the fields we want in the Select statement:

' Select all the fields
sQuery = "Select Item,Day,Price,Volume,Sales from [Transactions$]"

' Select Item and Sales
sQuery = "Select Item,Sales from [Transactions$]"

 ' Select Volume
sQuery = "Select Volume from [Transactions$]"

 ' Select Price, Item - changes order of fields
sQuery = "Select Item,Price from [Transactions$]"

Summing Totals

Summing totals is also simple. It only requires adding a Group By statement to the query

Let’s get the total volume and sales for each item:

' ADO_SumColums()'
' Requirements:
' 1. A worksheet "Transactions" containing data from this
' section: "The Dataset for this Article".
' 2. A worksheet for output called "Report".
'
' Details: Returns the total sales amount for each item.
' https://excelmacromastery.com/
Sub ADO_SumColums()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions Filter")
    Set shWrite = ThisWorkbook.Worksheets("Report")
     
    With shWrite
    
        ' Clear the data in output worksheet
        .Cells.ClearContents
        
        ' Set the cell formats
        .Columns(2).NumberFormat = "0"
        .Columns(3).NumberFormat = "$#,##0;[Red]$#,##0"
        
    End With
    
    ' To add ADO reference select Tools->Reference and
    ' check "Microsoft ActiveX Data Objects Objects 6.1 Library"
    Dim conn As New ADODB.Connection
    conn.Open "Provider=Microsoft.ACE.OLEDB.12.0;" & _
        "Data Source=" & ThisWorkbook.FullName & ";" & _
            "Extended Properties=""Excel 12.0;HDR=Yes;"";"

    ' Store the query in a string
    Dim query As String
    query = "Select Item,Sum(Volume) As [Total Volume] " _
        & ",Sum(Sales) As [Total Sales] " _
        & "from [" & shRead.name & "$] Group By Item "
    
    Dim rs As New Recordset
    rs.Open query, conn
    
    ' Write header
    Dim i As Long
    For i = 0 To rs.Fields.count - 1
        shWrite.Cells(1, i + 1).Value2 = rs.Fields(i).name
    Next i
    
    ' Write data
    shWrite.Range("A2").CopyFromRecordset rs
    
    conn.Close
    
End Sub

Pivot Table

Using a Pivot Table is a very powerful way to sum data. It is faster than using the other summing methods.

It is more flexible than using For with a Dictionary but easier to use than ADO as no knowledge of SQL is necessary.

We don’t actually need a copy method with the Pivot Table. We just need to specify range where the Pivot table will be created.

Summing Data

The Pivot Table automatically sums values.

We have rows and value fields in a Pivot Table. We can use these to sum data.

1. The Row field is the thing that we plan to get the total of e.g. Items.
2. The Value field is the value that we wish to sum e.g. Volume, Sales.

We can set these fields like this:

' Set the Row fields
.PivotFields("Item").Orientation = xlRowField

' Set the Value fields
.PivotFields("Volume").Orientation = xlDataField
.PivotFields("Sales").Orientation = xlDataField

The full PivotTable code looks like this:

' https://excelmacromastery.com/
Sub PivotTable_Sum()

    ' Get the worksheets
    Dim shRead As Worksheet, shWrite As Worksheet
    Set shRead = ThisWorkbook.Worksheets("Transactions")
    Set shWrite = ThisWorkbook.Worksheets("Report")
    
    ' Get the range
    Dim rg As Range
    Set rg = shRead.Range("A1").CurrentRegion
   
    ' Clear any existing pivot tables
    Dim piv As PivotTable
    For Each piv In shWrite.PivotTables
        piv.TableRange2.Clear
    Next piv
    
    ' Clear the data in output worksheet
    .Cells.ClearContents
  
    ' Create the cache
    Dim ptCache As PivotCache
    Set ptCache = ThisWorkbook.PivotCaches.Create( _
        SourceType:=xlDatabase _
        , SourceData:=rg _
        , Version:=xlPivotTableVersion15)
    
    ' Create the table
    Dim ptTable As PivotTable
    Set ptTable = shWrite.PivotTables.Add( _
             PivotCache:=ptCache _
            , TableDestination:=shWrite.Range("A1"))
    
    ' Set the name and style
    ptTable.name = "pvItems"
    ptTable.TableStyle2 = "PivotStyleDark14"
    
    ' Set the fields
    Dim ptField As PivotField
    With ptTable

        ' Set the rows fields
        .PivotFields("Item").Orientation = xlRowField
        
        ' Set the data(value) fields
        .PivotFields("Volume").Orientation = xlDataField
        .PivotFields("Sales").Orientation = xlDataField
        
    End With
    
End Sub

If we want to filter with the PivotTable then it is a bit long winded as we have to set each item individually.

To add a filter we can use the code below. Add this code before the “End With” line in the above code.

' Filter items
Dim pvItem As PivotItem
For Each pvItem In .PivotFields("Item").PivotItems
    If pvItem.Caption = "Laptop Model A" Then
        pvItem.Visible = True
    Else
        pvItem.Visible = False
    End If
Next pvItem

Conclusion

That concludes this article on copying and filtering data using the different Excel VBA Copy methods.

If you think something is missing or you have any questions or queries then please leave a comment below.

What’s Next?

Free VBA Tutorial If you are new to VBA or you want to sharpen your existing VBA skills then why not try out the The Ultimate VBA Tutorial.

Related Training: Get full access to the Excel VBA training webinars and all the tutorials.

(NOTE: Planning to build or manage a VBA Application? Learn how to build 10 Excel VBA applications from scratch.)