Что такое диапазон суммирования в excel суммесли - Word и Excel

Excel для Microsoft 365 Excel для Microsoft 365 для Mac Excel для Интернета Excel 2021 Excel 2021 для Mac Excel 2019 Excel 2019 для Mac Excel 2016 Excel 2016 для Mac Excel 2013 Excel 2010 Excel 2007 Excel для Mac 2011 Excel Starter 2010 Еще…Меньше

Функция СУММЕСЛИ используется, если необходимо просуммировать значения диапазон, соответствующие указанному критерию. Предположим, например, что в столбце с числами необходимо просуммировать только значения, превышающие 5. Для этого можно использовать следующую формулу: =СУММЕСЛИ(B2:B25;»> 5″)

Это видео — часть учебного курса Сложение чисел в Excel.

Советы:

При необходимости условия можно применить к одному диапазону, а просуммировать соответствующие значения из другого диапазона. Например, формула =СУММЕСЛИ(B2:B5; «Иван»; C2:C5) суммирует только те значения из диапазона C2:C5, для которых соответствующие значения из диапазона B2:B5 равны «Иван».
Если необходимо выполнить суммирование ячеек в соответствии с несколькими условиями, используйте функцию СУММЕСЛИМН.

Важно: Функция СУММЕСЛИ возвращает неверные результаты при использовании для сопоставления строк длиной более 255 символов или строкового #VALUE!.

Синтаксис

СУММЕСЛИ(диапазон; условие; [диапазон_суммирования])

Аргументы функции СУММЕСЛИ описаны ниже.

Диапазон — обязательный аргумент. Диапазон ячеек, оцениваемых на соответствие условиям. Ячейки в каждом диапазоне должны содержать числа, имена, массивы или ссылки на числа. Пустые и текстовые значения игнорируются. Выбранный диапазон может содержать даты в стандартном формате Excel (см. примеры ниже).
Условие .Обязательный аргумент. Условие в форме числа, выражения, ссылки на ячейку, текста или функции, определяющее, какие ячейки необходимо суммировать. Можно включить подстановочные знаки: вопросительный знак (?) для сопоставления с любым одним символом, звездочка (*) для сопоставления любой последовательности символов. Если требуется найти непосредственно вопросительный знак (или звездочку), необходимо поставить перед ним знак «тильда» (~).

Например, критерии можно выразить как 32, «>32», B5, «3?», «apple*», «*~?» или TODAY().

Важно: Все текстовые условия и условия с логическими и математическими знаками необходимо заключать в двойные кавычки («). Если условием является число, использовать кавычки не требуется.

Диапазон_суммирования .Необязательный аргумент. Ячейки, значения из которых суммируются, если они отличаются от ячеек, указанных в качестве диапазона. Если аргумент диапазон_суммирования опущен, Excel суммирует ячейки, указанные в аргументе диапазон (те же ячейки, к которым применяется условие).

Sum_range
должны иметь тот же размер и форму, что и диапазон. Если это не так, производительность может снизиться, и формула суммирует диапазон ячеек, который начинается с первой ячейки в sum_range но имеет те же размеры, что и диапазон. Например:

*диапазон*	*Диапазон_суммирования.*	Фактические суммированные ячейки
A1:A5	B1:B5	B1:B5
A1:A5	B1:K5	B1:B5

Примеры

Пример 1

Скопируйте образец данных из следующей таблицы и вставьте их в ячейку A1 нового листа Excel. Чтобы отобразить результаты формул, выделите их и нажмите клавишу F2, а затем — клавишу Enter. При необходимости измените ширину столбцов, чтобы видеть все данные.

Стоимость имущества	Комиссионные	Данные
1 000 000 ₽	70 000 ₽	2 500 000 ₽
2 000 000 ₽	140 000 ₽
3 000 000 ₽	210 000 ₽
4 000 000 ₽	280 000 ₽
Формула	Описание	Результат
=СУММЕСЛИ(A2:A5;»>160000″;B2:B5)	Сумма комиссионных за имущество стоимостью больше 1 600 000 ₽.	630 000 ₽
=СУММЕСЛИ(A2:A5; «>160000»)	Сумма по имуществу стоимостью больше 1 600 000 ₽.	9 000 000 ₽
=СУММЕСЛИ(A2:A5;300000;B2:B5)	Сумма комиссионных за имущество стоимостью 3 000 000 ₽.	210 000 ₽
=СУММЕСЛИ(A2:A5;»>» &C2;B2:B5)	Сумма комиссионных за имущество, стоимость которого превышает значение в ячейке C2.	490 000 ₽

Пример 2

Скопируйте образец данных из следующей таблицы и вставьте их в ячейку A1 нового листа Excel. Чтобы отобразить результаты формул, выделите их и нажмите клавишу F2, а затем — клавишу Enter. Кроме того, вы можете настроить ширину столбцов в соответствии с содержащимися в них данными.

Категория	Продукты	Объем продаж
Овощи	Помидоры	23 000 ₽
Овощи	Сельдерей	55 000 ₽
Фрукты	Апельсины	8 000 ₽
	Масло	4 000 ₽
Овощи	Морковь	42 000 ₽
Фрукты	Яблоки	12 000 ₽
Формула	Описание	Результат
=СУММЕСЛИ(A2:A7;»Фрукты»;C2:C7)	Объем продаж всех продуктов категории «Фрукты».	20 000 ₽
=СУММЕСЛИ(A2:A7;»Овощи»;C2:C7)	Объем продаж всех продуктов категории «Овощи».	120 000 ₽
=СУММЕСЛИ(B2:B7;»*ы»;C2:C7)	Объем продаж всех продуктов, названия которых заканчиваются на «ы» («Помидоры» и «Апельсины»).	43 000 ₽
=СУММЕСЛИ(A2:A7;»»;C2:C7)	Объем продаж всех продуктов, категория для которых не указана.	4 000 ₽

