Диаграмма топ 10 в excel

Сегодня мы научимся создавать список Топ 10. В качестве исходного материала мы будем использовать список продуктов с соответствующим количеством продаж по каждому продукту за выбранный период времени.

То, что мы хотим получить в конце — это сгенерированный список из 10 самых продаваемых товаров. Также мы хотим, что бы этот список автоматически обновлялся при каждом изменении количества продаж товаров и мы не хотим использовать VBA макросы для упрощения задачи.

Пожалуйста скачайте пример по ссылке ниже, что бы было проще понять те действия, которые будут описаны ниже:

Скачать пример.

Первый этап.

Во-первых, давайте отсортируем все продажи по убыванию и выберем 10 лучших.
Для этого я решил использовать функцию НАИБОЛЬШИЙ. 
Наша формула выглядит следующим образом:

=НАИБОЛЬШИЙ($C$4:$C$19;СТРОКА(ДВССЫЛ(«1:»&ЧСТРОК($C$4:$C$19))))

где C4:C19 это диапазон с количеством реализованных продуктов.
В результате мы получаем лист Топ-10 продаж. Далее, более сложная часть.

Второй этап.

Как назначить названия продуктов номерам?
Если Вы уверены, что количество проданных товаров

никогда не будет одинаковым

(т.е. не будет повторяющихся значений),  то мы можем использовать функции ИНДЕКС и ПОИСКПОЗ для поиска соответствующего наименования продукта выбранному количеству продаж.
Наша формула может выглядеть следующим образом:

=ИНДЕКС($B$4:$B$19;ПОИСКПОЗ(F4;$C$4:$C$19;0);1)

И она будет работать отлично.

Но, если количество продаж может повторяться, то предыдущая формулы будет возвращать одинаковое наименование продукта для каждого повторяющегося числа.Это явно не то, что мы хотим получить.Поэтому мы будем использовать несколько другой подход.

Для первого продукта мы воспользуемся формулой:

=ИНДЕКС($B$4:$B$19;ПОИСКПОЗ(F4;$C$4:$C$19;0);1)

А для последующих названий продуктов, будем использовать следующую формулу:

=ДВССЫЛ(«Лист1!»&АДРЕС(НАИМЕНЬШИЙ(ЕСЛИ(Лист1!$C$4:$C$19=F5;СТРОКА(Лист1!$B$4:$B$19);65536);СЧЁТЕСЛИ(F4:F5;F5));2))

Протягиваем эту формулу для всех оставшихся ячеек.

Как Вы можете видеть в приложенном файле, это решение отлично работает и дает нужный результат.

Обратите внимание на фигурные скобки перед и после формулы. Эти скобки обозначают что формула применена для массива. Что бы Вам добиться такого же результата, то внесите в ячейку формулу, а после нажмите комбинацию клавиш Ctrl+Shift+Enter.

При каждом изменении количества проданных товаров, перечень Топ-10 продаж будет автоматически перестраиваться.

Наслаждайтесь!

Список лучших используется для ранжирования компаний или отдельных лиц на основе ценностей. Предположим, у вас есть список оценок учеников класса, теперь вы хотите создать динамический список 10 лучших учеников, как показано ниже. В этой статье я представлю некоторые формулы для создания списка 10 лучших или n на листе Excel.

Создайте динамический список 10 лучших в Excel

В Excel 2019 и более ранних версиях, чтобы извлечь список 10 лучших или список 10 лучших с критериями, вы должны применить следующие формулы:

Формулы для создания динамического списка 10 лучших

1. Во-первых, вы должны извлечь первые 10 значений из диапазона данных, используйте приведенную ниже формулу в пустой ячейке — G2 и перетащите маркер заполнения вниз, чтобы получить первые 10 значений, см. снимок экрана:

=LARGE($B$2:$B$20,ROWS(B$2:B2))

Внимание: В этой формуле B2: B20 это список данных, из которого вы хотите получить первые 10 значений, и B2 это первая ячейка списка данных.

2. Затем продолжайте применять следующую формулу в ячейке — F2 и нажмите Shift + Ctrl + Enter вместе, чтобы получить первый результат, см. снимок экрана:

=INDEX($A$2:$A$20,SMALL(IF($B$2:$B$20=G2,ROW($B$2:$B$20)-ROW($B$1)),COUNTIF($G$2:G2,G2)))

Внимание: В приведенной выше формуле A2: A20 это список данных, из которого вы хотите получить имена первых 10 значений, B2: B20 список данных, содержащий все значения, G2 это ячейка с наибольшим значением, извлеченным из столбца B и B1 является ячейкой заголовка списка значений.

3. Получив первый результат, выберите ячейку формулы и перетащите дескриптор заполнения вниз, чтобы сразу получить другие имена, см. снимок экрана:

Формулы для создания динамического списка 10 лучших с критериями

Иногда вам может понадобиться получить список 10 лучших на основе критериев. Например, чтобы получить 10 лучших имен и оценок Class1, как показано ниже.

1. Чтобы получить список 10 лучших, вам также необходимо извлечь 10 лучших результатов с помощью этой формулы:

=LARGE(IF($B$2:$B$25=$F$2,$C$2:$C$25),ROW(I2)-ROW(I$1))

2, Затем нажмите Shift + Ctrl + Enter клавиши вместе, чтобы получить первый результат, затем перетащите эту формулу вниз, чтобы отобразить другие значения, см. снимок экрана:

3. Затем скопируйте и вставьте следующую формулу в ячейку — I2 и нажмите Shift + Ctrl + Enter клавиши одновременно, чтобы извлечь первый результат, а затем перетащите эту формулу, чтобы заполнить ее в другие ячейки, и 10 лучших имен отображаются, как показано ниже:

=INDEX($A$2:$A$25,SMALL(IF(($C$2:$C$25=J2)*($B$2:$B$25=$F$2),ROW($C$2:$C$25)-ROW($C$1)),COUNTIF(J2:$J$2,J2)))

Создайте динамический список 10 лучших в Office 365

Нам может быть сложно понять приведенные выше формулы, если вы используете Office 365 с его функциями ИНДЕКС, СОРТИРОВКА и ПОСЛЕДОВАТЕЛЬНОСТЬ, вы можете создать простые формулы для выполнения этой задачи.

Формула для создания динамического списка 10 лучших

Чтобы получить список данных10, используйте приведенную ниже формулу:

=INDEX(SORT(A2:B20,2,-1),SEQUENCE(10),{1,2})

А затем просто нажмите Enter ключ, все данные из списка 10 лучших отображаются сразу, см. снимок экрана:

Формула для создания динамического списка 10 лучших с критериями

Чтобы отобразить список 10 лучших с критериями, вы должны встроить функцию ФИЛЬТР в функцию СОРТИРОВКИ следующим образом:

=INDEX(SORT(FILTER(A2:C25,B2:B25=F2),3,-1),SEQUENCE(10),{1,3})

И просто нажмите Enter ключ, все данные списка 10 лучших по заданным критериям отображаются сразу, см. снимок экрана:

Всем привет, помогите упростить работу, сейчас я переношу проценты вручную и строю график топ10 из них есть топ 5 которые меня всегда интересуют и 5 которые статичные, график строится от Я до А, как воплатить это до автоматизации?

К сообщению приложен файл:

1653013.xlsx
(28.4 Kb)

Помогла ли Вам статья?