Count the unique values in excel

Let’s consider we have a long list of duplicate values in a range and our objective is to count only the unique occurrences of each value.

Though this can be a very common requirement in many scenarios but excel doesn’t have any single formula that can directly help us to count unique values in excel inside a range.

In today’s post, we will see 5 different ways of counting unique values in excel.

But, before starting let’s make our goal clear.

By looking at the above image, we can clearly see that what we mean by counting unique value in excel.

Method – 1: Using SumProduct and CountIF Formula:

The simplest and easiest way to count distinct values in excel is to use SumProduct and CountIF formula.

Following is the generic formula that you can use:

=SUMPRODUCT(1/COUNTIF(data,data))

‘data’ – data represents the range that contains the values

Let’s See How This Formula Works:

This formula consists of two functions combined together. Let’s first understand the role of inner CountIF function.

The CountIF function looks inside the data range (B2:B9) and counts the number of times each value appears in data range.

The result is an array of numbers and in our example it might look something like this: {2;2;3;3;3;2;2;1}.

Next, the results of CountIF formula are used as a divisor with 1 as numerator. This modifies the result of CountIF formula such that; values that only appear once in the array become 1 and the numbers corresponding to duplicate values become fractions corresponding to the multiple.

This means that, if a value appears 4 times in the range then its value will become as 1/4 = 0.25 and value that is present only once will become 1/1 = 1

Finally, the SumProduct formula adds up all the elements in the array and returns the final result.

Read these articles for more details on CountIF Function or SumProduct Function.

The Catch:

This formula woks nicely on a continuous set of values in a range, however if your values contain empty cells, then this formula fails. In such cases the formula throws a ‘divide by zero’ error.

Because, CountIF function generates a ‘0’ for each blank cell and when 1 is divided by 0 it returns a divide by zero error.

To fix this, you can use the following variant of the above formula that ignores the blank cells:

=SUMPRODUCT(((data<>"")/COUNTIF(data , data &"")))

‘data’ – data represents the range that contains the values

Method – 2: Using SUM, FREQUENCY AND MATCH Array Formula

The formula that we discussed above is good to be used for small ranges. As the range becomes bigger the SUMPRODUCT and COUNTIF formula will become slower and will eventually make your spreadsheets unresponsive while counting unique values inside a range.

So, for larger datasets, you may want to switch to a formula based on the FREQUENCY function.

The generic formula is as follows:

=SUM(IF(FREQUENCY(IF(data<>"", MATCH(data,data,0)),ROW(data)-ROW(firstcell)+1),1))

Here, ‘data’ represents the range that contains the values.

And ‘firstcell’ represents the first cell of the range.

Note: This is an array formula so, after writing the formula press ‘Control-Shift-Enter’ and the formula will get surrounded by curly braces as shown below.

Let’s Try To Understand How This Formula Works:

This formula uses Frequency function to count the unique values, but the problem here is that FREQUENCY function is only designed to work with numbers. So, here our first objective is to convert the values into a set of numbers.

Starting from inside, the MATCH function in this formula gives us the first occurrence or position number of each item that appears in the data range. If there are any values that are duplicate, then MATCH will return only the position of the first occurrence of that value in the data range.

After the MATCH function, there is an IF Statement. The reason IF function is required because MATCH will return a #N/A error for empty cells. So, we are excluding the empty cells with data <> "".

The resulting array contains a set of numbers combined with False for the blank cells. So, in our case the resulting array would be like:

{1;1;3;3;3;6;FALSE;6;9}

This array is fed to the FREQUENCY function which returns how often values occur within the set of data and finally the outer IF function sets each unique value to 1 and duplicate value to FALSE.

And the final result comes out to be 4.

Method – 3: Using PivotTable (Only works in Excel 2013 and above)

The integration of power pivot with excel (known as Data Model), has provided some powerful features to the users. Now pivot tables can also help you to get the distinct counts of unique values in excel.

To do this follow the below steps:

1. Navigate to the ‘Insert’ option on the top ribbon and click the ‘PivotTable’ option.

1. This will open a ‘PivotTable’ dialog, select the data range and check the checkbox that says ‘Add this data to Data Model’ and finally click ‘Ok’ button.

