Дата в userform excel

Никак не могу вставить данный код

 txt_Дата_3 = Format(Date, "dd.mm.yyyy"

в мой макрос, чтоб он автоматически выполнялся в TextBox (txt_Дата_3,txt_Дата_5,txt_Дата_7,txt_Дата_9).
Куда можно данный код вставить в макрос:

Sub vsii_1(s)
    Dim LastRow As Long
    Dim SummaStrok As Double
    Dim i As Long
    LastRow = Worksheets("ФІЛІЯ ВАСИЛЬ І ПЕТРО").Cells(Rows.Count, 1).End(xlUp).Row
    With UserForm_1
        If s = "СУМА" Then
            .TextBox2 = Application.Sum([B:B])
            For i = 4 To LastRow
                If CDate(Cells(i, 1).Value) >= CDate(.txt_Дата_2) And CDate(Cells(i, 1).Value) <= CDate(.txt_Дата_3) Then
                    SummaStrok = SummaStrok + CDbl(Cells(i, 2).Value)
                End If
            Next i
            .txt_Дата_3 = Format(Date, "dd.mm.yyyy")
            .TextBox2 = SummaStrok: SummaStrok = 0
        Else
           For i = 4 To LastRow
 If CDate(Cells(i, 1).Value) >= CDate(.txt_Дата_2) And CDate(Cells(i, 1).Value) <= CDate(.txt_Дата_3) Then
SummaStrok = SummaStrok + CDbl(Cells(i, 2).Value)
        End If
        Next i
        End If
        If UserForm_1.TextBox2.Value >= 0 Then
        If UserForm_1.TextBox2.Value >= 0 Then UserForm_1.TextBox4.Value = Val(UserForm_1.TextBox2.Value) - Val(UserForm_1.TextBox3.Value)
        End If
    End With
End Sub

Спасибо заранее.

Date Picker Calendar in Excel VBA

Oftentimes, users want to click a button and select a date. This is no different for Excel developers. Check out this ActiveX control by Microsoft that allows users to do just that. It’s a little old school looking, but actually has quite a nice feel to it.

Start by creating a userform and enabling the control by Right-clicking on the Tools menu and click Add additional tools

Now, let’s add this to the userform!

In the downloadable workbook, you’ll see the control was renamed to ‘fCal’. When you double-click the control you’ll see the following code which is the DateClick event of that control:

code snippet

This userform cleverly has two labels to store relevant info on the Userform that summoned it. 1.) The name of the userform that called it and 2.) The name of the control or textbox that needs the date sent to it.

Then, this code above loops through all userforms in your project until it finds one that matches the label for the Userform (lblUF) and the label for the textbox needed (lblCtrlName).

Also, you may need to enable Microsoft Windows Common Controls -2 6.0 (SP6) by using Tools->References and clicking:

Watch Us Make a Calendar In Excel On YouTube:

A calendar form can be used as an alternative to the date picker.
On a userform example, I used this calendar form to add dates to text boxes. When double-clicked on the textbox, the calendar form is displayed :

Private Sub txtDOTDate_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
Call GetCalendar
End Sub

Sub GetCalendar()
    dateVariable = CalendarForm.GetDate(DateFontSize:=11, _
        BackgroundColor:=RGB(242, 248, 238), _
        HeaderColor:=RGB(84, 130, 53), _
        HeaderFontColor:=RGB(255, 255, 255), _
        SubHeaderColor:=RGB(226, 239, 218), _
        SubHeaderFontColor:=RGB(55, 86, 35), _
        DateColor:=RGB(242, 248, 238), _
        DateFontColor:=RGB(55, 86, 35), _
        TrailingMonthFontColor:=RGB(106, 163, 67), _
        DateHoverColor:=RGB(198, 224, 180), _
        DateSelectedColor:=RGB(169, 208, 142), _
        TodayFontColor:=RGB(255, 0, 0))
If dateVariable <> 0 Then frmflightstats.txtDOTDate = dateVariable
End Sub

Source of template

Some fraction of a follow-up to The half-finished version.