К началу страницы

Дополнительные сведения

См. также

Функция СУММЕСЛИМН

СЧЁТЕСЛИ

Суммирование значений с учетом нескольких условий

Рекомендации, позволяющие избежать появления неработающих формул

Функция ВПР

Нужна дополнительная помощь?

Источник

Суммировать в программе Excel умеет, наверное, каждый. Но с усовершенствованной версией команды СУММ, которая называется СУММЕСЛИ, существенно расширяются возможности данной операции.

По названию команды можно понять, что она не просто считает сумму, но еще и подчиняется каким-либо логическим условиям.

СУММЕСЛИ и ее синтаксис

Функция СУММЕСЛИ позволяет суммировать ячейки, которые удовлетворяют определенному критерию (заданному условию). Аргументы команды следующие:

Диапазон – ячейки, которые следует оценить на основании критерия (заданного условия).
Критерий – определяет, какие ячейки из диапазона будут выбраны (записывается в кавычках).
Диапазон суммирования – фактические ячейки, которые необходимо просуммировать, если они удовлетворяют критерию.

Получается, что у функции всего 3 аргумента. Но иногда последний может быть исключен, и тогда команда будет работать только по диапазону и критерию.

Как работает функция СУММЕСЛИ в Excel?

Рассмотрим простейший пример, который наглядно продемонстрирует, как использовать функцию СУММЕСЛИ и насколько удобной она может оказаться при решении определенных задач.

Имеем таблицу, в которой указаны фамилии сотрудников, их пол и зарплата, начисленная за январь-месяц. Если нам нужно просто посчитать общее количество денег, которые требуется выдать работникам, мы используем функцию СУММ, указав диапазоном все заработные платы.

Но как быть, если нам нужно быстро посчитать заработные платы только продавцов? В дело вступает использование функции СУММЕСЛИ.

Прописываем аргументы.

Диапазоном в данном случае будет являться список всех должностей сотрудников, потому что нам нужно будет определить сумму заработных плат. Поэтому проставляем E2:E14.
Критерий выбора в нашем случае – продавец. Заключаем слово в кавычки и ставим вторым аргументом.
Диапазон суммирования – это заработные платы, потому что нам нужно узнать сумму зарплат всех продавцов. Поэтому F2:F14.

Получилось 92900. Т.е. функция автоматически проработала список должностей, выбрала из них только продавцов и просуммировала их зарплаты.

Аналогично можно подсчитать зарплаты всех менеджеров, продавцов-кассиров и охранников. Когда табличка небольшая, кажется, что все можно сосчитать и вручную, но при работе со списками, в которых по несколько сотен позиций, целесообразно использовать СУММЕСЛИ.

Функция СУММЕСЛИ в Excel с несколькими условиями

Если к стандартной записи команды СУММЕСЛИ в конце добавляются еще две буквы – МН (СУММЕСЛИМН), значит, подразумевается функция с несколькими условиями. Она применяется в случае, когда нужно задать не один критерий.

Синтаксис с использованием функции по нескольким критериям

Аргументов у СУММЕСЛИМН может быть сколько угодно, но минимум – это 5.

Диапазон суммирования. Если в СУММЕСЛИ он был в конце, то здесь он стоит на первом месте. Он также означает ячейки, которые необходимо просуммировать.
Диапазон условия 1 – ячейки, которые нужно оценить на основании первого критерия.
Условие 1 – определяет ячейки, которые функция выделит из первого диапазона условия.
Диапазон условия 2 – ячейки, которые следует оценить на основании второго критерия.
Условие 2 – определяет ячейки, которые функция выделит из второго диапазона условия.

И так далее. В зависимости от количества критериев, число аргументов может увеличиваться в арифметической прогрессии с шагом 2. Т.е. 5, 7, 9…

Пример использования

Предположим, нам нужно подсчитать сумму заработных плат за январь всех продавцов-женщин. У нас есть два условия. Сотрудник должен быть:

продавцом;
женщиной.

Значит, будем применять команду СУММЕСЛИМН.

Прописываем аргументы.

диапазон суммирования – ячейки с зарплатой;
диапазон условия 1 – ячейки с указанием должности сотрудника;
условия 1 – продавец;
диапазон условия 2 – ячейки с указанием пола сотрудника;
условие 2 – женский (ж).

Итог: все продавцы-женщины в январе получили в сумме 51100 рублей.

СУММЕСЛИ в Excel с динамическим условием

Функции СУММЕСЛИ и СУММЕСЛИМН хороши тем, что они автоматически подстраиваются под изменение условий. Т.е. мы можем изменить данные в ячейках, и суммы будут изменяться вместе с ними. Например, при подсчете заработных плат оказалось, что мы забыли учесть одну сотрудницу, которая работает продавцом. Мы можем добавить еще одну строчку через правую кнопку мыши и команду ВСТАВИТЬ.

У нас появилась дополнительная строчка. Сразу обращаем внимание, что диапазон условий и суммирования автоматически расширился до 15 строки.

Копируем данные сотрудника и вставляем их в общий перечень. Суммы в итоговых ячейках изменились. Функции среагировали на появление в диапазоне еще одного продавца-женщины.

Аналогично можно не только добавлять, но и удалять какие-либо строки (например, при увольнении сотрудника), изменять значения (заменить «январь» на «февраль» и подставить новые заработные платы) и т.п.

