1с затянуть данные с excel

Помогла ли Вам статья?

Содержание:

1.    Диалог выбора файла

2.    Чтение файла для 1С

3.    Загрузка в таблицу 1С

4.    Создание документов после переноса из Excel в документ 1С

Многие сталкиваются с необходимостью перенести большое количество данных из MS Excel в 1С. Для быстрого выполнения этой задачи можно создать внешнюю обработку для переноса данных, которая будет считывать наш файл и заполнять документ необходимыми данными.

Для чтения табличных документов Excel в 1С существует несколько способов. Но не все они универсальны. В данном случае мы будем разбирать способ – через создание COM-объекта. Этот способ требует обязательного наличия MS Excel на компьютере (сервере), на котором находится база данных.

В данной статье мы разберем создание команды, по которой из Excel файла будет происходить выгрузка данных в табличную часть документа 1С.

Создадим в конфигураторе Новую обработку для переноса данных, которая будет считывать данные из документа Excel и создавать на основе этих данных документы, в которых будет автоматически заполняться табличная часть. 

1.    Диалог выбора файла

Первым делом необходимо создать диалог выбора файла. Создадим реквизит формы «ПутьКФайлу» и вынесем его на форму в виде поля ввода:

Далее прописываем событие «НачалоВыбора» для нашего поля и пишем процедуру для этого события. Также можно установить фильтр, для того чтобы было видно только нужные типы файлов.  

2.    Чтение файла для 1С

После того как мы создали поле для указания файла, добавим команду формы «ЗагрузитьИзExcel», и вынесем ее на форму.

После чего привязываем к ней процедуру, которая будет загружать данные из документа Excel и помещать их в таблицу формы, для того чтобы можно было проверить, что загрузилось.

Данная процедура вызывает последовательное выполнение отдельных процедур и функций, о которых речь пойдет чуть ниже.

Функция «ПрочитатьФайлЭксель» возвращает массив с данными из указанного нами файла.

Подключаемся к Excel через COM-объект и проводим все технические настройки: определяем количество листов, определяем версию, так как для разных версий получается разное количество колонок и строк.   

Далее считываем данные и заполняем ими массив.

После создания функции, которая считывает данные, напишем процедуру, которая будет помещать их в таблицу формы.  

3.    Загрузка в таблицу 1С

Получим таблицу формы и объявим некоторые переменные, которые будем использовать далее.

Получаем номера колонок, данные которых нам необходимы.

С помощью простенькой функции, возвращающей данные нужной колонки для текущей строки, получаем необходимые значения и добавляем их в таблицу.

После загрузки в таблицу 1С можно подтянуть некоторые данные из справочников. В данном случае с помощью метода «НайтиПоРеквизиту()» искались наименования номенклатуры по ее артикулу и так же выгружались в таблицу формы.

При написании обработки для переноса данных нельзя забывать и о возможных ошибках, которые могут возникнуть в процессе работы. В данном случае предусмотрим, что не всегда артикулы, указанные в табличном документе, могут быть добавлены в справочник. И в случае если в справочнике нет данного артикула, будем выводить сообщение об этом. 

4.    Создание документов после переноса из Excel в документ 1С

Следующим этапом будет создание Документов на основании полученной таблицы.

Создадим команду, по которой будут создаваться документы и пропишем событие. Для того чтобы создать для каждого магазина новый документ, выгрузим таблицу формы в ТаблицуЗначений и свернем по колонке «магазин», чтобы получить массив различных магазинов.

После чего обойдем этот массив в цикле, создавая и заполняя Новый документ для каждого магазина. Обязательно следует запретить создавать документы при незаполненных значениях номенклатуры (выводить сообщения о том, что она не заполнена).

Данную обработку для переноса данных можно сделать как внешней, так и встроенной. Все зависит от потребностей. Существенных отличий между этими вариантами не будет за исключением того, что для внешней обработки в модуль объекта нужно будет прописать параметры регистрации и подключить ее. Для встроенной же нужно будет обновлять конфигурацию, что в некоторых случаях проблематично, если БД очень большая.

Специалист компании ООО «Кодерлайн»

Фархутдинов Айдар Сайярович