1. Build the PivotTable by placing the column that contains data range ‘Values’ and in the ‘Rows’ quadrant as shown below.

1. Doing this will show the total count including the duplicate values, however we only need to get the count of distinct values. So, right click over the Count column and select the ‘Value Field Settings’ option.

1. Next, In the ‘Value Field Settings’ window, select the ‘Distinct Count’ option and click ‘Ok’ button.

1. Doing this will fetch the distinct counts for the values and populate them in the PivotTable.

Method – 4: Using SUM and COUNTIF function

This is again an array formula to count distinct values in a range.

=SUM(IF(ISTEXT(range),1/COUNTIF(range, range), ""))

Here, ‘range’ represents the range that contains the values.

Note: This is an array formula so, after writing the formula press ‘Control-Shift-Enter’ and the formula will get surrounded by curly braces as shown below.

Let’s See How This Formula Works:

In this formula, we have used ISTEXT function. ISTEXT function returns a true for all the values that are text and false for other values.

If the value is a text value, then the COUNTIF function executes and looks inside the data range (B2:B9) and counts the number of times that each value appears in data range.

After this, the result of CountIF function are used as a divisor with 1 as the numerator (same as in first method). This means that, if a value appears 4 times in the range its value will become as 1/4 = 0.25 and when the value is present only once then it becomes 1/1 = 1

Finally, the SUM function computes the sum of all the values and returns the result.

Method 5 – COUNTUNIQUE User Defined Function:

If none of the above options work for you, then you can create your own user defined function (UDF) that can count unique values in excel for you.

Below is the code to write your own UDF that does the same:

Function COUNTUNIQUE(DataRange As Range, CountBlanks As Boolean) As Integer
Dim CellContent As Variant
Dim UniqueValues As New Collection
Application.Volatile
On Error Resume Next
For Each CellContent In DataRange
If CountBlanks = True Or IsEmpty(CellContent) = False Then
UniqueValues.Add CellContent, CStr(CellContent)
End If
Next
COUNTUNIQUE = UniqueValues.Count
End Function

To embed this function in Excel use the following steps:

1. Press Alt + F11 key on the Excel, this will open the VBA window.
2. On the VBA Window, right click over the ‘Microsoft Excel Objects’ > ‘Insert’ > ‘Module’.

1. Clicking the ‘Module’ will open a new module in the Excel. Paste the UDF code in the module window as shown below.

1. Finally, save your spreadsheet and the formula is ready to use.

How to Use the UDF:

To use the UDF, you can simply type the UDF name ‘CountUnique’ like a normal excel function.

=COUNTUNIQUE(data_range, count_blanks)

‘data_range’ – represents the range that contains the values.

‘count_blanks’ – is a boolean parameter that can have two values true or false. If you set this parameter as true then it will count the blank rows as unique. By setting this parameter to false the UDF will exclude the blank rows.

So, these were all the methods that can help you to count unique value in excel. Do let us know your own methods or tricks to do the same.

Let’s say you have a list of values where each value is entered more than once.

And now…

You want to count unique values from that list so that you can get the actual numbers of values that are there.

For this, you need to use a method that will count value only one time and ignore it’s all the other occurrences in the list.

In Excel, you can use different methods to get a count of unique values. It depends that which type of values you have so that you can use the best method for it.

In today’s post, I’d like to share with you 6 different methods to count unique values and use these methods according to the type of values you have.

data.xlsx

Advanced Filter to Get a Count of Unique Values

Using an advanced filter is one of the easiest ways to check the count of unique values and you don’t even need complex formulas. Here we have a list of names and from this list, you need to count the number of unique names.

Following are the steps you need to follow to get the unique values:

1. First of all, select any of the cells from the list.
   
2. After that, go to Data Tab ➜ Sort & Filter ➜ Click on Advanced.
   
3. Once you click on it, you will get a pop-up window to apply advanced filters.
4. Now from this window, select “Copy to another location”.
5. In “Copy to”, select a blank cell where you want to paste unique values.
6. Now, tick mark “Unique Records Only” and click OK.
   
7. At this point, you have a list of unique values.
   
8. Now, go to the cell below the last cell of the list and insert the following formula and hit enter.

