Create named ranges excel

Excel Named Range (Table of Contents)

• Named Range in Excel
• Define Names from a Selected Range
• How to Create a Named Range in Excel?

Introduction to Named Range in Excel

Named Range just makes the process of working with formulas exciting, especially to keep track of things. It is just very convenient to assign a name to a range. If there is any change in that range, it becomes infinitely easier to update the range through the Name Manager. It totally allows us to bypass the process of manually updating every formula. Also, in cases of nested formulas, where one formula has to be used in another formula or maybe just used in a different location, all that needs to be done is to refer to the formula by its name.

The importance of named ranges is that one can use any names in the formula without worrying about the cell addresses/references. Any name can be assigned to a range. Any named constant or any data can be given a named range, and these names can be used instead of the actual formula. In this way, it becomes easier to understand the formulas. So, what this does is that it gives a range of cells in Excel a human-understandable name. By making use of named ranges, one can make the usage of formulas straightforward in Excel. One can give a name to a range in a formula or function, a constant, or a table. After starting to use names in a sheet, one can easily comprehend these names.

Define Names from a Selected Range

Firstly, one has to select the range that you want to give a name. Thereafter navigate to Formulas and then select Create from Selection.

From the “Create Names from Selection” box, select either Bottom Row, Top Row, Left Column, or Right Column, and then click on OK.

The cells are named based on labels in the designated range:

• First, use names in formulas and then focus on a cell and then enter a formula.
• The cursor has to be placed at the location where we want to use the named range in a formula.
• The name can be selected from the list that opens up after typing the name’s first letter.
• Alternatively, navigate to Formulas and then Use in Formula, followed by selecting the name that you intend to use.
• Press Enter.

It is also possible to update the named ranges from the Name Manager. The shortcut to update the named ranges from the Name Manager is Ctrl+F3. We just need to select the name that we wish to change and then proceed to change the reference directly.

How to Create Named Ranges in Excel?

Let us understand the concept of the Named Range through some examples.

You can download this Named Range Excel Template here – Named Range Excel Template

Example #1

Create a Named Range by using the Define Name option

• First, focus on the cells by selecting the range of cells.

• Now, navigate to the Formulas tab. Next, go to the Defined Name group. Click to select Define Name.

• Now once the New Name dialog box opens, mention three things -Name, Scope, Comment.

• Now in the “Name:” category, provide a name for the range.

• Now in the “Scope:” category, from the dropdown, the name scope has to be set (by default, it is Workbook)

• Now move on to the ‘Refers to:’ section, verify the available reference, and modify it if required. After that, click on OK to save the changes you have made and close the dialog box.

Example #2

Create a Named Range by utilizing the Name Manager

• Navigate to the Formulas tab and then proceed towards Define Name Group and then click on Name Manager.

• Alternatively, you can also press Ctrl+F3, which is the shortcut for the same.

• Now, on the top, towards the Name Manager’s left corner, we have the ‘New’ button. Click on it.

Then the New Name dialog box will open.

Example #3

Create a Named Range using VBA

We can also create a Named Range in VBA.

So, this is what we did in the code snippet above:

• We created three variables – myWorksheet of Worksheet datatype, which will store the name of the Excel Worksheet, myNamedRange of Range datatype, which will hold the name of the range of cells that we wish to name, and myRangeName, of String datatype, which will hold the name of the Named Range.
• We defined our Worksheet (in the variable myWorksheet).
• We then went on to define the range of cells that we wanted to name (in the variable myNamedRange).
• After that, we defined the name of our Named Range in the variable myRangeName.
• After that, we proceed to create the Named Range and provide the reference to which it will point to.

This concludes the Named Range creation process through VBA.

Things to Remember

The following things must always be kept in mind while creating or dealing with Named Ranges in Excel.