&НаКлиенте
Процедура ЗагрузитьИзExcel(Команда)
	
	НомерПервойСтроки = 1;
	НомерПервойКолонки = 1;
	КоличествоСтрокВЭксель = 0;
	КоличествоКолонокВЭксель = 0;
	
	ДиалогВыбора = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);
	ДиалогВыбора.Заголовок = "Выберите файл";
	
	Если ДиалогВыбора.Выбрать() Тогда
		
		ИмяФайлаЭксель = ДиалогВыбора.ПолноеИмяФайла;
		
		//Подключаемся к Эксель
		Попытка
			Эксель = Новый COMОбъект("Excel.Application");
			Эксель.WorkBooks.Open(ИмяФайлаЭксель);
			Состояние("Обработка файла Microsoft Excel...");
		Исключение
			Сообщить("Ошибка при открытии файла с помощью Excel! Загрузка не будет произведена!");
			Сообщить(ОписаниеОшибки());
			Возврат;
		КонецПопытки;
		
		Попытка 
			//Открываем необходимый лист
			Эксель.Sheets(1).Select();  // лист 1, по умолчанию  
		Исключение
			//Закрываем Excel
			Эксель.ActiveWorkbook.Close();  
			Эксель = 0;
			Сообщить("Файл "+Строка(Объект.ИмяФайла)+" не соответствует необходимому формату! Первый лист не найден!");
			Возврат;
		КонецПопытки;
		
		//Получим количество строк и колонок.		
		КоличествоСтрокВЭксель = Эксель.Cells.SpecialCells(11).Row;
		КоличествоКолонокВЭксель = Эксель.Cells.SpecialCells(11).Column;
		
		// Выделяем область на листе Эксель.
		Область = Эксель.Range(Эксель.Cells(НомерПервойСтроки,НомерПервойКолонки), Эксель.Cells(КоличествоСтрокВЭксель,КоличествоКолонокВЭксель));
		
		// Выгружаем область Эксель в двумерный массив.
		Данные = Область.Value.Выгрузить();		
		
		//Отключаемся от Excel 
		Попытка
			Эксель.DisplayAlerts = 0;
			Эксель.ActiveWorkbook.Close();
			Эксель.DisplayAlerts = 1;
			Эксель.Quit(); 
			Эксель = Неопределено;        
		Исключение
			Сообщить("Не удалось отключиться от Excel - " + ОписаниеОшибки());
			Возврат;
		КонецПопытки;
		
		//Далее обрабатываем на сервере полученные из Эксель данные.
		ОбработатьДанныеИзЭксельНаСервере(Данные)
		
	КонецЕсли;
	
КонецПроцедуры

&НаСервере
Процедура ОбработатьДанныеИзЭксельНаСервере(Данные)
	
	ТаблицаЗначенийИзЭксель = Новый ТаблицаЗначений;
	ТаблицаЗначенийИзЭксель.Колонки.Добавить("Номенклатура", , "Номенклатура");
	ТаблицаЗначенийИзЭксель.Колонки.Добавить("Код", , "Код");
	ТаблицаЗначенийИзЭксель.Колонки.Добавить("Цена", , "Цена");
	ТаблицаЗначенийИзЭксель.Колонки.Добавить("Количество", , "Количество");
	
	Счетчик = 1;
	
	Для Индекс = 1 По Данные[0].Количество()-1 Цикл
		
		// Заполняем таблицу значений из массива.
		СтрокаТаблицаЗначенийИзЭксель = ТаблицаЗначенийИзЭксель.Добавить();
		СтрокаТаблицаЗначенийИзЭксель.Номенклатура = СокрЛП(Данные[1][Счетчик]);   // Номенклатура
		СтрокаТаблицаЗначенийИзЭксель.Код = СокрЛП(Данные[2][Счетчик]);            // Код
		СтрокаТаблицаЗначенийИзЭксель.ДирективнаяЦенаСНДС = СокрЛП(Данные[3][Счетчик]); // Цена
		СтрокаТаблицаЗначенийИзЭксель.Количество = СокрЛП(Данные[4][Счетчик]);  //Количество
		
		Счетчик = Счетчик +1;
		
	КонецЦикла;
	
	// Очищаем табличную часть элемента справочника
	Объект.ПозицииНоменклатуры.Очистить();
	
	// Заполняем табличную часть
	Для Каждого СтрокаТЗ Из ТаблицаЗначенийИзЭксель Цикл 
		
		Номенклатура = Справочники.Номенклатура.НайтиПоКоду(СтрокаТЗ.Код);
		
		Если Не ЗначениеЗаполнено(Номенклатура) Тогда
			
			Сообщить("В справочнике «Номенклатура» не найден элемент с кодом " + СтрокаТЗ.Код);
			
		Иначе
			
			НовСтрокаТчПозицииНоменклатуры = Объект.ПозицииНоменклатуры.Добавить();
			НовСтрокаТчПозицииНоменклатуры.Номенклатура = Номенклатура;
			НовСтрокаТчПозицииНоменклатуры.Код = СтрокаТЗ.Код;
			НовСтрокаТчПозицииНоменклатуры.ДирективнаяЦенаСНДС = СтрокаТЗ.Цена;
			НовСтрокаТчПозицииНоменклатуры.Количество = СтрокаТЗ.Количество;
			НовСтрокаТчПозицииНоменклатуры.Стоимость = ?(ЗначениеЗаполнено(СтрокаТЗ.Количество), СтрокаТЗ.Количество, 0)  * ?(ЗначениеЗаполнено(СтрокаТЗ.Цена), Цена, 0);
			
		КонецЕсли;
		
	КонецЦикла;
	
	ТаблицаЗначенийИзЭксель = Неопределено;
			
	Сообщить("Загрузка завершена"); 
	