=COUNTA(B2:B10)

It will return the count of unique values from that list of names.

Now you have a list of unique values and count as well. This method is simple and easy to follow as you don’t need to write complex formulas for this.

Combination of SUM and COUNTIF to Count Unique Values 

If you want to find the count of unique values in a single cell without extracting a separate list, then you can use a combination of SUM and COUNTIF.

In this method, you just have to refer to the list of the values and the formula will return the number of unique values. This is an array formula, so you need to enter it as an array, and while entering it use Ctrl + Shift + Enter.

And the formula is:

=SUM(1/COUNTIF(A2:A17,A2:A17))

When you enter this formula as an array it will look something like this.

{=SUM(1/COUNTIF(A2:A17,A2:A17))}

How it Works

To understand this formula you need to break it down into three parts and just remember that we have entered this formula as an array and there is a total of 16 values in this list, not unique but total.

Ok, so look.

In the first part, you have used COUNIF to count the number of each value from 16 and here COUNTIF returns values like the below.

In the second part, you have divided all the values by 1 which returns a value like this.

Let’s say if a value is there in the list twice, then it will return 0.5 for both of the values so that in the end when you sum it, it becomes 1 and if a value is there three times it will return 0.333 for each.

And, in the third part, you have simply used the SUM function to sum all those values and you have a count of unique values.

This formula is quite powerful and it can help you to get the count in a single cell.

Use SUMPRODUCT + COUNTIF to Get a Number of Unique Values from a List

In the last method, you used the SUM and COUNTIF methods. But, you can also use SUMPRODUCT instead of SUM.

And, when you use SUMPRODUCT, you don’t need to enter a formula as an array. Just edit the cell and enter the below formula.

=SUMPRODUCT(1/COUNTIF(A2:A17,A2:A17))

When you enter this formula as an array it will look something like this.

{=SUMPRODUCT(1/COUNTIF(A2:A17,A2:A17))}

How it Works

This formula exactly works in the same way as you have learned in the above method, the difference is just that you have used SUMPRODUCT instead of SUM.

And SUMPRODUCT can take an array without using Ctrl + Shift + Enter.

Count Only Unique Text Values from a List

Now, let’s say you have a list of names in which you also have mobile numbers and you want to count unique values just from text values. So in this case, you can use the below formula:

=SUM(IF(ISTEXT(A2:A17),1/COUNTIF(A2:A17, A2:A17),””))

And when you enter this formula as an array.

{=SUM(IF(ISTEXT(A2:A17),1/COUNTIF(A2:A17, A2:A17),””))}

How it Works

In this method, you have used the IF function and ISTEXT. ISTEXT first verifies whether all the values are text or not and return TRUE if a value is text.

After that, IF applies COUNTIF on all the text values where you have TRUE and other values remain blank.

And in the end, SUM returns the sum of all the unique values which are text and you get the count of unique text values this way.

Get Count of Unique Numbers from a List

And if you just want to count unique numbers from a list of values then you can use the below formula.

=SUM(IF(ISNUMBER(A2:A17),1/COUNTIF(A2:A17, A2:A17),””))

Enter this formula as an array.

{=SUM(IF(ISNUMBER(A2:A17),1/COUNTIF(A2:A17, A2:A17),””))}

How it works

In this method, you have used the IF function and ISNUMBER. ISNUMBER first verifies that all the values are numeric or not and return TRUE if a value is a number.

After that, IF applies COUNTIF on all the numeric values where you have TRUE and other values remain blank.

And in the end, SUM returns the sum of all the unique values which are numbers and you get the count of unique numbers this way.

Count Unique Values with a UDF

Here I have VBA (UDF) which can help you to count unique values without using any kind of formula.

Function CountUnique(ListRange As Range) As Integer
Dim CellValue As Variant
Dim UniqueValues As New Collection
Application.Volatile
On Error Resume Next
For Each CellValue In ListRange
UniqueValues.Add CellValue, CStr(CellValue) ' add the unique item
Next
CountUnique = UniqueValues.Count
End Function

Enter this function in your VBE by inserting a new module and after that go to your worksheet and insert the following formula.

=CountUnique(range)

Conclusion