What’s changed: Added year as well as Day/Month. Added input Validation. Implemented a poor man’s .EnableEvents = false for UserForms. Re-jigged the event heirarchy (Change year —> Repopulate Months or Days, Change Months —> Repopulate Days).

As always, all feedback welcomed.

In particular, if you were given this code to maintain, what would you be thinking as you read through it?

Initialisation and populating control values:

Option Explicit

Private Userform_EnableEvents As Boolean

Private Sub UserForm_Initialize()

    Userform_EnableEvents = True

    PopulateYearBox Me.UF_BankRec_cbx_Year

End Sub

Private Sub PopulateYearBox(ByRef yearBox As MSForms.ComboBox)
    DisableFormEvents

        Dim ixYear As Long

            For ixYear = 2000 To Year(Now)
                yearBox.AddItem ixYear
            Next ixYear

    EnableFormEvents
End Sub

Private Sub PopulateMonthBox(ByRef monthBox As MSForms.ComboBox, ByVal yearText As String)
    DisableFormEvents

    Dim ixYear As Long
        ixYear = CLng(yearText)

    Dim monthText As String
        monthText = monthBox.Text

    Dim ixMonth As Long, ixFinalMonth As Long
        If ixYear = Year(Now) Then
            ixFinalMonth = Month(Now)
        Else
            ixFinalMonth = 12
        End If

        monthBox.Clear
        For ixMonth = 1 To ixFinalMonth
            monthText = MonthName(ixMonth)
            monthBox.AddItem monthText
        Next ixMonth

    EnableFormEvents
End Sub

Private Sub PopulateDayBox(ByRef dayBox As MSForms.ComboBox, ByVal monthText As String, ByVal yearText As String)
    DisableFormEvents

    Dim dateCounter As Date, startDate As Date
        startDate = CDate("01/" & monthText & "/" & yearText)

        dateCounter = startDate
        dayBox.Clear
        dayBox.AddItem Day(dateCounter)
        dateCounter = dateCounter + 1
        Do While Month(dateCounter) = Month(dateCounter - 1)
            dayBox.AddItem Day(dateCounter)
            dateCounter = dateCounter + 1
        Loop

    EnableFormEvents
End Sub

Value_Change event triggers

Private Sub UF_BankRec_cbx_Year_Change()
    If Userform_EnableEvents Then

        DisableFormEvents

        Dim dayBox As MSForms.ComboBox
        Set dayBox = Me.UF_BankRec_cbx_EndDay

        Dim monthBox As MSForms.ComboBox
        Set monthBox = Me.UF_BankRec_cbx_Month

        Dim monthText As String
            monthText = monthBox.Text

        Dim yearText As String, ixYear As Long
            yearText = Me.UF_BankRec_cbx_Year.Text
            ixYear = CLng(yearText)

            If monthBox.ListCount <> 12 Or ixYear = Year(Now) Then
                PopulateMonthBox monthBox, yearText
            Else
                PopulateDayBox dayBox, monthText, yearText
            End If

        EnableFormEvents

    End If
End Sub

Private Sub UF_BankRec_cbx_Month_Change()
    If Userform_EnableEvents Then
        DisableFormEvents

        Dim dayBox As MSForms.ComboBox
        Set dayBox = Me.UF_BankRec_cbx_EndDay

        Dim monthBox As MSForms.ComboBox
        Set monthBox = Me.UF_BankRec_cbx_Month

        Dim yearBox As MSForms.ComboBox
        Set yearBox = Me.UF_BankRec_cbx_Year

        Dim monthText As String
            monthText = monthBox.Text

        Dim yearText As String
            yearText = yearBox.Text


            If yearBox.Text <> "" Then
                dayBox.Clear
                PopulateDayBox dayBox, monthText, yearText
            End If

        EnableFormEvents
    End If
End Sub

Private Sub DisableFormEvents()

    Userform_EnableEvents = False

End Sub

Private Sub EnableFormEvents()

    Userform_EnableEvents = True

End Sub

Exit Point