КонецПроцедуры

Информация о материале

Категория: Программирование 1С

Опубликовано: 15 апреля 2017

Вопрос загрузки в информационную базу 1С различных данных из документов Excel очень актуален. На практике задачи подобного рода «загрузки/выгрузки» данных «из/в» Excel будут встречаться очень часто. Поэтому научиться работать с этим очень важно. Конечно, сейчас очень много типовых обработок которые к тому же есть во многих типовых конфигурациях которые позволяют загружать и выгружать данные, но все же лучше научиться создавать их самому. Реализовать это можно разными способами, все их мы обязательно рассмотрим, ну а сегодня будем использовать для этого «Табличный документ».

Данная статья является продолжением статей «Как загрузить данные в 1С из различных файлов«, и «1С Последовательное чтение файлов«. Из них вы узнаете про два способа загрузки данных из текстовых файлов «ТХТ», так же в первой статье я рассказывал про создание обработки для загрузки, которою и будут использовать сейчас.

Загрузка данных из Excel

У объекта «Табличный документ» есть метод «Прочитать» у которого есть одна особенность о которой обязательно нужно знать, доступен он только на сервере, т.е процедура должна выполняться не на клиенте а на сервере.

Поэтому в обработчики события команды «Загрузить» будем вызывать процедуру.

&НаКлиенте
Процедура Загрузить(Команда)
	
	Объект.ДанныеФайла.Очистить(); 
	Прочитать_xls_НаСервере(); 
  
КонецПроцедуры

Для того чтобы данные не задвоились, сначала очистим ТЧ потом вызовем процедуру загрузки данных из Excel.

Далее создаем процедуру на сервере в которой пишем следующий код.

&НаСервере
Процедура  Прочитать_xls_НаСервере()
	
	ТабДок = Новый ТабличныйДокумент;
	
	Попытка
		  ТабДок.Прочитать(Объект.ВыбратьФайл, СпособЧтенияЗначенийТабличногоДокумента.значение);
	Исключение
		  Сообщиние = Новый СообщениеПользователю;
		  Сообщиние.Текст ="Не удалось прочитать " + ОписаниеОшибки();
		  Сообщиние.Сообщить();
		  Возврат;
	КонецПопытки;
	КоличествоСтрок = ТабДок.ВысотаТаблицы;
	
	Для НомерСтроки = 2 По КоличествоСтрок Цикл 
		СтрокаДанных = Объект.ДанныеФайла.Добавить();
		СтрокаДанных.Наименование = ТабДок.ПолучитьОбласть("R" + Формат(НомерСтроки,"ЧГ=0") + "C" +1).ТекущаяОбласть.Текст;
		СтрокаДанных.Расшифровка  = ТабДок.ПолучитьОбласть("R" + Формат(НомерСтроки,"ЧГ=0") + "C" +2).ТекущаяОбласть.Текст;
		СтрокаДанных.ИНН =          ТабДок.ПолучитьОбласть("R" + Формат(НомерСтроки,"ЧГ=0") + "C" +3).ТекущаяОбласть.Текст;
	КонецЦикла;	
	  
КонецПроцедуры	

Если кратко его описать то сначала создаем переменную «Табличный документ», далее добавляем конструкцию «Попытка/КонецПопытки» для обработки ошибок в момент чтения документа. После чего уже обрабатываем в цикле строки документа Excel.