Источник

По названиям функций из заголовка статьи уже можно понять, для чего они предназначены. Первая суммирует числа указанного диапазона только в том случае, если они попадают под критерий. СУММЕСЛИМН работает точно так же, но с возможностью указать несколько разных аргументов.

Я покажу, как устроен синтаксис этих функций в Microsoft Excel и для каких задач их можно применить.

Разбор синтаксиса СУММЕСЛИ

Начать стоит с правил ввода составляющих функции СУММЕСЛИ. Из ее частей формируется СУММЕСЛИМН, поэтому детальное описание второй опустим, а вернемся к ней только в завершающем разделе статьи. Стандартная запись функции выглядит как =СУММЕСЛИ(A1:A10;»>1″).

Значит, что суммироваться будут только те ячейки, которые подпадают под указанный критерий, то есть больше 1. Это удобно, например, когда вам нужно посчитать, сколько у вас всего значений, меньше, больше или равняются конкретному. Если вызвать окно «Аргументы функции», вы увидите более понятный вариант записи и можете использовать его, указав диапазон и критерий.

Задать значение для «Диапазон_суммирования» нужно только в том случае, если вы ищете значения больше или меньше конкретного, но при этом добавлять в сумму необходимо ячейки из другого столбца (пока это звучит непонятно, но далее вы увидите такое представление функции на наглядном примере).

Комьюнити теперь в Телеграм

Подпишитесь и будьте в курсе последних IT-новостей

Запись СУММЕСЛИ при неравенстве

Еще раз пройдемся по базовому типу использования СУММЕСЛИ. После объявления функции укажите диапазон для проверки в виде A1:A20;. Обязательно поставьте точку с запятой, ведь это нужно для корректной работы функции.

После этого введите вручную сам критерий (нужно именно указывать число, а не брать его из конкретной ячейки с записью A1). Выберите знак больше, меньше, равно или <>, чтобы указать, что число не равняется конкретному.

Функция берет указанный вами диапазон и ищет там значения по критерию. Если значения попадают, они включаются в сумму. Затем происходит обращение к следующим ячейкам и так до конца диапазона. В итоге вы видите сумму только из тех чисел, которые соответствуют введенному вами неравенству.

Использование СУММЕСЛИ с текстом

В качестве критерия можно использовать текст, вводя слово в точности так же, как оно указано и в ячейках. Для реализации мы будем использовать диапазон суммирования, который опустили при разборе предыдущего примера.

Допустим, у вас есть столбец, в котором несколько строк с названием «Морковь». Нужно сделать так, чтобы функция посчитала сумму всего количества морковок, но не брала во внимание другие овощи и фрукты, записанные в том же столбце. Для этого отлично подойдет рассматриваемая функция, а ее запись в таком случае будет выглядеть так:

Объявите саму функцию, после чего в качестве диапазона выберите столбец с наименованиями продуктов.
Затем вместо неравенства введите текст для поиска.
Поставьте после кавычки точку с запятой и укажите диапазон суммирования – тот столбец, где расположено количество морковок.
Это то самое значение «Диапазон_суммирования», о котором я говорил при просмотре окна «Аргументы функции».
На следующем скриншоте вы видите, что морковок в списке всего две, каждая запись имеет значение 12, а это значит, что в сумму попадают только эти два числа, в результате получается 24.

Вы можете использовать такой подход, например, чтобы посчитать количество рабочих дней конкретного человека, получить результаты по месяцам или пройтись по количеству одинаковой продукции, записанной в столбце. Ничего сложного в объединении СУММЕСЛИ с текстом нет, в чем вы и убедились выше.

Использование функции СУММЕСЛИМН

Последний пример – функция СУММЕСЛИМН, которая похожа на предыдущую, но позволяет работать со множеством аргументов. Возьмем таблицу, где указано наименование продукции с некоторыми одинаковыми названиями, есть разная цена и количество.

Посчитаем количество груш, но только тех, чья цена будет выше 10 за единицу. Соответственно, это только пример, а вы можете использовать функцию для совершенно разных задач как при работе с текстовыми значениями, так и неравенствами.

Объявите функцию СУММЕСЛИМН и сначала запишите тот диапазон, который будете считать. В моем случае это количество груш.
Далее нужно вычленить из списка продукции только груши, для чего используйте критерий текста точно так же, как это уже было показано в предыдущем примере.
Второй критерий – цена, которая должна превышать 10 за единицу. Соответственно, впишите блок с неравенством A1:A10;»>10″, где A1:A10 – диапазон ячеек, а >10 – критерий.
Нажмите клавишу Enter и ознакомьтесь с результатом. На следующем скриншоте вы видите, что груш с ценой больше 10 довольно много, все их количество суммировалось и отображается в отдельной ячейке.

При первой записи у вас могут возникнуть трудности с правильным написанием функции, ведь она содержит много условий. Я оставлю вам ее отдельно, чтобы вы могли скопировать ее и вставить, подставив вместо текущих диапазонов ячеек свои: =СУММЕСЛИМН(B2:B25;A2:A25;»Груши»;C2:C25;»>10″). Не забывайте о том, что первый диапазон – то, что вы считаете, далее идет первый критерий – диапазон с названием столбца, потом второй – диапазон с неравенством.

Это лишь несколько примеров использования функций СУММЕСЛИ и СУММЕСЛИМН в Excel. Полученные знания вы можете использовать в своих целях, выполняя необходимые расчеты и упрощая процесс взаимодействия с электронной таблицей.

Источник

7 примеров использования формулы СУММЕСЛИ в Excel с несколькими условиями

