Count if this and this excel

In this example, the goal is to count cells in the range D5:D15 that contain «red» or «blue». For convenience, the D5:D15 is named color. Counting cells equal to this OR that is more complicated than it first appears because there is no built-in function for counting with OR logic. The COUNTIFS function will allow multiple conditions, but all conditions are joined with AND logic. The article below explains several options.

COUNTIF + COUNTIF

A simple, manual way to count with OR is to use the COUNTIF function more than once:

=COUNTIF(color,"red") + COUNTIF(color,"blue")

In both cases, the range argument inside COUNTIF is color (D5:D15). However, criteria is «red» in the first COUNTIF and «blue» in the second. The first COUNTIF returns 4 and the second COUNTIF returns 3, so the final result is 7. This formula works fine, but it is somewhat redundant.

COUNTIF with array constant

Another way to configure COUNTIF is with an array constant that contains more than one value to use for criteria. This is the method used in the example shown above:

=SUM(COUNTIF(color,{"red","blue"}))

Inside the SUM function, the COUNTIF function is given color (D5:D16) for range and {«red»,»blue»} for criteria:

COUNTIF(color,{"red","blue"}) // returns {4,3}

This causes the COUNTIF function to return two counts: one for «red» and one for «blue». These counts are returned directly to the SUM function in a single array:

=SUM({4,3}) // returns 7

And SUM returns 7 as the result. In other words, COUNTIF returns multiple counts to SUM, and SUM returns a final result. This is an example of nesting one formula inside another.

For more complicated scenarios, see: COUNTIFS with multiple criteria and or logic

SUMPRODUCT function

Another way to solve this problem is with the SUMPRODUCT function like this:

=SUMPRODUCT((D5:D15="red")+(D5:D15="blue"))

This is an example of using Boolean logic. Inside SUMPRODUCT there are two expressions joined by the addition (+) operator. Because color contains 11 values, each expression creates an array with 11 TRUE and FALSE values:

=SUMPRODUCT({TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE}+{FALSE;FALSE;TRUE;FALSE;TRUE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE})

In the first array, the TRUE values correspond to cells that contain «red». In the second array, the TRUE values correspond to cells that contain «blue». When the two arrays are added together, the math operation converts the TRUE and FALSE values to 1s and 0s:

=SUMPRODUCT({1;1;1;0;1;0;1;0;1;1;0})

With just one array to process SUMPRODUCT sums the items in the array and returns 7 as a result. Another way to configure SUMPRODUCT is like this:

=SUMPRODUCT(--(D5:D15={"red","blue"}))

In this formula, the expression:

D5:D15={"red","blue"})

Returns a single array with 11 rows and 2 columns. The double negative coerces the TRUE and FALSE values to 1s and 0s:

=SUMPRODUCT({1,0;1,0;0,1;0,0;0,1;0,0;1,0;0,0;0,1;1,0;0,0})

And SUMPRODUCT again returns 7 as a final result.

For more complex scenarios see: SUMPRODUCT with multiple criteria and OR logic and Count cells equal to one of many things.

Double-counting risk

When counting with OR logic, be aware of the risk of double-counting. In this particular example, the values «red» and «blue» are values in the same field, so there is no danger in double-counting. However, if you are counting records where one field is «red» OR another field is «blue», take care not to double-count, since both can be true at the same time in the same record.

In our article, Count Cells That Contain Specific Text, we counted each cell that contains a specific text. In this article we will learn how to count cells that contains either this or that value. In other words, counting with OR logic.

You may think that you can use COUNTIF function two times and then add them up. But that is a wrong turn. You’ll know why.

Generic Formula

“This”: it is the first text you want count in the range. It can be any text.
“That”: it is the second text that you want to count in range. It can be any text.
Range: This is the range or array containing text in which you will count for your specific texts.

Let’s see an example:

Example:
Here I have feedback comments in range A2 to A8. I want to count the number of comments containing “good” or “nice” words.

To count cells containing specific texts “good” or “nice” write this formula:

You can see that there are four comments that contain either “good” or “nice.”

How it works?

Let’s start from inside.

SEARCH(«good»,A2:A8): this part returns an array of #VALUE error and numbers, representing the position of found text. {8;#VALUE!;#VALUE!;#VALUE!;#VALUE!;30;24}

ISNUMBER(SEARCH(«good»,A2:A8)): this part of the formula checks each value in array return by SEARCH function, if it is a number or not, and returns an array of TRUE and FALSE. For this example, it returns {TRUE;FALSE;FALSE;FALSE;FALSE;TRUE;TRUE}.

ISNUMBER(SEARCH(«nice»,A2:A8)): this part of formula does the same, but this time it looks for “nice” word in cell and returns an array of the TRUE and FALSE base on cell contains the “nice.”

Next, we have added these arrays using + sign. It boolean values into 1 and 0 and adds them up. Internally it will look like this, {1;0;0;0;0;1;1}+{0;1;0;0;0;1;0}={1;1;0;0;0;2;1}.

You can see that comment in A7 has both texts “nice” and “good.” And it is double-counted here. We don’t want it. So we make another comparison for converting every number into True and False.

((ISNUMBER(SEARCH(«good»,A2:A8)) + ISNUMBER(SEARCH(«nice»,A2:A8)))>0): This part of formula converts the resultant array into TRUE and FALSE. If the value is greater than 0, it is TRUE else FALSE. Here it will be {TRUE;TRUE;FALSE;FALSE;FALSE;TRUE;TRUE}.

The number of TRUE in the array is the name of the string contain “good” or “nice” words.
SUMPRODUCT(—((ISNUMBER(SEARCH(«good»,A2:A8)) + ISNUMBER(SEARCH(«nice»,A2:A8)))>0))

Next we use — negative symbols to convert them into numbers. And finally SUMPRODUCT sums up the array to return number of cells containing “good” or “nice”.
You can also use the SUM function, but then you’ll have to enter this formula as an array formula.

Why not use COUNTIFS?

Because of double counts.

If a cell contains both of the texts, then it will be counted twice, which is not correct in this scenario.
But if you want it to happen then use this formula,

=SUM(COUNTIFS(A2:A8,{«*nice*»,»*good*»}))

It will return 5 in our example. I have explained it here.

Making Case Sensitive Count

The proposed solution counts the given text irrespective of the case of letters. If you want to count case sensitive matches, then replace SEARCH function with FIND function.

The FIND function is case sensitive function. It returns the position of found text.

So yeah guys, this how you can count the number of cells that contain either this text or that. You can also click on the function names in the formula to read about that function. I have understandably elaborated them.

Related Articles:

How to Check If Cell Contains Specific Text in Excel

How to Check a list of Texts In String in Excel

Get COUNTIFS Two Criteria Match in Excel

Get COUNTIFS With OR For Multiple Criteria in Excel

Popular Articles :

50 Excel Shortcut to Increase Your Productivity : Get faster at your task. These 50 shortcuts will make you work even faster on Excel.

How to use the VLOOKUP Function in Excel : This is one of the most used and popular functions of excel that is used to lookup value from different ranges and sheets.

How to use the COUNTIF function in Excel : Count values with conditions using this amazing function. You don’t need to filter your data to count specific values. Countif function is essential to prepare your dashboard.

How to use the SUMIF Function in Excel : This is another dashboard essential function. This helps you sum up values on specific conditions.