Сам документ будет выглядеть следующим образом, в нем три колонки, первая это шапка её читать не нужно, поэтому в процедуре мы сразу добавили «+1».

Сохраняем обработку, и пробуем загрузить данные из документа.

Я уже говорил об общем принципе загрузке данных в предыдущих статьях, но еще раз повторюсь. Сразу загружать данные в базу 1С не правильно! Их нужно сначала прочитать/загрузить и отобразить пользователю и только после их проверки с помощью еще одной команды записать в базу! В данной статье Я рассказал про первый этап, т.е данные из файла были прочитаны и загружены в табличную часть обработки для отображения их пользователю, дальше нужно создать команду которая запишет их в базу (создаст на их основе контрагентов), но об этом в следующей статье.

Как видите в загрузке данных из Excel в 1С нет ничего сложного, но если у Вас возникли вопросы или что-то не получается, то обязательно напишите об этом, будем разбираться вместе.

MS Excel давно стал стандартом для работы с электронными таблицами. В статье рассматриваются способы программной выгрузки и загрузки из 1С в файлы Excel.

Существует несколько способов программной работы с файлами Excel из 1С. Каждый из них имеет свои преимущества и недостатки.

Обмен через табличный документ

Данный способ простой. Его суть заключается в том, что объект ТабличныйДокумент имеет методы:

• Записать(<ИмяФайла>, <ТипФайлаТаблицы>) для выгрузки данных в файл;
• Прочитать(<ИмяФайла>, <СпособЧтенияЗначений>) для загрузки данных из файла.

Внимание!

Метод Записать() доступен как на клиенте, так и на сервере. Метод Прочитать() доступен только на стороне сервера. Необходимо помнить об этом
при планировании клиент-серверного взаимодействия.

Рассмотрим пример сохранения табличного документа в файл. Необходимо любым способом создать и заполнить объект ТабличныйДокумент, а выгрузка в файл осуществляется всего лишь одной строкой:

ТабДок.Записать(ПутьКФайлу, ТипФайлаТабличногоДокумента.XLSX);

Здесь ТабДок — сформированный табличный документ, ПутьКФайлу — имя файла для выгрузки, ТипФайлаТабличногоДокумента.XLSX — формат создаваемого файла. Поддерживаются следующие форматы Excel:

• XLS95 — формат Excel 95;
• XLS97 — формат Excel 97;
• XLSX — формат Excel 2007.

Загрузка из файла осуществляется также достаточно просто:

ТабДок = Новый ТабличныйДокумент;
ТабДок.Прочитать(ПутьКФайлу, СпособЧтенияЗначенийТабличногоДокумента.Значение);

Здесь ПутьКФайлу — путь к загружаемому файлу Excel. СпособЧтенияЗначенийТабличногоДокумента.Значение определяет, каким образом нужно интерпретировать данные, считываемые из исходного документа. Доступны варианты:

• Значение;
• Текст.

Обмен через OLE

Обмен через технологию OLE automation, пожалуй, самый распространенный вариант программной работы с файлами Excel. Он позволяет использовать весь функционал, предоставляемый Excel, но отличается медленной скоростью работы по сравнению с другими способами. Для обмена через OLE требуется установка MS Excel:

• На компьютере конечного пользователя, если обмен происходит на стороне клиента;
• На компьютере сервера 1С:Предприятие, если обмен происходит на стороне сервера.

Пример выгрузки:

// Создание COM-объекта
Эксель = Новый COMОбъект(«Excel.Application»);
// Отключение вывода предупреждений и вопросов
Эксель.DisplayAlerts = Ложь;
// Создание новой книги
Книга = Эксель.WorkBooks.Add();
// Позиционирование на первом листе
Лист = Книга.Worksheets(1);

// Запись значения в ячейку
Лист.Cells(НомерСтроки, НомерКолонки).Value = ЗначениеЯчейки;

// Сохранение файла
Книга.SaveAs(ИмяФайла);

// Закрытие Эксель и освобождение памяти
Эксель.Quit();
Эксель = 0;

Примеры чтения:

// —— ВАРИАНТ 1 ——

// Создание COM-объекта
Эксель = Новый COMОбъект(«Excel.Application»);
// Открытие книги
Книга = Эксель.Workbooks.Open(ПутьКФайлу);
// Позиционирование на нужном листе
Лист = Книга.Worksheets(1);

