Excel and 2 vlookups

In this example, VLOOKUP is configured to look up 1000 invoice numbers in a table that contains 1 million invoices. Normally, this kind of lookup would perform quite slowly, because we would need to configure VLOOKUP to use an exact match, and exact match lookups on large data sets can be painfully slow. However, because the data is sorted by invoice number, we can use the modified VLOOKUP formula seen in the worksheet. Although this formula uses VLOOKUP twice, it performs well.

Exact-match VLOOKUP is slow

When you use VLOOKUP in «exact match mode» on a large set of data, it can really slow down the calculation time in a worksheet. With very large sets of data, the calculation time can be minutes. To use VLOOKUP in exact match mode, provide FALSE or zero as the fourth argument, range_lookup:

=VLOOKUP(value,data,n,FALSE) // exact match

The reason VLOOKUP is slow in this mode is that there is no requirement that the lookup values be sorted. As a result, VLOOKUP must check every record in the data set until a match is found, or not. This is sometimes referred to as a linear search.

Approximate-match VLOOKUP is very fast

In approximate-match mode, VLOOKUP is extremely fast. To use approximate-match VLOOKUP, sort the data by the first column (the lookup column), then specify TRUE for range_lookup or omit the argument:

=VLOOKUP(value,data,n,TRUE) // approximate match
=VLOOKUP(value,data,n) // approximate match

With very large sets of data, changing to approximate-match VLOOKUP can mean a dramatic speed increase. This is because VLOOKUP will assume data is sorted and use a different algorithm to speed up searching, sometimes called a binary search.

For a complete VLOOKUP overview with many examples, see How to use VLOOKUP.

The problem

At first glance, a solution seems simple: sort the data, and use VLOOKUP in approximate match mode. However, the problem is that VLOOKUP won’t return an error if a value is not found. Instead, it may return an incorrect result that looks completely normal. For example, in the worksheet shown, if we configure VLOOKUP to find the Amount for invoice 500010 with range_lookup set to TRUE, the result is 9225 even though invoice 500010 does not exist in the table:

=VLOOKUP(500010,data,2,TRUE) // returns 9225

This happens because VLOOKUP’s behavior with approximate match enabled is «exact match or next smaller value». When VLOOKUP can’t find invoice 500010, it matches the next smaller invoice number, which is 500008, and returns 9225. So, while the formula runs very quickly, the result is not reliable. Obviously, this is not something you want to explain to your boss.

A solution with VLOOKUP + VLOOKUP

One way to speed up VLOOKUP in this situation is to use VLOOKUP twice, both times in approximate match mode. This may seem counterintuitive because we are calling VLOOKUP twice. However, two fast operations are better than one slow operation. The trick is to structure the formula in a way that leverages two fast lookups in a way that requires an exact match result. We do that by testing the result of the first VLOOKUP to see if did actually find the lookup value. In the worksheet shown, the formula in F5, copied down, is:

=IF(VLOOKUP(E5,data,1)=E5,VLOOKUP(E5,data,2),NA())

Notice the IF function controls the flow of the formula. If we do find the lookup value, we run the second lookup. Otherwise, we return an error. The logical_test inside the IF function looks like this:

VLOOKUP(E5,data,1)=E5

Here, we use VLOOKUP to find and return the lookup value itself, and we do so in approximate match mode by omitting the range_lookup argument. Remember, VLOOKUP defaults to an approximate match. Then we test the result against the lookup value. If this test returns TRUE, we know the lookup value exists in the data and we run the second VLOOKUP to fetch the desired value:

VLOOKUP(E5,data,2)

However, if the test returns FALSE, it means we didn’t find the lookup value. In that case, we simply return an #N/A error with the NA function:

NA()  // returns #N/A

To summarize: if we find the invoice number, we look up the amount. If we don’t find an invoice number return #N/A error, which tells us the invoice number does not exist in the data. Even though the formula uses the VLOOKUP function two times, performance is good, because both instances of VLOOKUP use approximate match mode, which runs very quickly.

Summary

With large sets of data, exact match VLOOKUP can run painfully slow when configured for an exact match. This is because there is no requirement that the lookup values be sorted and VLOOKUP must perform a linear search, which is a slow operation when there are many values to check. On the other hand, if data is sorted, VLOOKUP can be configured for an approximate match by setting range_lookup to TRUE, or by omitting range_lookup altogether. In this configuration, VLOOKUP runs very fast. However, VLOOKUP may return an incorrect result. This happens because VLOOKUP’s behavior with approximate match enabled is «exact match or next smaller value», so VLOOKUP matches the previous value when a match is not found. One way around this problem is to use VLOOKUP twice, both times in approximate match mode. The trick is to structure the formula in a way that leverages two fast lookups in a way that still ensures an exact match result.

Notes

