Count if and sum if in excel

SUMIF, SUMIFS, COUNTIF, and COUNTIFS are extremely useful and powerful for data analysis. If there was an Excel Function Hall of Fame, this family of functions ought to be included. In this article, I’ll demonstrate a bunch of different ways to use these functions, focusing mainly on all the different criteria types.

The SUMIF and COUNTIF functions allow you to conditionally sum or count cells based on a single condition, and are compatible with almost all versions of Excel:

=SUMIF(criteria_range, criteria, sum_range)

=COUNTIF(criteria_range, criteria)

The SUMIFS and COUNTIFS functions allow you to use multiple criteria, but are only available beginning with Excel 2007:

=SUMIFS(sum_range, criteria_range1, criteria1, criteria_range2, criteria2,...)

=COUNTIFS(criteria_range1, criteria1, criteria_range2, criteria2,...)

AVERAGEIF and AVERAGEIFS are also part of this family of functions and have the same syntax as SUMIF and SUMIFS.

1) SUMIF and COUNTIF Examples

We’ll start off by using a product sales table to demonstrate a few different SUMIF and COUNTIF formulas. I’ve listed a few of these examples below. To see these formulas in action and try them out yourself, you can download the example file below:

Download the Example File (SumIf-CountIf.xlsx)

Criteria are Text Values

Example: Sum of Sales where Category equals «student»

=SUMIF(category_range,"student",sales_range)

NOTE This formula will also match «Student» because the SUMIF family of functions are not case-sensitive. You can use wildcard characters within the text string, such as «?s*» to match values where the second letter is s.

Not Equal To (<>)

Example: Sum of Sales where Model is NOT equal to «B»

=SUMIF(model_range,"<>B",sales_range)

Example: Sum of Sales where Category does NOT contain the letter «u»

=SUMIF(category_range,"<>*u*",sales_range)

Criteria is an Alphabetical Text Comparison

Example: Sum of Sales where Model is less than «C»

=SUMIF(model_range,"<C",sales_range)

Criteria is a Numeric Comparison

Example: Number of products priced over $40

=COUNTIF(price_range,">40")

NOTE When using numeric criteria, COUNTIF and SUMIF ignore text values. Numeric date values can be an exception to that (see below for date comparisons).

Criteria matches Blank Cells or Empty Cells

Example: Count of products where On Sale is blank

=COUNTIF(on_sale_range,"")

Criteria matches Non-Blank Cells

Example: Number of products on sale (where On Sale is not blank)

=COUNTIF(on_sale_range,"<>")

Criteria includes a Cell Reference

Example: Sum of Sales where Price is greater than the value in cell H3

=SUMIF(price_range,">"&H3,sales_range)

Criteria is In Another Cell

Example: Sum of Sales using the criteria defined in cell K9

=SUMIF(criteria_range,K9,sales_range)

Multiple Criteria

Example: Sum of Sales where Category = «student» AND Price > 30

=SUMIFS(sales_range,category_range,"student",price_range,">30")

Example: SUMIFS between two dates

=SUMIFS(sum_range,date_range,">=1/1/2017",date_range,"<1/31/2017")

NOTE The SUMIFS, COUNTIFS, and AVERAGEIFS functions are used for multiple AND conditions. Formulas for OR conditions are a bit more tricky (see below).

2) Using Dates as Criteria

When using dates as criteria for the COUNTIF and SUMIF functions, Excel does some interesting things, depending on whether you are using «=» or «<» as the criteria and whether the dates in the criteria range are stored as numeric date values or text values.

Remember: Date values are stored in Excel as sequential numbers starting with 1 for 1/1/1900. The cell formatting may display the date in different ways, but COUNTIF and SUMIF comparisons are based on the value stored in the cell, not the way a cell is formatted. That is a good, because we normally want to compare dates and numbers without having to worry about how they are formatted.

Criteria is a Date

=COUNTIF(criteria_range,"=3/1/17")

When using criteria such as «=3/1/17» or «Mar 1, 2017», Excel will recognize the criteria as a date and will count all date values in the criteria_range matching that date. Excel will ALSO count recognized dates stored as text values in the criteria_range, such as «March 1, 2017» and «3/1/2017» (but not «March 1st, 2017» because Excel doesn’t recognize it as a date).

