Длинные гиперссылки в excel

Здравствуйте.

Прошу меня сильно не пинать ногами, так как я не программер и в терминологии не очень. Поиск поюзал, но не нашёл ответ на свой вопрос, а может и не понял написанного… 

А вопрос вот какой: У меня есть созданная таблица. Скажем — в первом столбце, подряд у меня идут номера: 1000, 1001, 1002, 1003 и  так далее. В определённой папке, есть фотографии, которые имеют точно такие же номера — 1000, 1001, 1002 и т.д.

Цель — надо каждому номеру в таблице присвоить гиперссылку с соответствующим номером фотографии. Тыкать каждый раз номер и присваивать ему гиперссылку — слишком затратно по времени и трудоёмко. Вопрос — существует ли какой-нибудь автоматизированный или более облегчённый способ?

Большое спасибо, за ответ — если таковые будут. Ну а если ответ будет из разряда — «Для чайников», с меня ПИВО.

Прекрасно. Большое спасибо — всё вроде работает. А позвольте ещё один вопрос. Теперь у меня в ячейке В2 (в ячейке с гиперссылкой) слишком длинное и большое имя. Как это можно преобразовать в нечто более читаемое.

Скажем в ячейке у меня: =ГИПЕРССЫЛКА(«W:ДОКУМЕНТЫБаза — новоеФотографии»&A134&».jpg»).
А хочу, чтобы было: ФОТО или просто номер какой-нибудь.

Большущщее спасибо.

А… э…. а можно поподробней — чо делать то надо?

Спасибо ещё раз….

Здорово…. всё работает даже у такого пня как я. Ребза — вы просто кудесники.

Спасибо Вам огромное.

Ребяты — всем здрасти. Я снова с вопросом…. если позволите.

Мыше указанный способ присвоения ссылок работает. Но в процессе создания базы появилась необходимость всю папку переместить на другой ресурс. При перемещении адрес места хранения (а точнее диск) изменился и ссылки стали не действувющими…. то есть фотки не открываются.

Вопрос. Как с этим бороться? Может можно вставлять плавающую ссылку, чтобы при перемещении ссыла оставалась рабочей?

И ещё попутно один вопрос, правда не в тему — прошу меня сильно не пинать: Скажем так — я делаю в экселе базу данных с большим количеством листов (то есть страниц с ярлычками которые). Дык вот, периодически проскакивают некоторые одинаковые данные, но на разных страницах. Есть ли в экселе возможность их как нибудь отследить? Или может быть отсортировать, но в автоматическом режиме, чтобы потом удалить?

Маленькое уточнение — нужно не просто сравнить значения в двух столбах, а скажем по заданным параметрам отыскать схожее значение во всей книге…..

Большое спасибо.

Ясно. Кстати по поводу поиска одинаковых значений во всей книге — уже после того как написал вопрос до меня дошло, что можно попробовать поискать с помощью встроенного поисковика….. и это вполне устраивает….

Но всё равно — большое спасибо.

А вот по поводу невозможности плавающей ссылки — плохо, что нельзя….. а то получается что делаю базу у себя на компе, а потом её надо будет переносить — придётся все ссылки заменять вручную….. а это порядка 500 000 с разными параметрами и на разных листах…..

Выход один — купить флешку, заделать базу там и отдать пользователям вместе с флешкой…..

Да, конечно.

То есть это выглядит следующим образом — скажем есть папка с названием «1». В этой папке есть файл — «база» и папка с фотками — «фотки», где все фотографии и слиты…..

Цитата: _Boroda_ от 03.04.2010, 02:14
Насчет плавающей ссылки — у меня работает такая (2003 Excel):=ГИПЕРССЫЛКА(ИНФОРМ("каталог")&A2&".jpg";"Фото_"&A2)

в А2 название файла (например 1001)

Точно не помню, но вроде читал, что в 2007 у функции ИНФОРМ убрали аргумент «каталог». У кого 2007 — проверьте пожалуйста.

Еще такая формула:

=ГИПЕРССЫЛКА(ЛЕВСИМВ(ЯЧЕЙКА("имяфайла");ПОИСК("[";ЯЧЕЙКА("имяфайла"))-1)&A2&".jpg";"Фото_"&A2)