Counting unique values can be useful for you while working with large datasets.

The name list which you have used here had duplicate names and after calculating unique numbers, we get that there are 10 unique names in the list.

Well, all the methods which you have learned here are useful in different situations and you can use anyone from those which you think is a perfect fit for you.

If you ask me, advanced filter and SUMPRODUCT are my favorite methods, but now you need to tell me:

Which one is your favorite?

Please share your views with me in the comment section, I’d love to hear from you and don’t forget to share this tip with your friends.

Home > Microsoft Excel > How to Count Unique Values in Excel? 3 Easy Ways to Count Unique and Distinct Values

(Note: This guide on how to freeze rows in Excel is suitable for all Excel versions including Office 365)

Working with large amounts of data in Excel can be quite difficult. Some values may be repeated more than once. You might have to take into account multiple entries of data while performing any function to upgrade your accuracy. You will also need to count the values to organize or even acquire statistics from the data.

With large data, it would be nearly impossible to count the values manually. Especially, keeping a track of unique or distinct values can be quite arduous. Fortunately in Excel, there are many ways to count unique and distinct values.

You’ll Learn:

• Unique and Distinct Values
• How to Count Unique Values in Excel
  • Using SUM, IF, and COUNTIF Functions
    • Count Unique Text Values in Excel
    • Count Unique Numeric Values in Excel
• How to Count Distinct Values in Excel
  • Using Filter Option
  • Using SUM and COUNTIF functions

First, let us understand the difference between Unique and Distinct Values.

Unique and Distinct Values

Data can be repeated or unrepeated. These unrepeated data are of two types. They are called unique data and distinct data.

Unique data are those which occur in the dataset only once. 

Whereas, distinct data include the duplicate values but count them only once. 

I will explain unique and distinct data with an example for better understanding.

Consider an example, where column A has the list of people and column B lists their favorite colors. 

In this, red, green, and purple colors occur only once, so they are called unique elements. Therefore the unique elements count is 3

Whereas, there are 8 distinct elements. That is the colors, though repeated are counted once. The colors are red, green, yellow, blue, white, black, gray, and purple. So, the distinct value count is 8.

In this guide, I will show you how to count unique and distinct values in Excel. 

Let’s dive in.

How to Count Unique Values in Excel

First, let us see how to count unique values in excel.

Using SUM, IF, and COUNTIF Functions

In Excel, functions are always available to solve any operations. In this case, you can use a combination of SUM, IF and COUNTIF functions to count unique values in Excel.

To count unique values, enter the formula =SUM(IF(COUNTIF(range, range)=1,1,0)) in the desired cell. The range denotes the starting cell and the ending cell. 

This is an array formula where the count values are stored in a new array. Since this is an array formula, make sure you press Ctrl+Shift+Enter after entering the formula. Also, note that when you enter the formula, curly braces will automatically populate at the end of them. But, do not enter them manually.

Consider the above example. To calculate the unique values in the given Excel sheet, enter the formula in the destination cell. 

In the place of range, enter the cells which contain the elements whose unique value is to be found. Here, cells B3 to B16 house the said elements. So the formula becomes:

=SUM(IF(COUNTIF(B3:B16, B3:B16)=1,1,0))

Now, press Ctrl+Shift +Enter. This gives the count of unique values in the selected range. The unique value count is 3.

Simple, right? Now, let me explain how this formula gives the unique values in 3 simple steps.

1. The COUNTIF function counts the number of unique values in the given range B3 to B16. That is the number of times the value is repeated in the range. These counted values are stored in an array. So, the array becomes [1,1,2,3,2,3,2,2,2,2,2,3,1,2]
2. Then the IF function keeps the unique values(=1) and replaces anything other than 1 with 0. So the array becomes [1,1,0,0,0,0,0,0,0,0,0,0,1,0]
3. Now finally, the SUM function adds the unique value and returns the value 3.

There are two additional cases while using the SUM, IF, and COUNTIF functions. You can use them to find either unique text values or numeric values in Excel.

Count Unique Text Values in Excel

In some tables and worksheets, some texts might be intertwined with numbers. In such cases, you can use the above-mentioned function with a little modification to find the unique text values in Excel.