Criteria is Greater or Less than a Date

=COUNTIF(criteria_range,">3/1/17")

When using <, >, <=, or >=, Excel still recognizes the criteria as a date, but it does not convert text values in the criteria_range to date values.

Comparison to TODAY

You can use the TODAY function to make comparisons based on the current date, like this:

=SUMIF(date_range,"<"&TODAY(),sum_range)

3) SUMIFS Example: Income and Expense Report

SUMIFS is very useful in account registers, budgeting, and money management spreadsheets for summarizing expenses by category and between two dates.

The SUMIFS example below sums the Amount column with 3 criteria: (1) the Category matches «Fuel», (2) the Date is greater than or equal to the start date, and (3) the Date is less than or equal to the end date.

=SUMIFS(amount_range, category_range, "Fuel", date_range, ">=1/1/2018", date_range, "<=1/31/2018")

The following screenshot shows an example from the download file:

4) SUMIF and COUNTIF Between Two Numbers (1 < x < 4)

COUNTIFS and SUMIFS can easily handle a condition such as 1 < x < 4 (which means x > 1 AND x < 4). However, if you are trying to make a spreadsheet compatible with older versions of Excel, you can use COUNTIF or SUMIF by subtracting the results of the condition x <= 1 from the results of the condition x < 4.

A common need for these formulas is to sum values between two dates. Remember that date values are stored as numbers.

Example: SUMIF between two dates ( 1/1/2017 <= date <= 1/31/2017 )

=SUMIF(sum_range,date_range,"<=1/31/2017")-SUMIF(sum_range,date_range,"<1/1/2017")

5) SUMIF and COUNTIF with OR Conditions

COUNTIFS and SUMIFS handle multiple AND conditions, but OR conditions such as X<2 OR X>3 are usually easier to handle by evaluating each condition separately and then adding the results. The two formulas below do essentially the same thing.

To avoid double-counting cells, the conditions must not overlap. For example, the condition «=*e*» would overlap with the condition «=yes». The condition «<40» would overlap with the condition «>20». If the conditions overlap, you may end up counting or adding a value twice. If there is a possibility of conditions overlapping, then you may need to use a SUMPRODUCT formula as explained below.

Use SUMPRODUCT for overlapping OR conditions

The key to avoid double-counting is to recognize that FALSE+FALSE=0 and TRUE+FALSE=1 and TRUE+TRUE=2. This means that for a logical OR condition to be true, we can check whether the sum of two or more conditions is > 0.

Sum of Sales where Model is equal to A or B.

=SUMPRODUCT(sales,1*( ((model="A")+(model="B"))>0 ))

Sum of Sales where Model = «A» or Price > 45

=SUMPRODUCT(sales,1*( ((model="A")+(price>45))>0 ))

6) Case-Sensitive SUMIF and COUNTIF

The SUMIF family does not have a case-sensitive option, so we need to resort back to using array formulas or SUMPRODUCT. The FIND and EXACT functions both provide a way to do case-sensitive matches.

Sum of Sales where Category exactly matches «student» (case-sensitive)

=SUMPRODUCT(sales,1*EXACT(category,"student"))

Sum of Sales where Category contains «Stu» (case-sensitive)

=SUMPRODUCT(sales,1*ISNUMBER(FIND("Stu",category)))

7) MAXIF or MINIF Formula

MAXIFS and MINIFS are new Excel functions available in the latest releases (Excel for Microsoft 365, Excel 2019). Their syntax is similar to SUMIFS, allowing you to use multiple criteria.

Older versions of Excel do not have the MAXIFS or MINIFS functions, but you can use an array formula like this (remember to press Ctrl+Shift+Enter):

Example: Find the maximum Price where Model = «A»

(array formula) =MAX(IF(model_range="A",price_range,""))

Summary of Different Criteria Types

Some criteria, such as case-sensitive matches, may only be possible with array formulas or SUMPRODUCT.

You don’t use the functions AND, NOT, OR, ISBLANK, ISNUMBER, ISERROR, or other similar functions as criteria for SUMIF and COUNTIF. However, you can use these functions within a SUMPRODUCT formula (but that isn’t within the scope of this article).