см. вложение

Подскажи пожайлусто, а чтоб не на фото гиперссылку, а на папки с именами ячеек, что нужно подправить???

Цитата: _Boroda_ от 18.01.2012, 09:40
Нужно ж было написать нормально
Из другой Вашей темы

ЦитироватьПроблема вот в чем: есть файл Excel со списком(более 3000 наименований) и есть папка в которой созданы подпапки с именами как в столбце D файла Excel, необходимо чтобы список столбца D стал гиперссылками на папки с такими же названиями.

=ГИПЕРССЫЛКА($E$1&""&D2;D2)
в ячейке Е1 путь к папкам
см. вложение

Извеняюсь за неправельно поставленный вопрос.
Спасибо большое за пример эт значительно облегчит мою работу!!!!!

Содержание

1. Что такое гиперссылка
2. Абсолютные и относительные гиперссылки в Excel
3. Абсолютные гиперссылки
4. Относительные гиперссылки
5. Как создать гиперссылку в Excel
6. Как создать гиперссылку в Excel на другой документ
7. Как создать гиперссылку в Excel на веб-страницу
8. Как создать гиперссылку в Excel на конкретную область в текущем документе
9. Как создать гиперссылку в Excel на новую рабочую книгу
10. Как создать гиперссылку в Excel на создание Email
11. Как редактировать гиперссылку в Excel
12. Как отформатировать гиперссылку в Excel
13. Как удалить гиперссылку в Excel

Больше лайфхаков в нашем Telegram Подписаться

Как использовать более 255 символов в функции СЦЕПИТЬ в Excel? На самом деле я также использую функцию СЦЕПИТЬ в функции ГИПЕРССЫЛКА в EXCEL. Пример выглядит так:

=HYPERLINK(CONCATENATE("http://www.google/com/morethan255charsmorethan255charsmorethan255charsmorethan255charsmorethan255charsmorethan255charsmorethan255charsmorethan255charsmorethan255charsmorethan255chars","morethan255chars morethan255charsmorethan255charsmorethan255charsmorethan25"),"link");

ОБНОВЛЕНИЕ: это не проблема с функцией СЦЕПИТЬ, а проблема с первым параметром функции ГИПЕРССЫЛКА. Использование строки длиной более 255 символов прямо / косвенно (например: = ГИПЕРССЫЛКА (K204, «ссылка»), где K204 содержит ссылку длиной 256 символов) приводит к сбою функции ГИПЕРССЫЛКА.

Я понимаю, что могу использовать укорочитель URL-адресов, но я делаю это для МНОГО ссылок, которые потребуют ВСЕГО ручного использования сокращателя URL-адресов.

ОБНОВЛЕНИЕ: из-за комментария Карла я пересмотрел свой ответ и обнаружил, что Excel 2007, похоже, не позволяет функциям, определяемым пользователем, больше устанавливать гиперссылки (вполне разумно, см. Мой собственный комментарий в коде). Таким образом, исходный код (под строкой) не работает в более поздних версиях Excel (я не тестировал Excel 2010, но предполагаю, что результат такой же). По историческим причинам я не удаляю старый код (редактор может подумать иначе — не стесняйтесь редактировать / удалять соответственно).

Остается установить длинные гиперссылки программно, например

Sub insertVeryLongHyperlink()

    Dim curCell As Range
    Dim longHyperlink As String

    Set curCell = Range("A1")   ' or use any cell-reference
    longHyperlink = "http://www.veryLongURL.com/abcde"  ' Or a Cell reference like [C1]

    curCell.Hyperlinks.Add Anchor:=curCell, _
                    Address:=longHyperlink, _
                    SubAddress:="", _
                    ScreenTip:=" - Click here to follow the hyperlink", _
                    TextToDisplay:="Long Hyperlink"

End Sub

Следующее больше не работает в Excel 2010; см. мой комментарий выше

«Скопировать гиперссылку из Word и вставить в Excel» заставило меня задуматься. Таким образом, очевидно, что ограничение есть как во встроенной функции ГИПЕРССЫЛКИ, так и в диалоговом окне «редактировать гиперссылку». С другой стороны, должно быть — и это действительно возможно — установить более длинные гиперссылки через VBA.