В таблицах Excel можно не просто находить сумму чисел, но и делать это в зависимости от заранее определённых критериев отбора. Хорошо знакомая нам функция ЕСЛИ позволяет производить вычисления в зависимости от выполнения условия. Функция СУММ позволяет складывать числовые значения. А что если нам нужна формула ЕСЛИ СУММ? Для этого случая в Excel имеется специальная функция СУММЕСЛИ.

Мы рассмотрим, как правильно применить функцию СУММЕСЛИ (Sumif в английской версии) в таблицах Excel. Начнем с самых простых случаев, как можно использовать при этом знаки подстановки, назначить диапазон суммирования, работать с числами, текстом и датами. Особо остановимся на том, как использовать сразу несколько условий. И, конечно, мы применим новые знания на практике, рассмотрев несложные примеры.

Как пользоваться СУММЕСЛИ в Excel – синтаксис
Примеры использования функции СУММЕСЛИ в Excel
- Сумма если больше чем, меньше, или равно
- Критерии для текста.
- Подстановочные знаки для частичного совпадения.
- Точная дата либо диапазон дат.
- Сумма значений, соответствующих пустым либо непустым ячейкам
- Сумма по нескольким условиям.
- Почему СУММЕСЛИ у меня не работает?

Хорошо, что функция СУММЕСЛИ одинакова во всех версиях MS Excel. Еще одна приятная новость: если вы потратите некоторое время на ее изучение, вам потребуется совсем немного усилий, чтобы понять другие «ЕСЛИ»-функции, такие как СУММЕСЛИМН, СЧЕТЕСЛИ, СЧЕТЕСЛИМН и т.д.

Как пользоваться СУММЕСЛИ в Excel – синтаксис

Её назначение – найти итог значений, которые удовлетворяют определённым требованиям.

Синтаксис функции выглядит следующим образом:

=СУММЕСЛИ(диапазон, критерий, [диапазон_суммирования])

Диапазон – это область, которую мы исследуем на соответствие определённому значению.

Критерий – это значение или шаблон, по которому мы производим отбор чисел для суммирования.

Значение критерия может быть записано прямо в самой формуле. В этом случае не забывайте, что текст нужно обязательно заключать в двойные кавычки.

Также он может быть представлен в виде ссылки на ячейку таблицы, в которой будет указано требуемое ограничение. Безусловно, второй способ является более рациональным, поскольку позволяет гибко менять расчеты, не редактируя выражение.

Диапазон_суммирования — третий параметр, который является необязательным, однако он весьма полезен. Благодаря ему мы можем производить поиск в одной области, а суммировать значения из другой в соответствующих строках.

Итак, если он указан, то расчет идет именно по его данным. Если отсутствует, то складываются значения из той же области, где производился поиск.

Чтобы лучше понять это описание, рассмотрим несколько простых задач. Надеюсь, что они будут понятны не только «продвинутым» пользователям, но и подойдут для «чайников».

Примеры использования функции СУММЕСЛИ в Excel

Сумма если больше чем, меньше, или равно

Начнем с самого простого. Предположим, у нас есть данные о продажах шоколада. Рассчитаем различные варианты продаж.

В I3 записано:

=СУММЕСЛИ(D2:D21;I2)

D2:D21 – это координаты, в которых мы ищем значение.

I2 – ссылка на критерий отбора. Иначе говоря, мы ищем ячейки со значением 144 и складываем их.

Поскольку третий параметр функции не указан, то мы сразу складываем отобранные числа. Область поиска будет одновременно являться и диапазоном суммирования.

Кроме того, в качестве задания для отбора нужных значений можно указать текстовое выражение, состоящее из знаков >, <, <>, <= или >= и числа.

Можно указать его прямо в формуле, как это сделано в I13

=СУММЕСЛИ(D2:D21;«<144»)

То есть подытоживаем все заказы, в которых количество меньше 144.

Но, согласитесь, это не слишком удобно, поскольку нужно корректировать саму формулу, да и условие еще нужно не забыть заключить в кавычки.

В дальнейшем мы будем стараться использовать только ссылку на критерий, поскольку это значительно упрощает возможные корректировки.

Критерии для текста.

Гораздо чаще встречаются ситуации, когда поиск нужно проводить в одном месте, а в другом — суммировать данные, соответствующие найденному.

Чаще всего это необходимо, если необходимо использовать отбор по определённым словам. Ведь текстовые значения складывать нельзя, а вот соответствующие им числа – можно.

Как простой прием использования формулы СУММ ЕСЛИ в Эксель таблицах, рассчитаем итог по выполненным заказам.

В I3 запишем выражение:

=СУММЕСЛИ(F2:F21;I2;E2:Е21)

F2:F21 – это область, в которой мы отбираем подходящие значения.

I2 – здесь записано, что именно отбираем.

E2:E21 – складываем числа, соответствующие найденным совпадениям.

Конечно, можно указать параметр отбора прямо в выражении:

=СУММЕСЛИ(F2:F21;”Да”;E2:Е21)

Но мы уже договорились, что так делать не совсем рационально.

Важное замечание. Не забываем, что все текстовые значения необходимо заключать в кавычки.

Подстановочные знаки для частичного совпадения.

При работе с текстовыми данными часто приходится производить поиск по какой-то части слова или фразы.

Вернемся к нашему случаю. Определим, сколько всего было заказов на черный шоколад. В результате, у нас есть 2 подходящих наименования товара. Как учесть их оба? Для этого есть понятие неточного соответствия.

Мы можем производить поиск и подсчет значений, указывая не всё содержимое ячейки, а только её часть. Таким образом мы можем расширить границы поиска, применив знаки подстановки “?”, “*”.