// Чтение значения ячейки, обычно здесь располагается цикл обхода ячеек
ЗначениеЯчейки = Лист.Cells(НомерСтроки, НомерКолонки).Value;

// Закрытие книги
Книга.Close(0);

// Закрытие Эксель и освобождение памяти
Эксель.Quit();
Эксель = 0;

// —— ВАРИАНТ 2 ——

// Открытие книги
Книга = ПолучитьCOMОбъект(ПутьКФайлу);
// Позиционирование на нужном листе
Лист = Книга.Worksheets(1);

// Чтение значения ячейки, обычно здесь располагается цикл обхода ячеек
ЗначениеЯчейки = Лист.Cells(НомерСтроки, НомерКолонки).Value;

// Закрытие книги
Книга.Application.Quit();

Для обхода всех заполненных строк листа Excel можно использовать следующие приемы:

// —— ВАРИАНТ 1 ——
КоличествоСтрок = Лист.Cells(1, 1).SpecialCells(11).Row;
Для НомерСтроки = 1 По КоличествоСтрок Цикл
ЗначениеЯчейки = Лист.Cells(НомерСтроки, НомерКолонки).Value;
КонецЦикла;

// —— ВАРИАНТ 2 ——
НомерСтроки = 0;
Пока Истина Цикл
НомерСтроки = НомерСтроки + 1;
ЗначениеЯчейки = Лист.Cells(НомерСтроки, НомерКолонки).Value;
Если НЕ ЗначениеЗаполнено(ЗначениеЯчейки) Тогда
Прервать;
КонецЕсли;
КонецЦикла;

Вместо последовательного обхода всех строк листа можно выгрузить все данные в массив и работать с ним. Такой подход будет быстрее при чтении большого объема данных:

ВсегоКолонок = Лист.Cells(1, 1).SpecialCells(11).Column;
ВсегоСтрок = Лист.Cells(1, 1).SpecialCells(11).Row;

Область = Лист.Range(Лист.Cells(1, 1), Лист.Cells(ВсегоСтрок, ВсегоКолонок));
Данные = Область.Value.Выгрузить();

В таблице ниже приведены наиболее востребованные свойства и методы для работы с Excel через OLE:

Для того, чтобы узнать какое свойство нужно менять или какой метод вызвать можно воспользоваться макросами Excel. Если записать макрос с требуемыми действиями, то после можно посмотреть программный код на VBA записанного макроса.

Использование COMSafeArray

При выгрузке больших объемов данных из 1С в Excel для ускорения можно использовать объект COMSafeArray. Согласно определению из синтакс-помощника, COMSafeArray — объектная оболочка над многомерным массивом SafeArray из COM. Позволяет создавать и использовать SafeArray для обмена данными между COM-объектами. Проще говоря, это массив значений, который можно использовать для обмена между приложениями по технологии OLE.

// Создание COMSafeArray
МассивКом = Новый COMSafeArray(«VT_Variant», ВсегоКолонок, ВсегоСтрок);
// Заполнение COMSafeArray
Для Стр = 0 По ВсегоСтрок — 1 Цикл
Для Кол = 0 По ВсегоКолонок — 1 Цикл
МассивКом.SetValue(Кол, Стр, Значение);
КонецЦикла;
КонецЦикла;
// Присвоение области листа Excel значений из COMSafeArray
Лист.Range(Лист.Cells(1, 1), Лист.Cells(ВсегоСтрок, ВсегоКолонок)).Value = МассивКом;

Обмен через ADO

Файл Excel при обмене через ADO представляет собой базу данных, к которой можно обращаться при помощи SQL-запросов. Установка MS Excel не требуется, но обязательно наличие драйвера ODBC, при помощи которого будет осуществляться доступ. Используемый драйвер ODBC определяется при указании строки соединения к файлу. Обычно требуемый драйвер уже установлен на компьютере.

Обмен через ADO заметно быстрее обмена через OLE, но при выгрузке нет возможности использовать функционал Excel для оформления ячеек, разметки страниц, задания формул и т.д.

Пример выгрузки:

// Создание COM-объекта для соединения
Соединение = Новый COMОбъект(«ADODB.Connection»);

// Установка строки соединения
Соединение.ConnectionString = «
|Provider=Microsoft.ACE.OLEDB.12.0;
|Data Source=»+ИмяФайла+«;
|Extended Properties=»»Excel 12.0 XML;HDR=YES»»;»;
Соединение.Open(); // Открытие соединения