Этот код больше не работает в Excel 2010

Function myHyperlink(cell As Range, _
                        hyperlinkAddress As String, _
                        Optional TextToDisplay As Variant, _
                        Optional ScreenTip As Variant)

    ' Inserts a Hyperlink
    '   at the position     cell (this should be the position where the UDF is used,
    '                       since the return value of the UDF is = TextToDisplay)
    '   with the            hyperlinkAddress
    '   optional            TextToDisplay
    '   optional            ScreenTip

    ' #######################################
    ' Warning Warning Warning Warning Warning
    ' #######################################

    ' 1) Since it is really bad practice to have a function perform procedural
    '    tasks, you should not do this.
    ' 2) You have no garantee, the link is updated when the value hyperlinkAddress changes

    ' USE AT YOUR ONE RISK AND ONLY IN CASE OF EMERGENCIES :-)


    ' If more than one cell is selected as target range,
    ' use the top left cell
    Set cell = cell.Resize(1, 1)

    If IsMissing(TextToDisplay) Then
        TextToDisplay = hyperlinkAddress
    End If

    If IsMissing(ScreenTip) Then
        ScreenTip = hyperlinkAddress & " - Click here to follow the hyperlink"
    End If

    cell.Hyperlinks.Add Anchor:=ActiveCell, _
                        Address:=hyperlinkAddress, _
                        SubAddress:="", _
                        ScreenTip:=ScreenTip, _
                        TextToDisplay:=TextToDisplay

    ' There doesn't seem to be another way to set TextToDisplay
    myHyperlink = TextToDisplay

End Function

Используйте как обычную функцию Excel, но обязательно добавьте текущую ячейку в качестве первого параметра (т.е. следующая формула вставляется в ячейку A1)

=myHyperlink(A1,B1)
=myHyperlink(A1,B1,"TextToDisplay", "ScreenTip")

Вы не можете ни перетащить формулу, ни скопировать ее в другую ячейку. Если вы это сделаете, вам нужно разрешить пересчет формулы (ни ALT-CTRL-F9, ни ALT-CTRL-SHIFT-F9, поскольку принудительный пересчет, похоже, не работают), поэтому войдите в каждую ячейку, нажмите F2, чтобы активировать ее, и закончите с Return.

Надеюсь, я не помогу вам испортить слишком много Excel-Workbooks.

Вероятно, безопаснее написать явно запускаемый VBA, который выполняет итерацию по списку и записывает в гиперссылки. Таким образом, их можно использовать повторно, и в них не будет никаких функций.

С уважением, Андреас

Возможно, вам не повезло. Кажется, что ограничение на количество символов для гиперссылок в Excel составляет 256, как указано здесь . Если вы проверите это самостоятельно (у меня тоже есть Excel 2007), =HYPERLINK(REPT("a",255)) работает, а =HYPERLINK(REPT("a",256)) — нет, и выдает ошибку #VALUE! .

У меня есть Excel 2007, и я попытался создать ячейку с 300 символами в A1 и другую с 300 разными символами в B1.

Затем я сделал C1 = CONCATENATE(A1, B1).

Я вижу всех персонажей из обеих ячеек. Ничего не пропущено или усечено, и ошибок не было. Мне это нравится.

Что заставляет вас думать, что конкатенация не работает? У вас проблемы с просмотром результатов? Если ваша ячейка содержит более 1024 символов, в ячейке отображаются только первые 1024 символа. Однако они все еще там, и если вы скопируете и вставите их, все символы будут скопированы.

Изменить: Теперь, когда вы отредактировали свой вопрос, я понимаю, что проблема связана с HYPERLINK, а не с CONCATENATE.

Единственный способ обойти ограничение в 255 символов формулы HYPERLINK в Excel — скопировать гиперссылку из Word и вставить ее в ячейку Excel. Тогда это может быть очень долго. Я знаю, что это необоснованный ручной процесс, если у вас много ссылок, но кажется, что это единственный способ поместить его в электронную таблицу Excel и при этом все еще иметь гиперссылку, по которой можно щелкнуть и перенаправить. Если вам не нужно, чтобы он действовал как гиперссылка, я бы предложил переписать ваши запросы, чтобы гиперссылка возвращалась в виде собственного текстового поля, и тогда все будет в порядке.