Символ “?” позволяет заменить собой один любой символ.

Символ ”*” позволяет заменить собой не один, а любое количество символов (в том числе ноль).

Эти знаки можно применить в нашем случае двумя способами. Либо прямо вписать их в таблицу –

=СУММЕСЛИ(C2:C21;I2;E2:Е21) , где в E2 записано *[слово]*

либо

=СУММЕСЛИ(C2:C21;»*»&I2&»*»;E2:E21)

где * вставлены прямо в выражение и «склеены» с нужным текстом.

Давайте потренируемся:

“*черный*” — мы ищем фразу, в которой встречается это выражение, а до него и после него – любые буквы, знаки и числа. В нашем случае этому соответствуют “Черный шоколад” и “Супер Черный шоколад”.
“Д?” — необходимо слово из 2 букв, первая из которых “Д”, а вторая – любая. В нашем случае подойдет “Да”.
“???” — найдем слово из любых 3 букв

=СУММЕСЛИ(F2:F21;”???”;E2:E21)

Этому требованию соответствует “Нет”.

“???????*” — текст из любых 7 и более букв.

=СУММЕСЛИ(B2:B21;“???????*”;E8:E28)

Подойдет “Зеленый”, “Оранжевый”, “Серебряный”, “Голубой”, “Коричневый”, “Золотой”, “Розовый”.

“З*” — мы выбираем фразу, первая буква которой “З”, а далее – любые буквы, знаки и числа. Это “Золотой” и “Зеленый”.
“Черный*” — подходит фраза, которая начинаются именно с этого слова, а далее – любые буквы, знаки и числа. Подходит “Черный шоколад”.

Примечание. Если вам необходимо в качестве задания для поиска применять текст, который содержит в себе * и ?, то используйте знак тильда (~), поставив его перед этими символами. Тогда * и ? будут считаться обычными символами, а не шаблоном:

=СУММЕСЛИ(B2:B21;“*~?*”;E8:E28)

Важное замечание. Если в вашем тексте для поиска встречается несколько знаков * и ?, то тильду (~) нужно поставить перед каждым из них. К примеру, если мы будем искать текст, состоящий из трех звездочек, то формулу ЕСЛИ СУММ можно записать так:

=СУММЕСЛИ(B2:B21;“~*~*~*”;E8:E28)

А если текст просто содержит в себе 3 звездочки, то можно наше выражение переписать так:

=СУММЕСЛИ(B2:B21;“*~*~*~**”;E8:E28)

Точная дата либо диапазон дат.

Если нам нужно найти сумму чисел, соответствующих определённой дате, то проще всего в качестве критерия указать саму эту дату.

Примечание. При этом не забывайте, что формат указанной вами даты должен соответствовать региональным настройкам вашей таблицы!

Обратите внимание, что мы также можем здесь вписать ее прямо в формулу, а можем использовать ссылку.

Рассчитываем итог продаж за сегодняшний день – 04.02.2020г.

=СУММЕСЛИ(A2:A21;I1;E2:E21)

или же

=СУММЕСЛИ(A2:A21;СЕГОДНЯ();E2:E21)

Рассчитаем за вчерашний день.

=СУММЕСЛИ(A2:A21;СЕГОДНЯ()-1;E2:E21)

СЕГОДНЯ()-1 как раз и будет «вчера».

Складываем за даты, которые предшествовали 1 февраля.

=СУММЕСЛИ(A2:A21;»<«&»01.02.2020»;E2:E21)

После 1 февраля включительно:

=СУММЕСЛИ(A2:A21;»>=»&»01.02.2020″;E2:E21)

А если нас интересует временной интервал «от-до»?

Мы можем рассчитать итоги за определённый период времени. Для этого применим маленькую хитрость: разность функций СУММЕСЛИ. Предположим, нам нужна выручка с 1 по 4 февраля включительно. Из продаж после 1 февраля вычитаем все, что реализовано после 4 февраля.

=СУММЕСЛИ(A2:A21;»>=»&»01.02.2020″;E2:E21) — СУММЕСЛИ(A2:A21;»>=»&»04.02.2020″;E2:E21)

Сумма значений, соответствующих пустым либо непустым ячейкам

Случается, что в качестве условия суммирования нужно использовать все непустые клетки, в которых есть хотя бы одна буква, цифра или символ.

Рассмотрим ещё один вариант использования формулы СУММ ЕСЛИ в таблице Excel, где нам необходимо подсчитать заказы, в которых нет отметки о выполнении, а также сколько было вообще обработанных заказов.

Если критерий указать просто “*”, то мы учитываем для подсчета непустые ячейки, в которых имеется хотя бы одна буква или символ (кроме пустых).

=СУММЕСЛИ(F2:F21;»*»;E2:E21)

Точно такой же результат даёт использование вместо звездочки пары знаков «больше» и «меньше» — <>.

=СУММЕСЛИ(F2:F21;»<>»;E2:E21)

Теперь рассмотрим, как можно находить сумму, соответствующую пустым ячейкам.

Для того, чтобы найти пустые, в которых нет ни букв, ни цифр, в качестве критерия поставьте парные одинарные кавычки ‘’, если значение критерия указано в ячейке, а формула ссылается на неё.

Если же указать на отбор только пустых ячеек в самой формуле СУММ ЕСЛИ, то впишите двойные кавычки.

=СУММЕСЛИ(F2:F21;«»;E2:E21)

Сумма по нескольким условиям.