// Создание COM-объекта для команды
Команда = Новый COMОбъект(«ADODB.Command»);
Команда.ActiveConnection = Соединение;

// Присвоение текста команды для создания таблицы
Команда.CommandText = «CREATE TABLE [Лист1] (Колонка1 char(255), Колонка2 date, Колонка3 int, Колонка4 float)»;
Команда.Execute(); // Выполнение команды

// Присвоение текста команды для добавления строки таблицы
Команда.CommandText = «INSERT INTO [Лист1] (Колонка1, Колонка2, Колонка3, Колонка4) values (‘абвгдеё’, ‘8/11/2017’, ‘12345’, ‘12345,6789’)»;
Команда.Execute(); // Выполнение команды

// Удаление команды и закрытие соединения
Команда = Неопределено;
Соединение.Close();
Соединение = Неопределено;

Для создания нового листа и формирования его структуры можно воспользоваться объектами ADOX.Catalog и ADOX.Table. В этом случае код примет вид:

// Создание COM-объекта для работы с книгой
Книга = Новый COMОбъект(«ADOX.Catalog»);
Книга.ActiveConnection = Соединение;

// Создание COM-объекта для работы со структурой данных на листе
Таблица = Новый COMОбъект(«ADOX.Table»);
Таблица.Name = «Лист1»;
Таблица.Columns.Append(«Колонка1», 202);
Таблица.Columns.Append(«Колонка2», 7);
Таблица.Columns.Append(«Колонка3», 5);
Таблица.Columns.Append(«Колонка4», 5);

// Создание в книге листа с описанной структурой
Книга.Tables.Append(Таблица);
Таблица = Неопределено;
Книга = Неопределено;

В приведенном примере в методе

Таблица.Columns.Append(«Колонка1», 202);

во втором параметре указывается тип колонки. Параметр необязательный, вот некоторые значения типа колонки:

• 5 — adDouble;
• 6 — adCurrency;
• 7 — adDate;
• 11 — adBoolean;
• 202 — adVarWChar;
• 203 — adLongVarWChar.

Пример чтения:

// Создание COM-объекта для соединения
Соединение = Новый COMОбъект(«ADODB.Connection»);

// Установка строки соединения
Соединение.ConnectionString = «
|Provider=Microsoft.ACE.OLEDB.12.0;
|Data Source=»+ИмяФайла+«;
|Extended Properties=»»Excel 12.0 XML;HDR=YES»»;»;
Соединение.Open(); // Открытие соединения

// Создание COM-объекта для получения выборки
Выборка = Новый COMОбъект(«ADODB.Recordset»);
ТекстЗапроса = «SELECT * FROM [Лист1$]»;

// Выполнение запроса
Выборка.Open(ТекстЗапроса, Соединение);

// Обход результата выборки
Пока НЕ Выборка.EOF() Цикл
ЗначениеКолонки1 = Выборка.Fields.Item(«Колонка1»).Value; // Обращение по имени колонки
ЗначениеКолонки2 = Выборка.Fields.Item(0).Value; // Обращение по индексу колонки
Выборка.MoveNext();
КонецЦикла;

Выборка.Close();
Выборка = Неопределено;
Соединение.Close();
Соединение = Неопределено;

В строке соединения параметр HDR определяет как будет восприниматься первая строка на листе. Возможны варианты:

• YES — первая строка воспринимается как названия колонок. К значениям можно обращаться по имени и по индексу колонки.
• NO — первая строка воспринимается как данные. К значениям можно обращаться только по индексу колонки.

В приведенных примерах рассмотрено лишь несколько объектов ADO. Объектная модель ADO состоит из следующих объектов:

• Connection;
• Command;
• Recordset;
• Record;
• Fields;
• Stream;
• Errors;
• Parameters;
• Properties.

Выгрузка без программирования

Для сохранения данных из 1С в Excel не всегда целесообразно прибегать к программированию. Если в режиме Предприятия пользователь может отобразить требуемые для выгрузки данные, то, их возможно сохранить в Excel без программирования.

Для сохранения табличного документа (например, результата отчета) можно вызвать команду Сохранить или Сохранить как… главного меню.

В открывшемся окне требуется выбрать каталог, имя и формат сохраняемого файла.

Для сохранения данных динамических списков (например, списка номенклатуры) необходимо:

1. Вывести данные в табличный документ при помощи команды Еще ⇒ Вывести список…;
2. Сохранить табличный документ в требуемый формат.