9) Other Notes

• Comparisons are based on the value stored in the cell, not on how the cell is formatted.
• Error values in both the sum_range and criteria_range are ignored.
• SUMIFS and COUNTIFS formulas are generally faster than their SUMPRODUCT or array formula counterparts.
• The sum_range and criteria_range arguments can be references (e.g. A2:A42), named ranges or formulas that return a range (such as INDEX, OFFSET, or INDIRECT).
• Normally, you’ll want the sum_range and criteria_range to be the same length. See the documentation on the Microsoft sites (referenced below) for information about what happens when the sum_range and criteria_range are not the same length.
• The COUNTIF and SUMIF criteria can be a range (e.g. A2:A3) if you enter the formula as an array formula using Ctrl+Shift+Enter.
• The COUNTIF and SUMIF criteria can be a list such as {«>1″,»<4»}, but functions return an array containing results for the separate conditions, not a sum of both conditions (it is not the same as COUNTIFS or SUMIFS).

Some Templates that Use SUMIF

• Invoice Tracker — Uses SUMIF to create an Aging table that shows unpaid invoices past 30 days, 60 days, etc.
• Account Register — Uses a cumulative SUMIF formula to show the current account balance within the register.
• Weekly Money Manager — Uses SUMIF to show actual spending within a budget report.
• Checkbook Register — Uses SUMIF to show the current cleared balance based on whether the reconcile column contains «r» or «c».

References

• Spreadsheet Tips Workbook — vertex42.com — by Jon Wittwer and Brent Weight
• SUMIF Function — support.office.com — The official documentation of the SUMIF function.
• SUMIFS Function — support.office.com — The official documentation of the SUMIFS function.
• COUNTIF Function — support.office.com — The official documentation of the COUNTIF function.
• COUNTIFS Function — support.office.com — The official documentation of the COUNTIFS function.
• SUMIFS With Multiple Criteria and OR Logic — at exceljet.net — Describes how the function works when you use an array for the criteria such as {«=A»,»=B»}.

Learning Microsoft Excel is all about adding more and more formulas and functions to your toolbelt. Combine enough of these, and you can do practically anything with a spreadsheet.

In this tutorial, you’ll learn how to use three powerful Excel formulas: SUMIF, COUNTIF, and AVERAGEIF.

In the screenshot above, you can see that we have a list of transactions on the left side. If I want to keep an eye on my spending, I can use these three formulas to monitor it. 

On the right side, the Dining Out Expense box uses the three formulas to help me track my expenses:

• COUNTIF — Used to count the number of times that «Restaurant» appears in the list.
• SUMIF — Calculates the total expense for items labeled «Restaurant.»
• AVERAGIEF — Averages out all of my «Restaurant» expenses in the list.

More generically, here’s what each of those formulas do for you, and how you might use them to your advantage:

• SUMIF — Add values if a condition is met, such as adding up all purchases from one category.
• COUNTIF — Count up the number of items that meet a condition, such as counting the number of times a name appears in a list.
• AVERAGEIF — Conditionally average values; for instance, you could average your grades for only exams.

These formulas allow you to add logic to your spreadsheet. Let’s look at how to use each formula.

COUNTIF, SUMIF, and AVERAGEIF in Excel (Quick Video Tutorial)

Screencasts are one of the best ways to watch and learn a new skill, including getting started with these three key formulas in Microsoft Excel. Check out the video below to watch how I work in Excel. Make sure and download the free example workbook to use with this tutorial.

If you prefer to learn with written, step-by-step instructions, keep reading. I’ll share tips for how to use these formulas and ideas for why they’re useful.

How to Use SUMIF in Excel

Use the tab titled SUMIF in the free example workbook for this section of the tutorial.

Think of SUMIF as a way to add values that meet a rule. We can add up a list of values that are from a certain category, or all values greater than or less than a specific amount.

Here’s how the SUMIF formula works:

=SUMIF(Cells to check, what to check for, Sum of cells that meet the rules)

Let’s go back to my restaurant expense example to learn the SUMIF formula. Below, I show a list of my transactions for the month.

I want to know two things:

1. The total of what I spent at restaurants for the month.
2. All purchases greater than $50 for the month, from any category.

Instead of manually adding data up, we can write two SUMIF formulas to automate the process. I’ll put the results in the green Restaurant Expense box on the right side. Let’s look at how.

Total Restaurant Expense

To find my total restaurant expense, I’ll sum up all values with the expense type of «Restaurant», which is in column B.

Here’s the formula I’ll use for this example:

=SUMIF(B2:B17,"Restaurant",C2:C17)

Notice that each section is separated by a comma. This formula does three key things:

• Looks at what’s in cells B2 to B17 for the category of expense
• Uses «Restaurant» for the criteria of what to sum up
• Uses the values in cells C2 to C17 to total up the amounts

When I press enter, Excel calculates the total of my restaurant expenses. Using SUMIF, it’s easy to create these quick statistics to help you monitor data of certain types.

Purchases Greater Than $50

We’ve checked for a specific category, but now let’s sum up all values that are greater than an amount from any category. In this case, I want to find all purchases that were more than $50.

Let’s write a simple formula to find the sum of all purchases greater than $50:

=SUMIF(C2:C17,">50")

In this case, the formula is a bit simpler: since we’re summing up the same values that we’re testing (C2 to C17), we just need to specify those cells. Then, we’ll add a comma and «>50» to only sum values greater than $50.

This example uses a greater than sign, but for bonus points: try to sum up all small purchases, such as all purchases $20 or less.

How to Use COUNTIF in Excel

Use the tab titled COUNTIF in the free example workbook for this section of the tutorial.

While SUMIF is used to add values that meet a certain condition, COUNTIF will count up the number of times something appears in a given set of data.

Here’s the general format for the COUNTIF formula:

=COUNTIF(cells to count, criteria to count)

Using the same set of data, let’s count two key pieces of information:

• The number of clothing purchases I made in a month
• The number of purchases $100 or greater

Number of Clothing Purchases

My first COUNTIF will look at the expense type and count up the number of «Clothing» purchases in my transactions.

The final formula will be:

=COUNTIF(B2:B17,"Clothing")

That formula looks at the «Expense Type» column, counts up the number of times it sees clothing, and counts them. The result is 2.

Number of $100+ Purchases

Now, let’s count the number of transactions that were $100 or greater in my list. 

Here’s the formula I’ll use:

=COUNTIF(C2:C17,">100")

This is a simple, two part formula: simply point Excel to the list of data to count, and the rule to count. In this case, we’re checking cells C2 to C17, for all values greater than $100. 

How to Use AVERAGEIF in Excel

Use the tab titled AVERAGEIF in the free example workbook for this section of the tutorial.

Last up, let’s look at how to use an AVERAGEIF formula. By now, it should be no surprise that AVERAGEIF can be used to average specific values, based on a condition that we’ll give Excel.

The format for an AVERAGEIF formula is:

=AVERAGEIF(Cells to check, what to check for, Average of cells that meet the rules)

The format of the AVERAGEIF formula is most similar to the SUMIF formula.

Let’s use the AVERAGEIF formula to calculate two key stats about my spending:

1. The average of my restaurant expenses.
2. The average of all expenses less than $25.

Average of Restaurant Purchases

To average my restaurant expenses, I’ll write an AVERAGEIF formula to average all amounts based on the category.

=AVERAGEIF(B2:B17,"Restaurant",C2:C17)

There are three parts to this formula, each separated by a comma:

• B2:B17 specifies the cells to check a condition for. Since the expense type is specified in this column.
• «Restaurant» gives the formula something to look for.
• Finally, C2:C17 are the cells to average out in our calculation.

At the end, Excel averages out the expense of my restaurant trips. I’ve given it that formula.

You can also try out this formula by replacing «Restaurant» with another category, like «Clothing.»

Average of Expenses Less than $25

If I’m keeping an eye on my smaller purchases and want to know my average, I can write an AVERAGEIF for all purchases less than an amount.

Here’s the formula that I’ll use to do that:

=AVERAGEIF(C2:C17,"<25")

This simple formula just checks the values in column C, and averages all values greater than $25.

Recap and Keep Learning