Функция СУММЕСЛИ может работать только с одним условием, как мы это делали ранее. Но очень часто случается, что нужно найти совокупность данных, удовлетворяющих сразу нескольким требованиям. Сделать это можно как при помощи некоторых хитростей, так и с использованием других функций. Рассмотрим все по порядку.

Вновь вернемся к нашему случаю с заказами. Рассмотрим два условия и посчитаем, сколько всего сделано заказов черного и молочного шоколада.

1. СУММЕСЛИ + СУММЕСЛИ

Все просто:

=СУММЕСЛИ($C$2:$C$21;»*»&H3&»*»;$E$2:$E$21)+СУММЕСЛИ($C$2:$C$21;»*»&H4&»*»;$E$2:$E$21)

Находим сумму заказов по каждому виду товара, а затем просто их складываем. Думаю, с этим вы уже научились работать :).

Это самое простое решение, но не самое универсальное и далеко не единственное.

2. СУММ и СУММЕСЛИ с аргументами массива.

Вышеупомянутое решение очень простое и может выполнить работу быстро, когда критериев немного. Но если вы захотите работать с несколькими, то она станет просто огромной. В этом случае лучшим подходом является использование в качестве аргумента массива критериев. Давайте рассмотрим этот подход.

Вы можете начать с перечисления всех ваших условий, разделенных запятыми, а затем заключить итоговый список, разделенный точкой с запятой, в {фигурные скобки}, который технически называется массивом.

Если вы хотите найти покупки этих двух товаров, то ваши критерии в виде массива будут выглядеть так:

СУММЕСЛИ($C$2:$C$21;{«*черный*»;»*молочный*»};$E$2:$E$21)

Поскольку здесь использован массив критериев, то результатом вычислений также будет массив, состоящий из двух значений.

А теперь воспользуемся функцией СУММ, которая умеет работать с массивами данных, складывая их содержимое.

=СУММ(СУММЕСЛИ($C$2:$C$21;{«*черный*»;»*молочный*»};$E$2:$E$21))

Важно, что результаты вычислений в первом и втором случае совпадают.

3. СУММПРОИЗВ и СУММЕСЛИ.

А если вы предпочитаете перечислять критерии в какой-то специально отведенной для этого части таблицы? Можете использовать СУММЕСЛИ в сочетании с функцией СУММПРОИЗВ, которая умножает компоненты в заданных массивах и возвращает сумму этих произведений.

Вот как это будет выглядеть:

=СУММПРОИЗВ(СУММЕСЛИ(C2:C21;H3:H4;E2:E21))

в H3 и H4 мы запишем критерии отбора.

Но, конечно, ничто не мешает вам перечислить значения в виде массива критериев:

=СУММПРОИЗВ(СУММЕСЛИ(C2:C21;{«*черный*»;»*молочный*»};E2:E21))

Результат, возвращаемый в обоих случаях, будет идентичен тому, что вы наблюдаете на скриншоте.

Важное замечание! Обратите внимание, что все перечисленные выше три способа производят расчет по логическому ИЛИ. То есть, нам нужны продажи шоколада, который будет или черным, или молочным.

Почему СУММЕСЛИ у меня не работает?

Этому может быть несколько причин. Иногда ваше выражение не возвращает того, что вы ожидаете, только потому, что тип данных в ячейке или в каком-либо аргументе не подходит для нее. Итак, вот что нужно проверить.

1. «Диапазон данных» и «диапазон суммирования» должны быть указаны ссылками, а не в виде массива.

Первый и третий атрибуты функции всегда должны быть ссылкой на область таблицы, например A1: A10. Если вы попытаетесь передать что-нибудь еще, например, массив {1,2,3}, Excel выдаст сообщение об ошибке.

Правильно: =СУММЕСЛИ(A1:A3, «цвет», C1:C3)

Неверно : =СУММЕСЛИ({1,2,3}, «цвет», C1:C3)

2. Ошибка при суммировании значений из других листов или рабочих книг.

Как и любая другая функция Excel, СУММЕСЛИ может ссылаться на другие листы и рабочие книги, если они в данный момент открыты.

Найдем сумму значений в F2: F9 на листе 1 книги 1, если соответствующие данные записаны в столбце A, и если среди них содержатся «яблоки»:

=СУММЕСЛИ([Книга1.xlsx]Лист1!$A$2:$A$9,»яблоки»,[Книга1.xlsx]Лист1!$F$2:$F$9)

Однако это перестанет работать, как только Книга1 будет закрыта. Это происходит потому, что области, на которые ссылаются формулы в закрытых книгах, преобразуются в массивы и хранятся в таком виде в текущей книге. А поскольку в аргументах 1 и 3 массивы не допускаются, то формула выдает ошибку #ЗНАЧ!.

3. Чтобы избежать проблем, убедитесь, что диапазоны данных и поиска имеют одинаковый размер.

Как отмечалось в начале этого руководства, в современных версиях Microsoft Excel они не обязательно должны иметь одинаковый размер. Но вот в Excel 2000 и более ранних версиях это может вызвать проблемы. Однако, даже в самых последних версиях Excel сложные выражения, в которых диапазон сложения имеет меньше строк и/или столбцов, чем диапазон поиска, являются капризными. Вот почему рекомендуется всегда иметь их одинакового размера и формы.

Примеры расчета суммы:

Источник

Сумма в Excel — одна из самых частых операций. Однако зачастую недостаточно просто просуммировать все ячейки, а нужно сделать сумму ячеек, соответствующих определенному условию или нескольким условиям. В этой статье рассмотрим, как сделать суммирование ячеек в Excel по условию и по нескольким условиям.