• Named Ranges can have names that start with either a backslash (), letter, or underscore (_). Numbers or other special symbols are invalid as the starting character. If any other character other than letters, backslash or an underscore is given as the starting character, then Excel will throw an error.
• There is also a limitation on how long the name of a Named Range can be. The maximum length of a name can be 255 characters. Anything above 255 characters will cause Excel to throw an error.
• Every name has to be a continuous sequence of characters. There is no scope to have spaces, tabs, or any punctuation marks in the name. This is done so as to maintain uniformity and make the names easier.
• Another important instruction while working with Named Ranges is that a Named Range’s name must not have any conflict with cell references.
• As we saw, there is a limit on the maximum length for a name. Conversely, a name must also be of at least one character length at a minimum. Names are allowed to be of a single character length; however, there are few characters such as ‘r’ and ‘c’, which are reserved by Excel and can not be used as Names.
• As a bonus, Names aren’t case sensitive, which means that names such as “Jon”, “JON”, “jon” are all the same to Excel.

Recommended Articles

This has been a guide to Named Range in Excel. Here we discussed how to create a named range in excel along with practical examples and a downloadable excel template. You can also go through our other suggested articles to learn more –

1. Excel Function for Range
2. Range in Excel
3. VBA Named Range
4. VBA Range

In this VBA Tutorial, you learn how to create named ranges (for different ranges and with different scopes) with macros.

This VBA Tutorial is accompanied by Excel workbooks containing the macros I use in the examples below. You can get immediate free access to these example workbooks by subscribing to the Power Spreadsheets Newsletter.

Use the following Table of Contents to navigate to the section you’re interested in.

Related VBA and Macro Tutorials

The following VBA and Macro Tutorials may help you better understand and implement the contents below:

• General VBA constructs and structures:
  • Learn about commonly-used VBA terms here.
  • Learn about working with Sub procedures here.
  • Learn about the Excel VBA Object Model here.
  • Learn about working with VBA methods here.
  • Learn how to identify cell ranges here.
  • Learn how to declare and work with variables here.
  • Learn about VBA data types here.
  • Learn about A1 and R1C1-style references here.
• Practical VBA applications and macro examples:
  • Learn how to work with worksheets here.
  • Learn several ways to find the last row with data here.
  • Learn several ways to find the last column with data here.

You can find additional VBA and Macro Tutorials in the Archives.

VBA Code to Create Named Range

To create a named range using VBA, use a statement with the following structure:

Scope.Names.Add Name:=RangeName, RefersTo:=NamedRange

Process Followed by VBA to Create Named Range

VBA Statement Explanation

1. Item: Scope.
   • VBA Construct: Workbook or Worksheet object.
   • Description: Scope of the named range you create. The scope of a named range can generally be 1 of the following:
     • Workbook. In this case, Scope must represent a Workbook object. For these purposes, you can use VBA constructs such as the ActiveWorkbook property, the ThisWorkbook property or the Application.Workbooks property.
     • Worksheet. In this case, Scope must represent a Worksheet object. For these purposes, you can use VBA constructs such as the ActiveSheet property or the Workbook.Worksheets property.

       For a more detailed description of how to create a named range with worksheet scope, please refer to the appropriate section below.

2. Item: Names.
   • VBA Construct: Workbook.Names property (when Scope is a Workbook object) or Worksheet.Names property (when scope is a Worksheet object).
   • Description: The Names property returns a Names collection representing all the names in the workbook (when Scope is a Workbook object) or worksheet (when Scope is a Worksheet object) represented by Scope. The Names collection returned by the Workbook.Names property includes worksheet-specific names.
3. Item: Add.
   • VBA Construct: Names.Add method.
   • Description: The Names.Add method sets a new name for a cell range.
4. Item: Name:=RangeName.
   • VBA Construct: Name parameter of the Names.Add method.
   • Description: The Name parameter of the Names.Add method allows you to specify the name of the named range you specify. Consider the following usual requirements when specifying RangeName:
     • RangeName must start with a letter or underscore.
     • Certain characters aren’t allowed. For example, RangeName can’t include spaces.
     • RangeName can’t conflict with an existing name.
     • RangeName can’t be formatted as a cell reference. For example, names such as “ABC1” aren’t allowed.
     • If you want to specify the Name parameter using localized text, (i) work with the NameLocal parameter of the Names.Add method, and (ii) omit the Name parameter of the Names.Add method.

     If you explicitly declare a variable to represent RangeName, use the String data type.