Вот пример VBA, который использует bitly.com для сокращения URL-адреса. Он основан на документации bitly API.

1. Создайте бесплатную учетную запись на bitly.
2. Действительный адрес электронной почты с bitly.
3. Получите токен доступа от bitly.
4. Замените токен доступа в коде VBA ниже, где написано MY_TOKEN.
5. Скопируйте и вставьте код в Excel VBA.
6. В ячейке напишите следующее ‘= Hyperlink (GetURL («какой-то действительно длинный URL»))’ без одинарных кавычек ‘. Примечание. Вместо передачи строки в GetURL () передайте ссылку на ячейку, в которой есть URL-адрес в виде текста.

Public Function GetURL(longUrl As String) As String
  Dim xml As Object

  longUrl = URLEncode(longUrl)
  Set xml = CreateObject("MSXML2.XMLHTTP.6.0")

  xml.Open "GET", "https://api-ssl.bitly.com/v3/shorten?format=xml&access_token=MY_TOKEN=" & longUrl, False
  xml.Send

  GetURL = xml.responsetext

  head = InStr(GetURL, "<url>") + 5
  tail = InStr(GetURL, "</url>")

  GetURL = Mid(GetURL, head, tail - head)

End Function

Function URLEncode(ByVal Text As String) As String
  Dim i As Integer
  Dim acode As Integer
  Dim char As String
  URLEncode = Text
  For i = Len(URLEncode) To 1 Step -1
    acode = Asc(Mid$(URLEncode, i, 1))
    Select Case acode
      Case 48 To 57, 65 To 90, 97 To 122
        ' don't touch alphanumeric chars
      Case 32
        ' replace space with "+"
        Mid$(URLEncode, i, 1) = "+"
      Case Else
        ' replace punctuation chars with "%hex"
        URLEncode = Left$(URLEncode, i - 1) & "%" & Hex$(acode) & Mid$(URLEncode, i + 1)
    End Select
  Next
End Function

Не знаю, если мой ответ все еще полезен, но у меня была такая же проблема пару дней назад, лучший способ и проверенный способ сделать работоспособную гиперссылку, превышающую ограничение в 255 символов, — сначала разделить ее с помощью CONCATENATE() и использовать ячейка с функцией CONCATENATE() в VBA .

Для меня это выглядит так:

A1 = LinkPart1
A2 = LinkPart2
A3 = LinkPart3

A5 = CONCATENATE( A1; A2; A3 )

VBA Код, который необходимо связать с A5 :

Sub insertVeryLongHyperlink()

    Dim curCell As Range
    Dim longHyperlink As String

    Set curCell = Range("A7")   ' or use any cell-reference
    longHyperlink = [A5]

    curCell.Hyperlinks.Add Anchor:=curCell, _
                    Address:=longHyperlink, _
                    SubAddress:="", _
                    ScreenTip:=" - Click here to follow the hyperlink", _
                    TextToDisplay:="Click Here"

    End Sub

Вместо того чтобы писать

=CONCATENATE("Toto";"Tata")

Поместите Toto в ячейку Z1 (например) и Tata в ячейку Z2 и напишите

=CONCATENATE(Z1;Z2)

Функция гиперссылки имеет жесткий предел, который нельзя переступить. У меня была аналогичная проблема, и я просто импортировал лист Excel в Open Office Calc и вуаля — все сработало мгновенно, и гиперссылка, которая раньше была слишком долгой, теперь может существовать столько, сколько я хотел.

Вы можете использовать процедуру VBA Shell () для запуска браузера и передачи ему URL-адреса в командной строке, переданной через вызов Shell (). Таким образом, URL-адрес может иметь любую длину, поддерживаемую механизмом оболочки.

Кроме того, вы можете получить этот URL-адрес из любого значения ячейки, дважды щелкнув эту ячейку пользователем. Это значение может быть создано из множества ячеек с помощью одного вызова функции CONCATENATE ()! Правильно: всего один звонок. CONCATENATE () примет большое количество параметров и создаст строку длиной более 255 символов. Вам не нужно кропотливо объединять множество отдельных конкатенаций или использовать множество ячеек-строителей. Подойдет один!