Функция СУММЕСЛИ в Excel для суммирования по одному условию
Суммирование по нескольким условиям в Excel при помощи функции СУММЕСЛИМН
Суммирование по текстовому условию
Суммирование по числовому условию
Суммирование по условию даты
Почему СУММЕСЛИ или СУММЕСЛИМН не работает
СУММЕСЛИ или СУММЕСЛИМН в Excel — что лучше использовать?

Чтобы сделать суммирование ячеек в Excel по одному условию, можно использовать функцию СУММЕСЛИ (SUMIF в англ. версии).

Синтаксис функции:

=СУММЕСЛИ(диапазон;критерий;[диапазон_суммирования])

диапазон — область ячеек, в которых будет осуществляться поиск критерия суммирования

критерий — значение, по которому будет осуществляться поиск в диапазоне. Может быть текстом, числом, ссылкой на ячейку или шаблоном.

[диапазон_суммирования] — необязательный параметр, указывается в том случае, когда совпадение с критерием ищем в одном диапазоне,а суммируем значения из другого. Если этот параметр не указан, то будут суммироваться значения из первой области диапазон (если они могут быть просуммированы).

Рассмотрим функцию СУММЕСЛИ в Excel на примере.

У нас есть таблица с данными о сотрудниках.

Получим сумму заработной платы у всех сотрудников мужского пола.

Способ 1. С указанием критерия напрямую в формуле.

В ячейке, в которой нужно получить результат суммирования по условию, напишем формулу:

=СУММЕСЛИ(D3:D12;»муж»;G3:G12)

D3:D12 — диапазон, в котором будет происходить поиск совпадения с критерием. В нашем примере это столбец Пол.

«муж» — критерий поиска. Поскольку это текстовый критерий, он заключен в кавычки.

G3:G12 — диапазон, значения из которого будут просуммированы при наличии совпадений диапазона с критерием. В примере это столбец Заработная плата.

Способ 2. С указанием критерия ссылкой на ячейку

Этот способ наиболее распространен и универсален.

В ячейке слева от рабочей укажем критерий поиска (без кавычек!).

Формула будет выглядеть так:

=СУММЕСЛИ(D3:D12;I4;G3:G12)

где первый и третий аргументы — такие же, как в предыдущем способе.

I4 — это ссылка на ячейку, в которой содержится критерий суммирования значений.

Если формулу нужно “протянуть” (скопировать) в другие ячейки — не забывайте закреплять диапазоны и критерий абсолютными или относительными ссылками (знак $).

Суммирование по нескольким условиям в Excel при помощи функции СУММЕСЛИМН

Если критерием для суммирования больше одного, то на помощь придет функция СУММЕСЛИМН (SUMIFS в англ. версии).

Синтаксис функции:

=СУММЕСЛИМН(диапазон_суммирования; диапазон_условия 1; условие 1;…;диапазон_условия n; условие n)

У функции СУММЕСЛИМН такие же аргументы, как у СУММЕСЛИ, но немного другой их порядок — на первом месте указывает диапазон суммирования (область значений, которые должны быть просуммированы), а затем — диапазон условий и условие поиска.

Рассмотрим на примере: нужно просуммировать заработную плату всех женщин бухгалтеров.

Соответственно, условия суммирований будут:

Должность: Бухгалтер

Пол: жен

Формула суммирования по нескольким условиям в Excel будет такая:

=СУММЕСЛИМН(G3:G12;C3:C12;I4;D3:D12;J4)

где G3:G12 — диапазон суммирования

C3:C12 — первый диапазон условия, в котором будет искаться первое условие

I4 — ссылка на ячейку, содержащую первое условие поиска

D3:D12 — второй диапазон условия, в котором будет искаться второе условие

J4 — ссылка на ячейку, содержащую второе условие поиска

Как видите, Excel верно просуммировал заработную плату всех сотрудников с полом жен и должностью Бухгалтер.

Обратите внимание:

Функцию СУММЕСЛИМН можно использовать только для одного условия поиска (не обязательно их должно быть несколько)
для функции СУММЕСЛИМН действуют те же правила, как и для функции СУММЕСЛИ (регистр критерия поиска, абсолютные и относительные ссылки)
условия поиска можно располагать в любом порядке. В примере мы указали сначала условие Должность, затем условие Пол — можно сделать наоборот.

Главное правило: диапазон условия и условие, которое идет следом за ним, должны соответствовать друг другу.

условия поиска также можно указывать как в самой формуле, так и ссылкой на ячейку.
критерии поиска в стандартном варианте должны находиться в разных столбцах. Если несколько критериев суммирования находятся в одном столбце, то нужно использовать формулу массива.

Суммирование по текстовому условию

Пример суммирования по текстовому условию мы рассмотрели в первом пункте этой статьи.

Текстовые значения суммировать сами по себе нельзя, но можно получить сумму соответствующих им чисел.

Рассмотрим простой пример использования функции СУММЕСЛИ в эксель таблице: просуммируем заработную плату всех кассиров в таблице из предыдущего примера.

Точно так же можно сделать сумму значений по условию, указав критерий прямо в формуле. Текстовый критерий обязательно нужно заключить в кавычки!

Обратите внимание:

функции СУММЕСЛИ и СУММЕСЛИМН не чувствительны к регистру критерия. Например, сейчас критерий поиска Кассир

можно указать критерий с большой буквы или даже всеми большими буквами, например:

Как видите, формула работает и выдает тот же результат.

Но если добавить любой знак, например пробел или точку в конце — формула не будет работать, т.к. нет точного совпадения критерия со значениями диапазона для поиска.