5. Item: RefersTo:=NamedRange.
   • VBA Construct: RefersTo parameter of the Names.Add method.
   • Description: The RefersTo parameter of the Names.Add method allows you to specify the cell range to which the name refers to. The RefersTo parameter is of the Variant data type. Therefore, you commonly specify NamedRange as one of the following:
     • A Range object.
     • A string that uses the A1-style notation.

     When working with the Names.Add method, you can also specify the cell range to which the name refers to using the following parameters.

     • RefersToLocal: Allows you to specify the cell range in localized text using the A1-style notation.
     • RefersToR1C1: Allows you to specify the cell range in R1C1-style notation.
     • RefersToR1C1Local: Allows you to specify the cell range in localized text using the R1C1-style notation.

     When working with one of the 4 parameters I refer to (RefersTo, RefersToLocal, RefersToR1C1, or RefersToR1C1Local), specify that single parameter and omit the others.

     If you explicitly declare a variable to represent NamedRange, use the Range object data type (if specifying NamedRange as a Range object) or the String data type (if specifying NamedRange as a string).

Macro Example to Create Named Range

The following macro example creates a named range with workbook scope (ThisWorkbook) by setting the name of the cell range composed of cells A5 to C10 (myNamedRange) of the Named Range worksheet (myWorksheet) to “namedRange” (myRangeName).

Sub createNamedRange()

    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/vba-create-named-range/

    'declare object variables to hold references to worksheet containing cell range, and cell range itself
    Dim myWorksheet As Worksheet
    Dim myNamedRange As Range

    'declare variable to hold defined name
    Dim myRangeName As String

    'identify worksheet containing cell range, and cell range itself
    Set myWorksheet = ThisWorkbook.Worksheets("Named Range")
    Set myNamedRange = myWorksheet.Range("A5:C10")

    'specify defined name
    myRangeName = "namedRange"

    'create named range with workbook scope. Defined name and cell range are as specified
    ThisWorkbook.Names.Add Name:=myRangeName, RefersTo:=myNamedRange

End Sub

Effects of Executing Macro Example to Create Named Range

The following image illustrates the results of executing the macro example. The cell range containing cells A5 to C10 is named as “namedRange”.

#2: Create Named Range with Worksheet Scope

VBA Code to Create Named Range with Worksheet Scope

To create a named range with worksheet scope using VBA, use a statement with the following structure:

Worksheet.Names.Add Name:=RangeName, RefersTo:=NamedRangeWorksheet

Process Followed by VBA to Create Named Range with Worksheet Scope

VBA Statement Explanation

1. Item: Worksheet.
   • VBA Construct: Worksheet object.
   • Description: You can use VBA constructs such as the ActiveSheet property or the Workbook.Worksheets property to return a Worksheet object representing the worksheet to which you want to limit the scope of the named range.
2. Item: Names.
   • VBA Construct: Worksheet.Names property.
   • Description: The Worksheet.Names property returns a Names collection representing all the names in Worksheet.
3. Item: Add.
   • VBA Construct: Names.Add method.
   • Description: The Names.Add method sets a new name for a cell range.
4. Item: Name:=RangeName.
   • VBA Construct: Name parameter of the Names.Add method.
   • Description: The Name parameter of the Names.Add method allows you to specify the name of the named range you specify. Consider the following usual requirements when specifying RangeName:
     • RangeName must start with a letter or underscore.
     • Certain characters aren’t allowed. For example, RangeName can’t include spaces.
     • RangeName can’t conflict with an existing name.
     • RangeName can’t be formatted as a cell reference. For example, names such as “ABC1” aren’t allowed.
     • If you want to specify the Name parameter using localized text, (i) work with the NameLocal parameter of the Names.Add method, and (ii) omit the Name parameter of the Names.Add method.

     If you explicitly declare a variable to represent RangeName, use the String data type.

