Count pictures in word

In this article, we want to share 4 handy ways with you to get the total count of images in your Word document quickly and correctly.

Every now and then, a document will require multiple images to make it more professional. However, if you are a guy like me who prefer to insert images right after finishing editing, then you will probably worry about whether you’ve left one or two accidentally. Consequently, you will have to scroll up and down painstakingly to check out the total number of images in the document. Given this awkwardness, we offer you 4 really useful methods to save your time.

Method 1: Utilize “Find” Feature

1. First and foremost, click “Home” tab.
2. Then click the button behind “Find” icon.
3. And choose “Advanced Find” on the menu.
4. In “Find and Replace” dialog box, ensure no other text in “Find what” text box and enter “^g” there.
5. Next click “Find In” and choose “Main Document”.

Now there is the result on the dialog box, showing the number of inline shapes in this document. This means the “Find” feature can only count images set in “In line with text” wrapping style.

Method 2: Use “Go To” Feature

1. Firstly, press “Ctrl+ Home” to go to the beginning of the document and repeat first 2 steps in method 1.
2. This time choose “Go To” instead.
3. Then select “Graphic”.
4. Enter nothing in text box and click “Next”.

Each time you click “Next”, Word will bring you to the net graphic and you need to count by yourself. Still, this way includes only the inline shapes.

Here is a video demonstration:

Method 3: Press “Tab” Key

1. To start with, click on the first image on the document.
2. Next press “Tab” and the next image will be selected. Remember to count by yourself.

Luckily, method 3 includes both inline shapes and floating shapes like text boxes.

Method 4: Run Word Macro

1. At first, click “Developer” tab.
2. Then click “Visual Basic” to open VBA editor.
3. Next click “Insert” and choose “Module” to insert a new one under “Normal” project.
4. Double click on the new module to open the coding space.
5. And paste the following codes there:

Sub CountImages()
  Dim objDoc As Document
  Dim nFlowingShapes As Long, nInlineShapes As Long, nTextBox As Long, nTotalShapes As Long
  Dim objShape As Shape
 
  Set objDoc = ActiveDocument
  nTextBox = 0
 
  For Each objShape In objDoc.Shapes
    If objShape.Type = msoTextBox Then
      nTextBox = nTextBox + 1
    End If
  Next objShape
 
  nFlowingShapes = objDoc.Shapes.Count
  nInlineShapes = objDoc.InlineShapes.Count
  nTotalShapes = nFlowingShapes + nInlineShapes - nTextBox
 
  MsgBox "There are " & nTotalShapes & " images in this document, " & "with " & nFlowingShapes & " flowing shapes, " & nTextBox & "text boxes, and " & nInlineShapes & " inline shapes."
End Sub

1. Finally, click “Run”.

There shall be a message box, indicating the result.

Tool to Fix Word

Word is susceptible to errors and mistakes. And once it stops working, the shut down can wreak havoc with our Word files, which shall be a huge setback for us mentally. Nevertheless, there is still the remedy for having the broken files back that is to obtain a sophisticated tool to repair Word.

Author Introduction:

Vera Chen is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including xls repair and pdf repair software products. For more information visit www.datanumen.com

Word: graphics, or pictures count

Please Note:
This article is written for users of the following Microsoft Word versions: 97, 2000, 2002, and 2003. If you are using a later version (Word 2007 or later), this tip may not work for you. For a version of this tip written specifically for later versions of Word, click here: Counting All Graphics.

Bob needs to count all the graphics in a document. Some of the graphics are inline and some are floating. Some were inserted as pictures and some were created using the drawing tools in Word. Bob suspects there is somewhere between 150 and 200 graphics in the document, but he’d love a way to get a fast count.

There are a couple of things you can try to get your graphics count. The first thing is to use a simple search and replace. All you need to do is search for ^g and replace with ^&. That finds any graphic and replaces it with whatever was found. In other words, there are no changes to your document. However, Word informs you, when it is done, about how many «replacements» were made. This count is the number of graphics in your document.

The problem with this approach is that it counts only inline images within the document. It does not «find and replace» anything on the drawing layer. To get all the images, you’ll need to try a different approach. For instance, you could use the Go To feature of Word. Press F5 to display the Go To tab of the Find and Replace dialog box. If you pick Graphic in the right side of the screen, you can step through the graphics in the document by clicking on the Next button. If you have a bunch of graphics, you could simply put something like +150 in the box and click on Go To. You’ll jump to that graphic number, if it is available, and you can then step through the remaining ones, counting as you go.

This approach is better at finding graphics than the find-and-replace approach. It is not perfect, however, as there are places in your document where graphics can be placed that won’t be caught by Go To. (Or, honestly, by the Object Browser, which uses the same finding mechanism as Go To.) This approach finds graphics that are inline and on the drawing layer. It does not, however, find them in other places, such as headers or footers. To find those and include them in the count, you’ll need to use a macro. The following is a macro that will provide a more inclusive graphics count:

Sub CountGraphics()
    Const sBkMk = "ReturnHere"

    Dim lngSections As Long
    Dim lngSectionCounter As Long
    Dim lngMainDocInlineShapes As Long
    Dim lngMainDocShapes As Long
    Dim lngHdrInlineShapes As Long
    Dim lngHdrShapeRange As Long
    Dim lngFtrInlineShapes As Long
    Dim lngFtrShapeRange As Long
    Dim lngTotalInlineShapes As Long
    Dim lngTotalShapes As Long
    Dim sMsgText As String

    Application.ScreenUpdating = False

    'Get the number of sections in the document.
    lngSections = ActiveDocument.Sections.Count

    'Get the number of inline objects and
    'shape objects in the main document
    lngMainDocInlineShapes = ActiveDocument.InlineShapes.Count
    lngMainDocShapes = ActiveDocument.Shapes.Count

    'Insert a bookmark to return to this place in the document.
    ActiveDocument.Bookmarks.Add sBkMk, Selection.Range

    'Go to the first page of the document.
    Selection.HomeKey wdStory, wdMove

    'Cycle through all of the sections in the document
    'looking in headers and footers for graphics
    For lngSectionCounter = 1 To lngSections
        'Go to the header of the current page
        ActiveDocument.ActiveWindow.View.SeekView = wdSeekCurrentPageHeader
        Selection.WholeStory
        'Get the number of inline objects and shape objects
        lngHdrInlineShapes = lngHdrInlineShapes _
          + Selection.Range.InlineShapes.Count
        lngHdrShapeRange = lngHdrShapeRange _
          + Selection.Range.ShapeRange.Count

        'Go to the footer of the current page
        ActiveDocument.ActiveWindow.View.SeekView = wdSeekCurrentPageFooter
        Selection.WholeStory
        'Get the number of inline objects and shape objects
        lngFtrInlineShapes = lngFtrInlineShapes _
          + Selection.Range.InlineShapes.Count
        lngFtrShapeRange = lngFtrShapeRange _
          + Selection.Range.ShapeRange.Count

        Selection.GoTo wdGoToSection, wdGoToNext
    Next

    'Go to the main body of the document.
    ActiveDocument.ActiveWindow.View.SeekView = wdSeekMainDocument

    'Enable automatic screen updates
    Application.ScreenUpdating = True
    Application.ScreenRefresh

    'Go to the bookmark that was inserted earlier.
    If ActiveDocument.Bookmarks.Exists(sBkMk) Then
        Selection.GoTo wdGoToBookmark, , , sBkMk
        ActiveDocument.Bookmarks(sBkMk).Delete
    Else
        MsgBox "The bookmark '" & sBkMk & "' does not exist."
    End If

    'Calculate the total number of inlineshape objects
    'and (shape and shaperange) objects
    lngTotalInlineShapes = lngMainDocInlineShapes _
      + lngHdrInlineShapes + lngFtrInlineShapes
    lngTotalShapes = lngMainDocShapes _
      + lngHdrShapeRange + lngFtrShapeRange

    'Include the values from the variables into the
    'text of the message
    sMsgText = vbTab & vbTab & "Inline Shapes" _
      & vbTab & "Other Shapes" & vbCr _
      & "Main Document:" & vbTab & lngMainDocInlineShapes _
      & vbTab & vbTab & lngMainDocShapes & vbCr _
      & "Headers:" & vbTab & vbTab & lngHdrInlineShapes _
      & vbTab & vbTab & lngHdrShapeRange & vbCr _
      & "Footers:" & vbTab & vbTab & lngFtrInlineShapes _
      & vbTab & vbTab & lngFtrShapeRange & vbCr _
      & "Total:" & vbTab & vbTab & lngTotalInlineShapes _
      & vbTab & vbTab & lngTotalShapes & vbCr & vbCr _
      & "Note: The values for the headers and the footers " _
      & "could include duplicates."

    'Display the results of the procedure.
    MsgBox sMsgText
End Sub

Note that the macro gets not just the number of graphics in the main document, but also steps through each section in the document and examines the headers and footers for any graphics. There are a couple of things to remember with this macro that can affect the accuracy of the count returned. All of these items are part and parcel to how Word deals with graphics in a document.

• If the document contains a drawing canvas, it is treated as a single graphic (a shape object), regardless of the number of individual shapes that it contains.
• Separate shapes are counted separately. When separate shapes are grouped together, then they are counted as a single shape.

Finally, there is one other way in which you can try to get a count of graphics—simply save your document as a Web page (in HTML format). As part of the process of saving in this way, Word saves the graphic files in the document to their own folder. All you need to then do is look at the number of files in the folder and you’ll have a good idea of how many graphics were in the document. (How you save a document in HTML format is covered in other WordTips.)

Author Bio

With more than 50 non-fiction books and numerous magazine articles to his credit, Allen Wyatt is an internationally recognized author. He is president of Sharon Parq Associates, a computer and publishing services company. Learn more about Allen…