в качестве критерия всегда лучше использовать ссылку на ячейку, а не указывать его непосредственно в формуле. Так будет проще корректировать формулу, и меньше вероятности совершить ошибку при указании критерия. К тому же, в этом случае не нужно заключить в кавычки критерий поиска.

Поэтому в следующих примерах будем использовать только вариант со ссылкой на ячейку — лучше сразу приучить себя к такому способу.

СУММЕСЛИ или СУММЕСЛИМН по части текста

А вы знали, что можно сделать суммирование ячеек в Excel по одному или нескольким текстовым условиям, указав только часть текста? Подробно этот вариант рассмотрен в статье.

Например, получим сумму заработных плат сотрудниц по имени Елена. Критерием поиска в данном случае будет имя Елена — но ведь в нашей таблице нет столбца, в котором находится имя. Только ФИО. Однако, не нужно создавать дополнительных столбцов и разделять ФИО на компоненты.

Напишем следующую формулу:

=СУММЕСЛИ(B3:B12;»*елена*»;G3:G12)

Здесь критерием поиска будет «*елена*».

Используются два значка-оператора — кавычки и звездочка.

звездочка * — заменяет любое количество символов. Т.е. перед и после слова елена может находиться любое количество любых символов.
кавычки «» — обязательно ставятся для текстового аргумента поиска в функциях excel.

Вместо звездочки можно использовать знак вопроса ?. Отличие — символ * заменяем любое количество символов, а ? — только один символ.

Суммирование по числовому условию в Excel

Как правило, нужно определить сумму если больше чем, меньше чем или равно определенному числу.

Сумма чисел, если больше или меньше чем заданное число

Задача: получить сумму заработных плат, если величина заработной платы больше 50000 руб.

Формула будет такая:

=СУММЕСЛИ(G3:G12;»>50000″)

где G3:G12 — диапазон для поиска заданных значений и одновременно диапазон суммирования, поэтому третий критерий (не обязательный) в формуле не указывается.

«>50000» — критерий поиска.

Обратите внимание, что, несмотря на то, что критерий не текстовый, а числовой, используются кавычки.

Обязательно использовать кавычки, если в формуле применяются знаки больше > или меньше < ( а также >= и <=)

Если в качестве критерия используется знаки >, <, >=, <= и ссылка на ячейку, содержащую критерий (например >50000), то критерий поиска будет записан таким образом:

Знак сравнения должен быть заключен в кавычки, далее ставится амперсанд & и указывается ссылка на ячейку с критерием.

Сумма чисел, если равно заданному числу

В этом случае кавычки для критерия не используются.

Получим сумму заработных плат, равных 45000 руб.

Критерий поиска 45000 указывается без кавычек.

Также, если критерий указывается в ячейке, то формула будет как для текстового критерия:

Суммирование по условию даты

Чтобы сделать суммирование ячеек в excel по условию даты — равно определенной дате или больше или меньше определенной даты — то нужно указать эту дату в качестве критерия.

При этом дату также можно указывать непосредственно в формуле, а также ссылкой на ячейку, содержащую дату.

Для примера определим сумму заработных плат сотрудников, трудоустроенных после 1 января 2018 г.

Формула:

=СУММЕСЛИ(F3:F12;»>=»&I4;G3:G12)

Обратите внимание, как указан критерий — знак сравнения “больше или равно” заключен в кавычки и используется знак амперсанд &.

Если дату указывать напрямую в формуле, то ее нужно также заключить в кавычки:

Почему СУММЕСЛИ или СУММЕСЛИМН не работает

Формула СУММЕСЛИ иногда может выдавать ошибку #ЗНАЧ, если диапазон суммирования и диапазон условий имеют разный размер. Эта проблема решена в новых версиях Excel, но в ранних версиях она присутствует.

Также ошибка #ЗНАЧ может возникать, если формула ссылается на данные из другого файла, а этот файл в момент пересчета формулы закрыт. Необходимо просто открыть файл-источник, и ошибка исчезнет.

Если функция СУММЕСЛИ или СУММЕСЛИМН выдает значение 0 (при условии, что значение суммы никак не может быть равно 0), необходимо проверить критерий — не закрались ли в него лишние пробелы или знаки препинания.

СУММЕСЛИ или СУММЕСЛИМН в Excel — что лучше использовать?

Как вы могли заметить, эти функции похожи между собой.

В своей практике, я часто замечаю, что пользователи разграничивают действие этих функций: для суммирования по одному критерию используют строго функцию СУММЕСЛИ, по нескольким критериям — СУММЕСЛИМН.

Но обратите внимание:

Функцию СУММЕСЛИМН можно использовать для суммирования как по одному критерию, так и по нескольким критериям.

Другими словами, функция СУММЕСЛИМН универсальная. И функцию СУММЕСЛИ таким образом можно вообще не использовать, заменив ее СУММЕСЛИМН.

Почему СУММЕСЛИМН удобнее при суммировании по одному критерию?

Потому что условия задачи всегда могут измениться. Сейчас вы суммируете по одному критерию (например, по должности), а в следующий момент понадобилось добавить еще одно условие (пол). В случае с функцией СУММЕСЛИМН вы просто внесете дополнительное условие в ту же формулу, а функция СУММЕСЛИ здесь вовсе не подойдет (придется все равно переписывать на СУММЕСЛИМН).

Поэтому совет практика: использовать только функцию СУММЕСЛИМН.

Однако, окончательное решение в выборе функции всегда остается за вами.

В этой статье мы узнали, как сделать суммирование ячеек в excel по условию и познакомились с возможностью сделать суммирование по нескольким условиям.

Сообщество Excel Analytics | обучение Excel

Канал на Яндекс.Дзен

Вам может быть интересно:

Источник