Enter the formula =SUM(IF(ISTEXT(range)*COUNTIF(range,range)=1,1,0)) in the destination cell and press Ctrl+Shift+Enter. The range denotes the start and end cells that house the elements.

From the general formula, we have added the ISTEXT element to find the unique text values. If the value is a text, the ISTEXT function returns 1 and the value is counted in an array. If the cell houses a non-text value, it returns zero.

The functionality is also similar to the above common formula.

Count Unique Numeric values in Excel

This is a vice versa to the above-mentioned case. In case you only want to count unique numeric values intertwined with texts, you can use the below formula.

Enter the formula =SUM(IF(ISNUMBER(range)*COUNTIF(range,range)=1,1,0)) in the desired cell. The range denotes the start and end cells that hold the values.

Here, the ISNUMBER function returns 1 for numeric values and ignores other values. This function’s working is also similar to the above-mentioned case.

Note: In Excel, date and time are counted as numbers, so they are also counted.

We have seen how to count unique values in excel, we can also count distinct values by using the methods below. 

How to Count Distinct Values in Excel

In Excel, there are two easy methods to find the number of distinct values. 

Using Filter Option

This is an easy and simple method in Excel which gives you the unique values in your data. In this method, you can use the Filter option to pick out the distinct values. This option filters the elements to another row. then, you can use the ROWS function to find out the number of unique elements.

To find the unique rows using the Filter option, first select the rows/columns which have the duplicate elements.

Then, go to Data > Sort & Filter and click on Advanced.

The Advanced Filter dialog box appears. 

Specify the List range: i.e select the cells you need to apply the filter to. You can enter them manually, or click on the Collapse button , select the area and click Expand . 

First, select the Copy to another location. This copied the unique elements onto a new column.

Now, use the collapse and expand button to select the rows you want the unique elements to be copied. 

Finally, check Unique records only. And click OK.

Thus the distinct elements are copied onto a new row. 

To calculate the row count, you can select the columns and click on Quick analysis or Ctrl + Q. Select Totals and click on Row Count. This will give you the row count right below the unique elements. 

Or, you can use the function =ROWS(a:b), where a and b are the starting and ending cells respectively. 

Note: If you click on Filter the list, in-place, the selected values will be replaced in the same column. 

Using SUM and COUNTIF functions

You can use the SUM and COUNTIF functions to calculate the distinct values in Excel. In this case, we will inverse the COUNTIF function to arrive at distinct values.

To count distinct values in excel, first enter the formula =SUM(1/COUNTIF(range, range)) in the desired cell. The range specifies the starting cell and ending cell separated by a colon. This is an array function, so press Ctrl+Shift+Enter to apply the formula. 

Alternatively, you can also use the formula =SUMPRODUCT(1/COUNTIF(range, range)) in the desired cell to count distinct values. This is not an array function, so pressing Enter is sufficient to apply the formula.

Consider the same above-mentioned example. To count the distinct values, enter the formula =SUM(1/COUNTIF(B3:B16, B3:B16)) in the destination cell. Here, the range is B3:B16, so the values in cells B3 to B16 are taken into account.

First, the COUNTIF function counts the number of times the values occur in the given range. This value is stored in an array. Then, this value is divided by 1. So, if a value occurs twice, the value after dividing by 1 will be 0.5. Now, the SUM or SUMPRODUCT function adds up the fractional values and returns the result which is equal to the count of distinct values in the range.

Note: Similarly, you can also tweak the formulae a little to find distinct text values or distinct numeric values.

To find distinct text values: =SUM(IF(ISTEXT(range),1/COUNTIF(range, range),””))

To find distinct text values: =SUM(IF(ISNUMBER(range),1/COUNTIF(range, range),””))

Closing Thoughts

Finding the unique and distinct elements in a large dataset can be used to determine the statistics or probability of the data. 

In this guide, we saw how to count unique and distinct values in Excel. Based on your specifications and preferences, you can either find the count of unique or distinct values.

If you need more high-quality Excel guides, please check out our free Excel resources center.

Simon Sez IT has been teaching Excel for over ten years. For a low, monthly fee you can get access to 100+ IT training courses. Click here for advanced Excel courses with in-depth training modules.