Private Sub UF_BankRec_btn_RetrieveData_Click()

    Dim yearBox As MSForms.ComboBox, monthBox As MSForms.ComboBox, dayBox As MSForms.ComboBox, cellSelectionBox As RefEdit.RefEdit
    Dim yearText As String, monthText As String, dayText As String
    Dim ixYear As Long, ixMonth As Long, ixDay As Long
    Dim startDate As Date, endDate As Long

        Set yearBox = Me.UF_BankRec_cbx_Year
        Set monthBox = Me.UF_BankRec_cbx_Month
        Set dayBox = Me.UF_BankRec_cbx_EndDay
        Set cellSelectionBox = Me.UF_BankRec_ref_TitleCell

        ValidateControlInputs dayBox, monthBox, yearBox, cellSelectionBox

        yearText = yearBox.Text
        monthText = monthBox.Text
        dayText = dayBox.Text

        ixYear = Year("01/01/" & yearText)
        ixMonth = Month("01/" & monthText & "/2000")
        ixDay = CLng(dayText)

        startDate = DateSerial(ixYear, ixMonth, 1)
        endDate = DateSerial(ixYear, ixMonth, ixDay)

    Dim cellAddress As String, rngTitleCell As Range

        cellAddress = cellSelectionBox.value
        Set rngTitleCell = Range(cellAddress)

        GetBankRecData 'rngTitleCell, startDate, endDate

End Sub

Data Validation

Private Sub ValidateControlInputs(ByRef dayBox As MSForms.ComboBox, ByRef monthBox As MSForms.ComboBox, ByRef yearBox As MSForms.ComboBox, ByRef cellSelectionBox As RefEdit.RefEdit)

    ValidateDayBox dayBox

    ValidateMonthBox monthBox

    ValidateYearBox yearBox

    ValidateCellSelectionBox cellSelectionBox

End Sub

Private Sub ValidateDayBox(ByRef dayBox As MSForms.ComboBox)

    Dim dayString As String
        dayString = dayBox.Text

    Dim passedValidation As Boolean
        passedValidation = False

    Dim finalDay As Long
        finalDay = (dayBox.ListCount - 1)

    Dim strErrorMessage As String

        passedValidation = dayString <= finalDay And (dayString Like "#" Or dayString Like "##")

        If Not passedValidation Then
            strErrorMessage = "The selected day is invalid. Please select a valid date."
            PrintErrorMessage strErrorMessage
        End If

End Sub

Private Sub ValidateMonthBox(ByRef monthBox As MSForms.ComboBox)

    Dim monthString As String
        monthString = monthBox.Text

    Dim passedValidation As Boolean
        passedValidation = False

    Dim strErrorMessage As String

    Dim i As Long, strMonth As String

        passedValidation = False
        For i = 1 To 12
            strMonth = MonthName(i)
            If strMonth = monthString Then passedValidation = True
        Next i

        If Not passedValidation Then
            strErrorMessage = "Please Select a valid month"
            PrintErrorMessage strErrorMessage
        End If

End Sub

Private Sub ValidateYearBox(ByRef yearBox As MSForms.ComboBox)

    Dim yearString As String
        yearString = yearBox.Text

    Dim passedValidation As Boolean
        passedValidation = False

    Dim lngYear As Long, currentYear As Long
        lngYear = CLng(yearString)
        currentYear = Year(Now)

    Dim strErrorMessage As String

        passedValidation = lngYear >= 2000 And lngYear <= currentYear

        If Not passedValidation Then
            strErrorMessage = "Please select a valid year"
            PrintErrorMessage strErrorMessage
        End If

End Sub

Private Sub ValidateCellSelectionBox(ByRef cellSelectionBox As RefEdit.RefEdit)

    Dim cellAddress As String
        cellAddress = cellSelectionBox.Text

    Dim passedValidation As Boolean
        passedValidation = False

    Dim testRange As Variant
    Set testRange = Range(cellAddress)

    Dim strErrorMessage As String

        passedValidation = TypeName(testRange) = "Range" And testRange.Count = 1

        If Not passedValidation Then
            strErrorMessage = "Please select a valid cell address"
            PrintErrorMessage strErrorMessage
        End If

End Sub