5. Item: RefersTo:=NamedRangeWorksheet.
   • VBA Construct: RefersTo parameter of the Names.Add method.
   • Description: The RefersTo parameter of the Names.Add method allows you to specify the cell range to which the name refers to. The RefersTo parameter is of the Variant data type. Therefore, you commonly specify NamedRangeWorksheet as one of the following:
     • A Range object.
     • A string that uses the A1-style notation.

     When working with the Names.Add method, you can also specify the cell range to which the name refers to using the following parameters.

     • RefersToLocal: Allows you to specify the cell range in localized text using the A1-style notation.
     • RefersToR1C1: Allows you to specify the cell range in R1C1-style notation.
     • RefersToR1C1Local: Allows you to specify the cell range in localized text using the R1C1-style notation.

     When working with one of the 4 parameters I refer to (RefersTo, RefersToLocal, RefersToR1C1, or RefersToR1C1Local), specify that single parameter and omit the others.

     If you explicitly declare a variable to represent NamedRangeWorksheet, use the Range object data type (if specifying NamedRangeWorksheet as a Range object) or the String data type (if specifying NamedRangeWorksheet as a string).

Macro Example to Create Named Range with Worksheet Scope

The following macro example creates a named range with worksheet scope (myWorksheet) by setting the name of the cell range composed of cells D5 to F10 (myNamedRangeWorksheet) of the Named Range worksheet (myWorksheet) to “namedRangeWorksheet” (myRangeName).

Sub createNamedRangeWorksheetScope()

    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/vba-create-named-range/

    'declare object variables to hold references to worksheet containing cell range, and cell range itself
    Dim myWorksheet As Worksheet
    Dim myNamedRangeWorksheet As Range

    'declare variable to hold defined name
    Dim myRangeName As String

    'identify worksheet containing cell range, and cell range itself
    Set myWorksheet = ThisWorkbook.Worksheets("Named Range")
    Set myNamedRangeWorksheet = myWorksheet.Range("D5:F10")

    'specify defined name
    myRangeName = "namedRangeWorksheet"

    'create named range with worksheet scope. Defined name and cell range are as specified
    myWorksheet.Names.Add Name:=myRangeName, RefersTo:=myNamedRangeWorksheet

End Sub

Effects of Executing Macro Example to Create Named Range with Worksheet Scope

The following image illustrates the results of executing the macro example. The cell range containing cells D5 to F10 is named as “namedRangeWorksheet”.

#3: Create Named Range from Selection

VBA Code to Create Named Range from Selection

To create a named range from the current selection using VBA, use a statement with the following structure:

Scope.Names.Add Name:=RangeName, RefersTo:=Selection

Process Followed by VBA to Create Named Range from Selection

VBA Statement Explanation from Selection

1. Item: Scope.
   • VBA Construct: Workbook or Worksheet object.
   • Description: Scope of the named range you create. The scope of a named range can generally be 1 of the following:
     • Workbook. In this case, Scope must represent a Workbook object. For these purposes, you can use VBA constructs such as the ActiveWorkbook property, the ThisWorkbook property or the Application.Workbooks property.
     • Worksheet. In this case, Scope must represent a Worksheet object. For these purposes, you can use VBA constructs such as the ActiveSheet property.

       For a more detailed description of how to create a named range with worksheet scope, please refer to the appropriate section above.

2. Item: Names.
   • VBA Construct: Workbook.Names property (when Scope is a Workbook object) or Worksheet.Names property (when scope is a Worksheet object).
   • Description: The Names property returns a Names collection representing all the names in the workbook (when Scope is a Workbook object) or worksheet (when Scope is a Worksheet object) represented by Scope. The Names collection returned by the Workbook.Names property includes worksheet-specific names.
3. Item: Add.
   • VBA Construct: Names.Add method.
   • Description: The Names.Add method sets a new name for a cell range.
