Цвет диаграммы к цвету ячеек в excel

Цвет диаграммы из ячеек с ее данными

Постановка задачи

Хотелось бы, чтобы столбцы на гистограмме (или дольки на круговой и т.п.) автоматически имели тот цвет, который был использован для заливки соответствующих им ячеек с исходными данными:

Предвосхищая удивленно-возмущенные крики отдельных товарищей, надо отметить, что, конечно же, цвет заливки на диаграмме можно менять и вручную (правой кнопкой по столбцу — Формат точки/ряда данных (Format data point/series) и т.д. — никто не спорит. Но на практике случается куча ситуаций, когда проще и удобнее сделать это непосредственно в ячейках с данными, а диаграмма потом должна перекраситься уже автоматически. Попробуйте, например, задать заливку по регионам для столбцов на этой диаграмме:

Думаю, вы поняли идею, да?

Решение

Ничем, кроме как макросом, такое реализовать не получится. Поэтому открываем Редактор Visual Basic с вкладки Разработчик (Developer — Visual Basic Editor) или нажимаем сочетание клавиш Alt+F11, вставляем новый пустой модуль через меню Insert — Module и копируем туда текст вот такого макроса, который и будет делать всю работу:

Sub SetChartColorsFromDataCells()

    If TypeName(Selection) <> "ChartArea" Then
        MsgBox "Сначала выделите диаграмму!"
        Exit Sub
    End If
    Set c = ActiveChart
    For j = 1 To c.SeriesCollection.Count
        f = c.SeriesCollection(j).Formula
        m = Split(f, ",")
        Set r = Range(m(2))

        For i = 1 To r.Cells.Count
            c.SeriesCollection(j).Points(i).Format.Fill.ForeColor.RGB = _
                r.Cells(i).Interior.Color
        Next i
    Next j
End Sub

Теперь можно закрыть Visual Basic и вернуться в Excel. Использовать созданный макрос очень просто. Выделите диаграмму (область диаграммы, а не область построения, сетку или столбцы!):

и запустите наш макрос с помощью кнопки Макросы на вкладке Разработчик (Developer — Macros) или с помощью сочетания клавиш Alt+F8. В том же окне можно, в случае частого использования, назначить макросу сочетание клавиш с помощью кнопки Параметры (Options).

P.S.

Единственной ложкой дегтя остается невозможность применения подобной функции для случаев, когда цвет ячейкам исходных данных назначается с помощью правил условного форматирования. К сожалению, Visual Basic не имеет встроенных средств для считывания таких цветов. Есть, конечно, определенные «костыли», но работают они не для все случаев и не во всех версиях.

Ссылки по теме

• Что такое макросы, как их использовать, куда вставлять код макросов на Visual Basic
• Условное форматирование в Excel 2007-2013
• Новые возможности диаграмм в Excel 2013

Обычно при создании диаграммы по умолчанию используется цвет полосы столбца. Если вам нужно отформатировать цвет с заливкой на каждой панели на основе цветов ячеек, как показано на следующем снимке экрана, как вы могли бы решить эту проблему в Excel?

Раскрасьте диаграмму с одним или несколькими сериями данных в зависимости от цвета ячеек с помощью кодов VBA

Раскрасьте диаграмму с помощью одного или нескольких рядов данных в зависимости от цвета ячеек с помощью удивительной функции

Раскрасьте диаграмму с одним или несколькими сериями данных в зависимости от цвета ячеек с помощью кодов VBA

Раскрасьте диаграмму одной серией данных в зависимости от цвета ячейки

С помощью следующего кода VBA вы можете быстро изменить цвет диаграммы, которая содержит одну серию данных на основе исходного цвета значений ячеек, сделайте следующее:

1. Сначала создайте гистограмму или столбчатую диаграмму, как показано на следующем снимке экрана (выберите данные и нажмите Вставить > Вставить столбец или гистограмму):

2. Удерживайте ALT + F11 , чтобы открыть Microsoft Visual Basic для приложений окно.

3. Нажмите Вставить > Модулии вставьте следующий код в окно модуля.

Код VBA: цветные полосы диаграммы с одной серией данных в зависимости от цвета ячейки:

Sub ColorChartColumnsbyCellColor()
'Updateby Extendoffice
    Dim xChart As Chart
    Dim I As Long, xRows As Long
    Dim xRg As Range, xCell As Range
    On Error Resume Next
    Set xChart = ActiveSheet.ChartObjects("Chart 1").Chart
    If xChart Is Nothing Then Exit Sub
    With xChart.SeriesCollection(1)
        Set xRg = ActiveSheet.Range(Split(Split(.Formula, ",")(1), "!")(1))
        xRows = xRg.Rows.Count
        Set xRg = xRg(1)
        For I = 1 To xRows
            .Points(I).Format.Fill.ForeColor.RGB = ThisWorkbook.Colors(xRg.Offset(I - 1, 0).Interior.ColorIndex)
        Next
    End With
End Sub

Внимание: В приведенном выше коде Диаграмма 1 — это имя диаграммы, которое вы хотите использовать, измените его на свое.

4. После вставки вышеуказанного кода нажмите F5 ключ для запуска этого кода, и цвет полос диаграммы был изменен на основе исходного цвета ячейки, см. снимок экрана:

Раскрасьте диаграмму с несколькими рядами данных в зависимости от цвета ячейки

Если ваша диаграмма содержит несколько рядов данных, примените следующий код VBA:

1. Создайте столбчатую или столбчатую диаграмму, содержащую несколько рядов данных, как показано на следующем снимке экрана:

2. Удерживайте ALT + F11 , чтобы открыть Microsoft Visual Basic для приложений окно.

3. Нажмите Вставить > Модулии вставьте следующий код в окно модуля.

Код VBA: цветные полосы диаграммы с несколькими рядами данных в зависимости от цвета ячейки:

Sub CellColorsToChart()
'Updateby Extendoffice
    Dim xChart As Chart
    Dim I As Long, J As Long
    Dim xRowsOrCols As Long, xSCount As Long
    Dim xRg As Range, xCell As Range
    On Error Resume Next
    Set xChart = ActiveSheet.ChartObjects("Chart 1").Chart
    If xChart Is Nothing Then Exit Sub
    xSCount = xChart.SeriesCollection.Count
    For I = 1 To xSCount
        J = 1
        With xChart.SeriesCollection(I)
            Set xRg = ActiveSheet.Range(Split(Split(.Formula, ",")(2), "!")(1))
            If xSCount > 4 Then
                xRowsOrCols = xRg.Columns.Count
            Else
                xRowsOrCols = xRg.Rows.Count
            End If
            For Each xCell In xRg
                .Points(J).Format.Fill.ForeColor.RGB = ThisWorkbook.Colors(xCell.Interior.ColorIndex)
                .Points(J).Format.Line.ForeColor.RGB = ThisWorkbook.Colors(xCell.Interior.ColorIndex)
                J = J + 1
            Next
        End With
    Next
End Sub

4, Затем нажмите F5 нажмите клавишу для запуска этого кода, полосы диаграммы сразу заполняются исходным цветом ячеек, см. снимок экрана:

Ноты:

1. В приведенном выше коде Диаграмма 1 — это имя диаграммы, которое вы хотите использовать, измените его на свое.

2. Этот код также можно применить к линейному графику.

Раскрасьте диаграмму с помощью одного или нескольких рядов данных в зависимости от цвета ячеек с помощью удивительной функции

Используя приведенные выше коды, цвета диаграммы не всегда будут совпадать с цветом ячейки, чтобы решить эту проблему, здесь я представлю полезный инструмент — Изменить цвет диаграммы в соответствии с цветом ячейки of Kutools for Excel, с помощью этой удобной функции вы можете быстро и легко раскрасить диаграмму в зависимости от цвета ячейки.

Примечание: Чтобы применить это Изменить цвет диаграммы в соответствии с цветом ячейки, во-первых, вы должны скачать Kutools for Excel, а затем быстро и легко примените эту функцию.

После установки Kutools for Excel, пожалуйста, сделайте так:

1. Сначала вставьте диаграмму, которую вы хотите использовать, затем выберите диаграмму, затем нажмите Кутулс > Графики > Инструменты для диаграмм > Изменить цвет диаграммы в соответствии с цветом ячейки, см. снимок экрана:

2. Затем появится диалоговое окно, нажмите OK кнопку.

3. Теперь выбранная вами диаграмма окрашена в соответствии с цветами ячеек, как показано на скриншотах ниже:

Раскрасьте диаграмму одной серией данных в зависимости от цвета ячейки

Раскрасьте диаграмму с несколькими рядами данных в зависимости от цвета ячейки

Скачать и бесплатную пробную версию Kutools for Excel Сейчас !

Дополнительные статьи о диаграммах:

Расскажи друзьям, если статья оказалась полезной:

    Видеоинструкции по использованию надстройки MulTEx

Skip to content

Sub SopostavitCvetDiagrammiIIshodnihDannih()
'Шаг 1: Объявляем переменные
Dim oChart As Chart
Dim MySeries As Series
Dim FormulaSplit As Variant
Dim SourceRangeColor As Long

'Шаг 2: Наведите курсор на активный график
On Error Resume Next
Set oChart = ActiveChart

'Шаг 3: Выход не был выбран ни один график
If oChart Is Nothing Then
    MsgBox "График не выбран."
Exit Sub
End If

'Шаг 4: Цикл через серию диаграмм
For Each MySeries In oChart.SeriesCollection

    'Шаг 5: Получить диапазон исходных данных для целевой серии
    FormulaSplit = Split(MySeries.Formula, ",")(2)
    
    'Шаг 6: Захват цвета в первой ячейке
    SourceRangeColor = Range(FormulaSplit).Item(1).Interior.Color

    'Шаг 7: Применить окраску
    On Error Resume Next
    MySeries.Format.Line.ForeColor.RGB = SourceRangeColor
    MySeries.Format.Line.BackColor.RGB = SourceRangeColor
    MySeries.Format.Fill.ForeColor.RGB = SourceRangeColor
    If Not MySeries.MarkerStyle = xlMarkerStyleNone Then
        MySeries.MarkerBackgroundColor = SourceRangeColor
        MySeries.MarkerForegroundColor = SourceRangeColor
    End If

    'Шаг 8: Переход к следующей серии
Next MySeries

End Sub