In this tutorial, you learned how to use three conditional math formulas to review your data. Whether you’re summing, counting, or averaging data, these functions are advanced Excel skills you can put to good use.

For all of the «IF» formulas in this tutorial, the key takeaway is that you can apply conditions to your calculations in Excel.

Learning begets learning. Here are three more Excel tutorials to keep growing:

• In addition to COUNTIF, SUMIF, and AVERAGEIF, there are also general «IF» statements that can be used for other conditions. Check out our tutorial on How to Use Simple IF Statements.
• Learn to use Excel Dates and Times in conjunction with these formulas to work with values based upon date.
• The Excel VLOOKUP function can be used to match values from multiple lists. Learn more about How to Use the Excel VLOOKUP Function in this tutorial.

Can you think of other ways to use these formulas to add logic and conditions to your spreadsheet? Let me know with a comment below.

I wanted to continue building on my popular series on how to use IF statements and nested IF statements with “and, or, not” in Excel by discussing two additional and very useful functions called countif and sumif. Surprisingly, they’re not as widely used as you’d expect, and sometimes knowing which to use is a bit confusing.

Countif is a function that will count (as in 1, 2, 3…) the number of entries within a range if certain criteria are met, and the data within each entry can be text or numbers.

Sumif, on the other hand, is a function that will add the total number of numerical entries within a range if certain criteria are met. This means that sumif only works with numbers when adding up figures, so if your range includes any text, those will be ignored. Let’s walk through a simple example.

Suppose you have the following simple table of sales by type and # for each year from 2003-2009:

And what you’d like to know is how many sales of each type (in your store vs. by phone vs. online) were done in total. Countif will help you figure that out quickly. First, let’s enter the type of sale we’re interested in in a column to the right:

Next, we’ll type in the “countif” function. As you can see, countif takes two inputs, the range you’re interested in and the criteria that need to be met:

In our case, the data (store type) is in column B, so we input that into the first part of the countif function:

Next, we want each entry to be counted only if the type of sale was “store”, or what we’ve typed into cell E2:

Note that if we hadn’t typed in “store” in E2, we could type it directly into the function like this:

=countif(B2:B20, “store”)

By the way, remember to always put quotation marks (“”) around the criteria when working with text!

Either way, once we close the parenthesis and hit , we immediately get the result. There were 7 sales from 2003-2009 that took place at the store (one for each year).

Repeating the same thing for “telephone”:

We find the same result — 7 sales. Now let’s check “online”:

Turns out we had less online sales (maybe because we didn’t launch a website that accepted sales until 2005):

That’s fine and dandy, but not particularly useful info. How about if we wanted to know the total number of sales by type for the entire period? In that case, we’d want to use the sumif function.

For “store” sales, we’d enter in sumif and the appropriate inputs as
follows. First, sumif takes in slightly different inputs than countif.

The first input is the range that you’re interested in, very similar to countif:

The second input is the criteria, which in this case is also identical to what we put in for countif above:

But sumif also takes one additional argument: the range to be summed. In this case, we want to know the total number of sales, which is in column C:

Closing out the parenthesis, we find that we had 211 total sales in the store from 2003-2009:

Again, let’s repeat the same thing to find the total number of telephone sales:

…and online sales:

See the difference between what countif gives and what sumif gives?

Note that sumif can also take in different criteria. Let’s suppose we wanted to know the total number of sales that have taken place starting in 2008, regardless of type. To do this, we could make our range the year, found in column A:

and then add in the criteria of “>= 2008”:

Finally, we again want to sum up the total number of sales, which is in column C:

Closing out our final parenthesis, we get that we have had a total of 141 sales from 2008-2009:

Finally, just a quick example here will show what happens if you put in non-numerical data to sum using the sumif function. Let’s change the number of store sales in 2008 from “37” to “nonsense” and see what happens:

Notice how the calculations automatically ignore that entry, and the total number of store sales and the total number of sales since 2008 both drop by 37.

That’s it for now. A quick intro tutorial to using countif and sumif. Like most other Excel functions, these can get as complicated as you’d like (at the expense of readability), so always try to keep it as simple as possible.

***************************************************

Look Good at Work and Become Indispensable Become an Excel Pro and Impress Your Boss

***************************************************