4. Item: Name:=RangeName.
   • VBA Construct: Name parameter of the Names.Add method.
   • Description: The Name parameter of the Names.Add method allows you to specify the name of the named range you specify. Consider the following usual requirements when specifying RangeName:
     • RangeName must start with a letter or underscore.
     • Certain characters aren’t allowed. For example, RangeName can’t include spaces.
     • RangeName can’t conflict with an existing name.
     • RangeName can’t be formatted as a cell reference. For example, names such as “ABC1” aren’t allowed.
     • If you want to specify the Name parameter using localized text, (i) work with the NameLocal parameter of the Names.Add method, and (ii) omit the Name parameter of the Names.Add method.

     If you explicitly declare a variable to represent RangeName, use the String data type.

5. Item: RefersTo:=Selection.
   • VBA Construct: RefersTo parameter of the Names.Add method and Selection property.
   • Description: The RefersTo parameter of the Names.Add method allows you to specify the cell range to which the name refers to.

     The Selection property returns a Range object representing the current selected cells. This is the cell range you name.

Macro Example to Create Named Range from Selection

The following macro example creates a named range with workbook scope (ThisWorkbook) by setting the name of the selection (Selection) to “namedRangeFromSelection” (myRangeName).

Sub createNamedRangeFromSelection()

    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/vba-create-named-range/

    'declare variable to hold defined name
    Dim myRangeName As String

    'specify defined name
    myRangeName = "namedRangeFromSelection"

    'create named range with workbook scope. Defined name is as specified. Cell range is the selection
    ThisWorkbook.Names.Add Name:=myRangeName, RefersTo:=Selection

End Sub

Effects of Executing Macro Example to Create Named Range from Selection

The following image illustrates the results of executing the macro example. The current selection, containing cells G5 to I10 is named as “namedRangeFromSelection”.

#4: Create Named Range (Dynamic)

VBA Code to Create Named Range (Dynamic)

To create a named range from a dynamic range (where the number of the last row and last column changes) with VBA, use a macro with the following statement structure:

Dim LastRow As Long
Dim LastColumn As Long
Dim NamedRangeDynamic As Range
With Worksheet.Cells
    LastRow = .Find(What:="*", LookIn:=xlFormulas, LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
    LastColumn = .Find(What:="*", LookIn:=xlFormulas, LookAt:=xlPart, SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column
    Set NamedRangeDynamic = .Range(.Cells(1, 1), .Cells(LastRow, LastColumn))
End With
Scope.Names.Add Name:=RangeName, RefersTo:=NamedRangeDynamic

Process Followed by VBA to Create Named Range (Dynamic)

VBA Statement Explanation (Dynamic)

Line #1: Dim LastRow As Long

1. Item: Dim LastRow as Long.
   • VBA Construct: Dim statement.
   • Description: Declares the LastRow variable as of the Long data type.

     LastRow holds the number of the last row with data in the worksheet containing the cell range you name (Worksheet).

Line #2: Dim LastColumn As Long

1. Item: Dim LastColumn as Long.
   • VBA Construct: Dim statement.
   • Description: Declares the LastColumn variable as of the Long data type.

     LastColumn holds the number of the last column with data in the worksheet containing the cell range you name (Worksheet).

Line #3: Dim NamedRangeDynamic As Range

1. Item: Dim NamedRangeDynamic As Range.
   • VBA Construct: Dim statement.
   • Description: Declares the NamedRangeDynamic variable as of the Range object data type.

     NamedRangeDynamic represents the cell range you name.

Lines #4 and #8:With Worksheet.Cells | End With

1. Item: With… End With.
   • VBA Construct: With… End With statement.
   • Description: Statements within the With… End With statement are executed on the Range object returned by Worksheet.Cells.
2. Item: Worksheet.
   • VBA Construct: Worksheet object.
   • Description: Represents the worksheet containing the cell range you name. If you explicitly declare an object variable to represent Worksheet, use the Worksheet object data type.
3. Item: Cells.
   • VBA Construct: Worksheet.Cells property.
   • Description: Returns a Range object representing all the cells in Worksheet.

Line #5: LastRow = .Find(What:=”*”, LookIn:=xlFormulas, LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row

1. Item: LastRow.
   • VBA Construct: Variable of the long data type.
   • Description: LastRow holds the number of the last row with data in Worksheet.
2. Item: =.
   • VBA Construct: Assignment operator.
   • Description: Assigns the row number returned by the Range.Row property to the LastRow variable.
3. Item: Find.
   • VBA Construct: Range.Find method.
   • Description: Returns a Range object representing the first cell where the information specified by the parameters of the Range.Find method (What, LookIn, LookAt, SearchOrder and SearchDirection) is found. Within this macro structure, this Range object represents the last cell with data in the last row with data in Worksheet.
4. Item: What:=”*”.
   • VBA Construct: What parameter of the Range.Find method.
   • Description: Specifies the data the Range.Find method searches for. The asterisk (*) is a wildcard and, therefore, the Range.Find method searches for any character sequence.
5. Item: LookIn:=xlFormulas.
   • VBA Construct: LookIn parameter of the Range.Find method.
   • Description: Specifies that the Range.Find method looks in formulas (xlFormulas).
6. Item: LookAt:=xlPart.
   • VBA Construct: LookAt parameter of the Range.Find method.
   • Description: Specifies that the Range.Find method looks at (and matches) a part (xlPart) of the search data.
7. Item: SearchOrder:=xlByRows.
   • VBA Construct: SearchOrder parameter of the Range.Find method.
   • Description: Specifies that the Range.Find method searches by rows (xlByRows).
8. Item: SearchDirection:=xlPrevious.
   • VBA Construct: SearchDirection parameter of the Range.Find method.
   • Description: Specifies that the Range.Find method searches for the previous match (xlPrevious).
9. Item: Row.
   • VBA Construct: Range.Row property.
   • Description: Returns the row number of the Range object returned by the Range.Find method. Within this macro structure, this row number corresponds to the last row with data in Worksheet.

Line #6: LastColumn = .Find(What:=”*”, LookIn:=xlFormulas, LookAt:=xlPart, SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column

1. Item: LastColumn.
   • VBA Construct: Variable of the long data type.
   • Description: LastColumn holds the number of the last column with data in Worksheet.
2. Item: =.
   • VBA Construct: Assignment operator.
   • Description: Assigns the column number returned by the Range.Column property to the LastColumn variable.
3. Item: Find.
   • VBA Construct: Range.Find method.
   • Description: Returns a Range object representing the first cell where the information specified by the parameters of the Range.Find method (What, LookIn, LookAt, SearchOrder and SearchDirection) is found. Within this macro structure, this Range object represents the last cell with data in the last column with data in Worksheet.
4. Item: What:=”*”.
   • VBA Construct: What parameter of the Range.Find method.
   • Description: Specifies the data the Range.Find method searches for. The asterisk (*) is a wildcard and, therefore, the Range.Find method searches for any character sequence.
5. Item: LookIn:=xlFormulas.
   • VBA Construct: LookIn parameter of the Range.Find method.
   • Description: Specifies that the Range.Find method looks in formulas (xlFormulas).
6. Item: LookAt:=xlPart.
   • VBA Construct: LookAt parameter of the Range.Find method.
   • Description: Specifies that the Range.Find method looks at (and matches) a part (xlPart) of the search data.
7. Item: SearchOrder:=xlByColumns.
   • VBA Construct: SearchOrder parameter of the Range.Find method.
   • Description: Specifies that the Range.Find method searches by columns (xlByColumns).
8. Item: SearchDirection:=xlPrevious.
   • VBA Construct: SearchDirection parameter of the Range.Find method.
   • Description: Specifies that the Range.Find method searches for the previous match (xlPrevious).
9. Item: Column.
   • VBA Construct: Range.Column property.
   • Description: Returns the column number of the Range object returned by the Range.Find method. Within this macro structure, this column number corresponds to the last column with data in Worksheet.

Line #7: Set NamedRangeDynamic = .Range(.Cells(1, 1), .Cells(LastRow, LastColumn))

1. Item: NamedRangeDynamic.
   • VBA Construct: Object variable of the Range object data type.
   • Description: NamedRangeDynamic represents the cell range you name.
2. Item: =.
   • VBA Construct: Assignment operator.
   • Description: Assigns the Range object returned by the Range.Range property to the NamedRangeDynamic object variable.
3. Item: Range.
   • VBA Construct: Range.Range property.
   • Description: Returns a Range object representing the cell range you name. Within this macro structure, the Range property is applied to the Range object returned by the Worksheet.Cells property in the opening statement of the With… End With statement.
4. Item: Cells(1, 1).
   • VBA Construct: Cells1 parameter of the Range.Range property, Range.Cells property and Range.Item property.
   • Description: The Cells1 parameter of the Range.Range property specifies the cell in the upper-left corner of the cell range. Within this macro structure, Cells1 is the Range object returned by the Range.Cells property.

     The Range.Cells property returns all the cells within the cell range represented by the Range object returned by the Worksheet.Cells property in the opening statement of the With… End With statement. The Range.Item property is the default property and returns a Range object representing the cell on the first row and first column (Cells(1, 1)) of the cell range it works with.

     Since the Worksheet.Cells property in the opening statement of the With… End With statement returns all the cells in Worksheet, this is cell A1 of Worksheet.

5. Item: Cells(LastRow, LastColumn).
   • VBA Construct: Cells2 parameter of the Range.Range property, Range.Cells property and Range.Item property.
   • Description: The Cells2 parameter of the Range.Range property specifies the cells in the lower-right corner of the cell range. Within this macro structure, Cells2 is the Range object returned by the Range.Cells property.

     The Range.Cells property returns all the cells within the cell range represented by the Range object returned by the Worksheet.Cells property in the opening statement of the With… End With statement (line #4 above). The Range.Item property is the default property and returns a Range object representing the cell located at the intersection of LastRow and LastColumn.

     Since the Worksheet.Cells property in the opening statement of the With… End With statement returns all the cells in Worksheet, this is the cell located at the intersection of the last row and the last column (or the last cell with data) within Worksheet.

Line #9: Scope.Names.Add Name:=RangeName, RefersTo:=NamedRangeDynamic

1. Item: Scope.
   • VBA Construct: Workbook or Worksheet object.
   • Description: Scope of the named range you create. The scope of a named range can generally be 1 of the following:
     • Workbook. In this case, Scope must represent a Workbook object. For these purposes, you can use VBA constructs such as the ActiveWorkbook property, the ThisWorkbook property or the Application.Workbooks property.
     • Worksheet. In this case, Scope must represent a Worksheet object. For these purposes, you can use VBA constructs such as the ActiveSheet property or the Workbook.Worksheets property.

       For a more detailed description of how to create a named range with worksheet scope, please refer to the appropriate section above.

2. Item: Names.
   • VBA Construct: Workbook.Names property (when Scope is a Workbook object) or Worksheet.Names property (when scope is a Worksheet object).
   • Description: The Names property returns a Names collection representing all the names in the workbook (when Scope is a Workbook object) or worksheet (when Scope is a Worksheet object) represented by Scope. The Names collection returned by the Workbook.Names property includes worksheet-specific names.
3. Item: Add.
   • VBA Construct: Names.Add method.
   • Description: The Names.Add method sets a new name for a cell range.
4. Item: Name:=RangeName.
   • VBA Construct: Name parameter of the Names.Add method.
   • Description: The Name parameter of the Names.Add method allows you to specify the name of the named range you specify. Consider the following usual requirements when specifying RangeName:
     • RangeName must start with a letter or underscore.
     • Certain characters aren’t allowed. For example, RangeName can’t include spaces.
     • RangeName can’t conflict with an existing name.
     • RangeName can’t be formatted as a cell reference. For example, names such as “ABC1” aren’t allowed.
     • If you want to specify the Name parameter using localized text, (i) work with the NameLocal parameter of the Names.Add method, and (ii) omit the Name parameter of the Names.Add method.

     If you explicitly declare a variable to represent RangeName, use the String data type.

5. Item: RefersTo:=NamedRangeDynamic.
   • VBA Construct: RefersTo parameter of the Names.Add method.
   • Description: The RefersTo parameter of the Names.Add method allows you to specify the cell range to which the name refers to.

     NamedRangeDynamic is an object variable of the Range object data type representing the cell range you name.

Macro Example to Create Named Range (Dynamic)

The following macro example creates a named range with workbook scope (ThisWorkbook) by dynamically identifying the last row (myLastRow) and last column (myLastColumn) with data in the Named Range worksheet (myWorksheet) and setting its name to “namedRangeDynamic” (myRangeName). In this case, the first cell of namedRangeDynamic is A11 (intersection of myFirstRow and myFirstColumn).

Sub createNamedRangeDynamic()

    'Source: https://powerspreadsheets.com/
    'For further information: https://powerspreadsheets.com/vba-create-named-range/

    'declare object variable to hold reference to worksheet containing cell range
    Dim myWorksheet As Worksheet

    'declare variables to hold row and column numbers that define named cell range (dynamic)
    Dim myFirstRow As Long
    Dim myLastRow As Long
    Dim myFirstColumn As Long
    Dim myLastColumn As Long

    'declare object variable to hold reference to cell range
    Dim myNamedRangeDynamic As Range

    'declare variable to hold defined name
    Dim myRangeName As String

    'identify worksheet containing cell range
    Set myWorksheet = ThisWorkbook.Worksheets("Named Range")

    'identify first row and first column of cell range
    myFirstRow = 11
    myFirstColumn = 1

    'specify defined name
    myRangeName = "namedRangeDynamic"

    With myWorksheet.Cells

        'find last row and last column of source data cell range
        myLastRow = .Find(What:="*", LookIn:=xlFormulas, LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
        myLastColumn = .Find(What:="*", LookIn:=xlFormulas, LookAt:=xlPart, SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column

        'specify cell range
        Set myNamedRangeDynamic = .Range(.Cells(myFirstRow, myFirstColumn), .Cells(myLastRow, myLastColumn))

End With

    'create named range with workbook scope. Defined name is as specified. Cell range is as identified, with the last row and column being dynamically determined
    ThisWorkbook.Names.Add Name:=myRangeName, RefersTo:=myNamedRangeDynamic

End Sub

Effects of Executing Macro Example to Create Named Range (Dynamic)

The following image illustrates the results of executing the macro example. The cell range containing data (Data) (cells A11 to I20) is named as “namedRangeDynamic”.

References to VBA Constructs Used in this VBA Tutorial

Use the following links to visit the appropriate webpage in the Microsoft Developer Network:

1. Specify the scope of a named range (workbook or worksheet):
   • Workbook object.
   • Workbook.Names property.
   • Application.ActiveWorkbook property.
   • Application.ThisWorkbook property.
   • Application.Workbooks property.
   • Worksheet object.
   • Worksheet.Names property.
   • Application.ActiveSheet property.
   • Workbook.Worksheets property.
2. Identify the cell range to name:
   • Range object.
   • Worksheet.Range property.
   • Worksheet.Cells property.
   • Application.Selection property.
   • Range.Range property.
   • Range.Cells property.
   • Range.Item property.
   • Identify the last row or column with data in a worksheet:
     • Range.Find method.
     • Range.Row property.
     • Range.Column property.
3. Set a new named range:
   • Names collection.
   • Name object.
   • Names.Add method.
   • Range.Name property.
4. Work with variables and data types:
   • Dim statement.
   • Set statement.
   • Data types:
     • String data type.
     • Long data type.