Макрос необходимо создать, открыв параметр ПРОСМОТР КОДА, когда вы щелкаете правой кнопкой мыши вкладку в нижней части рабочего листа. Затем напишите следующий феноменально короткий, простой и безболезненный фрагмент кода:

Option Explicit             
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)               
   If Selection.Count = 1 Then              
      If Left(Target.Value, 7) = "HTTP://" Then             
         Cancel = True              
         Shell ("""" + Range("Browser").Value + """" + " " + """" + Target.Value + """")                
      End If                
   End If               
End Sub     

Обратите внимание, что «Браузер» — это именованная ячейка, которая должна содержать путь вашего браузера без кавычек, будь то IE, Opera, Mozilla или Chrome. Вы должны назвать ячейку самостоятельно или изменить макрос, чтобы он имел жесткую ссылку на ячейку, например «A2». И, конечно же, это значение ячейки должно быть допустимым путем в браузере!

После того, как все это будет готово, вы можете дважды щелкнуть ЛЮБУЮ ячейку, значение которой начинается с текста «HTTP: //», и Excel откроет браузер с этим полным значением, независимо от его длины. Все, что вам затем нужно, это построить свою строку в этой ячейке и, возможно, отформатировать ее по цвету / шрифту, чтобы было очевидно, что это ячейка гиперссылки, которую нужно дважды щелкнуть. Текстовая подсказка рядом также может быть уместна!

Кстати, альтернативой строке Shell () в макросе является:

ThisWorkbook.FollowHyperlink Address:=Target.Value 

Хотя это также будет обрабатывать URL-адреса, длина которых превышает 255 символов, я обнаружил, что эта функция FollowHyperlink () вызывает отправку URL-адреса ДВАЖДЫ. Один раз самой функцией Excel (предположительно, чтобы проверить ее), а затем снова браузером по умолчанию, который открывается в Excel! Это может быть нежелательно (и не в моем случае). Вот почему я решил использовать вместо этого функцию Shell ().

Вы можете создать гиперссылку в Microsoft Word, а затем скопировать ее в Excel. По какой-то причине эти элементы гиперссылки не ограничены 255 символами, но вы не сможете использовать функцию HYPERLINK().

Источник

Предполагая, что у вас не так много URL-адресов гиперссылок> 255 символов, просто используйте функцию Link. Функция ссылки доступна из контекстного меню. Нет необходимости переходить в Word или любое другое приложение MSOffice. Я знаю, что это работает, поскольку у меня есть URL-адрес длиной 281 символ, и этот работает. У меня есть только два очень длинных URL-адреса в моем листе, поэтому, когда / если они нуждаются в обновлении, я отмечаю, что они должны быть выполнены в целевой ячейке, а не в моем листе адресов гиперссылок.

Отработав ответ Андреаса Дж., вы можете использовать приведенный ниже фрагмент кода VBA для создания столбца гиперссылок из столбца простого -текстовые URI. Предполагая, что столбец A содержит URI в виде обычного текста, а столбец B содержит желаемый текст ссылки, следующий код проходит через каждую строку в Range("A:C") и генерирует гиперссылку в столбце C:

Sub createLink(a As Range, b As Range, c As Range)
    Dim curCell As Range
    Dim longHyperlink As String
    Dim linkText As String

    Set curCell = a
    longHyperlink = b
    linkText = c

    curCell.Hyperlinks.Add Anchor:=curCell, _
                    Address:=longHyperlink, _
                    SubAddress:="", _
                    ScreenTip:="", _
                    TextToDisplay:=linkText
End Sub

Sub insertLinks()
    Dim a As Range, b As Range
    Set a = Range("A:C")
    
    For Each b In a.Rows
        Dim curCell As Range, longHyperlink As Range, linkText As Range
        Set curCell = b.Cells().Item(1, 3)
        Set longHyperlink = b.Cells().Item(1, 1)
        Set linkText = b.Cells().Item(1, 2)
        
        If longHyperlink = "" Then
            Exit For
        End If
        createLink curCell, longHyperlink, linkText
    Next
End Sub