1. This approach is overkill unless lookup performance is an issue.
2. Data must be sorted by lookup value in ascending order.
3. The newer XLOOKUP function has a very fast binary search option.

4 different ways to perform LOOKUP with 2 lookup values

We know that VLOOKUP is very useful. At the same time, we know that VLOOKUP has its limitations. E.g. VLOOKUP only looks from left to right; VLOOKUP only handle one lookup value.  For a simple situation shown below, VLOOKUP doesn’t seem to work (directly).

No worry. There are at least four workarounds!

1. Using a helper column
2. Using CHOOSE to recreate the Table Array for VLOOKUP
3. Using INDEX, MATCH and = Operator
4. Using SUMPRODUCT

Let’s start with the basic.

1. Using a helper column

Most of the time, complicated problem will become easier and manageable when it is broken down into small pieces. Same applies in formula building in Excel.
Take below example:

By CONCATENATING “Month” and “Store” in column A (note: better to put the helper column to the left of the original Table as VLOOKUP looks from left to right.), we create the lookup value required in column A.  As a result, with the helper column A (which could be hidden later), the problem can be solved easily by

=VLOOKUP(G1&G2,$A$2:$D$10,4,FALSE)

Note: we need to combine the Month (G1) and Store (G2) as the lookup value

Non-helper column approach

Well, for any reason a helper column is not an option, we may do it by array formula. At least two different ways to perform the job:

2) Using CHOOSE to recreate the Table Array for VLOOKUP

This is a bit advance. The tricky part is to re-create the Table Array that is suitable for VLOOKUP by using CHOOSE.
CHOOSE({1,2},B2:B10&C2:C10,D2:D10) does two things

1. Combine “Month” and “Store” into a single array as “JanTW”;”FebTW”, etc……
2. Join the two arrays into a “table” of two columns

When we evaluate the result of the above CHOOSE (by selecting the whole CHOOSE formula in the formula bar and then press F9, we get the following result:

{"JanTW",171;"FebTW",177;"MarTW",179;"JanLP",199;"FebLP",130;"MarLP",103;"JanHC",122;"FebHC",177;"MarHC",200}

To visualize it in a Table format, it looks like the below:

Now the whole formula makes sense:

=VLOOKUP(G1&G2,CHOOSE({1,2},B2:B10&C2:C10,D2:D10),2,FALSE)
 CTRL SHIFT ENTER (not just ENTER)

IMPORTANT: As this is an array formula, we have to input CTRL SHIFT ENTER to tell Excel that we are going to input array formula. You will see the {} in the formula bar if array formula is input successfully.

• • Note: For both 1) and 2), the robust way to combine the lookup values should include a delimiter in between, e.g. A1 & “|” & B1 .  Please read Pay attention when concatenate for explanation.

3) Using INDEX, MATCH and = Operator

=INDEX(D2:D10,MATCH(1,(B2:B10=G1)*(C2:C10=G2),0))
 CTRL SHIFT ENTER

This formula actually looks more intuitive. How?

First let’s understand what the (B2:B10=G1)*(C2:C10=G2) does?

• B2:B10=G1 asks Excel to evaluate if B2=G1, if yes, it returns TRUE; if no, it returns FALSE. Then do the same for B3=G1, B4=G1…… until B10=G1. An array of TRUE/FALSE will be the result.
• C2:C10=G2 basically does the same thing but look at different values.

When we compare the two array of TRUE/FALSE by multiplying them, only TRUE * TRUE gives the result of 1 (TRUE).  A picture tells more. Let’s take a look at the screenshot below:

Bingo, we can identify the row that meets both lookup values.

Now you should be able to use MATCH to identify the position of the matching values. Then use INDEX to return the result required.

• =INDEX(D2:D10,MATCH(1,(B2:B10=G1)*(C2:C10=G2),0)) gives
• =INDEX(D2:D10,MATCH(1,{0;0;0;0;0;1;0;0;0},0) gives
• =INDEX(D2:D10,6) returns
• $103, the correct result!

4) Using SUMPRODUCT

SUMPRODUCT is a powerful function in Excel. I am going to write separate posts about SUMPRODUCT later. Although SUMPRODUCT seems to work in our example, it actually fails if the result we want is text instead of value.

To understand that, we have to understand how SUMPRODUCT behaves. If you want to know more about SUMPRODUCT, stay tuned! 🙂

So, which one do I use?

Although options 2) and 3) works fine, I prefer option 1) under normal circumstance.  Why?

In daily work life, I believe it is more important to build a spreadsheet that is manageable and readable by most users (including myself)… Not every one in workplace is Excel guru. If every one is, we don’t have to spend so much time to fight with spreadsheets.

As such, let’s obey the KISS principle whenever possible.

Other topics about vlookup:

1. The basic of vlookup
2. Tips in constructing vlookup
3. vlookup with Match 
4. vlookup options – True or False?
5. Advanced vlookup – Text vs. Number
6. Advanced vlookup – Wildcard Characters “?” and “*”
7. Alternative to vlookup – Index and Match
8. Three different ways to do case-sensitive lookup

Watch Video – How to Use VLOOKUP Function with Multiple Criteria

Excel VLOOKUP function, in its basic form, can look for one lookup value and return the corresponding value from the specified row.

But often there is a need to use the Excel VLOOKUP with multiple criteria.

How to Use VLOOKUP with Multiple Criteria

Suppose you have a data with students name, exam type, and the Math score (as shown below):

Using the VLOOKUP function to get the Math score for each student for respective exam levels could be a challenge.

One can argue that a better option would be to restructure the data set or use a Pivot Table. If that works for you, nothing like that. But in many cases, you are stuck with the data that you have and pivot table may not be an option.

In such cases, this tutorial is for you.

Now there are two ways you can get the lookup value using VLOOKUP with multiple criteria.

• Using a Helper Column.
• Using the CHOOSE function.

VLOOKUP with Multiple Criteria – Using a Helper Column

I am a fan of helper columns in Excel.

I find two significant advantages of using helper columns over array formulas:

• It makes it easy to understand what’s going on in the worksheet.
• It makes it faster as compared with the array functions (noticeable in large data sets).

Now, don’t get me wrong. I am not against array formulas. I love the amazing things can be done with array formulas. It’s just that I save them for special occasions when all other options are of no help.

Coming back to the question in point, the helper column is needed to create a unique qualifier. This unique qualifier can then be used to lookup the correct value. For example, there are three Matt in the data, but there is only one combination of Matt and Unit Test or Matt and Mid-Term.

Here are the steps:

How does this work?

We create unique qualifiers for each instance of a name and the exam. In the VLOOKUP function used here, the lookup value was modified to $F3&”|”&G$2 so that both the lookup criteria are combined and are used as a single lookup value. For example, the lookup value for the VLOOKUP function in G2 is Matt|Unit Test. Now this lookup value is used to get the score from C2:D19.

Clarifications:

There are a couple of questions that are likely to come to your mind, so I thought I will try and answer it here:

• Why have I used | symbol while joining the two criteria? – In some exceptionally rare (but possible) conditions, you may have two criteria that are different but ends up giving the same result when combined. Here is a very simple example (forgive me for my lack of creativity here):

Note that while A2 and A3 are different and B2 and B3 are different, the combinations end up being the same. But if you use a separator, then even the combination would be different (D2 and D3).

• Why did I insert the helper column between column B and C and not in the extreme left? – There is no harm in inserting the helper column to the extreme left. In fact, if you don’t want to temper with the original data, that should be the way to go. I did it as it makes me use less number of cells in the VLOOKUP function. Instead of having 4 columns in the table array, I could manage with only 2 columns. But that’s just me.

Now there is no one size that fits all. Some people may prefer to not use any helper column while using VLOOKUP with multiple criteria.

So here is the non-helper column method for you.

Download the Example File

VLOOKUP with Multiple Criteria – Using the CHOOSE Function

Using array formulas instead of helper columns saves you worksheet real estate, and the performance can be equally good if used less number of times in a workbook.

Considering the same data set as used above, here is the formula that will give you the result:

=VLOOKUP($E3&”|”&F$2,CHOOSE({1,2},$A$2:$A$19&”|”&$B$2:$B$19,$C$2:$C$19),2,0)

Since this is an array formula, use it with Control + Shift + Enter, instead of just Enter.

How does this work?

The formula also uses the concept of a helper column. The difference is that instead of putting the helper column in the worksheet, consider it as virtual helper data that is a part of the formula.

Let me show you what I mean by virtual helper data.

In the above illustration, as I select the CHOOSE part of the formula and press F9, it shows the result that the CHOOSE formula would give.

The result is {“Matt|Unit Test”,91;”Bob|Unit Test”, 52;……}

It’s an array where a comma represents next cell in the same row and semicolon represents that the following data is in the next column. Hence, this formula creates 2 columns of data – One column has the unique identifier and one has the score.

Now, when you use the VLOOKUP function, it simply looks for the value in the first column (of this virtual 2 column data) and returns the corresponding score.

Download the Example File

You can also use other formulas to do a lookup with multiple criteria (such as INDEX/MATCH or SUMPRODUCT).

Is there any other way you know to do this? If yes, do share with me in the comments section.

You May Also Like the Following LOOKUP Tutorials:

• VLOOKUP Vs. INDEX/MATCH
• Get Multiple Lookup Values Without Repetition in a Single Cell.
• How to make VLOOKUP Case Sensitive.
• Use IFERROR with VLOOKUP to Get Rid of #N/A Errors.